helm/software/components/tactics/paramodulation/equality.ml

   1 (* cOpyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 let _profiler = <:profiler<_profiler>>;;
  27
  28 (* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)
  29
  30 type rule = SuperpositionRight | SuperpositionLeft | Demodulation
  31 type uncomparable = int -> int
  32 type equality =
  33     uncomparable *       (* trick to break structural equality *)
  34     int  *               (* weight *)
  35     proof *
  36     (Cic.term *          (* type *)
  37      Cic.term *          (* left side *)
  38      Cic.term *          (* right side *)
  39      Utils.comparison) * (* ordering *)
  40     Cic.metasenv  *      (* environment for metas *)
  41     int                  (* id *)
  42 and proof =
  43   | Exact of Cic.term
  44   | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term)
  45             (* subst, (rule,eq1, eq2,predicate) *)
  46 and goal_proof = (rule * Utils.pos * int * Subst.substitution * Cic.term) list
  47 ;;
  48
  49 type goal = goal_proof * Cic.metasenv * Cic.term
  50
  51 (* globals *)
  52 let maxid = ref 0;;
  53 let id_to_eq = Hashtbl.create 1024;;
  54
  55 let freshid () =
  56   incr maxid; !maxid
  57 ;;
  58
  59 let reset () =
  60   maxid := 0;
  61   Hashtbl.clear  id_to_eq
  62 ;;
  63
  64 let uncomparable = fun _ -> 0
  65
  66 let mk_equality (weight,p,(ty,l,r,o),m) =
  67   let id = freshid () in
  68   let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  69   Hashtbl.add id_to_eq id eq;
  70
  71   eq
  72 ;;
  73
  74 let mk_tmp_equality (weight,(ty,l,r,o),m) =
  75   let id = -1 in
  76   uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
  77 ;;
  78
  79
  80 let open_equality (_,weight,proof,(ty,l,r,o),m,id) =
  81   (weight,proof,(ty,l,r,o),m,id)
  82
  83 let string_of_rule = function
  84   | SuperpositionRight -> "SupR"
  85   | SuperpositionLeft -> "SupL"
  86   | Demodulation -> "Demod"
  87 ;;
  88
  89 let string_of_equality ?env eq =
  90   match env with
  91   | None ->
  92       let w, _, (ty, left, right, o), m , id = open_equality eq in
  93       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  94               id w (CicPp.ppterm ty)
  95               (CicPp.ppterm left)
  96               (Utils.string_of_comparison o) (CicPp.ppterm right)
  97         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
  98   | Some (_, context, _) ->
  99       let names = Utils.names_of_context context in
 100       let w, _, (ty, left, right, o), m , id = open_equality eq in
 101       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
 102               id w (CicPp.pp ty names)
 103               (CicPp.pp left names) (Utils.string_of_comparison o)
 104               (CicPp.pp right names)
 105         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 106 ;;
 107
 108 let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
 109   Pervasives.compare s1 s2
 110 ;;
 111
 112 let rec max_weight_in_proof current =
 113   function
 114    | Exact _ -> current
 115    | Step (_, (_,id1,(_,id2),_)) ->
 116        let eq1 = Hashtbl.find id_to_eq id1 in
 117        let eq2 = Hashtbl.find id_to_eq id2 in
 118        let (w1,p1,(_,_,_,_),_,_) = open_equality eq1 in
 119        let (w2,p2,(_,_,_,_),_,_) = open_equality eq2 in
 120        let current = max current w1 in
 121        let current = max_weight_in_proof current p1 in
 122        let current = max current w2 in
 123        max_weight_in_proof current p2
 124
 125 let max_weight_in_goal_proof =
 126   List.fold_left
 127     (fun current (_,_,id,_,_) ->
 128        let eq = Hashtbl.find id_to_eq id in
 129        let (w,p,(_,_,_,_),_,_) = open_equality eq in
 130        let current = max current w in
 131        max_weight_in_proof current p)
 132
 133 let max_weight goal_proof proof =
 134   let current = max_weight_in_proof 0 proof in
 135   max_weight_in_goal_proof current goal_proof
 136
 137 let proof_of_id id =
 138   try
 139     let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
 140       p,l,r
 141   with
 142       Not_found -> assert false
 143
 144
 145 let string_of_proof ?(names=[]) p gp =
 146   let str_of_pos = function
 147     | Utils.Left -> "left"
 148     | Utils.Right -> "right"
 149   in
 150   let fst3 (x,_,_) = x in
 151   let rec aux margin name =
 152     let prefix = String.make margin ' ' ^ name ^ ": " in function
 153     | Exact t ->
 154         Printf.sprintf "%sExact (%s)\n"
 155           prefix (CicPp.pp t names)
 156     | Step (subst,(rule,eq1,(pos,eq2),pred)) ->
 157         Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
 158           prefix (string_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos)
 159           (CicPp.pp pred names)^
 160         aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id eq1)) ^
 161         aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id eq2))
 162   in
 163   aux 0 "" p ^
 164   String.concat "\n"
 165     (List.map
 166       (fun (r,pos,i,s,t) ->
 167         (Printf.sprintf
 168           "GOAL: %s %s %d %s %s\n" (string_of_rule r)
 169             (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^
 170         aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id i)))
 171       gp)
 172 ;;
 173
 174 let rec depend eq id seen =
 175   let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
 176   if List.mem ideq seen then
 177     false,seen
 178   else
 179     if id = ideq then
 180       true,seen
 181     else
 182       match p with
 183       | Exact _ -> false,seen
 184       | Step (_,(_,id1,(_,id2),_)) ->
 185           let seen = ideq::seen in
 186           let eq1 = Hashtbl.find id_to_eq id1 in
 187           let eq2 = Hashtbl.find id_to_eq id2 in
 188           let b1,seen = depend eq1 id seen in
 189           if b1 then b1,seen else depend eq2 id seen
 190 ;;
 191
 192 let depend eq id = fst (depend eq id []);;
 193
 194 let ppsubst = Subst.ppsubst ~names:[];;
 195
 196 (* returns an explicit named subst and a list of arguments for sym_eq_URI *)
 197 let build_ens uri termlist =
 198   let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 199   match obj with
 200   | Cic.Constant (_, _, _, uris, _) ->
 201       assert (List.length uris <= List.length termlist);
 202       let rec aux = function
 203         | [], tl -> [], tl
 204         | (uri::uris), (term::tl) ->
 205             let ens, args = aux (uris, tl) in
 206             (uri, term)::ens, args
 207         | _, _ -> assert false
 208       in
 209       aux (uris, termlist)
 210   | _ -> assert false
 211 ;;
 212
 213 let mk_sym uri ty t1 t2 p =
 214   let ens, args =  build_ens uri [ty;t1;t2;p] in
 215     Cic.Appl (Cic.Const(uri, ens) :: args)
 216 ;;
 217
 218 let mk_trans uri ty t1 t2 t3 p12 p23 =
 219   let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
 220     Cic.Appl (Cic.Const (uri, ens) :: args)
 221 ;;
 222
 223 let mk_eq_ind uri ty what pred p1 other p2 =
 224  Cic.Appl [Cic.Const (uri, []); ty; what; pred; p1; other; p2]
 225 ;;
 226
 227 let p_of_sym ens tl =
 228   let args = List.map snd ens @ tl in
 229   match args with
 230     | [_;_;_;p] -> p
 231     | _ -> assert false
 232 ;;
 233
 234 let open_trans ens tl =
 235   let args = List.map snd ens @ tl in
 236   match args with
 237     | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
 238     | _ -> assert false
 239 ;;
 240
 241 let open_sym ens tl =
 242   let args = List.map snd ens @ tl in
 243   match args with
 244     | [ty;l;r;p] -> ty,l,r,p
 245     | _ -> assert false
 246 ;;
 247
 248 let open_eq_ind args =
 249   match args with
 250   | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
 251   | _ -> assert false
 252 ;;
 253
 254 let open_pred pred =
 255   match pred with
 256   | Cic.Lambda (_,_,(Cic.Appl [Cic.MutInd (uri, 0,_);ty;l;r]))
 257      when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
 258   | _ -> prerr_endline (CicPp.ppterm pred); assert false
 259 ;;
 260
 261 let is_not_fixed t =
 262    CicSubstitution.subst (Cic.Implicit None) t <>
 263    CicSubstitution.subst (Cic.Rel 1) t
 264 ;;
 265
 266 let head_of_apply = function | Cic.Appl (hd::_) -> hd | t -> t;;
 267 let tail_of_apply = function | Cic.Appl (_::tl) -> tl | t -> [];;
 268 let count_args t = List.length (tail_of_apply t);;
 269 let rec build_nat =
 270   let u = UriManager.uri_of_string "cic:/matita/nat/nat/nat.ind" in
 271   function
 272     | 0 -> Cic.MutConstruct(u,0,1,[])
 273     | n ->
 274         Cic.Appl [Cic.MutConstruct(u,0,2,[]);build_nat (n-1)]
 275 ;;
 276 let tyof context menv t =
 277   try
 278     fst(CicTypeChecker.type_of_aux' menv context t CicUniv.empty_ugraph)
 279   with
 280   | CicTypeChecker.TypeCheckerFailure _
 281   | CicTypeChecker.AssertFailure _ -> assert false
 282 ;;
 283 let rec lambdaof left context = function
 284   | Cic.Prod (n,s,t) ->
 285       Cic.Lambda (n,s,lambdaof left context t)
 286   | Cic.Appl [Cic.MutInd (uri, 0,_);ty;l;r]
 287       when LibraryObjects.is_eq_URI uri -> if left then l else r
 288   | t ->
 289       let names = Utils.names_of_context context in
 290       prerr_endline ("lambdaof: " ^ (CicPp.pp t names));
 291       assert false
 292 ;;
 293
 294 let canonical t context menv =
 295   let rec remove_refl t =
 296     match t with
 297     | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
 298           when LibraryObjects.is_trans_eq_URI uri_trans ->
 299           let ty,l,m,r,p1,p2 = open_trans ens tl in
 300             (match p1,p2 with
 301               | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 ->
 302                   remove_refl p2
 303               | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] ->
 304                   remove_refl p1
 305               | _ -> Cic.Appl (List.map remove_refl args))
 306     | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
 307     | Cic.LetIn (name,bo,rest) ->
 308         Cic.LetIn (name,remove_refl bo,remove_refl rest)
 309     | _ -> t
 310   in
 311   let rec canonical context t =
 312     match t with
 313       | Cic.LetIn(name,bo,rest) ->
 314           let context' = (Some (name,Cic.Def (bo,None)))::context in
 315           Cic.LetIn(name,canonical context bo,canonical context' rest)
 316       | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
 317           when LibraryObjects.is_sym_eq_URI uri_sym ->
 318           (match p_of_sym ens tl with
 319              | Cic.Appl ((Cic.Const(uri,ens))::tl)
 320                  when LibraryObjects.is_sym_eq_URI uri ->
 321                    canonical context (p_of_sym ens tl)
 322              | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
 323                  when LibraryObjects.is_trans_eq_URI uri_trans ->
 324                  let ty,l,m,r,p1,p2 = open_trans ens tl in
 325                    mk_trans uri_trans ty r m l
 326                      (canonical context (mk_sym uri_sym ty m r p2))
 327                      (canonical context (mk_sym uri_sym ty l m p1))
 328              | Cic.Appl (([Cic.Const(uri_feq,ens);ty1;ty2;f;x;y;p])) ->
 329
 330                  let eq_f_sym =
 331                    Cic.Const (UriManager.uri_of_string
 332                      "cic:/matita/logic/equality/eq_f1.con",[])
 333                  in
 334                  Cic.Appl (([eq_f_sym;ty1;ty2;f;x;y;p]))
 335
 336 (*
 337                  let sym_eq = Cic.Const(uri_sym,ens) in
 338                  let eq_f = Cic.Const(uri_feq,[]) in
 339                  let b = Cic.MutConstruct (UriManager.uri_of_string
 340                    "cic:/matita/datatypes/bool/bool.ind",0,1,[])
 341                  in
 342                  let u = ty1 in
 343                  let ctx = f in
 344                  let n = build_nat (count_args p) in
 345                  let h = head_of_apply p in
 346                  let predl = lambdaof true context (tyof context menv h) in
 347                  let predr = lambdaof false context (tyof context menv h) in
 348                  let args = tail_of_apply p in
 349                  let appl =
 350                    Cic.Appl
 351                     ([Cic.Const(UriManager.uri_of_string
 352                       "cic:/matita/paramodulation/rewrite.con",[]);
 353                       eq; sym_eq; eq_f; b; u; ctx; n; predl; predr; h] @
 354                       args)
 355                  in
 356                  appl
 357 *)
 358 (*
 359              | Cic.Appl (((Cic.Const(uri_ind,ens)) as he)::tl)
 360                  when LibraryObjects.is_eq_ind_URI uri_ind ||
 361                       LibraryObjects.is_eq_ind_r_URI uri_ind ->
 362                  let ty, what, pred, p1, other, p2 =
 363                    match tl with
 364                    | [ty;what;pred;p1;other;p2] -> ty, what, pred, p1, other, p2
 365                    | _ -> assert false
 366                  in
 367                  let pred,l,r =
 368                    match pred with
 369                    | Cic.Lambda (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;l;r])
 370                        when LibraryObjects.is_eq_URI uri ->
 371                          Cic.Lambda
 372                            (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;r;l]),l,r
 373                    | _ ->
 374                        prerr_endline (CicPp.ppterm pred);
 375                        assert false
 376                  in
 377                  let l = CicSubstitution.subst what l in
 378                  let r = CicSubstitution.subst what r in
 379                  Cic.Appl
 380                    [he;ty;what;pred;
 381                     canonical (mk_sym uri_sym ty l r p1);other;canonical p2]
 382 *)
 383              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
 384                  when LibraryObjects.is_eq_URI uri -> t
 385              | _ -> Cic.Appl (List.map (canonical context) args))
 386       | Cic.Appl l -> Cic.Appl (List.map (canonical context) l)
 387       | _ -> t
 388   in
 389   remove_refl (canonical context t)
 390 ;;
 391
 392 let ty_of_lambda = function
 393   | Cic.Lambda (_,ty,_) -> ty
 394   | _ -> assert false
 395 ;;
 396
 397 let compose_contexts ctx1 ctx2 =
 398   ProofEngineReduction.replace_lifting
 399     ~equality:(=) ~what:[Cic.Implicit(Some `Hole)] ~with_what:[ctx2] ~where:ctx1
 400 ;;
 401
 402 let put_in_ctx ctx t =
 403   ProofEngineReduction.replace_lifting
 404     ~equality:(=) ~what:[Cic.Implicit (Some `Hole)] ~with_what:[t] ~where:ctx
 405 ;;
 406
 407 let mk_eq uri ty l r =
 408   Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r]
 409 ;;
 410
 411 let mk_refl uri ty t =
 412   Cic.Appl [Cic.MutConstruct(uri,0,1,[]);ty;t]
 413 ;;
 414
 415 let open_eq = function
 416   | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
 417       uri, ty, l ,r
 418   | _ -> assert false
 419 ;;
 420
 421 let mk_feq uri_feq ty ty1 left pred right t =
 422   Cic.Appl [Cic.Const(uri_feq,[]);ty;ty1;pred;left;right;t]
 423 ;;
 424
 425 let rec look_ahead aux = function
 426   | Cic.Appl ((Cic.Const(uri_ind,ens))::tl) as t
 427         when LibraryObjects.is_eq_ind_URI uri_ind ||
 428              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 429           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 430           let ty2,eq,lp,rp = open_pred pred in
 431           let hole = Cic.Implicit (Some `Hole) in
 432           let ty2 = CicSubstitution.subst hole ty2 in
 433           aux ty1 (CicSubstitution.subst other lp) (CicSubstitution.subst other rp) hole ty2 t
 434   | Cic.Lambda (n,s,t) -> Cic.Lambda (n,s,look_ahead aux t)
 435   | t -> t
 436 ;;
 437
 438 let contextualize uri ty left right t =
 439   let hole = Cic.Implicit (Some `Hole) in
 440   (* aux [uri] [ty] [left] [right] [ctx] [ctx_ty] [t]
 441    *
 442    * the parameters validate this invariant
 443    *   t: eq(uri) ty left right
 444    * that is used only by the base case
 445    *
 446    * ctx is a term with an hole. Cic.Implicit(Some `Hole) is the empty context
 447    * ctx_ty is the type of ctx
 448    *)
 449     let rec aux uri ty left right ctx_d ctx_ty = function
 450       | Cic.Appl ((Cic.Const(uri_sym,ens))::tl)
 451         when LibraryObjects.is_sym_eq_URI uri_sym  ->
 452           let ty,l,r,p = open_sym ens tl in
 453           mk_sym uri_sym ty l r (aux uri ty l r ctx_d ctx_ty p)
 454       | Cic.LetIn (name,body,rest) ->
 455           Cic.LetIn (name,look_ahead (aux uri) body, aux uri ty left right ctx_d ctx_ty rest)
 456       | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
 457         when LibraryObjects.is_eq_ind_URI uri_ind ||
 458              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 459           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 460           let ty2,eq,lp,rp = open_pred pred in
 461           let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
 462           let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 463           let is_not_fixed_lp = is_not_fixed lp in
 464           let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
 465           (* extract the context and the fixed term from the predicate *)
 466           let m, ctx_c, ty2 =
 467             let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
 468             (* they were under a lambda *)
 469             let m =  CicSubstitution.subst hole m in
 470             let ctx_c = CicSubstitution.subst hole ctx_c in
 471             let ty2 = CicSubstitution.subst hole ty2 in
 472             m, ctx_c, ty2
 473           in
 474           (* create the compound context and put the terms under it *)
 475           let ctx_dc = compose_contexts ctx_d ctx_c in
 476           let dc_what = put_in_ctx ctx_dc what in
 477           let dc_other = put_in_ctx ctx_dc other in
 478           (* m is already in ctx_c so it is put in ctx_d only *)
 479           let d_m = put_in_ctx ctx_d m in
 480           (* we also need what in ctx_c *)
 481           let c_what = put_in_ctx ctx_c what in
 482           (* now put the proofs in the compound context *)
 483           let p1 = (* p1: dc_what = d_m *)
 484             if is_not_fixed_lp then
 485               aux uri ty2 c_what m ctx_d ctx_ty p1
 486             else
 487               mk_sym uri_sym ctx_ty d_m dc_what
 488                 (aux uri ty2 m c_what ctx_d ctx_ty p1)
 489           in
 490           let p2 = (* p2: dc_other = dc_what *)
 491             if avoid_eq_ind then
 492               mk_sym uri_sym ctx_ty dc_what dc_other
 493                 (aux uri ty1 what other ctx_dc ctx_ty p2)
 494             else
 495               aux uri ty1 other what ctx_dc ctx_ty p2
 496           in
 497           (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
 498              if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
 499           let a,b,c,paeqb,pbeqc =
 500             if is_not_fixed_lp then
 501               dc_other,dc_what,d_m,p2,p1
 502             else
 503               d_m,dc_what,dc_other,
 504                 (mk_sym uri_sym ctx_ty dc_what d_m p1),
 505                 (mk_sym uri_sym ctx_ty dc_other dc_what p2)
 506           in
 507           mk_trans uri_trans ctx_ty a b c paeqb pbeqc
 508     | t when ctx_d = hole -> t
 509     | t ->
 510 (*         let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in *)
 511 (*         let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in *)
 512         let uri_feq =
 513           UriManager.uri_of_string "cic:/matita/logic/equality/eq_f.con"
 514         in
 515         let pred =
 516 (*           let r = CicSubstitution.lift 1 (put_in_ctx ctx_d left) in *)
 517           let l =
 518             let ctx_d = CicSubstitution.lift 1 ctx_d in
 519             put_in_ctx ctx_d (Cic.Rel 1)
 520           in
 521 (*           let lty = CicSubstitution.lift 1 ctx_ty in  *)
 522 (*           Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r)) *)
 523           Cic.Lambda (Cic.Name "foo",ty,l)
 524         in
 525 (*         let d_left = put_in_ctx ctx_d left in *)
 526 (*         let d_right = put_in_ctx ctx_d right in *)
 527 (*         let refl_eq = mk_refl uri ctx_ty d_left in *)
 528 (*         mk_sym uri_sym ctx_ty d_right d_left *)
 529 (*           (mk_eq_ind uri_ind ty left pred refl_eq right t) *)
 530           (mk_feq uri_feq ty ctx_ty left pred right t)
 531   in
 532   aux uri ty left right hole ty t
 533 ;;
 534
 535 let contextualize_rewrites t ty =
 536   let eq,ty,l,r = open_eq ty in
 537   contextualize eq ty l r t
 538 ;;
 539
 540 let add_subst subst =
 541   function
 542     | Exact t -> Exact (Subst.apply_subst subst t)
 543     | Step (s,(rule, id1, (pos,id2), pred)) ->
 544         Step (Subst.concat subst s,(rule, id1, (pos,id2), pred))
 545 ;;
 546
 547 let build_proof_step eq lift subst p1 p2 pos l r pred =
 548   let p1 = Subst.apply_subst_lift lift subst p1 in
 549   let p2 = Subst.apply_subst_lift lift subst p2 in
 550   let l  = CicSubstitution.lift lift l in
 551   let l = Subst.apply_subst_lift lift subst l in
 552   let r  = CicSubstitution.lift lift r in
 553   let r = Subst.apply_subst_lift lift subst r in
 554   let pred = CicSubstitution.lift lift pred in
 555   let pred = Subst.apply_subst_lift lift subst pred in
 556   let ty,body =
 557     match pred with
 558       | Cic.Lambda (_,ty,body) -> ty,body
 559       | _ -> assert false
 560   in
 561   let what, other =
 562     if pos = Utils.Left then l,r else r,l
 563   in
 564   let p =
 565     match pos with
 566       | Utils.Left ->
 567         mk_eq_ind (LibraryObjects.eq_ind_URI ~eq) ty what pred p1 other p2
 568       | Utils.Right ->
 569         mk_eq_ind (LibraryObjects.eq_ind_r_URI ~eq) ty what pred p1 other p2
 570   in
 571     p
 572 ;;
 573
 574 let parametrize_proof p l r ty =
 575   let uniq l = HExtlib.list_uniq (List.sort Pervasives.compare l) in
 576   let mot = CicUtil.metas_of_term_set in
 577   let parameters = uniq ((*mot p @*) mot l @ mot r) in
 578   (* ?if they are under a lambda? *)
 579   let parameters =
 580     HExtlib.list_uniq (List.sort Pervasives.compare parameters)
 581   in
 582   let what = List.map (fun (i,l) -> Cic.Meta (i,l)) parameters in
 583   let with_what, lift_no =
 584     List.fold_right (fun _ (acc,n) -> ((Cic.Rel n)::acc),n+1) what ([],1)
 585   in
 586   let p = CicSubstitution.lift (lift_no-1) p in
 587   let p =
 588     ProofEngineReduction.replace_lifting
 589     ~equality:(fun t1 t2 ->
 590       match t1,t2 with Cic.Meta (i,_),Cic.Meta(j,_) -> i=j | _ -> false)
 591     ~what ~with_what ~where:p
 592   in
 593   let ty_of_m _ = ty (*function
 594     | Cic.Meta (i,_) -> List.assoc i menv
 595     | _ -> assert false *)
 596   in
 597   let args, proof,_ =
 598     List.fold_left
 599       (fun (instance,p,n) m ->
 600         (instance@[m],
 601         Cic.Lambda
 602           (Cic.Name ("x"^string_of_int n),
 603           CicSubstitution.lift (lift_no - n - 1) (ty_of_m m),
 604           p),
 605         n+1))
 606       ([Cic.Rel 1],p,1)
 607       what
 608   in
 609   let instance = match args with | [x] -> x | _ -> Cic.Appl args in
 610   proof, instance
 611 ;;
 612
 613 let wfo goalproof proof id =
 614   let rec aux acc id =
 615     let p,_,_ = proof_of_id id in
 616     match p with
 617     | Exact _ -> if (List.mem id acc) then acc else id :: acc
 618     | Step (_,(_,id1, (_,id2), _)) ->
 619         let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
 620         let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
 621         id :: acc
 622   in
 623   let acc =
 624     match proof with
 625       | Exact _ -> [id]
 626       | Step (_,(_,id1, (_,id2), _)) -> aux (aux [id] id1) id2
 627   in
 628   List.fold_left (fun acc (_,_,id,_,_) -> aux acc id) acc goalproof
 629 ;;
 630
 631 let string_of_id names id =
 632   if id = 0 then "" else
 633   try
 634     let (_,p,(_,l,r,_),m,_) = open_equality (Hashtbl.find id_to_eq id) in
 635     match p with
 636     | Exact t ->
 637         Printf.sprintf "%d = %s: %s = %s [%s]" id
 638           (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
 639         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 640     | Step (_,(step,id1, (_,id2), _) ) ->
 641         Printf.sprintf "%6d: %s %6d %6d   %s = %s [%s]" id
 642           (string_of_rule step)
 643           id1 id2 (CicPp.pp l names) (CicPp.pp r names)
 644         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 645   with
 646       Not_found -> assert false
 647
 648 let pp_proof names goalproof proof subst id initial_goal =
 649   String.concat "\n" (List.map (string_of_id names) (wfo goalproof proof id)) ^
 650   "\ngoal:\n   " ^
 651     (String.concat "\n   "
 652       (fst (List.fold_right
 653         (fun (r,pos,i,s,pred) (acc,g) ->
 654           let _,_,left,right = open_eq g in
 655           let ty =
 656             match pos with
 657             | Utils.Left -> CicReduction.head_beta_reduce (Cic.Appl[pred;right])
 658             | Utils.Right -> CicReduction.head_beta_reduce (Cic.Appl[pred;left])
 659           in
 660           let ty = Subst.apply_subst s ty in
 661           ("("^ string_of_rule r ^ " " ^ string_of_int i^") -> "
 662           ^ CicPp.pp ty names) :: acc,ty) goalproof ([],initial_goal)))) ^
 663   "\nand then subsumed by " ^ string_of_int id ^ " when " ^ Subst.ppsubst subst
 664 ;;
 665
 666 module OT =
 667   struct
 668     type t = int
 669     let compare = Pervasives.compare
 670   end
 671
 672 module M = Map.Make(OT)
 673
 674 let rec find_deps m i =
 675   if M.mem i m then m
 676   else
 677     let p,_,_ = proof_of_id i in
 678     match p with
 679     | Exact _ -> M.add i [] m
 680     | Step (_,(_,id1,(_,id2),_)) ->
 681         let m = find_deps m id1 in
 682         let m = find_deps m id2 in
 683         (* without the uniq there is a stack overflow doing concatenation *)
 684         let xxx = [id1;id2] @ M.find id1 m @ M.find id2 m in
 685         let xxx = HExtlib.list_uniq (List.sort Pervasives.compare xxx) in
 686         M.add i xxx m
 687 ;;
 688
 689 let topological_sort l =
 690   (* build the partial order relation *)
 691   let m = List.fold_left (fun m i -> find_deps m i) M.empty l in
 692   let m = (* keep only deps inside l *)
 693     List.fold_left
 694       (fun m' i ->
 695         M.add i (List.filter (fun x -> List.mem x l) (M.find i m)) m')
 696       M.empty l
 697   in
 698   let m = M.map (fun x -> Some x) m in
 699   (* utils *)
 700   let keys m = M.fold (fun i _ acc -> i::acc) m [] in
 701   let split l m = List.filter (fun i -> M.find i m = Some []) l in
 702   let purge l m =
 703     M.mapi
 704       (fun k v -> if List.mem k l then None else
 705          match v with
 706          | None -> None
 707          | Some ll -> Some (List.filter (fun i -> not (List.mem i l)) ll))
 708       m
 709   in
 710   let rec aux m res =
 711       let keys = keys m in
 712       let ok = split keys m in
 713       let m = purge ok m in
 714       let res = ok @ res in
 715       if ok = [] then res else aux m res
 716   in
 717   let rc = List.rev (aux m []) in
 718   rc
 719 ;;
 720
 721
 722 (* returns the list of ids that should be factorized *)
 723 let get_duplicate_step_in_wfo l p =
 724   let ol = List.rev l in
 725   let h = Hashtbl.create 13 in
 726   (* NOTE: here the n parameter is an approximation of the dependency
 727      between equations. To do things seriously we should maintain a
 728      dependency graph. This approximation is not perfect. *)
 729   let add i =
 730     let p,_,_ = proof_of_id i in
 731     match p with
 732     | Exact _ -> true
 733     | _ ->
 734         try
 735           let no = Hashtbl.find h i in
 736           Hashtbl.replace h i (no+1);
 737           false
 738         with Not_found -> Hashtbl.add h i 1;true
 739   in
 740   let rec aux = function
 741     | Exact _ -> ()
 742     | Step (_,(_,i1,(_,i2),_)) ->
 743         let go_on_1 = add i1 in
 744         let go_on_2 = add i2 in
 745         if go_on_1 then aux (let p,_,_ = proof_of_id i1 in p);
 746         if go_on_2 then aux (let p,_,_ = proof_of_id i2 in p)
 747   in
 748   aux p;
 749   List.iter
 750     (fun (_,_,id,_,_) -> aux (let p,_,_ = proof_of_id id in p))
 751     ol;
 752   (* now h is complete *)
 753   let proofs = Hashtbl.fold (fun k count acc-> (k,count)::acc) h [] in
 754   let proofs = List.filter (fun (_,c) -> c > 1) proofs in
 755   let res = topological_sort (List.map (fun (i,_) -> i) proofs) in
 756   res
 757 ;;
 758
 759 let build_proof_term eq h lift proof =
 760   let proof_of_id aux id =
 761     let p,l,r = proof_of_id id in
 762     try List.assoc id h,l,r with Not_found -> aux p, l, r
 763   in
 764   let rec aux = function
 765      | Exact term ->
 766          CicSubstitution.lift lift term
 767      | Step (subst,(rule, id1, (pos,id2), pred)) ->
 768          let p1,_,_ = proof_of_id aux id1 in
 769          let p2,l,r = proof_of_id aux id2 in
 770          let varname =
 771            match rule with
 772            | SuperpositionRight -> Cic.Name ("SupR" ^ Utils.string_of_pos pos)
 773            | Demodulation -> Cic.Name ("DemEq"^ Utils.string_of_pos pos)
 774            | _ -> assert false
 775          in
 776          let pred =
 777            match pred with
 778            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 779            | _ -> assert false
 780          in
 781          let p = build_proof_step eq lift subst p1 p2 pos l r pred in
 782 (*         let cond =  (not (List.mem 302 (Utils.metas_of_term p)) || id1 = 8 || id1 = 132) in
 783            if not cond then
 784              prerr_endline ("ERROR " ^ string_of_int id1 ^ " " ^ string_of_int id2);
 785            assert cond;*)
 786            p
 787   in
 788    aux proof
 789 ;;
 790
 791 let build_goal_proof eq l initial ty se context menv =
 792   let se = List.map (fun i -> Cic.Meta (i,[])) se in
 793   let lets = get_duplicate_step_in_wfo l initial in
 794   let letsno = List.length lets in
 795   let _,mty,_,_ = open_eq ty in
 796   let lift_list l = List.map (fun (i,t) -> i,CicSubstitution.lift 1 t) l in
 797   let lets,_,h =
 798     List.fold_left
 799       (fun (acc,n,h) id ->
 800         let p,l,r = proof_of_id id in
 801         let cic = build_proof_term eq h n p in
 802         let real_cic,instance =
 803           parametrize_proof cic l r (CicSubstitution.lift n mty)
 804         in
 805         let h = (id, instance)::lift_list h in
 806         acc@[id,real_cic],n+1,h)
 807       ([],0,[]) lets
 808   in
 809   let proof,se =
 810     let rec aux se current_proof = function
 811       | [] -> current_proof,se
 812       | (rule,pos,id,subst,pred)::tl ->
 813           let p,l,r = proof_of_id id in
 814            let p = build_proof_term eq h letsno p in
 815            let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
 816          let varname =
 817            match rule with
 818            | SuperpositionLeft -> Cic.Name ("SupL" ^ Utils.string_of_pos pos)
 819            | Demodulation -> Cic.Name ("DemG"^ Utils.string_of_pos pos)
 820            | _ -> assert false
 821          in
 822          let pred =
 823            match pred with
 824            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 825            | _ -> assert false
 826          in
 827            let proof =
 828              build_proof_step eq letsno subst current_proof p pos l r pred
 829            in
 830            let proof,se = aux se proof tl in
 831            Subst.apply_subst_lift letsno subst proof,
 832            List.map (fun x -> Subst.apply_subst_lift letsno subst x) se
 833     in
 834     aux se (build_proof_term eq h letsno initial) l
 835   in
 836   let n,proof =
 837     let initial = proof in
 838     List.fold_right
 839       (fun (id,cic) (n,p) ->
 840         n-1,
 841         Cic.LetIn (
 842           Cic.Name ("H"^string_of_int id),
 843           cic, p))
 844     lets (letsno-1,initial)
 845   in
 846    canonical
 847      (contextualize_rewrites proof (CicSubstitution.lift letsno ty))
 848      context menv,
 849    se
 850 ;;
 851
 852 let refl_proof eq_uri ty term =
 853   Cic.Appl [Cic.MutConstruct (eq_uri, 0, 1, []); ty; term]
 854 ;;
 855
 856 let metas_of_proof p =
 857   let eq =
 858     match LibraryObjects.eq_URI () with
 859     | Some u -> u
 860     | None ->
 861         raise
 862           (ProofEngineTypes.Fail
 863             (lazy "No default equality defined when calling metas_of_proof"))
 864   in
 865   let p = build_proof_term eq [] 0 p in
 866   Utils.metas_of_term p
 867 ;;
 868
 869 let remove_local_context eq =
 870    let w, p, (ty, left, right, o), menv,id = open_equality eq in
 871    let p = Utils.remove_local_context p in
 872    let ty = Utils.remove_local_context ty in
 873    let left = Utils.remove_local_context left in
 874    let right = Utils.remove_local_context right in
 875    w, p, (ty, left, right, o), menv, id
 876 ;;
 877
 878 let relocate newmeta menv to_be_relocated =
 879   let subst, newmetasenv, newmeta =
 880     List.fold_right
 881       (fun i (subst, metasenv, maxmeta) ->
 882         let _,context,ty = CicUtil.lookup_meta i menv in
 883         let irl = [] in
 884         let newmeta = Cic.Meta(maxmeta,irl) in
 885         let newsubst = Subst.buildsubst i context newmeta ty subst in
 886         newsubst, (maxmeta,context,ty)::metasenv, maxmeta+1)
 887       to_be_relocated (Subst.empty_subst, [], newmeta+1)
 888   in
 889   let menv = Subst.apply_subst_metasenv subst menv @ newmetasenv in
 890   subst, menv, newmeta
 891
 892 let fix_metas_goal newmeta goal =
 893   let (proof, menv, ty) = goal in
 894   let to_be_relocated =
 895     HExtlib.list_uniq (List.sort Pervasives.compare (Utils.metas_of_term ty))
 896   in
 897   let subst, menv, newmeta = relocate newmeta menv to_be_relocated in
 898   let ty = Subst.apply_subst subst ty in
 899   let proof =
 900     match proof with
 901     | [] -> assert false (* is a nonsense to relocate the initial goal *)
 902     | (r,pos,id,s,p) :: tl -> (r,pos,id,Subst.concat subst s,p) :: tl
 903   in
 904   newmeta+1,(proof, menv, ty)
 905 ;;
 906
 907 let fix_metas newmeta eq =
 908   let w, p, (ty, left, right, o), menv,_ = open_equality eq in
 909   let to_be_relocated =
 910 (* List.map (fun i ,_,_ -> i) menv *)
 911     HExtlib.list_uniq
 912       (List.sort Pervasives.compare
 913          (Utils.metas_of_term left @ Utils.metas_of_term right))
 914   in
 915   let subst, metasenv, newmeta = relocate newmeta menv to_be_relocated in
 916   let ty = Subst.apply_subst subst ty in
 917   let left = Subst.apply_subst subst left in
 918   let right = Subst.apply_subst subst right in
 919   let fix_proof = function
 920     | Exact p -> Exact (Subst.apply_subst subst p)
 921     | Step (s,(r,id1,(pos,id2),pred)) ->
 922         Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
 923   in
 924   let p = fix_proof p in
 925   let eq' = mk_equality (w, p, (ty, left, right, o), metasenv) in
 926   newmeta+1, eq'
 927
 928 exception NotMetaConvertible;;
 929
 930 let meta_convertibility_aux table t1 t2 =
 931   let module C = Cic in
 932   let rec aux ((table_l, table_r) as table) t1 t2 =
 933     match t1, t2 with
 934     | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
 935         let tl1, tl2 = [],[] in
 936         let m1_binding, table_l =
 937           try List.assoc m1 table_l, table_l
 938           with Not_found -> m2, (m1, m2)::table_l
 939         and m2_binding, table_r =
 940           try List.assoc m2 table_r, table_r
 941           with Not_found -> m1, (m2, m1)::table_r
 942         in
 943         if (m1_binding <> m2) || (m2_binding <> m1) then
 944           raise NotMetaConvertible
 945         else (
 946           try
 947             List.fold_left2
 948               (fun res t1 t2 ->
 949                  match t1, t2 with
 950                  | None, Some _ | Some _, None -> raise NotMetaConvertible
 951                  | None, None -> res
 952                  | Some t1, Some t2 -> (aux res t1 t2))
 953               (table_l, table_r) tl1 tl2
 954           with Invalid_argument _ ->
 955             raise NotMetaConvertible
 956         )
 957     | C.Var (u1, ens1), C.Var (u2, ens2)
 958     | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
 959         aux_ens table ens1 ens2
 960     | C.Cast (s1, t1), C.Cast (s2, t2)
 961     | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
 962     | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
 963     | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
 964         let table = aux table s1 s2 in
 965         aux table t1 t2
 966     | C.Appl l1, C.Appl l2 -> (
 967         try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 968         with Invalid_argument _ -> raise NotMetaConvertible
 969       )
 970     | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
 971         when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
 972     | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
 973         when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
 974         aux_ens table ens1 ens2
 975     | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
 976         when (UriManager.eq u1 u2) && i1 = i2 ->
 977         let table = aux table s1 s2 in
 978         let table = aux table t1 t2 in (
 979           try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 980           with Invalid_argument _ -> raise NotMetaConvertible
 981         )
 982     | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
 983         try
 984           List.fold_left2
 985             (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
 986                if i1 <> i2 then raise NotMetaConvertible
 987                else
 988                  let res = (aux res s1 s2) in aux res t1 t2)
 989             table il1 il2
 990         with Invalid_argument _ -> raise NotMetaConvertible
 991       )
 992     | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
 993         try
 994           List.fold_left2
 995             (fun res (n1, s1, t1) (n2, s2, t2) ->
 996                let res = aux res s1 s2 in aux res t1 t2)
 997             table il1 il2
 998         with Invalid_argument _ -> raise NotMetaConvertible
 999       )
1000     | t1, t2 when t1 = t2 -> table
1001     | _, _ -> raise NotMetaConvertible
1002
1003   and aux_ens table ens1 ens2 =
1004     let cmp (u1, t1) (u2, t2) =
1005       Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
1006     in
1007     let ens1 = List.sort cmp ens1
1008     and ens2 = List.sort cmp ens2 in
1009     try
1010       List.fold_left2
1011         (fun res (u1, t1) (u2, t2) ->
1012            if not (UriManager.eq u1 u2) then raise NotMetaConvertible
1013            else aux res t1 t2)
1014         table ens1 ens2
1015     with Invalid_argument _ -> raise NotMetaConvertible
1016   in
1017   aux table t1 t2
1018 ;;
1019
1020
1021 let meta_convertibility_eq eq1 eq2 =
1022   let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
1023   let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
1024   if ty <> ty' then
1025     false
1026   else if (left = left') && (right = right') then
1027     true
1028   else if (left = right') && (right = left') then
1029     true
1030   else
1031     try
1032       let table = meta_convertibility_aux ([], []) left left' in
1033       let _ = meta_convertibility_aux table right right' in
1034       true
1035     with NotMetaConvertible ->
1036       try
1037         let table = meta_convertibility_aux ([], []) left right' in
1038         let _ = meta_convertibility_aux table right left' in
1039         true
1040       with NotMetaConvertible ->
1041         false
1042 ;;
1043
1044
1045 let meta_convertibility t1 t2 =
1046   if t1 = t2 then
1047     true
1048   else
1049     try
1050       ignore(meta_convertibility_aux ([], []) t1 t2);
1051       true
1052     with NotMetaConvertible ->
1053       false
1054 ;;
1055
1056 exception TermIsNotAnEquality;;
1057
1058 let term_is_equality term =
1059   match term with
1060   | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _]
1061     when LibraryObjects.is_eq_URI uri -> true
1062   | _ -> false
1063 ;;
1064
1065 let equality_of_term proof term =
1066   match term with
1067   | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2]
1068     when LibraryObjects.is_eq_URI uri ->
1069       let o = !Utils.compare_terms t1 t2 in
1070       let stat = (ty,t1,t2,o) in
1071       let w = Utils.compute_equality_weight stat in
1072       let e = mk_equality (w, Exact proof, stat,[]) in
1073       e
1074   | _ ->
1075       raise TermIsNotAnEquality
1076 ;;
1077
1078 let is_weak_identity eq =
1079   let _,_,(_,left, right,_),_,_ = open_equality eq in
1080   left = right || meta_convertibility left right
1081 ;;
1082
1083 let is_identity (_, context, ugraph) eq =
1084   let _,_,(ty,left,right,_),menv,_ = open_equality eq in
1085   left = right ||
1086   (* (meta_convertibility left right)) *)
1087   fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
1088 ;;
1089
1090
1091 let term_of_equality eq_uri equality =
1092   let _, _, (ty, left, right, _), menv, _= open_equality equality in
1093   let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
1094   let argsno = List.length menv in
1095   let t =
1096     CicSubstitution.lift argsno
1097       (Cic.Appl [Cic.MutInd (eq_uri, 0, []); ty; left; right])
1098   in
1099   snd (
1100     List.fold_right
1101       (fun (i,_,ty) (n, t) ->
1102          let name = Cic.Name ("X" ^ (string_of_int n)) in
1103          let ty = CicSubstitution.lift (n-1) ty in
1104          let t =
1105            ProofEngineReduction.replace
1106              ~equality:eq ~what:[i]
1107              ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
1108          in
1109            (n-1, Cic.Prod (name, ty, t)))
1110       menv (argsno, t))
1111 ;;
1112
1113 let symmetric eq_ty l id uri m =
1114   let eq = Cic.MutInd(uri,0,[]) in
1115   let pred =
1116     Cic.Lambda (Cic.Name "Sym",eq_ty,
1117      Cic.Appl [CicSubstitution.lift 1 eq ;
1118                CicSubstitution.lift 1 eq_ty;
1119                Cic.Rel 1;CicSubstitution.lift 1 l])
1120   in
1121   let prefl =
1122     Exact (Cic.Appl
1123       [Cic.MutConstruct(uri,0,1,[]);eq_ty;l])
1124   in
1125   let id1 =
1126     let eq = mk_equality (0,prefl,(eq_ty,l,l,Utils.Eq),m) in
1127     let (_,_,_,_,id) = open_equality eq in
1128     id
1129   in
1130   Step(Subst.empty_subst,
1131     (Demodulation,id1,(Utils.Left,id),pred))
1132 ;;
1133
1134 module IntOT = struct
1135   type t = int
1136   let compare = Pervasives.compare
1137 end
1138
1139 module IntSet = Set.Make(IntOT);;
1140
1141 let n_purged = ref 0;;
1142
1143 let collect alive1 alive2 alive3 =
1144   let _ = <:start<collect>> in
1145   let deps_of id =
1146     let p,_,_ = proof_of_id id in
1147     match p with
1148     | Exact _ -> IntSet.empty
1149     | Step (_,(_,id1,(_,id2),_)) ->
1150           IntSet.add id1 (IntSet.add id2 IntSet.empty)
1151   in
1152   let rec close s =
1153     let news = IntSet.fold (fun id s -> IntSet.union (deps_of id) s) s s in
1154     if IntSet.equal news s then s else close news
1155   in
1156   let l_to_s s l = List.fold_left (fun s x -> IntSet.add x s) s l in
1157   let alive_set = l_to_s (l_to_s (l_to_s IntSet.empty alive2) alive1) alive3 in
1158   let closed_alive_set = close alive_set in
1159   let to_purge =
1160     Hashtbl.fold
1161       (fun k _ s ->
1162         if not (IntSet.mem k closed_alive_set) then
1163           k::s else s) id_to_eq []
1164   in
1165   n_purged := !n_purged + List.length to_purge;
1166   List.iter (Hashtbl.remove id_to_eq) to_purge;
1167   let _ = <:stop<collect>> in ()
1168 ;;
1169
1170 let id_of e =
1171   let _,_,_,_,id = open_equality e in id
1172 ;;
1173
1174 let get_stats () =
1175   <:show<Equality.>> ^
1176   "# of purged eq by the collector: " ^ string_of_int !n_purged ^ "\n"
1177 ;;