helm/software/components/ng_tactics/nTactics.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 open Printf
  15
  16 let debug = true
  17 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  18
  19 open Continuationals.Stack
  20 open NTacStatus
  21 module Ast = CicNotationPt
  22
  23 let id_tac status = status ;;
  24 let print_tac message status = prerr_endline message; status ;;
  25
  26 let dot_tac status =
  27   let new_gstatus =
  28     match status.gstatus with
  29     | [] -> assert false
  30     | ([], _, [], _) :: _ as stack ->
  31         (* backward compatibility: do-nothing-dot *)
  32         stack
  33     | (g, t, k, tag) :: s ->
  34         match filter_open g, k with
  35         | loc :: loc_tl, _ ->
  36              (([ loc ], t, loc_tl @+ k, tag) :: s)
  37         | [], loc :: k ->
  38             assert (is_open loc);
  39             (([ loc ], t, k, tag) :: s)
  40         | _ -> fail (lazy "can't use \".\" here")
  41   in
  42    { status with gstatus = new_gstatus }
  43 ;;
  44
  45 let branch_tac status =
  46   let new_gstatus =
  47     match status.gstatus with
  48     | [] -> assert false
  49     | (g, t, k, tag) :: s ->
  50           match init_pos g with (* TODO *)
  51           | [] | [ _ ] -> fail (lazy "too few goals to branch");
  52           | loc :: loc_tl ->
  53                ([ loc ], [], [], `BranchTag) :: (loc_tl, t, k, tag) :: s
  54   in
  55    { status with gstatus = new_gstatus }
  56 ;;
  57
  58 let shift_tac status =
  59   let new_gstatus =
  60     match status.gstatus with
  61     | (g, t, k, `BranchTag) :: (g', t', k', tag) :: s ->
  62           (match g' with
  63           | [] -> fail (lazy "no more goals to shift")
  64           | loc :: loc_tl ->
  65                 (([ loc ], t @+ filter_open g @+ k, [],`BranchTag)
  66                 :: (loc_tl, t', k', tag) :: s))
  67      | _ -> fail (lazy "can't shift goals here")
  68   in
  69    { status with gstatus = new_gstatus }
  70 ;;
  71
  72 let pos_tac i_s status =
  73   let new_gstatus =
  74     match status.gstatus with
  75     | [] -> assert false
  76     | ([ loc ], t, [],`BranchTag) :: (g', t', k', tag) :: s
  77       when is_fresh loc ->
  78         let l_js = List.filter (fun (i, _) -> List.mem i i_s) ([loc] @+ g') in
  79           ((l_js, t , [],`BranchTag)
  80            :: (([ loc ] @+ g') @- l_js, t', k', tag) :: s)
  81     | _ -> fail (lazy "can't use relative positioning here")
  82   in
  83    { status with gstatus = new_gstatus }
  84 ;;
  85
  86 let wildcard_tac status =
  87   let new_gstatus =
  88     match status.gstatus with
  89     | [] -> assert false
  90     | ([ loc ] , t, [], `BranchTag) :: (g', t', k', tag) :: s
  91        when is_fresh loc ->
  92             (([loc] @+ g', t, [], `BranchTag) :: ([], t', k', tag) :: s)
  93     | _ -> fail (lazy "can't use wildcard here")
  94   in
  95    { status with gstatus = new_gstatus }
  96 ;;
  97
  98 let merge_tac status =
  99   let new_gstatus =
 100     match status.gstatus with
 101     | [] -> assert false
 102     | (g, t, k,`BranchTag) :: (g', t', k', tag) :: s ->
 103         ((t @+ filter_open g @+ g' @+ k, t', k', tag) :: s)
 104     | _ -> fail (lazy "can't merge goals here")
 105   in
 106    { status with gstatus = new_gstatus }
 107 ;;
 108
 109 let focus_tac gs status =
 110   let new_gstatus =
 111     match status.gstatus with
 112     | [] -> assert false
 113     | s -> assert(gs <> []);
 114           let stack_locs =
 115             let add_l acc _ _ l = if is_open l then l :: acc else acc in
 116             fold ~env:add_l ~cont:add_l ~todo:add_l [] s
 117           in
 118           List.iter
 119             (fun g ->
 120               if not (List.exists (fun l -> goal_of_loc l = g) stack_locs) then
 121                 fail (lazy (sprintf "goal %d not found (or closed)" g)))
 122             gs;
 123           (zero_pos gs, [], [], `FocusTag) :: deep_close gs s
 124   in
 125    { status with gstatus = new_gstatus }
 126 ;;
 127
 128 let unfocus_tac status =
 129   let new_gstatus =
 130     match status.gstatus with
 131     | [] -> assert false
 132     | ([], [], [], `FocusTag) :: s -> s
 133     | _ -> fail (lazy "can't unfocus, some goals are still open")
 134   in
 135    { status with gstatus = new_gstatus }
 136 ;;
 137
 138 let skip_tac status =
 139   let new_gstatus =
 140     match status.gstatus with
 141     | [] -> assert false
 142     | (gl, t, k, tag) :: s ->
 143         let gl = List.map switch_of_loc gl in
 144         if List.exists (function Open _ -> true | Closed _ -> false) gl then
 145           fail (lazy "cannot skip an open goal")
 146         else
 147           ([],t,k,tag) :: s
 148   in
 149    { status with gstatus = new_gstatus }
 150 ;;
 151
 152 let block_tac l status =
 153   List.fold_left (fun status tac -> tac status) status l
 154 ;;
 155
 156 let compare_statuses ~past ~present =
 157  let _,_,past,_,_ = past.pstatus in
 158  let _,_,present,_,_ = present.pstatus in
 159  let closed =
 160   List.map fst (List.filter (fun (i,_) -> not (List.mem_assoc i present)) past)
 161  in
 162  let opened =
 163    List.map fst (List.filter (fun (i,_) -> not(List.mem_assoc i past)) present)
 164  in
 165  opened, closed
 166 ;;
 167
 168
 169
 170 (* Exec and distribute_tac form a retraction pair:
 171     1) exec (distribute_tac low_tac) (s,i) = low_tac (s,i)
 172     2) tac [s]::G = G1::...::Gn::G' && G' is G with some goals closed =>
 173          distribute_tac (exec tac) [s]::G = (G1@...Gn)::G'
 174     3) tac G = distribute_tac (exec tac) G if
 175        tac = distribute_tac lowtac
 176     4) atomic_tac t === distribute_tac (exec t)
 177
 178    Note that executing an high tactic on a set of goals may be stronger
 179    than executing the same tactic on those goals, but once at a time
 180    (e.g. the tactic could perform a global analysis of the set of goals)
 181 *)
 182
 183 let exec tac low_status g =
 184   let stack = [ [0,Open g], [], [], `NoTag ] in
 185   let status = tac { gstatus = stack ; istatus = low_status } in
 186    status.istatus
 187 ;;
 188
 189 let distribute_tac tac status =
 190   match status.gstatus with
 191   | [] -> assert false
 192   | (g, t, k, tag) :: s ->
 193       debug_print (lazy ("context length " ^string_of_int (List.length g)));
 194       let rec aux s go gc =
 195         function
 196         | [] ->
 197             debug_print (lazy "no selected goals");
 198             s, go, gc
 199         | loc :: loc_tl ->
 200             debug_print (lazy "inner eval tactical");
 201             let s, go, gc =
 202               if List.exists ((=) (goal_of_loc loc)) gc then
 203                 s, go, gc
 204               else
 205                 match switch_of_loc loc with
 206                 | Closed _ -> fail (lazy "cannot apply to a Closed goal")
 207                 | Open n ->
 208                    let sn = tac s n in
 209                    let go', gc' = compare_statuses ~past:s ~present:sn in
 210                    sn, ((go @+ [n]) @- gc') @+ go', gc @+ gc'
 211             in
 212             aux s go gc loc_tl
 213       in
 214       let s0, go0, gc0 = status.istatus, [], [] in
 215       let sn, gon, gcn = aux s0 go0 gc0 g in
 216       debug_print (lazy ("opened: "
 217         ^ String.concat " " (List.map string_of_int gon)));
 218       debug_print (lazy ("closed: "
 219         ^ String.concat " " (List.map string_of_int gcn)));
 220       let stack =
 221         (zero_pos gon, t @~- gcn, k @~- gcn, tag) :: deep_close gcn s
 222       in
 223        { gstatus = stack; istatus = sn }
 224 ;;
 225
 226 let atomic_tac htac = distribute_tac (exec htac) ;;
 227
 228 let exact t status goal =
 229  let goalty = get_goalty status goal in
 230  let status, t = disambiguate status t (Some goalty) (ctx_of goalty) in
 231  instantiate status goal t
 232 ;;
 233
 234 let exact_tac t = distribute_tac (exact t) ;;
 235
 236 let find_in_context name context =
 237   let rec aux acc = function
 238     | [] -> raise Not_found
 239     | (hd,_) :: tl when hd = name -> acc
 240     | _ :: tl ->  aux (acc + 1) tl
 241   in
 242   aux 1 context
 243 ;;
 244
 245 let clear names status goal =
 246  let goalty = get_goalty status goal in
 247  let js =
 248    List.map
 249      (fun name ->
 250         try find_in_context name (ctx_of goalty)
 251         with Not_found ->
 252           fail (lazy ("hypothesis '" ^ name ^ "' not found")))
 253      names
 254  in
 255  let n,h,metasenv,subst,o = status.pstatus in
 256  let metasenv,subst,_ = NCicMetaSubst.restrict metasenv subst goal js in
 257   { status with pstatus = n,h,metasenv,subst,o }
 258 ;;
 259
 260 let clear_tac names =
 261  if names = [] then id_tac else distribute_tac (clear names)
 262 ;;
 263
 264 let generalize0_tac args =
 265  if args = [] then id_tac
 266  else exact_tac ("",0,Ast.Appl (Ast.Implicit :: args))
 267 ;;
 268
 269 let select0_tac ~where:(wanted,_,where) ~argsno =
 270  distribute_tac (fun status goal ->
 271    let goalty = get_goalty status goal in
 272    let path =
 273      match where with None -> NCic.Implicit `Term | Some where -> where
 274    in
 275    let status, newgoalty = select_term status argsno goalty (wanted,path) in
 276    let status, instance =
 277      mk_meta status (ctx_of newgoalty) (`Decl newgoalty)
 278    in
 279    instantiate status goal instance)
 280 ;;
 281
 282 let select_tac ~where ~argsno move_down_hyps =
 283  let (wanted,hyps,where) = GrafiteDisambiguate.disambiguate_npattern where in
 284  let path =
 285   match where with None -> NCic.Implicit `Term | Some where -> where in
 286  if not move_down_hyps then
 287   select0_tac ~where:(wanted,hyps,Some path) ~argsno
 288  else
 289   let path =
 290    List.fold_left
 291      (fun path (name,path_name) -> NCic.Prod ("_",path_name,path))
 292      path (List.rev hyps)
 293   in
 294    block_tac [
 295      generalize0_tac (List.map (fun (name,_) -> Ast.Ident (name,None)) hyps);
 296      select0_tac ~where:(wanted,[],Some path) ~argsno;
 297      clear_tac (List.map fst hyps) ]
 298 ;;
 299
 300 (*
 301 let generalize_tac ~where =
 302  block_tac [ select_tac ~where true ; generalize0_tac ???? ]
 303 ;;
 304 *)
 305
 306
 307 let reopen status =
 308  let n,h,metasenv,subst,o = status.pstatus in
 309  let subst, newm =
 310    List.partition
 311     (function (_,(Some tag,_,_,_)) ->
 312             tag <> NCicMetaSubst.in_scope_tag &&
 313             not (NCicMetaSubst.is_out_scope_tag tag)
 314     | _ -> true)
 315     subst
 316  in
 317  let in_m, out_m =
 318    List.partition
 319      (function (_,(Some tag,_,_,_)) ->
 320          tag = NCicMetaSubst.in_scope_tag | _ -> assert false)
 321      newm
 322  in
 323  let metasenv = List.map (fun (i,(_,c,_,t)) -> i,(None,c,t)) in_m @ metasenv in
 324  let in_m = List.map fst in_m in
 325  let out_m = match out_m with [i] -> i | _ -> assert false in
 326  { status with pstatus = n,h,metasenv,subst,o }, in_m, out_m
 327 ;;
 328
 329 let change ~where ~with_what status goal =
 330  let goalty = get_goalty status goal in
 331  let (wanted,_,where) = GrafiteDisambiguate.disambiguate_npattern where in
 332  let path =
 333    match where with None -> NCic.Implicit `Term | Some where -> where
 334  in
 335  let status, newgoalty = select_term status 1 goalty (wanted,path) in
 336  let status, in_scope, out_scope = reopen status in
 337  let status =  List.fold_left (exact with_what) status in_scope in
 338
 339  let j,(n,cctx,bo,_) = out_scope in
 340  let _ = typeof status (ctx_of goalty) (Obj.magic (n,cctx,bo))  in
 341
 342  let n,h,metasenv,subst,o = status.pstatus in
 343  let subst = out_scope :: subst in
 344  let status = { status with pstatus = n,h,metasenv,subst,o } in
 345
 346  let status, instance =
 347    mk_meta status (ctx_of newgoalty) (`Decl newgoalty)
 348  in
 349  instantiate status goal instance
 350 ;;
 351
 352 let apply t status goal = exact t status goal;;
 353
 354 let apply_tac t = distribute_tac (apply t) ;;
 355 let change_tac ~where ~with_what = distribute_tac (change ~where ~with_what) ;;
 356
 357 type indtyinfo = {
 358         rightno: int;
 359         leftno: int;
 360         consno: int;
 361         lefts: NCic.term list;
 362         rights: NCic.term list;
 363         reference: NReference.reference;
 364  }
 365 ;;
 366
 367 let analyze_indty_tac ~what indtyref = distribute_tac (fun status goal ->
 368   let goalty = get_goalty status goal in
 369   let status, what = disambiguate status what None (ctx_of goalty) in
 370   let ty_what = typeof status (ctx_of what) what in
 371   let r,consno,lefts,rights = analyse_indty status ty_what in
 372   let leftno = List.length rights in
 373   let rightno = List.length rights in
 374   indtyref := Some {
 375     rightno = rightno; leftno = leftno; consno = consno;
 376     lefts = lefts; rights = rights; reference = r;
 377   };
 378   prerr_endline "FO";
 379   exec id_tac status goal)
 380 ;;
 381
 382 let force f s = Lazy.force f s;;
 383
 384 let elim_tac ~what ~where =
 385   let indtyinfo = ref None in
 386   let sort = ref None in
 387   let compute_goal_sort_tac = distribute_tac (fun status goal ->
 388     let goalty = get_goalty status goal in
 389     let goalsort = typeof status (ctx_of goalty) goalty in
 390     prerr_endline "XXXXXXXX";
 391     sort := Some goalsort;
 392     exec id_tac status goal)
 393   in
 394   atomic_tac (block_tac [
 395     analyze_indty_tac ~what indtyinfo;
 396     force (lazy (select_tac
 397       ~where ~argsno:((HExtlib.unopt !indtyinfo).rightno+1) true));
 398     print_tac "CIAO";
 399     compute_goal_sort_tac;
 400     print_tac "CIAO2";
 401     force (lazy (
 402      let sort = HExtlib.unopt !sort in
 403      let ity = HExtlib.unopt !indtyinfo in
 404      let NReference.Ref (uri, _) = ity.reference in
 405      let name = NUri.name_of_uri uri ^
 406       match term_of_cic_term sort (ctx_of sort) with
 407        | NCic.Sort NCic.Prop -> "_ind"
 408        | NCic.Sort _ -> "_rect"
 409        | _ -> assert false
 410      in
 411      let holes =
 412        HExtlib.mk_list Ast.Implicit (ity.leftno+1+ ity.consno + ity.rightno) in
 413      let eliminator =
 414        let _,_,w = what in
 415        Ast.Appl(Ast.Ident(name,None)::holes @ [ w ])
 416      in
 417      exact_tac ("",0,eliminator))) ])
 418 ;;
 419
 420 let rewrite_tac ~dir ~what:(_,_,what) ~where =
 421  let name =
 422   match dir with `LeftToRight -> "eq_elim_r" | `RightToLeft -> "eq_ind"
 423  in
 424   block_tac
 425    [ select_tac ~where ~argsno:2 true;
 426      exact_tac
 427       ("",0,
 428        Ast.Appl(Ast.Ident(name,None)::HExtlib.mk_list Ast.Implicit 5 @
 429         [what]))]
 430 ;;
 431
 432 let intro_tac name =
 433  block_tac
 434   [ exact_tac
 435     ("",0,(Ast.Binder (`Lambda,
 436      (Ast.Ident (name,None),None),Ast.Implicit)));
 437      if name = "_" then clear_tac [name] else id_tac ]
 438 ;;
 439
 440 let cases ~what status goal =
 441  let gty = get_goalty status goal in
 442  let status, what = disambiguate status what None (ctx_of gty) in
 443  let ty = typeof status (ctx_of what) what in
 444  let ref, consno, _, _ = analyse_indty status ty in
 445  let t =
 446   NCic.Match (ref,NCic.Implicit `Term, term_of_cic_term what (ctx_of gty),
 447     HExtlib.mk_list (NCic.Implicit `Term) consno)
 448  in
 449  let ctx = ctx_of gty in
 450  let status,t,ty = refine status ctx (mk_cic_term ctx t) (Some gty) in
 451  instantiate status goal t
 452 ;;
 453
 454 let cases_tac ~what ~where =
 455   let indtyinfo = ref None in
 456   atomic_tac
 457    (block_tac [
 458       analyze_indty_tac ~what indtyinfo;
 459       select_tac ~where ~argsno:((HExtlib.unopt !indtyinfo).rightno+1) true;
 460       distribute_tac (cases ~what) ])
 461 ;;
 462
 463 let case1_tac name =
 464  let name = if name = "_" then "_clearme" else name in
 465  block_tac [ intro_tac name;
 466              cases_tac
 467               ~where:("",0,(None,[],None))
 468               ~what:("",0,Ast.Ident (name,None));
 469               if name = "_clearme" then clear_tac ["_clearme"] else id_tac ]
 470 ;;