helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 exception Error of string lazy_t
  15 let fail msg = raise (Error msg)
  16
  17 type lowtac_status = {
  18         pstatus : NCic.obj;
  19         lstatus : LexiconEngine.status
  20 }
  21
  22 type lowtactic = lowtac_status -> int -> lowtac_status
  23
  24 type tac_status = {
  25         gstatus : Continuationals.Stack.t;
  26         istatus : lowtac_status;
  27 }
  28
  29 type tactic = tac_status -> tac_status
  30
  31 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  32 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  33
  34 let pp_tac_status status =
  35   prerr_endline (NCicPp.ppobj status.istatus.pstatus)
  36 ;;
  37
  38 let pp_lowtac_status status =
  39   prerr_endline "--------------------------------------------";
  40   prerr_endline (NCicPp.ppobj status.pstatus)
  41 ;;
  42
  43 type cic_term = NCic.conjecture (* name, context, term *)
  44 let ctx_of (_,c,_) = c ;;
  45
  46 let relocate status destination (name,source,t as orig) =
  47  if source == destination then status, orig else
  48   let u, d, metasenv, subst, o = status.pstatus in
  49   let rec lcp ctx j i = function
  50     | (n1, NCic.Decl t1 as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  51         if n1 = n2 &&
  52            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  53           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  54         else
  55           HExtlib.mk_list (NCic.Appl
  56             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  57     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Def (b2,t2))::cl2 ->
  58         if n1 = n2 &&
  59            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  60            NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  61           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  62         else
  63           HExtlib.mk_list (NCic.Appl
  64             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  65     | (n1, NCic.Def (b1,t1) as e)::cl1, (n2, NCic.Decl t2)::cl2 ->
  66         if n1 = n2 &&
  67            NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  68           NCic.Rel i :: lcp (e::ctx)(j-1) (i-1) (cl1,cl2)
  69         else
  70           HExtlib.mk_list (NCic.Appl
  71             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  72     | (n1, NCic.Decl _)::cl1, (n2, NCic.Def _)::cl2 -> assert false
  73     | _::_, [] ->
  74           HExtlib.mk_list (NCic.Appl
  75             [NCic.Sort NCic.Prop; NCic.Sort NCic.Prop]) j
  76     | _ -> []
  77   in
  78   let lc =
  79     lcp [] (List.length destination) (List.length source)
  80       (List.rev destination, List.rev source)
  81   in
  82   let lc = (0,NCic.Ctx (List.rev lc)) in
  83   let db = NCicUnifHint.db () in (* XXX fixme *)
  84   let (metasenv, subst), t =
  85     NCicMetaSubst.delift
  86        ~unify:(fun m s c t1 t2 ->
  87          try Some (NCicUnification.unify db m s c t1 t2)
  88          with
  89           | NCicUnification.UnificationFailure _
  90           | NCicUnification.Uncertain _ -> None)
  91      metasenv subst source 0 lc t
  92   in
  93   let status = { status with pstatus = u, d, metasenv, subst, o } in
  94   status, (name, destination, t)
  95 ;;
  96
  97 let term_of_cic_term s t c =
  98   let s, (_,_,t) = relocate s c t in
  99   s, t
 100 ;;
 101
 102 let ppterm status t =
 103  let uri,height,metasenv,subst,obj = status.pstatus in
 104  let _,context,t = t in
 105   NCicPp.ppterm ~metasenv ~subst ~context t
 106 ;;
 107
 108 let disambiguate status t ty context =
 109  let status, expty =
 110    match ty with
 111    | None -> status, None
 112    | Some ty ->
 113        let status, (_,_,x) = relocate status context ty in status, Some x
 114  in
 115  let uri,height,metasenv,subst,obj = status.pstatus in
 116  let metasenv, subst, lexicon_status, t =
 117    GrafiteDisambiguate.disambiguate_nterm expty
 118     status.lstatus context metasenv subst t
 119  in
 120  let new_pstatus = uri,height,metasenv,subst,obj in
 121  { lstatus = lexicon_status; pstatus = new_pstatus }, (None, context, t)
 122 ;;
 123
 124 let typeof status ctx t =
 125   let status, (_,_,t) = relocate status ctx t in
 126   let _,_,metasenv,subst,_ = status.pstatus in
 127   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 128   status, (None, ctx, ty)
 129 ;;
 130
 131 let whd status ?delta ctx t =
 132   let status, (name,_,t) = relocate status ctx t in
 133   let _,_,_,subst,_ = status.pstatus in
 134   let t = NCicReduction.whd ~subst ?delta ctx t in
 135   status, (name, ctx, t)
 136 ;;
 137
 138 let normalize status ?delta ctx t =
 139   let status, (name,_,t) = relocate status ctx t in
 140   let _,_,_,subst,_ = status.pstatus in
 141   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 142   status, (name, ctx, t)
 143 ;;
 144
 145 let unify status ctx a b =
 146   let status, (_,_,a) = relocate status ctx a in
 147   let status, (_,_,b) = relocate status ctx b in
 148   let n,h,metasenv,subst,o = status.pstatus in
 149   let metasenv, subst =
 150     NCicUnification.unify (NCicUnifHint.db ()) metasenv subst ctx a b
 151   in
 152   { status with pstatus = n,h,metasenv,subst,o }
 153 ;;
 154
 155 let refine status ctx term expty =
 156   let status, (nt,_,term) = relocate status ctx term in
 157   let status, ne, expty =
 158     match expty with None -> status, None, None
 159     | Some e ->
 160         let status, (n,_, e) = relocate status ctx e in status, n, Some e
 161   in
 162   let name,height,metasenv,subst,obj = status.pstatus in
 163   let db = NCicUnifHint.db () in (* XXX fixme *)
 164   let coercion_db = NCicCoercion.db () in
 165   let look_for_coercion = NCicCoercion.look_for_coercion coercion_db in
 166   let metasenv, subst, t, ty =
 167    NCicRefiner.typeof db ~look_for_coercion metasenv subst ctx term expty
 168   in
 169   { status with pstatus = name,height,metasenv,subst,obj },
 170   (nt,ctx,t), (ne,ctx,ty)
 171 ;;
 172
 173 let get_goalty (status : lowtac_status) (g : int) =
 174  let _,_,metasenv,_,_ = status.pstatus in
 175  List.assoc g metasenv
 176 ;;
 177
 178 let instantiate status i t =
 179  let (gname, context, _ as gty) = get_goalty status i in
 180  let status, (_,_,t), (_,_,ty) =
 181    refine status (ctx_of gty) t (Some gty)
 182  in
 183
 184  let name,height,metasenv,subst,obj = status.pstatus in
 185  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 186  let subst = (i, (gname, context, t, ty)) :: subst in
 187  { status with pstatus = (name,height,metasenv,subst,obj) }
 188 ;;
 189
 190 let mk_meta status ?name ctx bo_or_ty =
 191   match bo_or_ty with
 192   | `Decl ty ->
 193       let status, (_,_,ty) = relocate status ctx ty in
 194       let n,h,metasenv,subst,o = status.pstatus in
 195       let metasenv, _, instance, _ =
 196         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty)
 197       in
 198       let status = { status with pstatus = n,h,metasenv,subst,o } in
 199       status, (None,ctx,instance)
 200   | `Def bo ->
 201       let status, (_,_,bo_ as bo) = relocate status ctx bo in
 202       let status, (_,_,ty) = typeof status ctx bo in
 203       let n,h,metasenv,subst,o = status.pstatus in
 204       let metasenv, metano, instance, _ =
 205         NCicMetaSubst.mk_meta ?name metasenv ctx (`WithType ty) in
 206       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 207       let subst = (metano, (name, ctx, bo_, ty)) :: subst in
 208       let status = { status with pstatus = n,h,metasenv,subst,o } in
 209       status, (None,ctx,instance)
 210 ;;
 211
 212 let mk_in_scope status t =
 213   mk_meta status ~name:NCicMetaSubst.in_scope_tag (ctx_of t) (`Def t)
 214 ;;
 215
 216 let mk_out_scope n status t =
 217   mk_meta status ~name:(NCicMetaSubst.out_scope_tag n) (ctx_of t) (`Def t)
 218 ;;
 219
 220 (* the following unification problem will be driven by
 221  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 222  *
 223  *   ? args = t
 224  *
 225  *   where argsn = length args and the pattern matches t
 226  *
 227  *  found is called on every selected term to map them
 228  *  postprocess is called on the entire term after selection
 229  *)
 230 let select_term
 231   low_status ~found ~postprocess (name,context,term) (wanted,path)
 232 =
 233   let is_found status ctx t wanted =
 234     (* we could lift wanted step-by-step *)
 235     try true, unify status ctx (None, ctx, t) wanted
 236     with
 237     | NCicUnification.UnificationFailure _
 238     | NCicUnification.Uncertain _ -> false, status
 239   in
 240   let match_term status ctx (wanted : cic_term) t =
 241     let rec aux ctx (status,already_found) t =
 242       let b, status = is_found status ctx t wanted in
 243       if b then
 244          let status , (_,_,t) = found status (None, ctx, t) in
 245          (status,true),t
 246       else
 247         let _,_,_,subst,_ = status.pstatus in
 248         match t with
 249         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 250             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 251             aux ctx (status,already_found) t
 252         | NCic.Meta _ -> (status,already_found),t
 253         | _ ->
 254           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 255            (status,already_found) t
 256      in
 257        aux ctx (status,false) t
 258   in
 259   let _,_,_,subst,_ = low_status.pstatus in
 260   let rec select status ctx pat cic =
 261     match pat, cic with
 262     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 263         let cic =
 264           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 265           NCicSubstitution.subst_meta lc t
 266         in
 267         select status ctx pat cic
 268     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 269         let status, t = select status ctx t1 t2 in
 270         let status, s = select status ctx s1 s2 in
 271         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 272         let status, b = select status ctx b1 b2 in
 273         status, NCic.LetIn (n,t,s,b)
 274     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 275         let status, s = select status ctx s1 s2 in
 276         let ctx = (n, NCic.Decl s2) :: ctx in
 277         let status, t = select status ctx t1 t2 in
 278         status, NCic.Lambda (n,s,t)
 279     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 280         let status, s = select status ctx s1 s2 in
 281         let ctx = (n, NCic.Decl s2) :: ctx in
 282         let status, t = select status ctx t1 t2 in
 283         status, NCic.Prod (n,s,t)
 284     | NCic.Appl l1, NCic.Appl l2 ->
 285         let status, l =
 286            List.fold_left2
 287              (fun (status,l) x y ->
 288               let status, x = select status ctx x y in
 289               status, x::l)
 290              (status,[]) l1 l2
 291         in
 292         status, NCic.Appl (List.rev l)
 293     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 294         let status, t = select status ctx t1 t2 in
 295         let status, ot = select status ctx ot1 ot2 in
 296         let status, pl =
 297            List.fold_left2
 298              (fun (status,l) x y ->
 299               let status, x = select status ctx x y in
 300               status, x::l)
 301              (status,[]) pl1 pl2
 302         in
 303         status, NCic.Match (u,ot,t,List.rev pl)
 304     | NCic.Implicit `Hole, t ->
 305         (match wanted with
 306         | Some wanted ->
 307              let status', wanted = disambiguate status wanted None ctx in
 308              let (status',found), t' = match_term status' ctx wanted t in
 309               if found then status',t' else status,t
 310         | None ->
 311            let (status,_),t = match_term status ctx (None,ctx,t) t in
 312             status,t)
 313     | NCic.Implicit _, t -> status, t
 314     | _,t ->
 315         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 316           ~context:[] ~subst:[] pat ^ " against " ^
 317           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 318   in
 319   let status, term = select low_status context path term in
 320   let term = (name, context, term) in
 321   postprocess status term
 322 ;;
 323
 324 let analyse_indty status ty =
 325  let status, reduct = whd status (ctx_of ty) ty in
 326  let ref, args =
 327   match reduct with
 328    | _,_,NCic.Const ref -> ref, []
 329    | _,_,NCic.Appl (NCic.Const ref :: args) -> ref, args
 330    | _,_,_ -> fail (lazy ("not an inductive type")) in
 331  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 332  let _,_,_,cl = List.nth tl i in
 333  let consno = List.length cl in
 334  let left, right = HExtlib.split_nth lno args in
 335  status, (ref, consno, left, right)
 336 ;;
 337
 338 let mk_cic_term c t = None,c,t ;;
 339
 340 let apply_subst status ctx t =
 341  let status, (name,_,t) = relocate status ctx t in
 342  let _,_,_,subst,_ = status.pstatus in
 343   status, (name, ctx, NCicUntrusted.apply_subst subst ctx t)
 344 ;;