helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 exception Error of string lazy_t * exn option
  15 let fail ?exn msg = raise (Error (msg,exn))
  16
  17 let wrap f x =
  18   try f x
  19   with
  20   | MultiPassDisambiguator.DisambiguationError _
  21   | NCicRefiner.RefineFailure _
  22   | NCicUnification.UnificationFailure _
  23   | NCicTypeChecker.TypeCheckerFailure _
  24   | NCicMetaSubst.MetaSubstFailure _ as exn -> fail ~exn (lazy "")
  25 ;;
  26
  27 class pstatus =
  28  fun (o: NCic.obj) ->
  29   object
  30    inherit NEstatus.status
  31    val obj = o
  32    method obj = obj
  33    method set_obj o = {< obj = o >}
  34   end
  35
  36 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  37 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  38
  39 let pp_status status =
  40   prerr_endline (NCicPp.ppobj status#obj)
  41 ;;
  42
  43 type cic_term = NCic.conjecture (* name, context, term *)
  44 let ctx_of (_,c,_) = c ;;
  45
  46 let relocate status destination (name,source,t as orig) =
  47  if source == destination then status, orig else
  48   let u, d, metasenv, subst, o = status#obj in
  49   let rec lcp ctx j i = function
  50     | (n1, NCic.Decl t1 as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  51         if n1 = n2 &&
  52            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  53           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  54         else
  55           HExtlib.mk_list (NCic.Appl
  56             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  57     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Def (b2,t2))::cl2 ->
  58         if n1 = n2 &&
  59            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  60            NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  61           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  62         else
  63           HExtlib.mk_list (NCic.Appl
  64             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  65     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  66         if n1 = n2 &&
  67            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  68           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  69         else
  70           HExtlib.mk_list (NCic.Appl
  71             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  72     | (n1, NCic.Decl _)::cl1, (n2, NCic.Def _)::cl2 -> assert false
  73     | _::_, [] ->
  74           HExtlib.mk_list (NCic.Appl
  75             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  76     | _ -> []
  77   in
  78   let lc =
  79     lcp [] (List.length destination) (List.length source)
  80       (List.rev destination, List.rev source)
  81   in
  82   let lc = (0,NCic.Ctx (List.rev lc)) in
  83   let (metasenv, subst), t =
  84     NCicMetaSubst.delift
  85        ~unify:(fun m s c t1 t2 ->
  86          try Some (NCicUnification.unify status m s c t1 t2)
  87          with
  88           | NCicUnification.UnificationFailure _
  89           | NCicUnification.Uncertain _ -> None)
  90      metasenv subst source 0 lc t
  91   in
  92   let status = status#set_obj (u, d, metasenv, subst, o) in
  93   status, (name, destination, t)
  94 ;;
  95 let relocate a b c = wrap (relocate a b) c;;
  96
  97 let term_of_cic_term s t c =
  98   let s, (_,_,t) = relocate s c t in
  99   s, t
 100 ;;
 101
 102 let ppterm status t =
 103  let uri,height,metasenv,subst,obj = status#obj in
 104  let _,context,t = t in
 105   NCicPp.ppterm ~metasenv ~subst ~context t
 106 ;;
 107
 108 let disambiguate status t ty context =
 109  let status, expty =
 110    match ty with
 111    | None -> status, None
 112    | Some ty ->
 113        let status, (_,_,x) = relocate status context ty in status, Some x
 114  in
 115  let uri,height,metasenv,subst,obj = status#obj in
 116  let metasenv, subst, status, t =
 117    GrafiteDisambiguate.disambiguate_nterm expty status context metasenv subst t
 118  in
 119  let new_pstatus = uri,height,metasenv,subst,obj in
 120   status#set_obj new_pstatus, (None, context, t)
 121 ;;
 122 let disambiguate a b c d = wrap (disambiguate a b c) d;;
 123
 124 let typeof status ctx t =
 125   let status, (_,_,t) = relocate status ctx t in
 126   let _,_,metasenv,subst,_ = status#obj in
 127   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 128   status, (None, ctx, ty)
 129 ;;
 130 let typeof a b c = wrap (typeof a b) c;;
 131
 132 let whd status ?delta ctx t =
 133   let status, (name,_,t) = relocate status ctx t in
 134   let _,_,_,subst,_ = status#obj in
 135   let t = NCicReduction.whd ~subst ?delta ctx t in
 136   status, (name, ctx, t)
 137 ;;
 138
 139 let normalize status ?delta ctx t =
 140   let status, (name,_,t) = relocate status ctx t in
 141   let _,_,_,subst,_ = status#obj in
 142   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 143   status, (name, ctx, t)
 144 ;;
 145
 146 let unify status ctx a b =
 147   let status, (_,_,a) = relocate status ctx a in
 148   let status, (_,_,b) = relocate status ctx b in
 149   let n,h,metasenv,subst,o = status#obj in
 150   let metasenv, subst = NCicUnification.unify status metasenv subst ctx a b in
 151    status#set_obj (n,h,metasenv,subst,o)
 152 ;;
 153 let unify a b c d = wrap (unify a b c) d;;
 154
 155 let refine status ctx term expty =
 156   let status, (nt,_,term) = relocate status ctx term in
 157   let status, ne, expty =
 158     match expty with None -> status, None, None
 159     | Some e ->
 160         let status, (n,_, e) = relocate status ctx e in status, n, Some e
 161   in
 162   let name,height,metasenv,subst,obj = status#obj in
 163   let metasenv,subst,t,ty =
 164    NCicRefiner.typeof status metasenv subst ctx term expty
 165   in
 166    status#set_obj (name,height,metasenv,subst,obj), (nt,ctx,t), (ne,ctx,ty)
 167 ;;
 168 let refine a b c d = wrap (refine a b c) d;;
 169
 170 let get_goalty status g =
 171  let _,_,metasenv,_,_ = status#obj in
 172  List.assoc g metasenv
 173 ;;
 174
 175 let instantiate status i t =
 176  let (gname, context, _ as gty) = get_goalty status i in
 177  let status, (_,_,t), (_,_,ty) =
 178    refine status (ctx_of gty) t (Some gty)
 179  in
 180
 181  let name,height,metasenv,subst,obj = status#obj in
 182  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 183  let subst = (i, (gname, context, t, ty)) :: subst in
 184   status#set_obj (name,height,metasenv,subst,obj)
 185 ;;
 186
 187 let mk_meta status ?name ctx bo_or_ty =
 188   match bo_or_ty with
 189   | `Decl ty ->
 190       let status, (_,_,ty) = relocate status ctx ty in
 191       let n,h,metasenv,subst,o = status#obj in
 192       let metasenv, _, instance, _ =
 193         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty)
 194       in
 195       let status = status#set_obj (n,h,metasenv,subst,o) in
 196       status, (None,ctx,instance)
 197   | `Def bo ->
 198       let status, (_,_,bo_ as bo) = relocate status ctx bo in
 199       let status, (_,_,ty) = typeof status ctx bo in
 200       let n,h,metasenv,subst,o = status#obj in
 201       let metasenv, metano, instance, _ =
 202         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty) in
 203       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 204       let subst = (metano, (name, ctx, bo_, ty)) :: subst in
 205       let status = status#set_obj (n,h,metasenv,subst,o) in
 206       status, (None,ctx,instance)
 207 ;;
 208
 209 let mk_in_scope status t =
 210   mk_meta status ~name:NCicMetaSubst.in_scope_tag (ctx_of t) (`Def t)
 211 ;;
 212
 213 let mk_out_scope n status t =
 214   mk_meta status ~name:(NCicMetaSubst.out_scope_tag n) (ctx_of t) (`Def t)
 215 ;;
 216
 217 (* the following unification problem will be driven by
 218  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 219  *
 220  *   ? args = t
 221  *
 222  *   where argsn = length args and the pattern matches t
 223  *
 224  *  found is called on every selected term to map them
 225  *  postprocess is called on the entire term after selection
 226  *)
 227 let select_term
 228   low_status ~found ~postprocess (name,context,term) (wanted,path)
 229 =
 230   let is_found status ctx t wanted =
 231     (* we could lift wanted step-by-step *)
 232     try true, unify status ctx (None, ctx, t) wanted
 233     with
 234     | NCicUnification.UnificationFailure _
 235     | NCicUnification.Uncertain _ -> false, status
 236   in
 237   let match_term status ctx (wanted : cic_term) t =
 238     let rec aux ctx (status,already_found) t =
 239       let b, status = is_found status ctx t wanted in
 240       if b then
 241          let status , (_,_,t) = found status (None, ctx, t) in
 242          (status,true),t
 243       else
 244         let _,_,_,subst,_ = status#obj in
 245         match t with
 246         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 247             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 248             aux ctx (status,already_found) t
 249         | NCic.Meta _ -> (status,already_found),t
 250         | _ ->
 251           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 252            (status,already_found) t
 253      in
 254        aux ctx (status,false) t
 255   in
 256   let _,_,_,subst,_ = low_status#obj in
 257   let rec select status ctx pat cic =
 258     match pat, cic with
 259     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 260         let cic =
 261           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 262           NCicSubstitution.subst_meta lc t
 263         in
 264         select status ctx pat cic
 265     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 266         let status, t = select status ctx t1 t2 in
 267         let status, s = select status ctx s1 s2 in
 268         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 269         let status, b = select status ctx b1 b2 in
 270         status, NCic.LetIn (n,t,s,b)
 271     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 272         let status, s = select status ctx s1 s2 in
 273         let ctx = (n, NCic.Decl s2) :: ctx in
 274         let status, t = select status ctx t1 t2 in
 275         status, NCic.Lambda (n,s,t)
 276     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 277         let status, s = select status ctx s1 s2 in
 278         let ctx = (n, NCic.Decl s2) :: ctx in
 279         let status, t = select status ctx t1 t2 in
 280         status, NCic.Prod (n,s,t)
 281     | NCic.Appl l1, NCic.Appl l2 ->
 282         let status, l =
 283            List.fold_left2
 284              (fun (status,l) x y ->
 285               let status, x = select status ctx x y in
 286               status, x::l)
 287              (status,[]) l1 l2
 288         in
 289         status, NCic.Appl (List.rev l)
 290     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 291         let status, t = select status ctx t1 t2 in
 292         let status, ot = select status ctx ot1 ot2 in
 293         let status, pl =
 294            List.fold_left2
 295              (fun (status,l) x y ->
 296               let status, x = select status ctx x y in
 297               status, x::l)
 298              (status,[]) pl1 pl2
 299         in
 300         status, NCic.Match (u,ot,t,List.rev pl)
 301     | NCic.Implicit `Hole, t ->
 302         (match wanted with
 303         | Some wanted ->
 304              let status', wanted = disambiguate status wanted None ctx in
 305              let (status',found), t' = match_term status' ctx wanted t in
 306               if found then status',t' else status,t
 307         | None ->
 308            let (status,_),t = match_term status ctx (None,ctx,t) t in
 309             status,t)
 310     | NCic.Implicit _, t -> status, t
 311     | _,t ->
 312         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 313           ~context:[] ~subst:[] pat ^ " against " ^
 314           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 315   in
 316   let status, term = select low_status context path term in
 317   let term = (name, context, term) in
 318   postprocess status term
 319 ;;
 320
 321 let analyse_indty status ty =
 322  let status, reduct = whd status (ctx_of ty) ty in
 323  let ref, args =
 324   match reduct with
 325    | _,_,NCic.Const ref -> ref, []
 326    | _,_,NCic.Appl (NCic.Const ref :: args) -> ref, args
 327    | _,_,_ -> fail (lazy ("not an inductive type")) in
 328  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 329  let _,_,_,cl = List.nth tl i in
 330  let consno = List.length cl in
 331  let left, right = HExtlib.split_nth lno args in
 332  status, (ref, consno, left, right)
 333 ;;
 334
 335 let mk_cic_term c t = None,c,t ;;
 336
 337 let apply_subst status ctx t =
 338  let status, (name,_,t) = relocate status ctx t in
 339  let _,_,_,subst,_ = status#obj in
 340   status, (name, ctx, NCicUntrusted.apply_subst subst ctx t)
 341 ;;
 342
 343 (* ============= move this elsewhere ====================*)
 344
 345 class ['stack] status =
 346  fun (o: NCic.obj) (s: 'stack) ->
 347   object
 348    inherit (pstatus o)
 349    val stack = s
 350    method stack = stack
 351    method set_stack s = {< stack = s >}
 352   end
 353
 354 class type lowtac_status = [unit] status
 355
 356 type 'status lowtactic = #lowtac_status as 'status -> int -> 'status
 357
 358 class type tac_status = [Continuationals.Stack.t] status
 359
 360 type 'status tactic = #tac_status as 'status -> 'status
 361