helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 let debug = ref false;;
  15 let pp x =
  16  if !debug then prerr_endline (Lazy.force x) else ()
  17 ;;
  18
  19 exception Error of string lazy_t * exn option
  20 let fail ?exn msg = raise (Error (msg,exn))
  21
  22 module NRef = NReference
  23
  24 let wrap fname f x =
  25   try f x
  26   with
  27   | MultiPassDisambiguator.DisambiguationError _
  28   | NCicRefiner.RefineFailure _
  29   | NCicUnification.UnificationFailure _
  30   | NCicTypeChecker.TypeCheckerFailure _
  31   | NCicMetaSubst.MetaSubstFailure _ as exn -> fail ~exn (lazy fname)
  32 ;;
  33
  34 class pstatus =
  35  fun (o: NCic.obj) ->
  36   object
  37    inherit NEstatus.status
  38    val obj = o
  39    method obj = obj
  40    method set_obj o = {< obj = o >}
  41   end
  42
  43 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  44 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  45
  46 let pp_status status =
  47   pp (lazy (NCicPp.ppobj status#obj))
  48 ;;
  49
  50 type cic_term = NCic.context * NCic.term
  51 let ctx_of (c,_) = c ;;
  52 let mk_cic_term c t = c,t ;;
  53
  54 let ppterm status t =
  55  let uri,height,metasenv,subst,obj = status#obj in
  56  let context,t = t in
  57   NCicPp.ppterm ~metasenv ~subst ~context t
  58 ;;
  59
  60 let ppcontext status c =
  61  let uri,height,metasenv,subst,obj = status#obj in
  62   NCicPp.ppcontext ~metasenv ~subst c
  63 ;;
  64
  65 let ppterm_and_context status t =
  66  let uri,height,metasenv,subst,obj = status#obj in
  67  let context,t = t in
  68   NCicPp.ppcontext ~metasenv ~subst context ^ "\n ⊢ "^
  69   NCicPp.ppterm ~metasenv ~subst ~context t
  70 ;;
  71
  72 let relocate status destination (source,t as orig) =
  73  pp(lazy("relocate:\n" ^ ppterm_and_context status orig));
  74  pp(lazy("relocate in:\n" ^ ppcontext status destination));
  75  let rc =
  76    if source == destination then status, orig else
  77     let _, _, metasenv, subst, _ = status#obj in
  78     let rec compute_ops ctx = function (* destination, source *)
  79       | (n1, NCic.Decl t1 as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
  80           if n1 = n2 &&
  81              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  82             compute_ops (e::ctx) (cl1,cl2)
  83           else
  84             [ `Delift ctx; `Lift (List.rev ex) ]
  85       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Def (b2,t2))::cl2 ->
  86           if n1 = n2 &&
  87              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  88              NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  89             compute_ops (e::ctx) (cl1,cl2)
  90           else
  91             [ `Delift ctx; `Lift (List.rev ex) ]
  92       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
  93           if n1 = n2 &&
  94              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  95             compute_ops (e::ctx) (cl1,cl2)
  96           else
  97             [ `Delift ctx; `Lift (List.rev ex) ]
  98       | (n1, NCic.Decl _)::cl1 as ex, (n2, NCic.Def _)::cl2 ->
  99             [ `Delift ctx; `Lift (List.rev ex) ]
 100       | _::_ as ex, [] -> [ `Lift (List.rev ex) ]
 101       | [], _::_ -> [ `Delift ctx ]
 102       | [],[] -> []
 103     in
 104     let ops = compute_ops [] (List.rev destination, List.rev source) in
 105     let rec mk_irl i j = if i > j then [] else NCic.Rel i :: mk_irl (i+1) j in
 106     List.fold_left
 107      (fun (status, (source,t)) -> function
 108       | `Lift extra_ctx ->
 109            let len = List.length extra_ctx in
 110            status, (extra_ctx@source, NCicSubstitution.lift len t)
 111       | `Delift ctx ->
 112             let len_ctx = List.length ctx in
 113             let irl = mk_irl 1 (List.length ctx) in
 114             let lc = List.length source - len_ctx, NCic.Ctx irl in
 115             let u, d, metasenv, subst, o = status#obj in
 116             pp(lazy("delifting as " ^
 117               NCicPp.ppterm ~metasenv ~subst ~context:source
 118                (NCic.Meta (0,lc))));
 119             let (metasenv, subst), t =
 120               NCicMetaSubst.delift
 121                  ~unify:(fun m s c t1 t2 ->
 122                    try Some (NCicUnification.unify status m s c t1 t2)
 123                    with
 124                     | NCicUnification.UnificationFailure _
 125                     | NCicUnification.Uncertain _ -> None)
 126                metasenv subst source 0 lc t
 127             in
 128             let status = status#set_obj (u, d, metasenv, subst, o) in
 129             status, (ctx,t))
 130        (status,orig) ops
 131  in
 132  pp(lazy("relocated: " ^ ppterm (fst rc) (snd rc)));
 133  rc
 134 ;;
 135 let relocate a b c = wrap "relocate" (relocate a b) c;;
 136
 137 let term_of_cic_term s t c =
 138   let s, (_,t) = relocate s c t in
 139   s, t
 140 ;;
 141
 142 let disambiguate status context t ty =
 143  let status, expty =
 144    match ty with
 145    | None -> status, None
 146    | Some ty ->
 147        let status, (_,x) = relocate status context ty in status, Some x
 148  in
 149  let uri,height,metasenv,subst,obj = status#obj in
 150  let metasenv, subst, status, t =
 151    GrafiteDisambiguate.disambiguate_nterm expty status context metasenv subst t
 152  in
 153  let new_pstatus = uri,height,metasenv,subst,obj in
 154   status#set_obj new_pstatus, (context, t)
 155 ;;
 156 let disambiguate a b c d = wrap "disambiguate" (disambiguate a b c) d;;
 157
 158 let typeof status ctx t =
 159   let status, (_,t) = relocate status ctx t in
 160   let _,_,metasenv,subst,_ = status#obj in
 161   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 162   status, (ctx, ty)
 163 ;;
 164 let typeof a b c = wrap "typeof" (typeof a b) c;;
 165
 166 let saturate status ?delta (ctx,t) =
 167   let n,h,metasenv,subst,k = status#obj in
 168   let t,metasenv,args = NCicMetaSubst.saturate ?delta metasenv subst ctx t 0 in
 169   let status = status#set_obj (n,h,metasenv,subst,k) in
 170   status, (ctx,t), List.map (fun x -> ctx,x) args
 171 ;;
 172 let saturate a ?delta b = wrap "saturate" (saturate a ?delta) b;;
 173
 174 let whd status ?delta ctx t =
 175   let status, (_,t) = relocate status ctx t in
 176   let _,_,_,subst,_ = status#obj in
 177   let t = NCicReduction.whd ~subst ?delta ctx t in
 178   status, (ctx, t)
 179 ;;
 180
 181 let normalize status ?delta ctx t =
 182   let status, (_,t) = relocate status ctx t in
 183   let _,_,_,subst,_ = status#obj in
 184   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 185   status, (ctx, t)
 186 ;;
 187
 188 let unify status ctx a b =
 189   let status, (_,a) = relocate status ctx a in
 190   let status, (_,b) = relocate status ctx b in
 191   let n,h,metasenv,subst,o = status#obj in
 192   let metasenv, subst = NCicUnification.unify status metasenv subst ctx a b in
 193    status#set_obj (n,h,metasenv,subst,o)
 194 ;;
 195 let unify a b c d = wrap "unify" (unify a b c) d;;
 196
 197 let fix_sorts status (ctx,t) =
 198  let f () =
 199   let name,height,metasenv,subst,obj = status#obj in
 200   let metasenv, t =
 201     NCicUnification.fix_sorts metasenv subst t in
 202   let status = status#set_obj (name,height,metasenv,subst,obj) in
 203    status, (ctx,t)
 204  in
 205   wrap "fix_sorts" f ()
 206 ;;
 207
 208 let refine status ctx term expty =
 209   let status, (_,term) = relocate status ctx term in
 210   let status, expty =
 211     match expty with
 212       None -> status, None
 213     | Some e ->
 214         let status, (_, e) = relocate status ctx e in status, Some e
 215   in
 216   let name,height,metasenv,subst,obj = status#obj in
 217   let metasenv,subst,t,ty =
 218    NCicRefiner.typeof status metasenv subst ctx term expty
 219   in
 220    status#set_obj (name,height,metasenv,subst,obj), (ctx,t), (ctx,ty)
 221 ;;
 222 let refine a b c d = wrap "refine" (refine a b c) d;;
 223
 224 let get_goalty status g =
 225  let _,_,metasenv,_,_ = status#obj in
 226  try
 227    let _, ctx, ty = NCicUtils.lookup_meta g metasenv in
 228    ctx, ty
 229  with NCicUtils.Meta_not_found _ as exn -> fail ~exn (lazy "get_goalty")
 230 ;;
 231
 232 let to_subst status i entry =
 233  let name,height,metasenv,subst,obj = status#obj in
 234  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 235  let subst = (i, entry) :: subst in
 236   status#set_obj (name,height,metasenv,subst,obj)
 237 ;;
 238
 239 let instantiate status i t =
 240  let _,_,metasenv,_,_ = status#obj in
 241  let gname, context, gty = List.assoc i metasenv in
 242  let status, (_,t), (_,ty) = refine status context t (Some (context,gty)) in
 243   to_subst status i (gname,context,t,ty)
 244 ;;
 245
 246 let instantiate_with_ast status i t =
 247  let _,_,metasenv,_,_ = status#obj in
 248  let gname, context, gty = List.assoc i metasenv in
 249  let ggty = mk_cic_term context gty in
 250  let status, (_,t) = disambiguate status context t (Some ggty) in
 251   to_subst status i (gname,context,t,gty)
 252 ;;
 253
 254 let mk_meta status ?(attrs=[]) ctx bo_or_ty kind =
 255   match bo_or_ty with
 256   | `Decl ty ->
 257       let status, (_,ty) = relocate status ctx ty in
 258       let n,h,metasenv,subst,o = status#obj in
 259       let metasenv, _, instance, _ =
 260         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind
 261       in
 262       let status = status#set_obj (n,h,metasenv,subst,o) in
 263       status, (ctx,instance)
 264   | `Def bo ->
 265       let status, (_,bo_ as bo) = relocate status ctx bo in
 266       let status, (_,ty) = typeof status ctx bo in
 267       let n,h,metasenv,subst,o = status#obj in
 268       let metasenv, metano, instance, _ =
 269         NCicMetaSubst.mk_meta ~attrs metasenv ctx ~with_type:ty kind in
 270       let attrs,_,_ = NCicUtils.lookup_meta metano metasenv in
 271       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 272       let subst = (metano, (attrs, ctx, bo_, ty)) :: subst in
 273       let status = status#set_obj (n,h,metasenv,subst,o) in
 274       status, (ctx,instance)
 275 ;;
 276
 277 let mk_in_scope status t =
 278   mk_meta status ~attrs:[`InScope] (ctx_of t) (`Def t) `IsTerm
 279 ;;
 280
 281 let mk_out_scope n status t =
 282   mk_meta status ~attrs:[`OutScope n] (ctx_of t) (`Def t) `IsTerm
 283 ;;
 284
 285 (* the following unification problem will be driven by
 286  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 287  *
 288  *   ? args = t
 289  *
 290  *   where argsn = length args and the pattern matches t
 291  *
 292  *  found is called on every selected term to map them
 293  *  postprocess is called on the entire term after selection
 294  *)
 295 let select_term
 296   low_status ~found ~postprocess (context,term) (wanted,path)
 297 =
 298   let is_found status ctx t wanted =
 299     (* we could lift wanted step-by-step *)
 300     pp(lazy("is_found: "^ppterm status (ctx,t)));
 301     try true, unify status ctx (ctx, t) wanted
 302     with
 303     | Error (_, Some (NCicUnification.UnificationFailure _))
 304     | Error (_, Some (NCicUnification.Uncertain _)) -> false, status
 305   in
 306   let match_term status ctx (wanted : cic_term) t =
 307     let rec aux ctx (status,already_found) t =
 308       let b, status = is_found status ctx t wanted in
 309       if b then
 310          let status , (_,t) = found status (ctx, t) in
 311          (status,true),t
 312       else
 313         let _,_,_,subst,_ = status#obj in
 314         match t with
 315         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 316             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 317             aux ctx (status,already_found) t
 318         | NCic.Meta _ -> (status,already_found),t
 319         | _ ->
 320           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 321            (status,already_found) t
 322      in
 323        aux ctx (status,false) t
 324   in
 325   let _,_,_,subst,_ = low_status#obj in
 326   let rec select status ctx pat cic =
 327     match pat, cic with
 328     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 329         let cic =
 330           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 331           NCicSubstitution.subst_meta lc t
 332         in
 333         select status ctx pat cic
 334     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 335         let status, t = select status ctx t1 t2 in
 336         let status, s = select status ctx s1 s2 in
 337         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 338         let status, b = select status ctx b1 b2 in
 339         status, NCic.LetIn (n,t,s,b)
 340     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 341         let status, s = select status ctx s1 s2 in
 342         let ctx = (n, NCic.Decl s2) :: ctx in
 343         let status, t = select status ctx t1 t2 in
 344         status, NCic.Lambda (n,s,t)
 345     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 346         let status, s = select status ctx s1 s2 in
 347         let ctx = (n, NCic.Decl s2) :: ctx in
 348         let status, t = select status ctx t1 t2 in
 349         status, NCic.Prod (n,s,t)
 350     | NCic.Appl l1, NCic.Appl l2 ->
 351         let status, l =
 352            List.fold_left2
 353              (fun (status,l) x y ->
 354               let status, x = select status ctx x y in
 355               status, x::l)
 356              (status,[]) l1 l2
 357         in
 358         status, NCic.Appl (List.rev l)
 359     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 360         let status, t = select status ctx t1 t2 in
 361         let status, ot = select status ctx ot1 ot2 in
 362         let status, pl =
 363            List.fold_left2
 364              (fun (status,l) x y ->
 365               let status, x = select status ctx x y in
 366               status, x::l)
 367              (status,[]) pl1 pl2
 368         in
 369         status, NCic.Match (u,ot,t,List.rev pl)
 370     | NCic.Implicit `Hole, t ->
 371         (match wanted with
 372         | Some wanted ->
 373              let status', wanted = disambiguate status ctx wanted None in
 374              pp(lazy("wanted: "^ppterm status' wanted));
 375              let (status',found), t' = match_term status' ctx wanted t in
 376               if found then status',t' else status,t
 377         | None ->
 378            let (status,_),t = match_term status ctx (ctx,t) t in
 379             status,t)
 380     | NCic.Implicit _, t -> status, t
 381     | _,t ->
 382         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 383           ~context:[] ~subst:[] pat ^ " against " ^
 384           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 385   in
 386   pp(lazy ("select in: "^ppterm low_status (context,term)));
 387   let status, term = select low_status context path term in
 388   let term = (context, term) in
 389   pp(lazy ("postprocess: "^ppterm low_status term));
 390   postprocess status term
 391 ;;
 392
 393 let analyse_indty status ty =
 394  let status, reduct = whd status (ctx_of ty) ty in
 395  let ref, args =
 396   match reduct with
 397    | _,NCic.Const ref -> ref, []
 398    | _,NCic.Appl (NCic.Const (NRef.Ref (_,(NRef.Ind _)) as ref) :: args) ->
 399          ref, args
 400    | _,_ -> fail (lazy ("not an inductive type")) in
 401  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 402  let _,_,_,cl = List.nth tl i in
 403  let consno = List.length cl in
 404  let left, right = HExtlib.split_nth lno args in
 405  status, (ref, consno, left, right)
 406 ;;
 407
 408 let apply_subst status ctx t =
 409  let status, (_,t) = relocate status ctx t in
 410  let _,_,_,subst,_ = status#obj in
 411   status, (ctx, NCicUntrusted.apply_subst subst ctx t)
 412 ;;
 413
 414 let metas_of_term status (context,t) =
 415  let _,_,_,subst,_ = status#obj in
 416  NCicUntrusted.metas_of_term subst context t
 417 ;;
 418
 419 (* ============= move this elsewhere ====================*)
 420
 421 class ['stack] status =
 422  fun (o: NCic.obj) (s: 'stack) ->
 423   object
 424    inherit (pstatus o)
 425    val stack = s
 426    method stack = stack
 427    method set_stack s = {< stack = s >}
 428   end
 429
 430 class type lowtac_status = [unit] status
 431
 432 type 'status lowtactic = #lowtac_status as 'status -> int -> 'status
 433
 434 class type tac_status = [Continuationals.Stack.t] status
 435
 436 type 'status tactic = #tac_status as 'status -> 'status
 437
 438 module NCicInverseRelIndexable : Discrimination_tree.Indexable
 439 with type input = cic_term and type constant_name = NUri.uri = struct
 440
 441 open Discrimination_tree
 442
 443 type input = cic_term
 444 type constant_name = NUri.uri
 445
 446 let ppelem = function
 447   | Constant (uri,arity) ->
 448       "("^NUri.name_of_uri uri ^ "," ^ string_of_int arity^")"
 449   | Bound (i,arity) ->
 450       "("^string_of_int i ^ "," ^ string_of_int arity^")"
 451   | Variable -> "?"
 452   | Proposition -> "Prop"
 453   | Datatype -> "Type"
 454   | Dead -> "Dead"
 455 ;;
 456
 457 let string_of_path l = String.concat "." (List.map ppelem l) ;;
 458
 459 let path_string_of (ctx,t) =
 460   let len_ctx = List.length ctx in
 461   let rec aux arity = function
 462     | NCic.Appl ((NCic.Meta _|NCic.Implicit _)::_) -> [Variable]
 463     | NCic.Appl (NCic.Lambda _ :: _) -> [Variable] (* maybe we should b-reduce *)
 464     | NCic.Appl [] -> assert false
 465     | NCic.Appl (hd::tl) ->
 466         aux (List.length tl) hd @ List.flatten (List.map (aux 0) tl)
 467     | NCic.Lambda _ | NCic.Prod _ -> [Variable]
 468         (* I think we should CicSubstitution.subst Implicit t *)
 469     | NCic.LetIn _ -> [Variable] (* z-reduce? *)
 470     | NCic.Meta _ | NCic.Implicit _ -> assert (arity = 0); [Variable]
 471     | NCic.Rel i -> [Bound (len_ctx - i, arity)]
 472     | NCic.Sort (NCic.Prop) -> assert (arity=0); [Proposition]
 473     | NCic.Sort _ -> assert (arity=0); [Datatype]
 474     | NCic.Const (NReference.Ref (u,_)) -> [Constant (u, arity)]
 475     | NCic.Match _ -> [Dead]
 476   in
 477   let path = aux 0 t in
 478 (*   prerr_endline (string_of_path path); *)
 479   path
 480 ;;
 481
 482 let compare e1 e2 =
 483   match e1,e2 with
 484   | Constant (u1,a1),Constant (u2,a2) ->
 485        let x = NUri.compare u1 u2 in
 486        if x = 0 then Pervasives.compare a1 a2 else x
 487   | e1,e2 -> Pervasives.compare e1 e2
 488 ;;
 489
 490
 491 end
 492
 493 module Ncic_termOT : Set.OrderedType with type t = cic_term =
 494  struct
 495    type t = cic_term
 496    let compare = Pervasives.compare
 497  end
 498
 499 module Ncic_termSet : Set.S with type elt = cic_term = Set.Make(Ncic_termOT)
 500
 501 module InvRelDiscriminationTree =
 502    Discrimination_tree.Make(NCicInverseRelIndexable)(Ncic_termSet)
 503