helm/software/components/tactics/paramodulation/equality.ml

   1 (* cOpyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id: inference.ml 6245 2006-04-05 12:07:51Z tassi $ *)
  27
  28 type rule = SuperpositionRight | SuperpositionLeft | Demodulation
  29 type uncomparable = int -> int
  30 type equality =
  31     uncomparable *       (* trick to break structural equality *)
  32     int  *               (* weight *)
  33     proof *
  34     (Cic.term *          (* type *)
  35      Cic.term *          (* left side *)
  36      Cic.term *          (* right side *)
  37      Utils.comparison) * (* ordering *)
  38     Cic.metasenv  *      (* environment for metas *)
  39     int                  (* id *)
  40 and proof =
  41   | Exact of Cic.term
  42   | Step of Subst.substitution * (rule * int*(Utils.pos*int)* Cic.term)
  43             (* subst, (rule,eq1, eq2,predicate) *)
  44 and goal_proof = (rule * Utils.pos * int * Subst.substitution * Cic.term) list
  45 ;;
  46
  47 (* globals *)
  48 let maxid = ref 0;;
  49 let id_to_eq = Hashtbl.create 1024;;
  50
  51 let freshid () =
  52   incr maxid; !maxid
  53 ;;
  54
  55 let reset () =
  56   maxid := 0;
  57   Hashtbl.clear  id_to_eq
  58 ;;
  59
  60 let uncomparable = fun _ -> 0
  61
  62 let mk_equality (weight,p,(ty,l,r,o),m) =
  63   let id = freshid () in
  64   let eq = (uncomparable,weight,p,(ty,l,r,o),m,id) in
  65   Hashtbl.add id_to_eq id eq;
  66   eq
  67 ;;
  68
  69 let mk_tmp_equality (weight,(ty,l,r,o),m) =
  70   let id = -1 in
  71   uncomparable,weight,Exact (Cic.Implicit None),(ty,l,r,o),m,id
  72 ;;
  73
  74
  75 let open_equality (_,weight,proof,(ty,l,r,o),m,id) =
  76   (weight,proof,(ty,l,r,o),m,id)
  77
  78 let string_of_rule = function
  79   | SuperpositionRight -> "SupR"
  80   | SuperpositionLeft -> "SupL"
  81   | Demodulation -> "Demod"
  82 ;;
  83
  84 let string_of_equality ?env eq =
  85   match env with
  86   | None ->
  87       let w, _, (ty, left, right, o), m , id = open_equality eq in
  88       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  89               id w (CicPp.ppterm ty)
  90               (CicPp.ppterm left)
  91               (Utils.string_of_comparison o) (CicPp.ppterm right)
  92         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
  93   | Some (_, context, _) ->
  94       let names = Utils.names_of_context context in
  95       let w, _, (ty, left, right, o), m , id = open_equality eq in
  96       Printf.sprintf "Id: %d, Weight: %d, {%s}: %s =(%s) %s [%s]"
  97               id w (CicPp.pp ty names)
  98               (CicPp.pp left names) (Utils.string_of_comparison o)
  99               (CicPp.pp right names)
 100         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 101 ;;
 102
 103 let compare (_,_,_,s1,_,_) (_,_,_,s2,_,_) =
 104   Pervasives.compare s1 s2
 105 ;;
 106
 107 let proof_of_id id =
 108   try
 109     let (_,p,(_,l,r,_),_,_) = open_equality (Hashtbl.find id_to_eq id) in
 110       p,l,r
 111   with
 112       Not_found -> assert false
 113
 114
 115 let string_of_proof ?(names=[]) p gp =
 116   let str_of_pos = function
 117     | Utils.Left -> "left"
 118     | Utils.Right -> "right"
 119   in
 120   let fst3 (x,_,_) = x in
 121   let rec aux margin name =
 122     let prefix = String.make margin ' ' ^ name ^ ": " in function
 123     | Exact t ->
 124         Printf.sprintf "%sExact (%s)\n"
 125           prefix (CicPp.pp t names)
 126     | Step (subst,(rule,eq1,(pos,eq2),pred)) ->
 127         Printf.sprintf "%s%s(%s|%d with %d dir %s pred %s))\n"
 128           prefix (string_of_rule rule) (Subst.ppsubst ~names subst) eq1 eq2 (str_of_pos pos)
 129           (CicPp.pp pred names)^
 130         aux (margin+1) (Printf.sprintf "%d" eq1) (fst3 (proof_of_id eq1)) ^
 131         aux (margin+1) (Printf.sprintf "%d" eq2) (fst3 (proof_of_id eq2))
 132   in
 133   aux 0 "" p ^
 134   String.concat "\n"
 135     (List.map
 136       (fun (r,pos,i,s,t) ->
 137         (Printf.sprintf
 138           "GOAL: %s %s %d %s %s\n" (string_of_rule r)
 139             (str_of_pos pos) i (Subst.ppsubst ~names s) (CicPp.pp t names)) ^
 140         aux 1 (Printf.sprintf "%d " i) (fst3 (proof_of_id i)))
 141       gp)
 142 ;;
 143
 144 let rec depend eq id seen =
 145   let (_,p,(_,_,_,_),_,ideq) = open_equality eq in
 146   if List.mem ideq seen then
 147     false,seen
 148   else
 149     if id = ideq then
 150       true,seen
 151     else
 152       match p with
 153       | Exact _ -> false,seen
 154       | Step (_,(_,id1,(_,id2),_)) ->
 155           let seen = ideq::seen in
 156           let eq1 = Hashtbl.find id_to_eq id1 in
 157           let eq2 = Hashtbl.find id_to_eq id2 in
 158           let b1,seen = depend eq1 id seen in
 159           if b1 then b1,seen else depend eq2 id seen
 160 ;;
 161
 162 let depend eq id = fst (depend eq id []);;
 163
 164 let ppsubst = Subst.ppsubst ~names:[];;
 165
 166 (* returns an explicit named subst and a list of arguments for sym_eq_URI *)
 167 let build_ens uri termlist =
 168   let obj, _ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 169   match obj with
 170   | Cic.Constant (_, _, _, uris, _) ->
 171       assert (List.length uris <= List.length termlist);
 172       let rec aux = function
 173         | [], tl -> [], tl
 174         | (uri::uris), (term::tl) ->
 175             let ens, args = aux (uris, tl) in
 176             (uri, term)::ens, args
 177         | _, _ -> assert false
 178       in
 179       aux (uris, termlist)
 180   | _ -> assert false
 181 ;;
 182
 183 let mk_sym uri ty t1 t2 p =
 184   let ens, args =  build_ens uri [ty;t1;t2;p] in
 185     Cic.Appl (Cic.Const(uri, ens) :: args)
 186 ;;
 187
 188 let mk_trans uri ty t1 t2 t3 p12 p23 =
 189   let ens, args = build_ens uri [ty;t1;t2;t3;p12;p23] in
 190     Cic.Appl (Cic.Const (uri, ens) :: args)
 191 ;;
 192
 193 let mk_eq_ind uri ty what pred p1 other p2 =
 194  Cic.Appl [Cic.Const (uri, []); ty; what; pred; p1; other; p2]
 195 ;;
 196
 197 let p_of_sym ens tl =
 198   let args = List.map snd ens @ tl in
 199   match args with
 200     | [_;_;_;p] -> p
 201     | _ -> assert false
 202 ;;
 203
 204 let open_trans ens tl =
 205   let args = List.map snd ens @ tl in
 206   match args with
 207     | [ty;l;m;r;p1;p2] -> ty,l,m,r,p1,p2
 208     | _ -> assert false
 209 ;;
 210
 211 let open_sym ens tl =
 212   let args = List.map snd ens @ tl in
 213   match args with
 214     | [ty;l;r;p] -> ty,l,r,p
 215     | _ -> assert false
 216 ;;
 217
 218 let open_eq_ind args =
 219   match args with
 220   | [ty;l;pred;pl;r;pleqr] -> ty,l,pred,pl,r,pleqr
 221   | _ -> assert false
 222 ;;
 223
 224 let open_pred pred =
 225   match pred with
 226   | Cic.Lambda (_,ty,(Cic.Appl [Cic.MutInd (uri, 0,_);_;l;r]))
 227      when LibraryObjects.is_eq_URI uri -> ty,uri,l,r
 228   | _ -> prerr_endline (CicPp.ppterm pred); assert false
 229 ;;
 230
 231 let is_not_fixed t =
 232    CicSubstitution.subst (Cic.Implicit None) t <>
 233    CicSubstitution.subst (Cic.Rel 1) t
 234 ;;
 235
 236
 237 let canonical t =
 238   let rec remove_refl t =
 239     match t with
 240     | Cic.Appl (((Cic.Const(uri_trans,ens))::tl) as args)
 241           when LibraryObjects.is_trans_eq_URI uri_trans ->
 242           let ty,l,m,r,p1,p2 = open_trans ens tl in
 243             (match p1,p2 with
 244               | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_],p2 ->
 245                   remove_refl p2
 246               | p1,Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] ->
 247                   remove_refl p1
 248               | _ -> Cic.Appl (List.map remove_refl args))
 249     | Cic.Appl l -> Cic.Appl (List.map remove_refl l)
 250     | Cic.LetIn (name,bo,rest) ->
 251         Cic.LetIn (name,remove_refl bo,remove_refl rest)
 252     | _ -> t
 253   in
 254   let rec canonical t =
 255     match t with
 256       | Cic.LetIn(name,bo,rest) -> Cic.LetIn(name,canonical bo,canonical rest)
 257       | Cic.Appl (((Cic.Const(uri_sym,ens))::tl) as args)
 258           when LibraryObjects.is_sym_eq_URI uri_sym ->
 259           (match p_of_sym ens tl with
 260              | Cic.Appl ((Cic.Const(uri,ens))::tl)
 261                  when LibraryObjects.is_sym_eq_URI uri ->
 262                    canonical (p_of_sym ens tl)
 263              | Cic.Appl ((Cic.Const(uri_trans,ens))::tl)
 264                  when LibraryObjects.is_trans_eq_URI uri_trans ->
 265                  let ty,l,m,r,p1,p2 = open_trans ens tl in
 266                    mk_trans uri_trans ty r m l
 267                      (canonical (mk_sym uri_sym ty m r p2))
 268                      (canonical (mk_sym uri_sym ty l m p1))
 269              | Cic.Appl (((Cic.Const(uri_ind,ens)) as he)::tl)
 270                  when LibraryObjects.is_eq_ind_URI uri_ind ||
 271                       LibraryObjects.is_eq_ind_r_URI uri_ind ->
 272                  let ty, what, pred, p1, other, p2 =
 273                    match tl with
 274                    | [ty;what;pred;p1;other;p2] -> ty, what, pred, p1, other, p2
 275                    | _ -> assert false
 276                  in
 277                  let pred,l,r =
 278                    match pred with
 279                    | Cic.Lambda (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;l;r])
 280                        when LibraryObjects.is_eq_URI uri ->
 281                          Cic.Lambda
 282                            (name,s,Cic.Appl [Cic.MutInd(uri,0,ens);ty;r;l]),l,r
 283                    | _ ->
 284                        prerr_endline (CicPp.ppterm pred);
 285                        assert false
 286                  in
 287                  let l = CicSubstitution.subst what l in
 288                  let r = CicSubstitution.subst what r in
 289                  Cic.Appl
 290                    [he;ty;what;pred;
 291                     canonical (mk_sym uri_sym ty l r p1);other;canonical p2]
 292              | Cic.Appl [Cic.MutConstruct (uri, 0, 1,_);_;_] as t
 293                  when LibraryObjects.is_eq_URI uri -> t
 294              | _ -> Cic.Appl (List.map canonical args))
 295       | Cic.Appl l -> Cic.Appl (List.map canonical l)
 296       | _ -> t
 297   in
 298   remove_refl (canonical t)
 299 ;;
 300
 301 let ty_of_lambda = function
 302   | Cic.Lambda (_,ty,_) -> ty
 303   | _ -> assert false
 304 ;;
 305
 306 let compose_contexts ctx1 ctx2 =
 307   ProofEngineReduction.replace_lifting
 308     ~equality:(=) ~what:[Cic.Rel 1] ~with_what:[ctx2] ~where:ctx1
 309 ;;
 310
 311 let put_in_ctx ctx t =
 312   ProofEngineReduction.replace_lifting
 313     ~equality:(=) ~what:[Cic.Rel 1] ~with_what:[t] ~where:ctx
 314 ;;
 315
 316 let mk_eq uri ty l r =
 317   Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r]
 318 ;;
 319
 320 let mk_refl uri ty t =
 321   Cic.Appl [Cic.MutConstruct(uri,0,1,[]);ty;t]
 322 ;;
 323
 324 let open_eq = function
 325   | Cic.Appl [Cic.MutInd(uri,0,[]);ty;l;r] when LibraryObjects.is_eq_URI uri ->
 326       uri, ty, l ,r
 327   | _ -> assert false
 328 ;;
 329
 330 let contextualize uri ty left right t =
 331   (* aux [uri] [ty] [left] [right] [ctx] [t]
 332    *
 333    * the parameters validate this invariant
 334    *   t: eq(uri) ty left right
 335    * that is used only by the base case
 336    *
 337    * ctx is a term with an open (Rel 1). (Rel 1) is the empty context
 338    *)
 339     let rec aux uri ty left right ctx_d = function
 340       | Cic.Appl ((Cic.Const(uri_sym,ens))::tl)
 341         when LibraryObjects.is_sym_eq_URI uri_sym  ->
 342           let ty,l,r,p = open_sym ens tl in
 343           mk_sym uri_sym ty l r (aux uri ty l r ctx_d p)
 344       | Cic.LetIn (name,body,rest) ->
 345           (* we should go in body *)
 346           Cic.LetIn (name,body,aux uri ty left right ctx_d rest)
 347       | Cic.Appl ((Cic.Const(uri_ind,ens))::tl)
 348         when LibraryObjects.is_eq_ind_URI uri_ind ||
 349              LibraryObjects.is_eq_ind_r_URI uri_ind ->
 350           let ty1,what,pred,p1,other,p2 = open_eq_ind tl in
 351           let ty2,eq,lp,rp = open_pred pred in
 352           let uri_trans = LibraryObjects.trans_eq_URI ~eq:uri in
 353           let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 354           let is_not_fixed_lp = is_not_fixed lp in
 355           let avoid_eq_ind = LibraryObjects.is_eq_ind_URI uri_ind in
 356           (* extract the context and the fixed term from the predicate *)
 357           let m, ctx_c =
 358             let m, ctx_c = if is_not_fixed_lp then rp,lp else lp,rp in
 359             (* they were under a lambda *)
 360             let m =  CicSubstitution.subst (Cic.Implicit None) m in
 361             let ctx_c = CicSubstitution.subst (Cic.Rel 1) ctx_c in
 362             m, ctx_c
 363           in
 364           (* create the compound context and put the terms under it *)
 365           let ctx_dc = compose_contexts ctx_d ctx_c in
 366           let dc_what = put_in_ctx ctx_dc what in
 367           let dc_other = put_in_ctx ctx_dc other in
 368           (* m is already in ctx_c so it is put in ctx_d only *)
 369           let d_m = put_in_ctx ctx_d m in
 370           (* we also need what in ctx_c *)
 371           let c_what = put_in_ctx ctx_c what in
 372           (* now put the proofs in the compound context *)
 373           let p1 = (* p1: dc_what = d_m *)
 374             if is_not_fixed_lp then
 375               aux uri ty1 c_what m ctx_d p1
 376             else
 377               mk_sym uri_sym ty d_m dc_what
 378                 (aux uri ty1 m c_what ctx_d p1)
 379           in
 380           let p2 = (* p2: dc_other = dc_what *)
 381             if avoid_eq_ind then
 382               mk_sym uri_sym ty dc_what dc_other
 383                 (aux uri ty1 what other ctx_dc p2)
 384             else
 385               aux uri ty1 other what ctx_dc p2
 386           in
 387           (* if pred = \x.C[x]=m --> t : C[other]=m --> trans other what m
 388              if pred = \x.m=C[x] --> t : m=C[other] --> trans m what other *)
 389           let a,b,c,paeqb,pbeqc =
 390             if is_not_fixed_lp then
 391               dc_other,dc_what,d_m,p2,p1
 392             else
 393               d_m,dc_what,dc_other,
 394                 (mk_sym uri_sym ty dc_what d_m p1),
 395                 (mk_sym uri_sym ty dc_other dc_what p2)
 396           in
 397           mk_trans uri_trans ty a b c paeqb pbeqc
 398     | t ->
 399         let uri_sym = LibraryObjects.sym_eq_URI ~eq:uri in
 400         let uri_ind = LibraryObjects.eq_ind_URI ~eq:uri in
 401         let pred =
 402           (* ctx_d will go under a lambda, but put_in_ctx substitutes Rel 1 *)
 403           let ctx_d = CicSubstitution.lift_from 2 1 ctx_d in (* bleah *)
 404           let r = put_in_ctx ctx_d (CicSubstitution.lift 1 left) in
 405           let l = ctx_d in
 406           let lty = CicSubstitution.lift 1 ty in
 407           Cic.Lambda (Cic.Name "foo",ty,(mk_eq uri lty l r))
 408         in
 409         let d_left = put_in_ctx ctx_d left in
 410         let d_right = put_in_ctx ctx_d right in
 411         let refl_eq = mk_refl uri ty d_left in
 412         mk_sym uri_sym ty d_right d_left
 413           (mk_eq_ind uri_ind ty left pred refl_eq right t)
 414   in
 415   let empty_context = Cic.Rel 1 in
 416   aux uri ty left right empty_context t
 417 ;;
 418
 419 let contextualize_rewrites t ty =
 420   let eq,ty,l,r = open_eq ty in
 421   contextualize eq ty l r t
 422 ;;
 423
 424 let build_proof_step ?(sym=false) lift subst p1 p2 pos l r pred =
 425   let p1 = Subst.apply_subst_lift lift subst p1 in
 426   let p2 = Subst.apply_subst_lift lift subst p2 in
 427   let l  = CicSubstitution.lift lift l in
 428   let l = Subst.apply_subst_lift lift subst l in
 429   let r  = CicSubstitution.lift lift r in
 430   let r = Subst.apply_subst_lift lift subst r in
 431   let pred = CicSubstitution.lift lift pred in
 432   let pred = Subst.apply_subst_lift lift subst pred in
 433   let ty,body =
 434     match pred with
 435       | Cic.Lambda (_,ty,body) -> ty,body
 436       | _ -> assert false
 437   in
 438   let what, other =
 439     if pos = Utils.Left then l,r else r,l
 440   in
 441   let p =
 442     match pos with
 443       | Utils.Left ->
 444         mk_eq_ind (Utils.eq_ind_URI ()) ty what pred p1 other p2
 445       | Utils.Right ->
 446         mk_eq_ind (Utils.eq_ind_r_URI ()) ty what pred p1 other p2
 447   in
 448   if sym then
 449     let uri,pl,pr =
 450       let eq,_,pl,pr = open_eq body in
 451       LibraryObjects.sym_eq_URI ~eq, pl, pr
 452     in
 453     let l = CicSubstitution.subst other pl in
 454     let r = CicSubstitution.subst other pr in
 455     mk_sym uri ty l r p
 456   else
 457     p
 458 ;;
 459
 460 let parametrize_proof p l r ty =
 461   let parameters = CicUtil.metas_of_term p
 462 @ CicUtil.metas_of_term l
 463 @ CicUtil.metas_of_term r
 464 in (* ?if they are under a lambda? *)
 465   let parameters =
 466     HExtlib.list_uniq (List.sort Pervasives.compare parameters)
 467   in
 468   let what = List.map (fun (i,l) -> Cic.Meta (i,l)) parameters in
 469   let with_what, lift_no =
 470     List.fold_right (fun _ (acc,n) -> ((Cic.Rel n)::acc),n+1) what ([],1)
 471   in
 472   let p = CicSubstitution.lift (lift_no-1) p in
 473   let p =
 474     ProofEngineReduction.replace_lifting
 475     ~equality:(fun t1 t2 ->
 476       match t1,t2 with Cic.Meta (i,_),Cic.Meta(j,_) -> i=j | _ -> false)
 477     ~what ~with_what ~where:p
 478   in
 479   let ty_of_m _ = ty (*function
 480     | Cic.Meta (i,_) -> List.assoc i menv
 481     | _ -> assert false *)
 482   in
 483   let args, proof,_ =
 484     List.fold_left
 485       (fun (instance,p,n) m ->
 486         (instance@[m],
 487         Cic.Lambda
 488           (Cic.Name ("x"^string_of_int n),
 489           CicSubstitution.lift (lift_no - n - 1) (ty_of_m m),
 490           p),
 491         n+1))
 492       ([Cic.Rel 1],p,1)
 493       what
 494   in
 495   let instance = match args with | [x] -> x | _ -> Cic.Appl args in
 496   proof, instance
 497 ;;
 498
 499 let wfo goalproof proof id =
 500   let rec aux acc id =
 501     let p,_,_ = proof_of_id id in
 502     match p with
 503     | Exact _ -> if (List.mem id acc) then acc else id :: acc
 504     | Step (_,(_,id1, (_,id2), _)) ->
 505         let acc = if not (List.mem id1 acc) then aux acc id1 else acc in
 506         let acc = if not (List.mem id2 acc) then aux acc id2 else acc in
 507         id :: acc
 508   in
 509   let acc =
 510     match proof with
 511       | Exact _ -> [id]
 512       | Step (_,(_,id1, (_,id2), _)) -> aux (aux [id] id1) id2
 513   in
 514   List.fold_left (fun acc (_,_,id,_,_) -> aux acc id) acc goalproof
 515 ;;
 516
 517 let string_of_id names id =
 518   if id = 0 then "" else
 519   try
 520     let (_,p,(_,l,r,_),m,_) = open_equality (Hashtbl.find id_to_eq id) in
 521     match p with
 522     | Exact t ->
 523         Printf.sprintf "%d = %s: %s = %s [%s]" id
 524           (CicPp.pp t names) (CicPp.pp l names) (CicPp.pp r names)
 525         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 526     | Step (_,(step,id1, (_,id2), _) ) ->
 527         Printf.sprintf "%6d: %s %6d %6d   %s = %s [%s]" id
 528           (string_of_rule step)
 529           id1 id2 (CicPp.pp l names) (CicPp.pp r names)
 530         (String.concat ", " (List.map (fun (i,_,_) -> string_of_int i) m))
 531   with
 532       Not_found -> assert false
 533
 534 let pp_proof names goalproof proof subst id initial_goal =
 535   String.concat "\n" (List.map (string_of_id names) (wfo goalproof proof id)) ^
 536   "\ngoal:\n   " ^
 537     (String.concat "\n   "
 538       (fst (List.fold_right
 539         (fun (r,pos,i,s,pred) (acc,g) ->
 540           let _,_,left,right = open_eq g in
 541           let ty =
 542             match pos with
 543             | Utils.Left -> CicReduction.head_beta_reduce (Cic.Appl[pred;right])
 544             | Utils.Right -> CicReduction.head_beta_reduce (Cic.Appl[pred;left])
 545           in
 546           let ty = Subst.apply_subst s ty in
 547           ("("^ string_of_rule r ^ " " ^ string_of_int i^") -> "
 548           ^ CicPp.pp ty names) :: acc,ty) goalproof ([],initial_goal)))) ^
 549   "\nand then subsumed by " ^ string_of_int id ^ " when " ^ Subst.ppsubst subst
 550 ;;
 551
 552 module OT =
 553   struct
 554     type t = int
 555     let compare = Pervasives.compare
 556   end
 557
 558 module M = Map.Make(OT)
 559
 560 let rec find_deps m i =
 561   if M.mem i m then m
 562   else
 563     let p,_,_ = proof_of_id i in
 564     match p with
 565     | Exact _ -> M.add i [] m
 566     | Step (_,(_,id1,(_,id2),_)) ->
 567         let m = find_deps m id1 in
 568         let m = find_deps m id2 in
 569         M.add i (M.find id1 m @ M.find id2 m @ [id1;id2]) m
 570 ;;
 571
 572 let topological_sort l =
 573   (* build the partial order relation *)
 574   let m =
 575     List.fold_left (fun m i -> find_deps m i)
 576     M.empty l
 577   in
 578   let m = M.map (fun x -> Some x) m in
 579   (* utils *)
 580   let keys m = M.fold (fun i _ acc -> i::acc) m [] in
 581   let split l m = List.filter (fun i -> M.find i m = Some []) l in
 582   let purge l m =
 583     M.mapi
 584       (fun k v -> if List.mem k l then None else
 585          match v with
 586          | None -> None
 587          | Some ll -> Some (List.filter (fun i -> not (List.mem i l)) ll))
 588       m
 589   in
 590   let rec aux m =
 591       let keys = keys m in
 592       let ok = split keys m in
 593       let m = purge ok m in
 594       ok @ (if ok = [] then [] else aux m)
 595   in
 596   aux m
 597 ;;
 598
 599
 600 (* returns the list of ids that should be factorized *)
 601 let get_duplicate_step_in_wfo l p =
 602   let ol = List.rev l in
 603   let h = Hashtbl.create 13 in
 604   (* NOTE: here the n parameter is an approximation of the dependency
 605      between equations. To do things seriously we should maintain a
 606      dependency graph. This approximation is not perfect. *)
 607   let add i =
 608     let p,_,_ = proof_of_id i in
 609     match p with
 610     | Exact _ -> true
 611     | _ ->
 612         try
 613           let no = Hashtbl.find h i in
 614           Hashtbl.replace h i (no+1);
 615           false
 616         with Not_found -> Hashtbl.add h i 1;true
 617   in
 618   let rec aux = function
 619     | Exact _ -> ()
 620     | Step (_,(_,i1,(_,i2),_)) ->
 621         let go_on_1 = add i1 in
 622         let go_on_2 = add i2 in
 623         if go_on_1 then aux (let p,_,_ = proof_of_id i1 in p);
 624         if go_on_2 then aux (let p,_,_ = proof_of_id i2 in p)
 625   in
 626   aux p;
 627   List.iter
 628     (fun (_,_,id,_,_) -> aux (let p,_,_ = proof_of_id id in p))
 629     ol;
 630   (* now h is complete *)
 631   let proofs = Hashtbl.fold (fun k count acc-> (k,count)::acc) h [] in
 632   let proofs = List.filter (fun (_,c) -> c > 1) proofs in
 633   topological_sort (List.map (fun (i,_) -> i) proofs)
 634 ;;
 635
 636 let build_proof_term h lift proof =
 637   let proof_of_id aux id =
 638     let p,l,r = proof_of_id id in
 639     try List.assoc id h,l,r with Not_found -> aux p, l, r
 640   in
 641   let rec aux = function
 642      | Exact term -> CicSubstitution.lift lift term
 643      | Step (subst,(rule, id1, (pos,id2), pred)) ->
 644          let p1,_,_ = proof_of_id aux id1 in
 645          let p2,l,r = proof_of_id aux id2 in
 646          let varname =
 647            match rule with
 648            | SuperpositionRight -> Cic.Name ("SupR" ^ Utils.string_of_pos pos)
 649            | Demodulation -> Cic.Name ("DemEq"^ Utils.string_of_pos pos)
 650            | _ -> assert false
 651          in
 652          let pred =
 653            match pred with
 654            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 655            | _ -> assert false
 656          in
 657          let p =   build_proof_step lift subst p1 p2 pos l r pred in
 658 (*         let cond =  (not (List.mem 302 (Utils.metas_of_term p)) || id1 = 8 || id1 = 132) in
 659            if not cond then
 660              prerr_endline ("ERROR " ^ string_of_int id1 ^ " " ^ string_of_int id2);
 661            assert cond;*)
 662            p
 663   in
 664    aux proof
 665 ;;
 666
 667 let build_goal_proof l initial ty se =
 668   let se = List.map (fun i -> Cic.Meta (i,[])) se in
 669   let lets = get_duplicate_step_in_wfo l initial in
 670   let letsno = List.length lets in
 671   let _,mty,_,_ = open_eq ty in
 672   let lift_list l = List.map (fun (i,t) -> i,CicSubstitution.lift 1 t) l
 673   in
 674   let lets,_,h =
 675     List.fold_left
 676       (fun (acc,n,h) id ->
 677         let p,l,r = proof_of_id id in
 678         let cic = build_proof_term h n p in
 679         let real_cic,instance =
 680           parametrize_proof cic l r (CicSubstitution.lift n mty)
 681         in
 682         let h = (id, instance)::lift_list h in
 683         acc@[id,real_cic],n+1,h)
 684       ([],0,[]) lets
 685   in
 686   let proof,se =
 687     let rec aux se current_proof = function
 688       | [] -> current_proof,se
 689       | (rule,pos,id,subst,pred)::tl ->
 690           let p,l,r = proof_of_id id in
 691            let p = build_proof_term h letsno p in
 692            let pos = if pos = Utils.Left then Utils.Right else Utils.Left in
 693          let varname =
 694            match rule with
 695            | SuperpositionLeft -> Cic.Name ("SupL" ^ Utils.string_of_pos pos)
 696            | Demodulation -> Cic.Name ("DemG"^ Utils.string_of_pos pos)
 697            | _ -> assert false
 698          in
 699          let pred =
 700            match pred with
 701            | Cic.Lambda (_,a,b) -> Cic.Lambda (varname,a,b)
 702            | _ -> assert false
 703          in
 704            let proof =
 705              build_proof_step letsno subst current_proof p pos l r pred
 706            in
 707            let proof,se = aux se proof tl in
 708            Subst.apply_subst_lift letsno subst proof,
 709            List.map (fun x -> Subst.apply_subst_lift letsno subst x) se
 710     in
 711     aux se (build_proof_term h letsno initial) l
 712   in
 713   let n,proof =
 714     let initial = proof in
 715     List.fold_right
 716       (fun (id,cic) (n,p) ->
 717         n-1,
 718         Cic.LetIn (
 719           Cic.Name ("H"^string_of_int id),
 720           cic, p))
 721     lets (letsno-1,initial)
 722   in
 723   canonical (contextualize_rewrites proof (CicSubstitution.lift letsno ty)),
 724    se
 725 ;;
 726
 727 let refl_proof ty term =
 728   Cic.Appl
 729     [Cic.MutConstruct
 730        (LibraryObjects.eq_URI (), 0, 1, []);
 731        ty; term]
 732 ;;
 733
 734 let metas_of_proof p =
 735   let p = build_proof_term [] 0 p in
 736   Utils.metas_of_term p
 737 ;;
 738
 739 let relocate newmeta menv to_be_relocated =
 740   let subst, newmetasenv, newmeta =
 741     List.fold_right
 742       (fun i (subst, metasenv, maxmeta) ->
 743         let _,context,ty = CicUtil.lookup_meta i menv in
 744         let irl = [] in
 745         let newmeta = Cic.Meta(maxmeta,irl) in
 746         let newsubst = Subst.buildsubst i context newmeta ty subst in
 747         newsubst, (maxmeta,context,ty)::metasenv, maxmeta+1)
 748       to_be_relocated (Subst.empty_subst, [], newmeta+1)
 749   in
 750   let menv = Subst.apply_subst_metasenv subst menv @ newmetasenv in
 751   subst, menv, newmeta
 752
 753
 754 let fix_metas newmeta eq =
 755   let w, p, (ty, left, right, o), menv,_ = open_equality eq in
 756   let to_be_relocated =
 757     HExtlib.list_uniq
 758       (List.sort Pervasives.compare
 759          (Utils.metas_of_term left @ Utils.metas_of_term right))
 760   in
 761   let subst, metasenv, newmeta = relocate newmeta menv to_be_relocated in
 762   let ty = Subst.apply_subst subst ty in
 763   let left = Subst.apply_subst subst left in
 764   let right = Subst.apply_subst subst right in
 765   let fix_proof = function
 766     | Exact p -> Exact (Subst.apply_subst subst p)
 767     | Step (s,(r,id1,(pos,id2),pred)) ->
 768         Step (Subst.concat s subst,(r,id1,(pos,id2), pred))
 769   in
 770   let p = fix_proof p in
 771   let eq' = mk_equality (w, p, (ty, left, right, o), metasenv) in
 772   newmeta+1, eq'
 773
 774 exception NotMetaConvertible;;
 775
 776 let meta_convertibility_aux table t1 t2 =
 777   let module C = Cic in
 778   let rec aux ((table_l, table_r) as table) t1 t2 =
 779     match t1, t2 with
 780     | C.Meta (m1, tl1), C.Meta (m2, tl2) ->
 781         let m1_binding, table_l =
 782           try List.assoc m1 table_l, table_l
 783           with Not_found -> m2, (m1, m2)::table_l
 784         and m2_binding, table_r =
 785           try List.assoc m2 table_r, table_r
 786           with Not_found -> m1, (m2, m1)::table_r
 787         in
 788         if (m1_binding <> m2) || (m2_binding <> m1) then
 789           raise NotMetaConvertible
 790         else (
 791           try
 792             List.fold_left2
 793               (fun res t1 t2 ->
 794                  match t1, t2 with
 795                  | None, Some _ | Some _, None -> raise NotMetaConvertible
 796                  | None, None -> res
 797                  | Some t1, Some t2 -> (aux res t1 t2))
 798               (table_l, table_r) tl1 tl2
 799           with Invalid_argument _ ->
 800             raise NotMetaConvertible
 801         )
 802     | C.Var (u1, ens1), C.Var (u2, ens2)
 803     | C.Const (u1, ens1), C.Const (u2, ens2) when (UriManager.eq u1 u2) ->
 804         aux_ens table ens1 ens2
 805     | C.Cast (s1, t1), C.Cast (s2, t2)
 806     | C.Prod (_, s1, t1), C.Prod (_, s2, t2)
 807     | C.Lambda (_, s1, t1), C.Lambda (_, s2, t2)
 808     | C.LetIn (_, s1, t1), C.LetIn (_, s2, t2) ->
 809         let table = aux table s1 s2 in
 810         aux table t1 t2
 811     | C.Appl l1, C.Appl l2 -> (
 812         try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 813         with Invalid_argument _ -> raise NotMetaConvertible
 814       )
 815     | C.MutInd (u1, i1, ens1), C.MutInd (u2, i2, ens2)
 816         when (UriManager.eq u1 u2) && i1 = i2 -> aux_ens table ens1 ens2
 817     | C.MutConstruct (u1, i1, j1, ens1), C.MutConstruct (u2, i2, j2, ens2)
 818         when (UriManager.eq u1 u2) && i1 = i2 && j1 = j2 ->
 819         aux_ens table ens1 ens2
 820     | C.MutCase (u1, i1, s1, t1, l1), C.MutCase (u2, i2, s2, t2, l2)
 821         when (UriManager.eq u1 u2) && i1 = i2 ->
 822         let table = aux table s1 s2 in
 823         let table = aux table t1 t2 in (
 824           try List.fold_left2 (fun res t1 t2 -> (aux res t1 t2)) table l1 l2
 825           with Invalid_argument _ -> raise NotMetaConvertible
 826         )
 827     | C.Fix (i1, il1), C.Fix (i2, il2) when i1 = i2 -> (
 828         try
 829           List.fold_left2
 830             (fun res (n1, i1, s1, t1) (n2, i2, s2, t2) ->
 831                if i1 <> i2 then raise NotMetaConvertible
 832                else
 833                  let res = (aux res s1 s2) in aux res t1 t2)
 834             table il1 il2
 835         with Invalid_argument _ -> raise NotMetaConvertible
 836       )
 837     | C.CoFix (i1, il1), C.CoFix (i2, il2) when i1 = i2 -> (
 838         try
 839           List.fold_left2
 840             (fun res (n1, s1, t1) (n2, s2, t2) ->
 841                let res = aux res s1 s2 in aux res t1 t2)
 842             table il1 il2
 843         with Invalid_argument _ -> raise NotMetaConvertible
 844       )
 845     | t1, t2 when t1 = t2 -> table
 846     | _, _ -> raise NotMetaConvertible
 847
 848   and aux_ens table ens1 ens2 =
 849     let cmp (u1, t1) (u2, t2) =
 850       Pervasives.compare (UriManager.string_of_uri u1) (UriManager.string_of_uri u2)
 851     in
 852     let ens1 = List.sort cmp ens1
 853     and ens2 = List.sort cmp ens2 in
 854     try
 855       List.fold_left2
 856         (fun res (u1, t1) (u2, t2) ->
 857            if not (UriManager.eq u1 u2) then raise NotMetaConvertible
 858            else aux res t1 t2)
 859         table ens1 ens2
 860     with Invalid_argument _ -> raise NotMetaConvertible
 861   in
 862   aux table t1 t2
 863 ;;
 864
 865
 866 let meta_convertibility_eq eq1 eq2 =
 867   let _, _, (ty, left, right, _), _,_ = open_equality eq1 in
 868   let _, _, (ty', left', right', _), _,_ = open_equality eq2 in
 869   if ty <> ty' then
 870     false
 871   else if (left = left') && (right = right') then
 872     true
 873   else if (left = right') && (right = left') then
 874     true
 875   else
 876     try
 877       let table = meta_convertibility_aux ([], []) left left' in
 878       let _ = meta_convertibility_aux table right right' in
 879       true
 880     with NotMetaConvertible ->
 881       try
 882         let table = meta_convertibility_aux ([], []) left right' in
 883         let _ = meta_convertibility_aux table right left' in
 884         true
 885       with NotMetaConvertible ->
 886         false
 887 ;;
 888
 889
 890 let meta_convertibility t1 t2 =
 891   if t1 = t2 then
 892     true
 893   else
 894     try
 895       ignore(meta_convertibility_aux ([], []) t1 t2);
 896       true
 897     with NotMetaConvertible ->
 898       false
 899 ;;
 900
 901 exception TermIsNotAnEquality;;
 902
 903 let term_is_equality term =
 904   let iseq uri = UriManager.eq uri (LibraryObjects.eq_URI ()) in
 905   match term with
 906   | Cic.Appl [Cic.MutInd (uri, _, _); _; _; _] when iseq uri -> true
 907   | _ -> false
 908 ;;
 909
 910 let equality_of_term proof term =
 911   let eq_uri = LibraryObjects.eq_URI () in
 912   let iseq uri = UriManager.eq uri eq_uri in
 913   match term with
 914   | Cic.Appl [Cic.MutInd (uri, _, _); ty; t1; t2] when iseq uri ->
 915       let o = !Utils.compare_terms t1 t2 in
 916       let stat = (ty,t1,t2,o) in
 917       let w = Utils.compute_equality_weight stat in
 918       let e = mk_equality (w, Exact proof, stat,[]) in
 919       e
 920   | _ ->
 921       raise TermIsNotAnEquality
 922 ;;
 923
 924 let is_weak_identity eq =
 925   let _,_,(_,left, right,_),_,_ = open_equality eq in
 926   left = right || meta_convertibility left right
 927 ;;
 928
 929 let is_identity (_, context, ugraph) eq =
 930   let _,_,(ty,left,right,_),menv,_ = open_equality eq in
 931   left = right ||
 932   (* (meta_convertibility left right)) *)
 933   fst (CicReduction.are_convertible ~metasenv:menv context left right ugraph)
 934 ;;
 935
 936
 937 let term_of_equality equality =
 938   let _, _, (ty, left, right, _), menv, _= open_equality equality in
 939   let eq i = function Cic.Meta (j, _) -> i = j | _ -> false in
 940   let argsno = List.length menv in
 941   let t =
 942     CicSubstitution.lift argsno
 943       (Cic.Appl [Cic.MutInd (LibraryObjects.eq_URI (), 0, []); ty; left; right])
 944   in
 945   snd (
 946     List.fold_right
 947       (fun (i,_,ty) (n, t) ->
 948          let name = Cic.Name ("X" ^ (string_of_int n)) in
 949          let ty = CicSubstitution.lift (n-1) ty in
 950          let t =
 951            ProofEngineReduction.replace
 952              ~equality:eq ~what:[i]
 953              ~with_what:[Cic.Rel (argsno - (n - 1))] ~where:t
 954          in
 955            (n-1, Cic.Prod (name, ty, t)))
 956       menv (argsno, t))
 957 ;;
 958
 959 let symmetric eq_ty l id uri m =
 960   let eq = Cic.MutInd(uri,0,[]) in
 961   let pred =
 962     Cic.Lambda (Cic.Name "Sym",eq_ty,
 963      Cic.Appl [CicSubstitution.lift 1 eq ;
 964                CicSubstitution.lift 1 eq_ty;
 965                Cic.Rel 1;CicSubstitution.lift 1 l])
 966   in
 967   let prefl =
 968     Exact (Cic.Appl
 969       [Cic.MutConstruct(uri,0,1,[]);eq_ty;l])
 970   in
 971   let id1 =
 972     let eq = mk_equality (0,prefl,(eq_ty,l,l,Utils.Eq),m) in
 973     let (_,_,_,_,id) = open_equality eq in
 974     id
 975   in
 976   Step(Subst.empty_subst,
 977     (Demodulation,id1,(Utils.Left,id),pred))
 978 ;;
 979