helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 let debug = ref false;;
  15 let pp x =
  16  if !debug then prerr_endline (Lazy.force x) else ()
  17 ;;
  18
  19 exception Error of string lazy_t * exn option
  20 let fail ?exn msg = raise (Error (msg,exn))
  21
  22 module NRef = NReference
  23
  24 let wrap fname f x =
  25   try f x
  26   with
  27   | MultiPassDisambiguator.DisambiguationError _
  28   | NCicRefiner.RefineFailure _
  29   | NCicUnification.UnificationFailure _
  30   | NCicTypeChecker.TypeCheckerFailure _
  31   | NCicMetaSubst.MetaSubstFailure _ as exn -> fail ~exn (lazy fname)
  32 ;;
  33
  34 class type g_pstatus =
  35  object
  36   inherit NEstatus.g_status
  37   method obj: NCic.obj
  38  end
  39
  40 class pstatus =
  41  fun (o: NCic.obj) ->
  42  object (self)
  43    inherit NEstatus.status
  44    val obj = o
  45    method obj = obj
  46    method set_obj o = {< obj = o >}
  47    method set_pstatus : 'status. #g_pstatus as 'status -> 'self
  48    = fun o -> (self#set_estatus o)#set_obj o#obj
  49   end
  50
  51 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  52 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  53
  54 let pp_tac_status status =
  55   prerr_endline (NCicPp.ppobj status#obj);
  56   prerr_endline ("STACK:\n" ^ Continuationals.Stack.pp status#stack)
  57 ;;
  58
  59 type cic_term = NCic.context * NCic.term
  60 let ctx_of (c,_) = c ;;
  61 let mk_cic_term c t = c,t ;;
  62
  63 let ppterm status t =
  64  let uri,height,metasenv,subst,obj = status#obj in
  65  let context,t = t in
  66   NCicPp.ppterm ~metasenv ~subst ~context t
  67 ;;
  68
  69 let ppcontext status c =
  70  let uri,height,metasenv,subst,obj = status#obj in
  71   NCicPp.ppcontext ~metasenv ~subst c
  72 ;;
  73
  74 let ppterm_and_context status t =
  75  let uri,height,metasenv,subst,obj = status#obj in
  76  let context,t = t in
  77   NCicPp.ppcontext ~metasenv ~subst context ^ "\n ⊢ "^
  78   NCicPp.ppterm ~metasenv ~subst ~context t
  79 ;;
  80
  81 let relocate status destination (source,t as orig) =
  82  pp(lazy("relocate:\n" ^ ppterm_and_context status orig));
  83  pp(lazy("relocate in:\n" ^ ppcontext status destination));
  84  let rc =
  85    if source == destination then status, orig else
  86     let _, _, metasenv, subst, _ = status#obj in
  87     let rec compute_ops ctx = function (* destination, source *)
  88       | (n1, NCic.Decl t1 as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
  89           if n1 = n2 &&
  90              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  91             compute_ops (e::ctx) (cl1,cl2)
  92           else
  93             [ `Delift ctx; `Lift (List.rev ex) ]
  94       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Def (b2,t2))::cl2 ->
  95           if n1 = n2 &&
  96              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  97              NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  98             compute_ops (e::ctx) (cl1,cl2)
  99           else
 100             [ `Delift ctx; `Lift (List.rev ex) ]
 101       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
 102           if n1 = n2 &&
 103              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
 104             compute_ops (e::ctx) (cl1,cl2)
 105           else
 106             [ `Delift ctx; `Lift (List.rev ex) ]
 107       | (n1, NCic.Decl _)::cl1 as ex, (n2, NCic.Def _)::cl2 ->
 108             [ `Delift ctx; `Lift (List.rev ex) ]
 109       | _::_ as ex, [] -> [ `Lift (List.rev ex) ]
 110       | [], _::_ -> [ `Delift ctx ]
 111       | [],[] -> []
 112     in
 113     let ops = compute_ops [] (List.rev destination, List.rev source) in
 114     let rec mk_irl i j = if i > j then [] else NCic.Rel i :: mk_irl (i+1) j in
 115     List.fold_left
 116      (fun (status, (source,t)) -> function
 117       | `Lift extra_ctx ->
 118            let len = List.length extra_ctx in
 119            status, (extra_ctx@source, NCicSubstitution.lift len t)
 120       | `Delift ctx ->
 121             let len_ctx = List.length ctx in
 122             let irl = mk_irl 1 (List.length ctx) in
 123             let lc = List.length source - len_ctx, NCic.Ctx irl in
 124             let u, d, metasenv, subst, o = status#obj in
 125             pp(lazy("delifting as " ^
 126               NCicPp.ppterm ~metasenv ~subst ~context:source
 127                (NCic.Meta (0,lc))));
 128             let (metasenv, subst), t =
 129               NCicMetaSubst.delift
 130                  ~unify:(fun m s c t1 t2 ->
 131                    try Some (NCicUnification.unify status m s c t1 t2)
 132                    with
 133                     | NCicUnification.UnificationFailure _
 134                     | NCicUnification.Uncertain _ -> None)
 135                metasenv subst source 0 lc t
 136             in
 137             let status = status#set_obj (u, d, metasenv, subst, o) in
 138             status, (ctx,t))
 139        (status,orig) ops
 140  in
 141  pp(lazy("relocated: " ^ ppterm (fst rc) (snd rc)));
 142  rc
 143 ;;
 144 let relocate a b c = wrap "relocate" (relocate a b) c;;
 145
 146 let term_of_cic_term s t c =
 147   let s, (_,t) = relocate s c t in
 148   s, t
 149 ;;
 150
 151 let disambiguate status context t ty =
 152  let status, expty =
 153    match ty with
 154    | None -> status, None
 155    | Some ty ->
 156        let status, (_,x) = relocate status context ty in status, Some x
 157  in
 158  let uri,height,metasenv,subst,obj = status#obj in
 159  let metasenv, subst, status, t =
 160    GrafiteDisambiguate.disambiguate_nterm expty status context metasenv subst t
 161  in
 162  let new_pstatus = uri,height,metasenv,subst,obj in
 163   status#set_obj new_pstatus, (context, t)
 164 ;;
 165 let disambiguate a b c d = wrap "disambiguate" (disambiguate a b c) d;;
 166
 167 let typeof status ctx t =
 168   let status, (_,t) = relocate status ctx t in
 169   let _,_,metasenv,subst,_ = status#obj in
 170   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 171   status, (ctx, ty)
 172 ;;
 173 let typeof a b c = wrap "typeof" (typeof a b) c;;
 174
 175 let saturate status ?delta (ctx,t) =
 176   let n,h,metasenv,subst,k = status#obj in
 177   let t,metasenv,args = NCicMetaSubst.saturate ?delta metasenv subst ctx t 0 in
 178   let status = status#set_obj (n,h,metasenv,subst,k) in
 179   status, (ctx,t), List.map (fun x -> ctx,x) args
 180 ;;
 181 let saturate a ?delta b = wrap "saturate" (saturate a ?delta) b;;
 182
 183 let whd status ?delta ctx t =
 184   let status, (_,t) = relocate status ctx t in
 185   let _,_,_,subst,_ = status#obj in
 186   let t = NCicReduction.whd ~subst ?delta ctx t in
 187   status, (ctx, t)
 188 ;;
 189
 190 let normalize status ?delta ctx t =
 191   let status, (_,t) = relocate status ctx t in
 192   let _,_,_,subst,_ = status#obj in
 193   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 194   status, (ctx, t)
 195 ;;
 196
 197 let unify status ctx a b =
 198   let status, (_,a) = relocate status ctx a in
 199   let status, (_,b) = relocate status ctx b in
 200   let n,h,metasenv,subst,o = status#obj in
 201   let metasenv, subst = NCicUnification.unify status metasenv subst ctx a b in
 202    status#set_obj (n,h,metasenv,subst,o)
 203 ;;
 204 let unify a b c d = wrap "unify" (unify a b c) d;;
 205
 206 let fix_sorts status (ctx,t) =
 207  let f () =
 208   let name,height,metasenv,subst,obj = status#obj in
 209   let metasenv, t =
 210     NCicUnification.fix_sorts metasenv subst t in
 211   let status = status#set_obj (name,height,metasenv,subst,obj) in
 212    status, (ctx,t)
 213  in
 214   wrap "fix_sorts" f ()
 215 ;;
 216
 217 let refine status ctx term expty =
 218   let status, (_,term) = relocate status ctx term in
 219   let status, expty =
 220     match expty with
 221       None -> status, None
 222     | Some e ->
 223         let status, (_, e) = relocate status ctx e in status, Some e
 224   in
 225   let name,height,metasenv,subst,obj = status#obj in
 226   let metasenv,subst,t,ty =
 227    NCicRefiner.typeof status metasenv subst ctx term expty
 228   in
 229    status#set_obj (name,height,metasenv,subst,obj), (ctx,t), (ctx,ty)
 230 ;;
 231 let refine a b c d = wrap "refine" (refine a b c) d;;
 232
 233 let get_goalty status g =
 234  let _,_,metasenv,_,_ = status#obj in
 235  try
 236    let _, ctx, ty = NCicUtils.lookup_meta g metasenv in
 237    ctx, ty
 238  with NCicUtils.Meta_not_found _ as exn -> fail ~exn (lazy "get_goalty")
 239 ;;
 240
 241 let get_subst status =
 242   let _,_,_,subst,_ = status#obj in subst
 243 ;;
 244
 245 let to_subst status i entry =
 246  let name,height,metasenv,subst,obj = status#obj in
 247  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 248  let subst = (i, entry) :: subst in
 249   status#set_obj (name,height,metasenv,subst,obj)
 250 ;;
 251
 252 let instantiate status i t =
 253  let _,_,metasenv,_,_ = status#obj in
 254  let gname, context, gty = List.assoc i metasenv in
 255  let status, (_,t), (_,ty) = refine status context t (Some (context,gty)) in
 256   to_subst status i (gname,context,t,ty)
 257 ;;
 258
 259 let instantiate_with_ast status i t =
 260  let _,_,metasenv,_,_ = status#obj in
 261  let gname, context, gty = List.assoc i metasenv in
 262  let ggty = mk_cic_term context gty in
 263  let status, (_,t) = disambiguate status context t (Some ggty) in
 264   to_subst status i (gname,context,t,gty)
 265 ;;
 266
 267 let mk_meta status ?(attrs=[]) ctx bo_or_ty kind =
 268   match bo_or_ty with
 269   | `Decl ty ->
 270       let status, (_,ty) = relocate status ctx ty in
 271       let n,h,metasenv,subst,o = status#obj in
 272       let metasenv, _, instance, _ =
 273         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind
 274       in
 275       let status = status#set_obj (n,h,metasenv,subst,o) in
 276       status, (ctx,instance)
 277   | `Def bo ->
 278       let status, (_,bo_ as bo) = relocate status ctx bo in
 279       let status, (_,ty) = typeof status ctx bo in
 280       let n,h,metasenv,subst,o = status#obj in
 281       let metasenv, metano, instance, _ =
 282         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind in
 283       let attrs,_,_ = NCicUtils.lookup_meta metano metasenv in
 284       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 285       let subst = (metano, (attrs, ctx, bo_, ty)) :: subst in
 286       let status = status#set_obj (n,h,metasenv,subst,o) in
 287       status, (ctx,instance)
 288 ;;
 289
 290 let mk_in_scope status t =
 291   mk_meta status ~attrs:[`InScope] (ctx_of t) (`Def t) `IsTerm
 292 ;;
 293
 294 let mk_out_scope n status t =
 295   mk_meta status ~attrs:[`OutScope n] (ctx_of t) (`Def t) `IsTerm
 296 ;;
 297
 298 (* the following unification problem will be driven by
 299  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 300  *
 301  *   ? args = t
 302  *
 303  *   where argsn = length args and the pattern matches t
 304  *
 305  *  found is called on every selected term to map them
 306  *  postprocess is called on the entire term after selection
 307  *)
 308 let select_term
 309   low_status ~found ~postprocess (context,term) (wanted,path)
 310 =
 311   let is_found status ctx t wanted =
 312     (* we could lift wanted step-by-step *)
 313     pp(lazy("is_found: "^ppterm status (ctx,t)));
 314     try true, unify status ctx (ctx, t) wanted
 315     with
 316     | Error (_, Some (NCicUnification.UnificationFailure _))
 317     | Error (_, Some (NCicUnification.Uncertain _)) -> false, status
 318   in
 319   let match_term status ctx (wanted : cic_term) t =
 320     let rec aux ctx (status,already_found) t =
 321       let b, status = is_found status ctx t wanted in
 322       if b then
 323          let status , (_,t) = found status (ctx, t) in
 324          (status,true),t
 325       else
 326         let _,_,_,subst,_ = status#obj in
 327         match t with
 328         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 329             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 330             aux ctx (status,already_found) t
 331         | NCic.Meta _ -> (status,already_found),t
 332         | _ ->
 333           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 334            (status,already_found) t
 335      in
 336        aux ctx (status,false) t
 337   in
 338   let _,_,_,subst,_ = low_status#obj in
 339   let rec select status ctx pat cic =
 340     match pat, cic with
 341     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 342         let cic =
 343           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 344           NCicSubstitution.subst_meta lc t
 345         in
 346         select status ctx pat cic
 347     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 348         let status, t = select status ctx t1 t2 in
 349         let status, s = select status ctx s1 s2 in
 350         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 351         let status, b = select status ctx b1 b2 in
 352         status, NCic.LetIn (n,t,s,b)
 353     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 354         let status, s = select status ctx s1 s2 in
 355         let ctx = (n, NCic.Decl s2) :: ctx in
 356         let status, t = select status ctx t1 t2 in
 357         status, NCic.Lambda (n,s,t)
 358     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 359         let status, s = select status ctx s1 s2 in
 360         let ctx = (n, NCic.Decl s2) :: ctx in
 361         let status, t = select status ctx t1 t2 in
 362         status, NCic.Prod (n,s,t)
 363     | NCic.Appl l1, NCic.Appl l2 ->
 364         let status, l =
 365            List.fold_left2
 366              (fun (status,l) x y ->
 367               let status, x = select status ctx x y in
 368               status, x::l)
 369              (status,[]) l1 l2
 370         in
 371         status, NCic.Appl (List.rev l)
 372     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 373         let status, t = select status ctx t1 t2 in
 374         let status, ot = select status ctx ot1 ot2 in
 375         let status, pl =
 376            List.fold_left2
 377              (fun (status,l) x y ->
 378               let status, x = select status ctx x y in
 379               status, x::l)
 380              (status,[]) pl1 pl2
 381         in
 382         status, NCic.Match (u,ot,t,List.rev pl)
 383     | NCic.Implicit `Hole, t ->
 384         (match wanted with
 385         | Some wanted ->
 386              let status', wanted = disambiguate status ctx wanted None in
 387              pp(lazy("wanted: "^ppterm status' wanted));
 388              let (status',found), t' = match_term status' ctx wanted t in
 389               if found then status',t' else status,t
 390         | None ->
 391            let (status,_),t = match_term status ctx (ctx,t) t in
 392             status,t)
 393     | NCic.Implicit _, t -> status, t
 394     | _,t ->
 395         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 396           ~context:[] ~subst:[] pat ^ " against " ^
 397           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 398   in
 399   pp(lazy ("select in: "^ppterm low_status (context,term)));
 400   let status, term = select low_status context path term in
 401   let term = (context, term) in
 402   pp(lazy ("postprocess: "^ppterm low_status term));
 403   postprocess status term
 404 ;;
 405
 406 let analyse_indty status ty =
 407  let status, reduct = whd status (ctx_of ty) ty in
 408  let ref, args =
 409   match reduct with
 410    | _,NCic.Const ref -> ref, []
 411    | _,NCic.Appl (NCic.Const (NRef.Ref (_,(NRef.Ind _)) as ref) :: args) ->
 412          ref, args
 413    | _,_ -> fail (lazy ("not an inductive type: " ^ ppterm status ty)) in
 414  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 415  let _,_,_,cl = List.nth tl i in
 416  let consno = List.length cl in
 417  let left, right = HExtlib.split_nth lno args in
 418  status, (ref, consno, left, right)
 419 ;;
 420
 421 let apply_subst status ctx t =
 422  let status, (_,t) = relocate status ctx t in
 423  let _,_,_,subst,_ = status#obj in
 424   status, (ctx, NCicUntrusted.apply_subst subst ctx t)
 425 ;;
 426
 427 let apply_subst_context status ~fix_projections ctx =
 428  let _,_,_,subst,_ = status#obj in
 429   NCicUntrusted.apply_subst_context ~fix_projections subst ctx
 430 ;;
 431
 432 let metas_of_term status (context,t) =
 433  let _,_,_,subst,_ = status#obj in
 434  NCicUntrusted.metas_of_term subst context t
 435 ;;
 436
 437 (* ============= move this elsewhere ====================*)
 438
 439 class type ['stack] g_status =
 440  object
 441   inherit g_pstatus
 442   method stack: 'stack
 443  end
 444
 445 class ['stack] status =
 446  fun (o: NCic.obj) (s: 'stack) ->
 447  object (self)
 448    inherit (pstatus o)
 449    val stack = s
 450    method stack = stack
 451    method set_stack s = {< stack = s >}
 452    method set_status : 'status. 'stack #g_status as 'status -> 'self
 453    = fun o -> (self#set_pstatus o)#set_stack o#stack
 454   end
 455
 456 class type lowtac_status = [unit] status
 457
 458 type 'status lowtactic = #lowtac_status as 'status -> int -> 'status
 459
 460 class type tac_status = [Continuationals.Stack.t] status
 461
 462 type 'status tactic = #tac_status as 'status -> 'status
 463
 464 module NCicInverseRelIndexable : Discrimination_tree.Indexable
 465 with type input = cic_term and type constant_name = NUri.uri = struct
 466
 467 open Discrimination_tree
 468
 469 type input = cic_term
 470 type constant_name = NUri.uri
 471
 472 let ppelem = function
 473   | Constant (uri,arity) ->
 474       "("^NUri.name_of_uri uri ^ "," ^ string_of_int arity^")"
 475   | Bound (i,arity) ->
 476       "("^string_of_int i ^ "," ^ string_of_int arity^")"
 477   | Variable -> "?"
 478   | Proposition -> "Prop"
 479   | Datatype -> "Type"
 480   | Dead -> "Dead"
 481 ;;
 482
 483 let string_of_path l = String.concat "." (List.map ppelem l) ;;
 484
 485 let path_string_of (ctx,t) =
 486   let len_ctx = List.length ctx in
 487   let rec aux arity = function
 488     | NCic.Appl ((NCic.Meta _|NCic.Implicit _)::_) -> [Variable]
 489     | NCic.Appl (NCic.Lambda _ :: _) -> [Variable] (* maybe we should b-reduce *)
 490     | NCic.Appl [] -> assert false
 491     | NCic.Appl (hd::tl) ->
 492         aux (List.length tl) hd @ List.flatten (List.map (aux 0) tl)
 493     | NCic.Lambda _ | NCic.Prod _ -> [Variable]
 494         (* I think we should CicSubstitution.subst Implicit t *)
 495     | NCic.LetIn _ -> [Variable] (* z-reduce? *)
 496     | NCic.Meta _ | NCic.Implicit _ -> assert (arity = 0); [Variable]
 497     | NCic.Rel i -> [Bound (len_ctx - i, arity)]
 498     | NCic.Sort (NCic.Prop) -> assert (arity=0); [Proposition]
 499     | NCic.Sort _ -> assert (arity=0); [Datatype]
 500     | NCic.Const (NReference.Ref (u,_)) -> [Constant (u, arity)]
 501     | NCic.Match _ -> [Dead]
 502   in
 503   let path = aux 0 t in
 504 (*   prerr_endline (string_of_path path); *)
 505   path
 506 ;;
 507
 508 let compare e1 e2 =
 509   match e1,e2 with
 510   | Constant (u1,a1),Constant (u2,a2) ->
 511        let x = NUri.compare u1 u2 in
 512        if x = 0 then Pervasives.compare a1 a2 else x
 513   | e1,e2 -> Pervasives.compare e1 e2
 514 ;;
 515
 516
 517 end
 518
 519 module Ncic_termOT : Set.OrderedType with type t = cic_term =
 520  struct
 521    type t = cic_term
 522    let compare = Pervasives.compare
 523  end
 524
 525 module Ncic_termSet : Set.S with type elt = cic_term = Set.Make(Ncic_termOT)
 526
 527 module InvRelDiscriminationTree =
 528    Discrimination_tree.Make(NCicInverseRelIndexable)(Ncic_termSet)
 529