helm/software/components/ng_refiner/nCicUnification.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception UnificationFailure of string Lazy.t;;
  15 exception Uncertain of string Lazy.t;;
  16 exception AssertFailure of string Lazy.t;;
  17
  18 let (===) x y = Pervasives.compare x y = 0 ;;
  19
  20 let uncert_exc metasenv subst context t1 t2 =
  21   Uncertain (lazy (
  22   "Can't unify " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^
  23   " with " ^ NCicPp.ppterm ~metasenv ~subst ~context t2))
  24 ;;
  25
  26 let fail_exc metasenv subst context t1 t2 =
  27   UnificationFailure (lazy (
  28   "Can't unify " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^
  29   " with " ^ NCicPp.ppterm ~metasenv ~subst ~context t2));
  30 ;;
  31
  32 let mk_appl ~upto hd tl =
  33   NCicReduction.head_beta_reduce ~upto
  34     (match hd with
  35     | NCic.Appl l -> NCic.Appl (l@tl)
  36     | _ -> NCic.Appl (hd :: tl))
  37 ;;
  38
  39 exception WrongShape;;
  40
  41 let eta_reduce subst t =
  42   let delift_if_not_occur body =
  43     try
  44         Some (NCicSubstitution.psubst ~avoid_beta_redexes:true
  45           (fun () -> raise WrongShape) [()] body)
  46     with WrongShape -> None
  47   in
  48   let rec eat_lambdas ctx = function
  49     | NCic.Lambda (name, src, tgt) ->
  50         eat_lambdas ((name, src) :: ctx) tgt
  51     | NCic.Meta (i,lc) as t->
  52         (try
  53           let _,_,t,_ = NCicUtils.lookup_subst i subst in
  54           let t = NCicSubstitution.subst_meta lc t in
  55           eat_lambdas ctx t
  56         with Not_found -> ctx, t)
  57     | t -> ctx, t
  58   in
  59   let context_body = eat_lambdas [] t in
  60   let rec aux = function
  61     | [],body -> body
  62     | (name, src)::ctx, (NCic.Appl (hd::[NCic.Rel 1]) as bo) ->
  63         (match delift_if_not_occur hd with
  64         | None -> aux (ctx,NCic.Lambda(name,src, bo))
  65         | Some bo -> aux (ctx,bo))
  66     | (name, src)::ctx, (NCic.Appl args as bo)
  67       when HExtlib.list_last args = NCic.Rel 1 ->
  68         let args, _ = HExtlib.split_nth (List.length args - 1) args in
  69         (match delift_if_not_occur (NCic.Appl args) with
  70         | None -> aux (ctx,NCic.Lambda(name,src, bo))
  71         | Some bo -> aux (ctx,bo))
  72     | (name, src) :: ctx, t ->
  73         aux (ctx,NCic.Lambda(name,src, t))
  74   in
  75     aux context_body
  76 ;;
  77
  78 module C = NCic;;
  79 module Ref = NReference;;
  80
  81 let debug = false;;
  82 let indent = ref "";;
  83 let pp =
  84  if debug then
  85   fun s -> prerr_endline (Printf.sprintf "%-20s" !indent ^ " " ^ Lazy.force s)
  86  else
  87   fun _ -> ()
  88 ;;
  89 let inside c =
  90  indent := !indent ^ String.make 1 c;
  91  if debug then prerr_endline ("{{{" ^ !indent ^ " ")
  92 ;;
  93 let outside ok =
  94  if debug then prerr_endline "}}}";
  95  if not ok then pp (lazy "exception raised!");
  96  try
  97   indent := String.sub !indent 0 (String.length !indent -1)
  98  with
  99   Invalid_argument _ -> indent := "??"; ()
 100 ;;
 101
 102 let ppcontext ~metasenv ~subst c =
 103       "\nctx:\n"^ NCicPp.ppcontext ~metasenv ~subst c
 104 ;;
 105 let ppmetasenv ~subst m = "\nmenv:\n" ^ NCicPp.ppmetasenv ~subst m;;
 106
 107 let ppcontext ~metasenv:_metasenv ~subst:_subst _context = "";;
 108 let ppmetasenv ~subst:_subst _metasenv = "";;
 109
 110 let fix_sorts swap exc t =
 111   let rec aux () = function
 112     | NCic.Sort (NCic.Type u) as orig ->
 113         if swap then
 114          match NCicEnvironment.sup u with
 115          | None ->
 116             prerr_endline ("no sup for " ^ NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] orig) ;
 117             raise exc
 118          | Some u1 -> if u = u1 then orig else NCic.Sort (NCic.Type u1)
 119         else
 120          NCic.Sort (NCic.Type (
 121            match NCicEnvironment.sup NCicEnvironment.type0 with
 122            | Some x -> x
 123            | _ -> assert false))
 124     | NCic.Meta _ as orig -> orig
 125     | t -> NCicUtils.map (fun _ _ -> ()) () aux t
 126   in
 127     aux () t
 128 ;;
 129
 130 let is_locked n subst =
 131    try
 132      match NCicUtils.lookup_subst n subst with
 133      | tag, _,_,_ when NCicMetaSubst.is_out_scope_tag tag -> true
 134      | _ -> false
 135    with NCicUtils.Subst_not_found _ -> false
 136 ;;
 137
 138 let rec mk_irl =
 139  function
 140     0 -> []
 141   | n -> NCic.Rel n :: mk_irl (n-1)
 142 ;;
 143
 144 (* the argument must be a term in whd *)
 145 let rec could_reduce =
 146  function
 147   | C.Meta _ -> true
 148   | C.Appl (C.Const (Ref.Ref (_,Ref.Fix (_,recno,_)))::args)
 149      when List.length args > recno -> could_reduce (List.nth args recno)
 150   | C.Match (_,_,arg,_) -> could_reduce arg
 151   | C.Appl (he::_) -> could_reduce he
 152   | C.Sort _ | C.Rel _ | C.Prod _ | C.Lambda _ | C.Const _ -> false
 153   | C.Appl [] | C.LetIn _ | C.Implicit _ -> assert false
 154 ;;
 155
 156 let rec lambda_intros rdb metasenv subst context t args =
 157  let tty = NCicTypeChecker.typeof ~metasenv ~subst context t in
 158  let argsty =
 159   List.map
 160   (fun arg -> arg, NCicTypeChecker.typeof ~metasenv ~subst context arg) args in
 161  let context_of_args = context in
 162  let rec mk_lambda metasenv subst context n processed_args = function
 163    | [] ->
 164        let metasenv, _, bo, _ =
 165          NCicMetaSubst.mk_meta metasenv context
 166            (`WithType (NCicSubstitution.lift n tty))
 167        in
 168        metasenv, subst, bo
 169    | (arg,ty)::tail ->
 170        pp(lazy("arg{ " ^
 171          NCicPp.ppterm ~metasenv ~subst ~context:context_of_args arg ^  ":" ^
 172          NCicPp.ppterm ~metasenv ~subst ~context:context_of_args ty));
 173        let metasenv, subst, telescopic_ty =
 174          if processed_args = [] then metasenv, subst, ty else
 175          let _ = pp(lazy("delift")) in
 176          delift_type_wrt_terms rdb metasenv subst context_of_args ty
 177            (List.rev processed_args)
 178        in
 179        pp(lazy("arg}"));
 180        let name = "HBeta"^string_of_int n in
 181        let metasenv, subst, bo =
 182         mk_lambda metasenv subst ((name,NCic.Decl telescopic_ty)::context) (n+1)
 183          (arg::processed_args) tail
 184        in
 185         metasenv, subst, NCic.Lambda (name, telescopic_ty, bo)
 186  in
 187  pp(lazy("LAMBDA_INTROS{ " ^
 188    NCicPp.ppterm ~metasenv ~subst ~context t ^  ":" ^
 189    NCicPp.ppterm ~metasenv ~subst ~context tty ^ " over " ^
 190    String.concat "," (List.map (NCicPp.ppterm ~metasenv ~subst ~context)args)));
 191  let rc = mk_lambda metasenv subst context 0 [] argsty in
 192  pp(lazy("LAMBDA_INTROS}"));
 193  rc
 194
 195 and instantiate rdb test_eq_only metasenv subst context n lc t swap =
 196  (*D*)  inside 'I'; try let rc =
 197          pp (lazy(string_of_int n ^ " :=?= "^
 198            NCicPp.ppterm ~metasenv ~subst ~context t));
 199   let unify test_eq_only m s c t1 t2 =
 200     if swap then unify rdb test_eq_only m s c t2 t1
 201     else unify rdb test_eq_only m s c t1 t2
 202   in
 203   let has_tag = List.exists in
 204   let tags, _, ty = NCicUtils.lookup_meta n metasenv in
 205   (* on the types *)
 206   let metasenv, subst, t =
 207     match ty with
 208     | NCic.Implicit (`Typeof _) ->
 209          pp(lazy("meta with no type"));
 210          assert(has_tag ((=)`IsSort) tags);
 211          metasenv, subst, t
 212     | _ ->
 213        let exc_to_be = fail_exc metasenv subst context (NCic.Meta (n,lc)) t in
 214        let t, ty_t =
 215          try t, NCicTypeChecker.typeof ~subst ~metasenv context t
 216          with
 217          | NCicTypeChecker.AssertFailure msg as exn ->
 218               pp(lazy("we try to fix the sort\n"^
 219                 Lazy.force msg^"\n"^NCicPp.ppmetasenv ~subst metasenv));
 220               let ft = fix_sorts swap exc_to_be t in
 221               pp(lazy("unable to fix the sort"));
 222               if ft == t then raise exn;
 223               (try ft, NCicTypeChecker.typeof ~subst ~metasenv context ft
 224                with NCicTypeChecker.AssertFailure _ -> raise exn)
 225          | NCicTypeChecker.TypeCheckerFailure msg ->
 226               prerr_endline (Lazy.force msg);
 227               prerr_endline (NCicPp.ppterm ~metasenv ~subst ~context t);
 228               prerr_endline (ppcontext ~metasenv ~subst context);
 229               prerr_endline (ppmetasenv ~subst metasenv);
 230               assert false
 231        in
 232        match ty_t with
 233        | NCic.Implicit (`Typeof _) ->
 234            raise (UnificationFailure(lazy "trying to unify a term with a type"))
 235        | _ ->
 236           let lty = NCicSubstitution.subst_meta lc ty in
 237           pp (lazy ("On the types: " ^
 238               NCicPp.ppterm ~metasenv ~subst ~context lty ^ " === " ^
 239               NCicPp.ppterm ~metasenv ~subst ~context ty_t));
 240           let metasenv,subst =
 241            try unify test_eq_only metasenv subst context lty ty_t
 242            with NCicEnvironment.BadConstraint _ as exc ->
 243             let ty_t = fix_sorts swap exc_to_be ty_t in
 244              try unify test_eq_only metasenv subst context lty ty_t
 245              with
 246              | NCicEnvironment.BadConstraint _
 247              | UnificationFailure _ -> raise exc
 248           in
 249            metasenv, subst, t
 250   in
 251   (* viral sortification *)
 252   let is_sort metasenv subst context t =
 253     match NCicReduction.whd ~subst context t with
 254     | NCic.Meta (i,_) ->
 255          let tags, _, _ = NCicUtils.lookup_meta i metasenv in
 256          has_tag ((=) `IsSort) tags
 257     | NCic.Sort _ -> true
 258     | _ -> false
 259   in
 260   let rec sortify metasenv subst = function
 261     | NCic.Implicit (`Typeof _) -> assert false
 262     | NCic.Sort _ as t -> metasenv, subst, t, 0
 263     | NCic.Meta (i,_) as t ->
 264          let tags, context, ty = NCicUtils.lookup_meta i metasenv in
 265          if has_tag ((=) `IsSort) tags then metasenv, subst, t, i
 266          else
 267            let ty = NCicReduction.whd ~subst context ty in
 268            let metasenv, subst, ty, _ = sortify metasenv subst ty in
 269            let metasenv, j, m, _ =
 270              NCicMetaSubst.mk_meta metasenv ~attrs:[`IsSort] [] (`WithType ty)
 271            in
 272            pp(lazy("rimpiazzo " ^ string_of_int i^" con "^string_of_int j));
 273            let subst_entry = i, (tags, context, m, ty) in
 274            let subst = subst_entry :: subst in
 275            let metasenv = List.filter (fun x,_ -> i <> x) metasenv in
 276            metasenv, subst, m, j
 277     | t ->
 278          if could_reduce t then raise (Uncertain(lazy "not a sort"))
 279          else raise (UnificationFailure(lazy "not a sort"))
 280   in
 281   let metasenv, subst, _, n =
 282     if has_tag ((=) `IsSort) tags then
 283       let m,s,x,_ = sortify metasenv subst (NCicReduction.whd ~subst context t)
 284       in m,s,x,n
 285     else if is_sort metasenv subst context t then
 286       sortify metasenv subst (NCic.Meta (n,lc))
 287     else
 288       metasenv, subst, NCic.Rel ~-1,n
 289   in
 290   let tags, ctx, ty = NCicUtils.lookup_meta n metasenv in
 291   (* instantiation *)
 292
 293   (* sortification:
 294       - Meta sort === t -> check t is sort or sortify
 295         - add tag `IsSort and set cc=[] to n and its pile
 296         - se gli ancestor non sono sorte o meta... bum...
 297           - cambiare in-place menv
 298           - geneare meta fresh sorta e dall'alto al basso
 299       - Meta _ === Meta sort -> sortify n (i.e. add `IsSort)
 300        *)
 301   pp (lazy(string_of_int n ^ " := 111 = "^
 302     NCicPp.ppterm ~metasenv ~subst ~context t));
 303   let (metasenv, subst), t =
 304     try
 305       NCicMetaSubst.delift
 306        ~unify:(fun m s c t1 t2 ->
 307          let ind = !indent in
 308          let res =
 309            try Some (unify test_eq_only m s c t1 t2 )
 310            with UnificationFailure _ | Uncertain _ -> None
 311          in
 312          indent := ind; res)
 313        metasenv subst context n lc t
 314     with NCicMetaSubst.Uncertain msg ->
 315          pp (lazy ("delift fails: " ^ Lazy.force msg));
 316          raise (Uncertain msg)
 317     | NCicMetaSubst.MetaSubstFailure msg ->
 318          pp (lazy ("delift fails: " ^ Lazy.force msg));
 319          raise (UnificationFailure msg)
 320   in
 321          pp (lazy(string_of_int n ^ " := 222 = "^
 322            NCicPp.ppterm ~metasenv ~subst ~context:ctx t
 323          ^ ppmetasenv ~subst metasenv));
 324   (* Unifying the types may have already instantiated n. *)
 325   try
 326     let _, _,oldt,_ = NCicUtils.lookup_subst n subst in
 327     let oldt = NCicSubstitution.subst_meta lc oldt in
 328     let t = NCicSubstitution.subst_meta lc t in
 329     (* conjecture: always fail --> occur check *)
 330     unify test_eq_only metasenv subst context oldt t
 331   with NCicUtils.Subst_not_found _ ->
 332     (* by cumulativity when unify(?,Type_i)
 333      * we could ? := Type_j with j <= i... *)
 334     let subst = (n, (tags, ctx, t, ty)) :: subst in
 335     pp (lazy ("?"^string_of_int n^" := "^NCicPp.ppterm
 336       ~metasenv ~subst ~context (NCicSubstitution.subst_meta lc t)));
 337     let metasenv =
 338       List.filter (fun (m,_) -> not (n = m)) metasenv
 339     in
 340     metasenv, subst
 341  (*D*)  in outside true; rc with exn -> outside false; raise exn
 342
 343 and unify rdb test_eq_only metasenv subst context t1 t2 =
 344  (*D*) inside 'U'; try let rc =
 345    let fo_unif test_eq_only metasenv subst t1 t2 =
 346     (*D*) inside 'F'; try let rc =
 347      pp (lazy("  " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " ==?== " ^
 348          NCicPp.ppterm ~metasenv ~subst ~context t2 ^ ppmetasenv
 349          ~subst metasenv));
 350      if t1 === t2 then
 351        metasenv, subst
 352      else
 353        match (t1,t2) with
 354        | C.Appl [_], _ | _, C.Appl [_] | C.Appl [], _ | _, C.Appl []
 355        | C.Appl (C.Appl _::_), _ | _, C.Appl (C.Appl _::_) ->
 356            prerr_endline "Appl [Appl _;_] or Appl [] or Appl [_] invariant";
 357            assert false
 358        | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only ->
 359            if NCicEnvironment.universe_leq a b then metasenv, subst
 360            else raise (fail_exc metasenv subst context t1 t2)
 361        | (C.Sort (C.Type a), C.Sort (C.Type b)) ->
 362            if NCicEnvironment.universe_eq a b then metasenv, subst
 363            else raise (fail_exc metasenv subst context t1 t2)
 364        | (C.Sort C.Prop,C.Sort (C.Type _)) ->
 365            if (not test_eq_only) then metasenv, subst
 366            else raise (fail_exc metasenv subst context t1 t2)
 367
 368        | (C.Lambda (name1,s1,t1), C.Lambda(_,s2,t2))
 369        | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 370            let metasenv, subst = unify rdb true metasenv subst context s1 s2 in
 371            unify rdb test_eq_only metasenv subst ((name1, C.Decl s1)::context) t1 t2
 372        | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 373            let metasenv,subst=unify rdb test_eq_only metasenv subst context ty1 ty2 in
 374            let metasenv,subst=unify rdb test_eq_only metasenv subst context s1 s2 in
 375            let context = (name1, C.Def (s1,ty1))::context in
 376            unify rdb test_eq_only metasenv subst context t1 t2
 377
 378        | (C.Meta (n1,(s1,l1 as lc1)),C.Meta (n2,(s2,l2 as lc2))) when n1 = n2 ->
 379           (try
 380            let l1 = NCicUtils.expand_local_context l1 in
 381            let l2 = NCicUtils.expand_local_context l2 in
 382            let metasenv, subst, to_restrict, _ =
 383             List.fold_right2
 384              (fun t1 t2 (metasenv, subst, to_restrict, i) ->
 385                 try
 386                   let metasenv, subst =
 387                    unify rdb test_eq_only metasenv subst context
 388                     (NCicSubstitution.lift s1 t1) (NCicSubstitution.lift s2 t2)
 389                   in
 390                   metasenv, subst, to_restrict, i-1
 391                 with UnificationFailure _ | Uncertain _ ->
 392                   metasenv, subst, i::to_restrict, i-1)
 393              l1 l2 (metasenv, subst, [], List.length l1)
 394            in
 395            if to_restrict <> [] then
 396              let metasenv, subst, _ =
 397                NCicMetaSubst.restrict metasenv subst n1 to_restrict
 398              in
 399                metasenv, subst
 400            else metasenv, subst
 401           with
 402            | Invalid_argument _ -> assert false
 403            | NCicMetaSubst.MetaSubstFailure msg ->
 404               try
 405                 let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 406                 let term1 = NCicSubstitution.subst_meta lc1 term in
 407                 let term2 = NCicSubstitution.subst_meta lc2 term in
 408                   unify rdb test_eq_only metasenv subst context term1 term2
 409               with NCicUtils.Subst_not_found _-> raise (UnificationFailure msg))
 410
 411        | _, NCic.Meta (n, _) when is_locked n subst ->
 412            (let (metasenv, subst), i =
 413               match NCicReduction.whd ~subst context t1 with
 414               | NCic.Appl (NCic.Meta (i,l)::args) ->
 415                  let metasenv, subst, lambda_Mj =
 416                    lambda_intros rdb metasenv subst context t1 args
 417                  in
 418                    unify rdb test_eq_only metasenv subst context
 419                     (C.Meta (i,l)) lambda_Mj,
 420                    i
 421               | NCic.Meta (i,_) -> (metasenv, subst), i
 422               | _ ->
 423                  raise (UnificationFailure (lazy "Locked term vs non
 424                   flexible term; probably not saturated enough yet!"))
 425              in
 426               let t1 = NCicReduction.whd ~subst context t1 in
 427               let j, lj =
 428                 match t1 with NCic.Meta (j,l) -> j, l | _ -> assert false
 429               in
 430               let metasenv, subst =
 431                 instantiate rdb test_eq_only metasenv subst context j lj t2 true
 432               in
 433               (* We need to remove the out_scope_tags to avoid propagation of
 434                  them that triggers again the ad-hoc case *)
 435               let subst =
 436                List.map (fun (i,(tag,ctx,bo,ty)) ->
 437                 let tag =
 438                  List.filter
 439                   (function `InScope | `OutScope _ -> false | _ -> true) tag
 440                 in
 441                   i,(tag,ctx,bo,ty)
 442                 ) subst
 443               in
 444               (try
 445                 let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 446                 let term = eta_reduce subst term in
 447                 let subst = List.filter (fun (j,_) -> j <> i) subst in
 448                 metasenv, ((i, (name, ctx, term, ty)) :: subst)
 449               with Not_found -> assert false))
 450
 451        | C.Meta (n,lc), t ->
 452            (try
 453              let _,_,term,_ = NCicUtils.lookup_subst n subst in
 454              let term = NCicSubstitution.subst_meta lc term in
 455                unify rdb test_eq_only metasenv subst context term t
 456            with NCicUtils.Subst_not_found _->
 457              instantiate rdb test_eq_only metasenv subst context n lc
 458                (NCicReduction.head_beta_reduce ~subst t) false)
 459
 460        | t, C.Meta (n,lc) ->
 461            (try
 462              let _,_,term,_ = NCicUtils.lookup_subst n subst in
 463              let term = NCicSubstitution.subst_meta lc term in
 464                unify rdb test_eq_only metasenv subst context t term
 465            with NCicUtils.Subst_not_found _->
 466              instantiate rdb test_eq_only metasenv subst context n lc
 467               (NCicReduction.head_beta_reduce ~subst t) true)
 468
 469        | NCic.Appl (NCic.Meta (i,l)::args), _ when List.mem_assoc i subst ->
 470             let _,_,term,_ = NCicUtils.lookup_subst i subst in
 471             let term = NCicSubstitution.subst_meta l term in
 472               unify rdb test_eq_only metasenv subst context
 473                 (mk_appl ~upto:(List.length args) term args) t2
 474
 475        | _, NCic.Appl (NCic.Meta (i,l)::args) when List.mem_assoc i subst ->
 476             let _,_,term,_ = NCicUtils.lookup_subst i subst in
 477             let term = NCicSubstitution.subst_meta l term in
 478               unify rdb test_eq_only metasenv subst context t1
 479                 (mk_appl ~upto:(List.length args) term args)
 480
 481        |  NCic.Appl (NCic.Meta (i,_)::_ as l1),
 482           NCic.Appl (NCic.Meta (j,_)::_ as l2) when i=j ->
 483             (try
 484               List.fold_left2
 485                 (fun (metasenv, subst) t1 t2 ->
 486                   unify rdb test_eq_only metasenv subst context t1 t2)
 487                 (metasenv,subst) l1 l2
 488             with Invalid_argument _ ->
 489               raise (fail_exc metasenv subst context t1 t2))
 490
 491        | NCic.Appl (NCic.Meta (i,l)::args), _ ->
 492           let metasenv, subst, lambda_Mj =
 493             lambda_intros rdb metasenv subst context t1 args
 494           in
 495           let metasenv, subst =
 496             unify rdb test_eq_only metasenv subst context
 497               (C.Meta (i,l)) lambda_Mj
 498           in
 499           let metasenv, subst =
 500             unify rdb test_eq_only metasenv subst context t1 t2
 501           in
 502           (try
 503             let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 504             let term = eta_reduce subst term in
 505             let subst = List.filter (fun (j,_) -> j <> i) subst in
 506             metasenv, ((i, (name, ctx, term, ty)) :: subst)
 507           with Not_found -> assert false)
 508
 509        | _, NCic.Appl (NCic.Meta (i,l)::args) ->
 510          let metasenv, subst, lambda_Mj =
 511            lambda_intros rdb metasenv subst context t2 args
 512          in
 513          let metasenv, subst =
 514            unify rdb test_eq_only metasenv subst context
 515             lambda_Mj (C.Meta (i,l))
 516          in
 517          let metasenv, subst =
 518            unify rdb test_eq_only metasenv subst context t1 t2
 519          in
 520          (try
 521            let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 522            let term = eta_reduce subst term in
 523            let subst = List.filter (fun (j,_) -> j <> i) subst in
 524            metasenv, ((i, (name, ctx, term, ty)) :: subst)
 525          with Not_found -> assert false)
 526
 527        (* processing this case here we avoid a useless small delta step *)
 528        | (C.Appl ((C.Const r1) as _hd1::tl1), C.Appl (C.Const r2::tl2))
 529          when Ref.eq r1 r2 ->
 530            let relevance = NCicEnvironment.get_relevance r1 in
 531            let relevance = match r1 with
 532              | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 533                  let relevance =
 534                   try snd (HExtlib.split_nth lno relevance)
 535                   with Failure _ -> []
 536                  in
 537                    HExtlib.mk_list false lno @ relevance
 538              | _ -> relevance
 539            in
 540            let metasenv, subst, _ =
 541              try
 542                List.fold_left2
 543                  (fun (metasenv, subst, relevance) t1 t2 ->
 544                     let b, relevance =
 545                       match relevance with b::tl -> b,tl | _ -> true, [] in
 546                     let metasenv, subst =
 547                       try unify rdb test_eq_only metasenv subst context t1 t2
 548                       with UnificationFailure _ | Uncertain _ when not b ->
 549                         metasenv, subst
 550                     in
 551                       metasenv, subst, relevance)
 552                  (metasenv, subst, relevance) tl1 tl2
 553              with Invalid_argument _ ->
 554                raise (uncert_exc metasenv subst context t1 t2)
 555            in
 556              metasenv, subst
 557
 558        | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 559           C.Match (ref2,outtype2,term2,pl2)) ->
 560            let _,_,itl,_,_ = NCicEnvironment.get_checked_indtys ref1 in
 561            let _,_,ty,_ = List.nth itl tyno in
 562            let rec remove_prods ~subst context ty =
 563              let ty = NCicReduction.whd ~subst context ty in
 564              match ty with
 565              | C.Sort _ -> ty
 566              | C.Prod (name,so,ta) ->
 567                    remove_prods ~subst ((name,(C.Decl so))::context) ta
 568              | _ -> assert false
 569            in
 570            let is_prop =
 571              match remove_prods ~subst [] ty with
 572              | C.Sort C.Prop -> true
 573              | _ -> false
 574            in
 575            if not (Ref.eq ref1 ref2) then
 576              raise (uncert_exc metasenv subst context t1 t2)
 577            else
 578              let metasenv, subst =
 579               unify rdb test_eq_only metasenv subst context outtype1 outtype2 in
 580              let metasenv, subst =
 581                try unify rdb test_eq_only metasenv subst context term1 term2
 582                with UnificationFailure _ | Uncertain _ when is_prop ->
 583                  metasenv, subst
 584              in
 585              (try
 586               List.fold_left2
 587                (fun (metasenv,subst) ->
 588                   unify rdb test_eq_only metasenv subst context)
 589                (metasenv, subst) pl1 pl2
 590              with Invalid_argument _ -> assert false)
 591        | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 592        | _ when NCicUntrusted.metas_of_term subst context t1 = [] &&
 593                 NCicUntrusted.metas_of_term subst context t2 = [] ->
 594                   raise (fail_exc metasenv subst context t1 t2)
 595        | _ -> raise (uncert_exc metasenv subst context t1 t2)
 596      (*D*)  in outside true; rc with exn -> outside false; raise exn
 597     in
 598     let try_hints metasenv subst t1 t2 (* exc*) =
 599     (*D*) inside 'H'; try let rc =
 600 (*
 601       prerr_endline ("\nProblema:\n" ^
 602         NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " =?= " ^
 603         NCicPp.ppterm ~metasenv ~subst ~context t2);
 604 *)
 605       let candidates =
 606         NCicUnifHint.look_for_hint rdb metasenv subst context t1 t2
 607       in
 608       let rec cand_iter = function
 609         | [] -> None (* raise exc *)
 610         | (metasenv,(c1,c2),premises)::tl ->
 611             pp (lazy ("\nProvo il candidato:\n" ^
 612               String.concat "\n"
 613                 (List.map
 614                   (fun (a,b) ->
 615                    NCicPp.ppterm ~metasenv ~subst ~context a ^  " =?= " ^
 616                    NCicPp.ppterm ~metasenv ~subst ~context b) premises) ^
 617               "\n-------------------------------------------\n"^
 618               NCicPp.ppterm ~metasenv ~subst ~context c1 ^  " = " ^
 619               NCicPp.ppterm ~metasenv ~subst ~context c2));
 620             try
 621     (*D*) inside 'K'; try let rc =
 622               let metasenv,subst =
 623                 fo_unif test_eq_only metasenv subst t1 c1 in
 624               let metasenv,subst =
 625                 fo_unif test_eq_only metasenv subst c2 t2 in
 626               let metasenv,subst =
 627                 List.fold_left
 628                   (fun (metasenv, subst) (x,y) ->
 629                      unify rdb test_eq_only metasenv subst context x y)
 630                   (metasenv, subst) premises
 631               in
 632               Some (metasenv, subst)
 633      (*D*)  in outside true; rc with exn -> outside false; raise exn
 634             with
 635               UnificationFailure _ | Uncertain _ ->
 636                 cand_iter tl
 637       in
 638         cand_iter candidates
 639      (*D*)  in outside true; rc with exn -> outside false; raise exn
 640     in
 641     let height_of = function
 642      | NCic.Const (Ref.Ref (_,Ref.Def h))
 643      | NCic.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 644      | NCic.Appl(NCic.Const(Ref.Ref(_,Ref.Def h))::_)
 645      | NCic.Appl(NCic.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 646      | _ -> 0
 647     in
 648     let put_in_whd m1 m2 =
 649       NCicReduction.reduce_machine ~delta:max_int ~subst context m1,
 650       NCicReduction.reduce_machine ~delta:max_int ~subst context m2
 651     in
 652     let small_delta_step ~subst
 653       ((_,_,t1,_ as m1, norm1) as x1) ((_,_,t2,_ as m2, norm2) as x2)
 654     =
 655      assert (not (norm1 && norm2));
 656      if norm1 then
 657       x1,NCicReduction.reduce_machine ~delta:(height_of t2 -1) ~subst context m2
 658      else if norm2 then
 659       NCicReduction.reduce_machine ~delta:(height_of t1 -1) ~subst context m1,x2
 660      else
 661       let h1 = height_of t1 in
 662       let h2 = height_of t2 in
 663       let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 664       NCicReduction.reduce_machine ~delta ~subst context m1,
 665       NCicReduction.reduce_machine ~delta ~subst context m2
 666     in
 667     let rec unif_machines metasenv subst =
 668       function
 669       | ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2),norm2 as m2) ->
 670      (*D*) inside 'M'; try let rc =
 671          pp (lazy("UM: " ^
 672            NCicPp.ppterm ~metasenv ~subst ~context
 673              (NCicReduction.unwind (k1,e1,t1,s1)) ^
 674            " === " ^
 675            NCicPp.ppterm ~metasenv ~subst ~context
 676              (NCicReduction.unwind (k2,e2,t2,s2))));
 677 pp (lazy (string_of_bool norm1 ^ " ?? " ^ string_of_bool norm2));
 678           let relevance = [] (* TO BE UNDERSTOOD
 679             match t1 with
 680             | C.Const r -> NCicEnvironment.get_relevance r
 681             | _ -> [] *) in
 682           let unif_from_stack t1 t2 b metasenv subst =
 683               try
 684                 let t1 = NCicReduction.from_stack ~delta:max_int t1 in
 685                 let t2 = NCicReduction.from_stack ~delta:max_int t2 in
 686                 unif_machines metasenv subst (put_in_whd t1 t2)
 687               with UnificationFailure _ | Uncertain _ when not b ->
 688                 metasenv, subst
 689           in
 690           let rec check_stack l1 l2 r todo =
 691             match l1,l2,r with
 692             | x1::tl1, x2::tl2, r::tr-> check_stack tl1 tl2 tr ((x1,x2,r)::todo)
 693             | x1::tl1, x2::tl2, []-> check_stack tl1 tl2 [] ((x1,x2,true)::todo)
 694             | l1, l2, _ ->
 695                NCicReduction.unwind (k1,e1,t1,List.rev l1),
 696                 NCicReduction.unwind (k2,e2,t2,List.rev l2),
 697                 todo
 698           in
 699         let hh1,hh2,todo=check_stack (List.rev s1) (List.rev s2) relevance [] in
 700         try
 701          let metasenv,subst = fo_unif test_eq_only metasenv subst hh1 hh2 in
 702          List.fold_left
 703           (fun (metasenv,subst) (x1,x2,r) ->
 704             unif_from_stack x1 x2 r metasenv subst
 705           ) (metasenv,subst) todo
 706         with UnificationFailure _ | Uncertain _ when not (norm1 && norm2) ->
 707             unif_machines metasenv subst (small_delta_step ~subst m1 m2)
 708       (*D*)  in outside true; rc with exn -> outside false; raise exn
 709      in
 710      try fo_unif test_eq_only metasenv subst t1 t2
 711      with
 712      | UnificationFailure msg as exn ->
 713           (try
 714             unif_machines metasenv subst
 715              (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 716           with
 717           | UnificationFailure _ -> raise (UnificationFailure msg)
 718           | Uncertain _ -> raise exn)
 719      | Uncertain msg as exn ->
 720        match try_hints metasenv subst t1 t2 with
 721        | Some x -> x
 722        | None ->
 723           try
 724             unif_machines metasenv subst
 725              (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 726           with
 727           | UnificationFailure _ -> raise (UnificationFailure msg)
 728           | Uncertain _ -> raise exn
 729  (*D*)  in outside true; rc with exn -> outside false; raise exn
 730
 731 and delift_type_wrt_terms rdb metasenv subst context t args =
 732   let (metasenv, subst), t =
 733    try
 734     NCicMetaSubst.delift
 735       ~unify:(fun m s c t1 t2 ->
 736          let ind = !indent in
 737          let res =
 738            try Some (unify rdb false m s c t1 t2 )
 739            with UnificationFailure _ | Uncertain _ -> None
 740          in
 741          indent := ind; res)
 742       metasenv subst context 0 (0,NCic.Ctx (args @
 743         List.rev (mk_irl (List.length context)))) t
 744    with NCicMetaSubst.MetaSubstFailure _ -> (metasenv, subst), t
 745   in
 746    metasenv, subst, t
 747 ;;
 748
 749
 750 let unify rdb ?(test_eq_only=false) =
 751   indent := "";
 752   unify rdb test_eq_only;;
 753
 754 let fix_sorts = fix_sorts true (UnificationFailure (lazy "no sup"));;