helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 exception Error of string lazy_t
  15 let fail msg = raise (Error msg)
  16
  17 type lowtac_status = {
  18         pstatus : NCic.obj;
  19         estatus : NEstatus.extra_status;
  20 }
  21
  22 type lowtactic = lowtac_status -> int -> lowtac_status
  23
  24 type tac_status = {
  25         gstatus : Continuationals.Stack.t;
  26         istatus : lowtac_status;
  27 }
  28
  29 type tactic = tac_status -> tac_status
  30
  31 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  32 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  33
  34 let pp_tac_status status =
  35   prerr_endline (NCicPp.ppobj status.istatus.pstatus)
  36 ;;
  37
  38 let pp_lowtac_status status =
  39   prerr_endline "--------------------------------------------";
  40   prerr_endline (NCicPp.ppobj status.pstatus)
  41 ;;
  42
  43 type cic_term = NCic.conjecture (* name, context, term *)
  44 let ctx_of (_,c,_) = c ;;
  45
  46 let relocate status destination (name,source,t as orig) =
  47  if source == destination then status, orig else
  48   let u, d, metasenv, subst, o = status.pstatus in
  49   let rec lcp ctx j i = function
  50     | (n1, NCic.Decl t1 as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  51         if n1 = n2 &&
  52            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  53           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  54         else
  55           HExtlib.mk_list (NCic.Appl
  56             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  57     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Def (b2,t2))::cl2 ->
  58         if n1 = n2 &&
  59            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  60            NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  61           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  62         else
  63           HExtlib.mk_list (NCic.Appl
  64             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  65     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  66         if n1 = n2 &&
  67            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  68           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  69         else
  70           HExtlib.mk_list (NCic.Appl
  71             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  72     | (n1, NCic.Decl _)::cl1, (n2, NCic.Def _)::cl2 -> assert false
  73     | _::_, [] ->
  74           HExtlib.mk_list (NCic.Appl
  75             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  76     | _ -> []
  77   in
  78   let lc =
  79     lcp [] (List.length destination) (List.length source)
  80       (List.rev destination, List.rev source)
  81   in
  82   let lc = (0,NCic.Ctx (List.rev lc)) in
  83   let (metasenv, subst), t =
  84     NCicMetaSubst.delift
  85        ~unify:(fun m s c t1 t2 ->
  86          try Some (NCicUnification.unify
  87            status.estatus.NEstatus.rstatus m s c t1 t2)
  88          with
  89           | NCicUnification.UnificationFailure _
  90           | NCicUnification.Uncertain _ -> None)
  91      metasenv subst source 0 lc t
  92   in
  93   let status = { status with pstatus = u, d, metasenv, subst, o } in
  94   status, (name, destination, t)
  95 ;;
  96
  97 let term_of_cic_term s t c =
  98   let s, (_,_,t) = relocate s c t in
  99   s, t
 100 ;;
 101
 102 let ppterm status t =
 103  let uri,height,metasenv,subst,obj = status.pstatus in
 104  let _,context,t = t in
 105   NCicPp.ppterm ~metasenv ~subst ~context t
 106 ;;
 107
 108 let disambiguate status t ty context =
 109  let status, expty =
 110    match ty with
 111    | None -> status, None
 112    | Some ty ->
 113        let status, (_,_,x) = relocate status context ty in status, Some x
 114  in
 115  let uri,height,metasenv,subst,obj = status.pstatus in
 116  let metasenv, subst, estatus, t =
 117    GrafiteDisambiguate.disambiguate_nterm expty
 118     status.estatus context metasenv subst t
 119  in
 120  let new_pstatus = uri,height,metasenv,subst,obj in
 121  { estatus = estatus; pstatus = new_pstatus }, (None, context, t)
 122 ;;
 123
 124 let typeof status ctx t =
 125   let status, (_,_,t) = relocate status ctx t in
 126   let _,_,metasenv,subst,_ = status.pstatus in
 127   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 128   status, (None, ctx, ty)
 129 ;;
 130
 131 let whd status ?delta ctx t =
 132   let status, (name,_,t) = relocate status ctx t in
 133   let _,_,_,subst,_ = status.pstatus in
 134   let t = NCicReduction.whd ~subst ?delta ctx t in
 135   status, (name, ctx, t)
 136 ;;
 137
 138 let normalize status ?delta ctx t =
 139   let status, (name,_,t) = relocate status ctx t in
 140   let _,_,_,subst,_ = status.pstatus in
 141   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 142   status, (name, ctx, t)
 143 ;;
 144
 145 let unify status ctx a b =
 146   let status, (_,_,a) = relocate status ctx a in
 147   let status, (_,_,b) = relocate status ctx b in
 148   let n,h,metasenv,subst,o = status.pstatus in
 149   let metasenv, subst =
 150     NCicUnification.unify status.estatus.NEstatus.rstatus metasenv subst ctx a b
 151   in
 152   { status with pstatus = n,h,metasenv,subst,o }
 153 ;;
 154
 155 let refine status ctx term expty =
 156   let status, (nt,_,term) = relocate status ctx term in
 157   let status, ne, expty =
 158     match expty with None -> status, None, None
 159     | Some e ->
 160         let status, (n,_, e) = relocate status ctx e in status, n, Some e
 161   in
 162   let name,height,metasenv,subst,obj = status.pstatus in
 163   let rdb = status.estatus.NEstatus.rstatus in
 164   let metasenv, subst, t, ty =
 165    NCicRefiner.typeof rdb metasenv subst ctx term expty
 166   in
 167   { status with pstatus = name,height,metasenv,subst,obj },
 168   (nt,ctx,t), (ne,ctx,ty)
 169 ;;
 170
 171 let get_goalty (status : lowtac_status) (g : int) =
 172  let _,_,metasenv,_,_ = status.pstatus in
 173  List.assoc g metasenv
 174 ;;
 175
 176 let instantiate status i t =
 177  let (gname, context, _ as gty) = get_goalty status i in
 178  let status, (_,_,t), (_,_,ty) =
 179    refine status (ctx_of gty) t (Some gty)
 180  in
 181
 182  let name,height,metasenv,subst,obj = status.pstatus in
 183  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 184  let subst = (i, (gname, context, t, ty)) :: subst in
 185  { status with pstatus = (name,height,metasenv,subst,obj) }
 186 ;;
 187
 188 let mk_meta status ?name ctx bo_or_ty =
 189   match bo_or_ty with
 190   | `Decl ty ->
 191       let status, (_,_,ty) = relocate status ctx ty in
 192       let n,h,metasenv,subst,o = status.pstatus in
 193       let metasenv, _, instance, _ =
 194         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty)
 195       in
 196       let status = { status with pstatus = n,h,metasenv,subst,o } in
 197       status, (None,ctx,instance)
 198   | `Def bo ->
 199       let status, (_,_,bo_ as bo) = relocate status ctx bo in
 200       let status, (_,_,ty) = typeof status ctx bo in
 201       let n,h,metasenv,subst,o = status.pstatus in
 202       let metasenv, metano, instance, _ =
 203         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty) in
 204       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 205       let subst = (metano, (name, ctx, bo_, ty)) :: subst in
 206       let status = { status with pstatus = n,h,metasenv,subst,o } in
 207       status, (None,ctx,instance)
 208 ;;
 209
 210 let mk_in_scope status t =
 211   mk_meta status ~name:NCicMetaSubst.in_scope_tag (ctx_of t) (`Def t)
 212 ;;
 213
 214 let mk_out_scope n status t =
 215   mk_meta status ~name:(NCicMetaSubst.out_scope_tag n) (ctx_of t) (`Def t)
 216 ;;
 217
 218 (* the following unification problem will be driven by
 219  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 220  *
 221  *   ? args = t
 222  *
 223  *   where argsn = length args and the pattern matches t
 224  *
 225  *  found is called on every selected term to map them
 226  *  postprocess is called on the entire term after selection
 227  *)
 228 let select_term
 229   low_status ~found ~postprocess (name,context,term) (wanted,path)
 230 =
 231   let is_found status ctx t wanted =
 232     (* we could lift wanted step-by-step *)
 233     try true, unify status ctx (None, ctx, t) wanted
 234     with
 235     | NCicUnification.UnificationFailure _
 236     | NCicUnification.Uncertain _ -> false, status
 237   in
 238   let match_term status ctx (wanted : cic_term) t =
 239     let rec aux ctx (status,already_found) t =
 240       let b, status = is_found status ctx t wanted in
 241       if b then
 242          let status , (_,_,t) = found status (None, ctx, t) in
 243          (status,true),t
 244       else
 245         let _,_,_,subst,_ = status.pstatus in
 246         match t with
 247         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 248             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 249             aux ctx (status,already_found) t
 250         | NCic.Meta _ -> (status,already_found),t
 251         | _ ->
 252           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 253            (status,already_found) t
 254      in
 255        aux ctx (status,false) t
 256   in
 257   let _,_,_,subst,_ = low_status.pstatus in
 258   let rec select status ctx pat cic =
 259     match pat, cic with
 260     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 261         let cic =
 262           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 263           NCicSubstitution.subst_meta lc t
 264         in
 265         select status ctx pat cic
 266     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 267         let status, t = select status ctx t1 t2 in
 268         let status, s = select status ctx s1 s2 in
 269         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 270         let status, b = select status ctx b1 b2 in
 271         status, NCic.LetIn (n,t,s,b)
 272     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 273         let status, s = select status ctx s1 s2 in
 274         let ctx = (n, NCic.Decl s2) :: ctx in
 275         let status, t = select status ctx t1 t2 in
 276         status, NCic.Lambda (n,s,t)
 277     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 278         let status, s = select status ctx s1 s2 in
 279         let ctx = (n, NCic.Decl s2) :: ctx in
 280         let status, t = select status ctx t1 t2 in
 281         status, NCic.Prod (n,s,t)
 282     | NCic.Appl l1, NCic.Appl l2 ->
 283         let status, l =
 284            List.fold_left2
 285              (fun (status,l) x y ->
 286               let status, x = select status ctx x y in
 287               status, x::l)
 288              (status,[]) l1 l2
 289         in
 290         status, NCic.Appl (List.rev l)
 291     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 292         let status, t = select status ctx t1 t2 in
 293         let status, ot = select status ctx ot1 ot2 in
 294         let status, pl =
 295            List.fold_left2
 296              (fun (status,l) x y ->
 297               let status, x = select status ctx x y in
 298               status, x::l)
 299              (status,[]) pl1 pl2
 300         in
 301         status, NCic.Match (u,ot,t,List.rev pl)
 302     | NCic.Implicit `Hole, t ->
 303         (match wanted with
 304         | Some wanted ->
 305              let status', wanted = disambiguate status wanted None ctx in
 306              let (status',found), t' = match_term status' ctx wanted t in
 307               if found then status',t' else status,t
 308         | None ->
 309            let (status,_),t = match_term status ctx (None,ctx,t) t in
 310             status,t)
 311     | NCic.Implicit _, t -> status, t
 312     | _,t ->
 313         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 314           ~context:[] ~subst:[] pat ^ " against " ^
 315           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 316   in
 317   let status, term = select low_status context path term in
 318   let term = (name, context, term) in
 319   postprocess status term
 320 ;;
 321
 322 let analyse_indty status ty =
 323  let status, reduct = whd status (ctx_of ty) ty in
 324  let ref, args =
 325   match reduct with
 326    | _,_,NCic.Const ref -> ref, []
 327    | _,_,NCic.Appl (NCic.Const ref :: args) -> ref, args
 328    | _,_,_ -> fail (lazy ("not an inductive type")) in
 329  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 330  let _,_,_,cl = List.nth tl i in
 331  let consno = List.length cl in
 332  let left, right = HExtlib.split_nth lno args in
 333  status, (ref, consno, left, right)
 334 ;;
 335
 336 let mk_cic_term c t = None,c,t ;;
 337
 338 let apply_subst status ctx t =
 339  let status, (name,_,t) = relocate status ctx t in
 340  let _,_,_,subst,_ = status.pstatus in
 341   status, (name, ctx, NCicUntrusted.apply_subst subst ctx t)
 342 ;;