helm/software/components/ng_tactics/nTacStatus.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 let debug = ref false;;
  15 let pp x =
  16  if !debug then prerr_endline (Lazy.force x) else ()
  17 ;;
  18
  19 exception Error of string lazy_t * exn option
  20 let fail ?exn msg = raise (Error (msg,exn))
  21
  22 module NRef = NReference
  23
  24 let wrap fname f x =
  25   try f x
  26   with
  27   | MultiPassDisambiguator.DisambiguationError _
  28   | NCicRefiner.RefineFailure _
  29   | NCicUnification.UnificationFailure _
  30   | NCicTypeChecker.TypeCheckerFailure _
  31   | NCicMetaSubst.MetaSubstFailure _ as exn -> fail ~exn (lazy fname)
  32 ;;
  33
  34 class pstatus =
  35  fun (o: NCic.obj) ->
  36   object
  37    inherit NEstatus.status
  38    val obj = o
  39    method obj = obj
  40    method set_obj o = {< obj = o >}
  41   end
  42
  43 type tactic_term = CicNotationPt.term Disambiguate.disambiguator_input
  44 type tactic_pattern = GrafiteAst.npattern Disambiguate.disambiguator_input
  45
  46 let pp_status status =
  47   pp (lazy (NCicPp.ppobj status#obj))
  48 ;;
  49
  50 type cic_term = NCic.context * NCic.term
  51 let ctx_of (c,_) = c ;;
  52 let mk_cic_term c t = c,t ;;
  53
  54 let ppterm status t =
  55  let uri,height,metasenv,subst,obj = status#obj in
  56  let context,t = t in
  57   NCicPp.ppterm ~metasenv ~subst ~context t
  58 ;;
  59
  60 let ppcontext status c =
  61  let uri,height,metasenv,subst,obj = status#obj in
  62   NCicPp.ppcontext ~metasenv ~subst c
  63 ;;
  64
  65 let ppterm_and_context status t =
  66  let uri,height,metasenv,subst,obj = status#obj in
  67  let context,t = t in
  68   NCicPp.ppcontext ~metasenv ~subst context ^ "\n ⊢ "^
  69   NCicPp.ppterm ~metasenv ~subst ~context t
  70 ;;
  71
  72 let relocate status destination (source,t as orig) =
  73  pp(lazy("relocate:\n" ^ ppterm_and_context status orig));
  74  pp(lazy("relocate in:\n" ^ ppcontext status destination));
  75  let rc =
  76    if source == destination then status, orig else
  77     let _, _, metasenv, subst, _ = status#obj in
  78     let rec compute_ops ctx = function (* destination, source *)
  79       | (n1, NCic.Decl t1 as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
  80           if n1 = n2 &&
  81              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  82             compute_ops (e::ctx) (cl1,cl2)
  83           else
  84             [ `Delift ctx; `Lift (List.rev ex) ]
  85       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Def (b2,t2))::cl2 ->
  86           if n1 = n2 &&
  87              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 &&
  88              NCicReduction.are_convertible ctx ~subst ~metasenv b1 b2 then
  89             compute_ops (e::ctx) (cl1,cl2)
  90           else
  91             [ `Delift ctx; `Lift (List.rev ex) ]
  92       | (n1, NCic.Def (b1,t1) as e)::cl1 as ex, (n2, NCic.Decl t2)::cl2 ->
  93           if n1 = n2 &&
  94              NCicReduction.are_convertible ctx ~subst ~metasenv t1 t2 then
  95             compute_ops (e::ctx) (cl1,cl2)
  96           else
  97             [ `Delift ctx; `Lift (List.rev ex) ]
  98       | (n1, NCic.Decl _)::cl1 as ex, (n2, NCic.Def _)::cl2 ->
  99             [ `Delift ctx; `Lift (List.rev ex) ]
 100       | _::_ as ex, [] -> [ `Lift (List.rev ex) ]
 101       | [], _::_ -> [ `Delift ctx ]
 102       | [],[] -> []
 103     in
 104     let ops = compute_ops [] (List.rev destination, List.rev source) in
 105     let rec mk_irl i j = if i > j then [] else NCic.Rel i :: mk_irl (i+1) j in
 106     List.fold_left
 107      (fun (status, (source,t)) -> function
 108       | `Lift extra_ctx ->
 109            let len = List.length extra_ctx in
 110            status, (extra_ctx@source, NCicSubstitution.lift len t)
 111       | `Delift ctx ->
 112             let len_ctx = List.length ctx in
 113             let irl = mk_irl 1 (List.length ctx) in
 114             let lc = List.length source - len_ctx, NCic.Ctx irl in
 115             let u, d, metasenv, subst, o = status#obj in
 116             pp(lazy("delifting as " ^
 117               NCicPp.ppterm ~metasenv ~subst ~context:source
 118                (NCic.Meta (0,lc))));
 119             let (metasenv, subst), t =
 120               NCicMetaSubst.delift
 121                  ~unify:(fun m s c t1 t2 ->
 122                    try Some (NCicUnification.unify status m s c t1 t2)
 123                    with
 124                     | NCicUnification.UnificationFailure _
 125                     | NCicUnification.Uncertain _ -> None)
 126                metasenv subst source 0 lc t
 127             in
 128             let status = status#set_obj (u, d, metasenv, subst, o) in
 129             status, (ctx,t))
 130        (status,orig) ops
 131  in
 132  pp(lazy("relocated: " ^ ppterm (fst rc) (snd rc)));
 133  rc
 134 ;;
 135 let relocate a b c = wrap "relocate" (relocate a b) c;;
 136
 137 let term_of_cic_term s t c =
 138   let s, (_,t) = relocate s c t in
 139   s, t
 140 ;;
 141
 142 let disambiguate status context t ty =
 143  let status, expty =
 144    match ty with
 145    | None -> status, None
 146    | Some ty ->
 147        let status, (_,x) = relocate status context ty in status, Some x
 148  in
 149  let uri,height,metasenv,subst,obj = status#obj in
 150  let metasenv, subst, status, t =
 151    GrafiteDisambiguate.disambiguate_nterm expty status context metasenv subst t
 152  in
 153  let new_pstatus = uri,height,metasenv,subst,obj in
 154   status#set_obj new_pstatus, (context, t)
 155 ;;
 156 let disambiguate a b c d = wrap "disambiguate" (disambiguate a b c) d;;
 157
 158 let typeof status ctx t =
 159   let status, (_,t) = relocate status ctx t in
 160   let _,_,metasenv,subst,_ = status#obj in
 161   let ty = NCicTypeChecker.typeof ~subst ~metasenv ctx t in
 162   status, (ctx, ty)
 163 ;;
 164 let typeof a b c = wrap "typeof" (typeof a b) c;;
 165
 166 let saturate status ?delta (ctx,t) =
 167   let n,h,metasenv,subst,k = status#obj in
 168   let t,metasenv,args = NCicMetaSubst.saturate ?delta metasenv subst ctx t 0 in
 169   let status = status#set_obj (n,h,metasenv,subst,k) in
 170   status, (ctx,t), List.map (fun x -> ctx,x) args
 171 ;;
 172 let saturate a ?delta b = wrap "saturate" (saturate a ?delta) b;;
 173
 174 let whd status ?delta ctx t =
 175   let status, (_,t) = relocate status ctx t in
 176   let _,_,_,subst,_ = status#obj in
 177   let t = NCicReduction.whd ~subst ?delta ctx t in
 178   status, (ctx, t)
 179 ;;
 180
 181 let normalize status ?delta ctx t =
 182   let status, (_,t) = relocate status ctx t in
 183   let _,_,_,subst,_ = status#obj in
 184   let t = NCicTacReduction.normalize ~subst ?delta ctx t in
 185   status, (ctx, t)
 186 ;;
 187
 188 let unify status ctx a b =
 189   let status, (_,a) = relocate status ctx a in
 190   let status, (_,b) = relocate status ctx b in
 191   let n,h,metasenv,subst,o = status#obj in
 192   let metasenv, subst = NCicUnification.unify status metasenv subst ctx a b in
 193    status#set_obj (n,h,metasenv,subst,o)
 194 ;;
 195 let unify a b c d = wrap "unify" (unify a b c) d;;
 196
 197 let fix_sorts (ctx,t) =
 198  let f () =
 199   let t = NCicUnification.fix_sorts t in
 200    ctx,t
 201  in
 202   wrap "fix_sorts" f ()
 203 ;;
 204
 205 let refine status ctx term expty =
 206   let status, (_,term) = relocate status ctx term in
 207   let status, expty =
 208     match expty with
 209       None -> status, None
 210     | Some e ->
 211         let status, (_, e) = relocate status ctx e in status, Some e
 212   in
 213   let name,height,metasenv,subst,obj = status#obj in
 214   let metasenv,subst,t,ty =
 215    NCicRefiner.typeof status metasenv subst ctx term expty
 216   in
 217    status#set_obj (name,height,metasenv,subst,obj), (ctx,t), (ctx,ty)
 218 ;;
 219 let refine a b c d = wrap "refine" (refine a b c) d;;
 220
 221 let get_goalty status g =
 222  let _,_,metasenv,_,_ = status#obj in
 223  try
 224    let _, ctx, ty = NCicUtils.lookup_meta g metasenv in
 225    ctx, ty
 226  with NCicUtils.Meta_not_found _ as exn -> fail ~exn (lazy "get_goalty")
 227 ;;
 228
 229 let to_subst status i entry =
 230  let name,height,metasenv,subst,obj = status#obj in
 231  let metasenv = List.filter (fun j,_ -> j <> i) metasenv in
 232  let subst = (i, entry) :: subst in
 233   status#set_obj (name,height,metasenv,subst,obj)
 234 ;;
 235
 236 let instantiate status i t =
 237  let _,_,metasenv,_,_ = status#obj in
 238  let gname, context, gty = List.assoc i metasenv in
 239  let status, (_,t), (_,ty) = refine status context t (Some (context,gty)) in
 240   to_subst status i (gname,context,t,ty)
 241 ;;
 242
 243 let instantiate_with_ast status i t =
 244  let _,_,metasenv,_,_ = status#obj in
 245  let gname, context, gty = List.assoc i metasenv in
 246  let ggty = mk_cic_term context gty in
 247  let status, (_,t) = disambiguate status context t (Some ggty) in
 248   to_subst status i (gname,context,t,gty)
 249 ;;
 250
 251 let mk_meta status ?(attrs=[]) ctx bo_or_ty =
 252   match bo_or_ty with
 253   | `Decl ty ->
 254       let status, (_,ty) = relocate status ctx ty in
 255       let n,h,metasenv,subst,o = status#obj in
 256       let metasenv, _, instance, _ =
 257         NCicMetaSubst.mk_meta ~attrs metasenv ctx (`WithType ty)
 258       in
 259       let status = status#set_obj (n,h,metasenv,subst,o) in
 260       status, (ctx,instance)
 261   | `Def bo ->
 262       let status, (_,bo_ as bo) = relocate status ctx bo in
 263       let status, (_,ty) = typeof status ctx bo in
 264       let n,h,metasenv,subst,o = status#obj in
 265       let metasenv, metano, instance, _ =
 266         NCicMetaSubst.mk_meta ~attrs metasenv ctx (`WithType ty) in
 267       let metasenv = List.filter (fun j,_ -> j <> metano) metasenv in
 268       let subst = (metano, (attrs, ctx, bo_, ty)) :: subst in
 269       let status = status#set_obj (n,h,metasenv,subst,o) in
 270       status, (ctx,instance)
 271 ;;
 272
 273 let mk_in_scope status t =
 274   mk_meta status ~attrs:[`InScope] (ctx_of t) (`Def t)
 275 ;;
 276
 277 let mk_out_scope n status t =
 278   mk_meta status ~attrs:[`OutScope n] (ctx_of t) (`Def t)
 279 ;;
 280
 281 (* the following unification problem will be driven by
 282  *   select s ~found:mk_in_scope ~postprocess:(mk_out_scope argsno) t pattern
 283  *
 284  *   ? args = t
 285  *
 286  *   where argsn = length args and the pattern matches t
 287  *
 288  *  found is called on every selected term to map them
 289  *  postprocess is called on the entire term after selection
 290  *)
 291 let select_term
 292   low_status ~found ~postprocess (context,term) (wanted,path)
 293 =
 294   let is_found status ctx t wanted =
 295     (* we could lift wanted step-by-step *)
 296     pp(lazy("is_found: "^ppterm status (ctx,t)));
 297     try true, unify status ctx (ctx, t) wanted
 298     with
 299     | Error (_, Some (NCicUnification.UnificationFailure _))
 300     | Error (_, Some (NCicUnification.Uncertain _)) -> false, status
 301   in
 302   let match_term status ctx (wanted : cic_term) t =
 303     let rec aux ctx (status,already_found) t =
 304       let b, status = is_found status ctx t wanted in
 305       if b then
 306          let status , (_,t) = found status (ctx, t) in
 307          (status,true),t
 308       else
 309         let _,_,_,subst,_ = status#obj in
 310         match t with
 311         | NCic.Meta (i,lc) when List.mem_assoc i subst ->
 312             let _,_,t,_ = NCicUtils.lookup_subst i subst in
 313             aux ctx (status,already_found) t
 314         | NCic.Meta _ -> (status,already_found),t
 315         | _ ->
 316           NCicUntrusted.map_term_fold_a (fun e c -> e::c) ctx aux
 317            (status,already_found) t
 318      in
 319        aux ctx (status,false) t
 320   in
 321   let _,_,_,subst,_ = low_status#obj in
 322   let rec select status ctx pat cic =
 323     match pat, cic with
 324     | _, NCic.Meta (i,lc) when List.mem_assoc i subst ->
 325         let cic =
 326           let _,_,t,_ = NCicUtils.lookup_subst i subst in
 327           NCicSubstitution.subst_meta lc t
 328         in
 329         select status ctx pat cic
 330     | NCic.LetIn (_,t1,s1,b1), NCic.LetIn (n,t2,s2,b2) ->
 331         let status, t = select status ctx t1 t2 in
 332         let status, s = select status ctx s1 s2 in
 333         let ctx = (n, NCic.Def (s2,t2)) :: ctx in
 334         let status, b = select status ctx b1 b2 in
 335         status, NCic.LetIn (n,t,s,b)
 336     | NCic.Lambda (_,s1,t1), NCic.Lambda (n,s2,t2) ->
 337         let status, s = select status ctx s1 s2 in
 338         let ctx = (n, NCic.Decl s2) :: ctx in
 339         let status, t = select status ctx t1 t2 in
 340         status, NCic.Lambda (n,s,t)
 341     | NCic.Prod (_,s1,t1), NCic.Prod (n,s2,t2) ->
 342         let status, s = select status ctx s1 s2 in
 343         let ctx = (n, NCic.Decl s2) :: ctx in
 344         let status, t = select status ctx t1 t2 in
 345         status, NCic.Prod (n,s,t)
 346     | NCic.Appl l1, NCic.Appl l2 ->
 347         let status, l =
 348            List.fold_left2
 349              (fun (status,l) x y ->
 350               let status, x = select status ctx x y in
 351               status, x::l)
 352              (status,[]) l1 l2
 353         in
 354         status, NCic.Appl (List.rev l)
 355     | NCic.Match (_,ot1,t1,pl1), NCic.Match (u,ot2,t2,pl2) ->
 356         let status, t = select status ctx t1 t2 in
 357         let status, ot = select status ctx ot1 ot2 in
 358         let status, pl =
 359            List.fold_left2
 360              (fun (status,l) x y ->
 361               let status, x = select status ctx x y in
 362               status, x::l)
 363              (status,[]) pl1 pl2
 364         in
 365         status, NCic.Match (u,ot,t,List.rev pl)
 366     | NCic.Implicit `Hole, t ->
 367         (match wanted with
 368         | Some wanted ->
 369              let status', wanted = disambiguate status ctx wanted None in
 370              pp(lazy("wanted: "^ppterm status' wanted));
 371              let (status',found), t' = match_term status' ctx wanted t in
 372               if found then status',t' else status,t
 373         | None ->
 374            let (status,_),t = match_term status ctx (ctx,t) t in
 375             status,t)
 376     | NCic.Implicit _, t -> status, t
 377     | _,t ->
 378         fail (lazy ("malformed pattern: " ^ NCicPp.ppterm ~metasenv:[]
 379           ~context:[] ~subst:[] pat ^ " against " ^
 380           NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))
 381   in
 382   pp(lazy ("select in: "^ppterm low_status (context,term)));
 383   let status, term = select low_status context path term in
 384   let term = (context, term) in
 385   pp(lazy ("postprocess: "^ppterm low_status term));
 386   postprocess status term
 387 ;;
 388
 389 let analyse_indty status ty =
 390  let status, reduct = whd status (ctx_of ty) ty in
 391  let ref, args =
 392   match reduct with
 393    | _,NCic.Const ref -> ref, []
 394    | _,NCic.Appl (NCic.Const (NRef.Ref (_,(NRef.Ind _)) as ref) :: args) ->
 395          ref, args
 396    | _,_ -> fail (lazy ("not an inductive type")) in
 397  let _,lno,tl,_,i = NCicEnvironment.get_checked_indtys ref in
 398  let _,_,_,cl = List.nth tl i in
 399  let consno = List.length cl in
 400  let left, right = HExtlib.split_nth lno args in
 401  status, (ref, consno, left, right)
 402 ;;
 403
 404 let apply_subst status ctx t =
 405  let status, (_,t) = relocate status ctx t in
 406  let _,_,_,subst,_ = status#obj in
 407   status, (ctx, NCicUntrusted.apply_subst subst ctx t)
 408 ;;
 409
 410 let metas_of_term status (context,t) =
 411  let _,_,_,subst,_ = status#obj in
 412  NCicUntrusted.metas_of_term subst context t
 413 ;;
 414
 415 (* ============= move this elsewhere ====================*)
 416
 417 class ['stack] status =
 418  fun (o: NCic.obj) (s: 'stack) ->
 419   object
 420    inherit (pstatus o)
 421    val stack = s
 422    method stack = stack
 423    method set_stack s = {< stack = s >}
 424   end
 425
 426 class type lowtac_status = [unit] status
 427
 428 type 'status lowtactic = #lowtac_status as 'status -> int -> 'status
 429
 430 class type tac_status = [Continuationals.Stack.t] status
 431
 432 type 'status tactic = #tac_status as 'status -> 'status
 433
 434 module NCicInverseRelIndexable : Discrimination_tree.Indexable
 435 with type input = cic_term and type constant_name = NUri.uri = struct
 436
 437 open Discrimination_tree
 438
 439 type input = cic_term
 440 type constant_name = NUri.uri
 441
 442 let ppelem = function
 443   | Constant (uri,arity) ->
 444       "("^NUri.name_of_uri uri ^ "," ^ string_of_int arity^")"
 445   | Bound (i,arity) ->
 446       "("^string_of_int i ^ "," ^ string_of_int arity^")"
 447   | Variable -> "?"
 448   | Proposition -> "Prop"
 449   | Datatype -> "Type"
 450   | Dead -> "Dead"
 451 ;;
 452
 453 let string_of_path l = String.concat "." (List.map ppelem l) ;;
 454
 455 let path_string_of (ctx,t) =
 456   let len_ctx = List.length ctx in
 457   let rec aux arity = function
 458     | NCic.Appl ((NCic.Meta _|NCic.Implicit _)::_) -> [Variable]
 459     | NCic.Appl (NCic.Lambda _ :: _) -> [Variable] (* maybe we should b-reduce *)
 460     | NCic.Appl [] -> assert false
 461     | NCic.Appl (hd::tl) ->
 462         aux (List.length tl) hd @ List.flatten (List.map (aux 0) tl)
 463     | NCic.Lambda _ | NCic.Prod _ -> [Variable]
 464         (* I think we should CicSubstitution.subst Implicit t *)
 465     | NCic.LetIn _ -> [Variable] (* z-reduce? *)
 466     | NCic.Meta _ | NCic.Implicit _ -> assert (arity = 0); [Variable]
 467     | NCic.Rel i -> [Bound (len_ctx - i, arity)]
 468     | NCic.Sort (NCic.Prop) -> assert (arity=0); [Proposition]
 469     | NCic.Sort _ -> assert (arity=0); [Datatype]
 470     | NCic.Const (NReference.Ref (u,_)) -> [Constant (u, arity)]
 471     | NCic.Match _ -> [Dead]
 472   in
 473   let path = aux 0 t in
 474 (*   prerr_endline (string_of_path path); *)
 475   path
 476 ;;
 477
 478 let compare e1 e2 =
 479   match e1,e2 with
 480   | Constant (u1,a1),Constant (u2,a2) ->
 481        let x = NUri.compare u1 u2 in
 482        if x = 0 then Pervasives.compare a1 a2 else x
 483   | e1,e2 -> Pervasives.compare e1 e2
 484 ;;
 485
 486
 487 end
 488
 489 module Ncic_termOT : Set.OrderedType with type t = cic_term =
 490  struct
 491    type t = cic_term
 492    let compare = Pervasives.compare
 493  end
 494
 495 module Ncic_termSet : Set.S with type elt = cic_term = Set.Make(Ncic_termOT)
 496
 497 module InvRelDiscriminationTree =
 498    Discrimination_tree.Make(NCicInverseRelIndexable)(Ncic_termSet)
 499