helm/software/components/tactics/reductionTactics.ml

   1 (* Copyright (C) 2002, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open ProofEngineTypes
  29
  30 (* Note: this code is almost identical to change_tac and
  31 *  it could be unified by making the change function a callback *)
  32 let reduction_tac ~reduction ~pattern (proof,goal) =
  33   let curi,metasenv,_subst,pbo,pty, attrs = proof in
  34   let (metano,context,ty) as conjecture = CicUtil.lookup_meta goal metasenv in
  35   let change subst where terms metasenv ugraph =
  36    if terms = [] then where, metasenv, ugraph
  37    else
  38      let pairs, metasenv, ugraph =
  39        List.fold_left
  40         (fun (pairs, metasenv, ugraph) (context, t) ->
  41           let reduction, metasenv, ugraph = reduction context metasenv ugraph in
  42           ((t, reduction context t) :: pairs), metasenv, ugraph)
  43         ([], metasenv, ugraph)
  44         terms
  45      in
  46      let terms, terms' = List.split pairs in
  47      let where' =
  48        ProofEngineReduction.replace ~equality:(==) ~what:terms ~with_what:terms'
  49         ~where:where
  50      in
  51      CicMetaSubst.apply_subst subst where', metasenv, ugraph
  52   in
  53   let (subst,metasenv,ugraph,selected_context,selected_ty) =
  54     ProofEngineHelpers.select ~metasenv ~ugraph:CicUniv.empty_ugraph
  55       ~conjecture ~pattern
  56   in
  57   let ty', metasenv, ugraph = change subst ty selected_ty metasenv ugraph in
  58   let context', metasenv, ugraph =
  59    List.fold_right2
  60     (fun entry selected_entry (context', metasenv, ugraph) ->
  61       match entry,selected_entry with
  62          None,None -> None::context', metasenv, ugraph
  63        | Some (name,Cic.Decl ty),Some (`Decl selected_ty) ->
  64           let ty', metasenv, ugraph =
  65             change subst ty selected_ty metasenv ugraph
  66           in
  67           Some (name,Cic.Decl ty')::context', metasenv, ugraph
  68        | Some (name,Cic.Def (bo,ty)),Some (`Def (selected_bo,selected_ty)) ->
  69           let bo', metasenv, ugraph =
  70             change subst bo selected_bo metasenv ugraph
  71           in
  72           let ty', metasenv, ugraph =
  73            match ty,selected_ty with
  74               None,None -> None, metasenv, ugraph
  75             | Some ty,Some selected_ty ->
  76                 let ty', metasenv, ugraph =
  77                   change subst ty selected_ty metasenv ugraph
  78                 in
  79                 Some ty', metasenv, ugraph
  80             | _,_ -> assert false
  81           in
  82            (Some (name,Cic.Def (bo',ty'))::context'), metasenv, ugraph
  83        | _,_ -> assert false
  84     ) context selected_context ([], metasenv, ugraph) in
  85   let metasenv' =
  86     List.map (function
  87       | (n,_,_) when n = metano -> (metano,context',ty')
  88       | _ as t -> t
  89     ) metasenv
  90   in
  91   (curi,metasenv',_subst,pbo,pty, attrs), [metano]
  92 ;;
  93
  94 let simpl_tac ~pattern =
  95  mk_tactic (reduction_tac
  96   ~reduction:(const_lazy_reduction ProofEngineReduction.simpl) ~pattern)
  97
  98 let unfold_tac what ~pattern =
  99   let reduction =
 100     match what with
 101     | None -> const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 102     | Some lazy_term ->
 103         (fun context metasenv ugraph ->
 104           let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 105           ProofEngineReduction.unfold ~what, metasenv, ugraph)
 106   in
 107   mk_tactic (reduction_tac ~reduction ~pattern)
 108
 109 let whd_tac ~pattern =
 110  mk_tactic (reduction_tac
 111   ~reduction:(const_lazy_reduction CicReduction.whd) ~pattern)
 112
 113 let normalize_tac ~pattern =
 114  mk_tactic (reduction_tac
 115   ~reduction:(const_lazy_reduction CicReduction.normalize) ~pattern)
 116
 117 let head_beta_reduce_tac ?delta ?upto ~pattern =
 118  mk_tactic (reduction_tac
 119   ~reduction:
 120     (const_lazy_reduction
 121       (fun _context -> CicReduction.head_beta_reduce ?delta ?upto)) ~pattern)
 122
 123 exception NotConvertible
 124
 125 (* Note: this code is almost identical to reduction_tac and
 126 *  it could be unified by making the change function a callback *)
 127 (* CSC: with_what is parsed in the context of the goal, but it should replace
 128         something that lives in a completely different context. Thus we
 129         perform a delift + lift phase to move it in the right context. However,
 130         in this way the tactic is less powerful than expected: with_what cannot
 131         reference variables that are local to the term that is going to be
 132         replaced. To fix this we should parse with_what in the context of the
 133         term(s) to be replaced. *)
 134 let change_tac ?(with_cast=false) ~pattern with_what  =
 135  let change_tac ~pattern ~with_what (proof, goal) =
 136   let curi,metasenv,_subst,pbo,pty, attrs = proof in
 137   let (metano,context,ty) as conjecture = CicUtil.lookup_meta goal metasenv in
 138   let change subst where terms metasenv ugraph =
 139    if terms = [] then where, metasenv, ugraph
 140    else
 141     let pairs, metasenv, ugraph =
 142       List.fold_left
 143         (fun (pairs, metasenv, ugraph) (context_of_t, t) ->
 144           let with_what, metasenv, ugraph =
 145             with_what context_of_t metasenv ugraph
 146           in
 147           let _,u =
 148             CicTypeChecker.type_of_aux' metasenv context_of_t with_what ugraph
 149           in
 150           let b,_ =
 151            CicReduction.are_convertible ~metasenv context_of_t t with_what u
 152           in
 153           if b then
 154            ((t, with_what) :: pairs), metasenv, ugraph
 155           else
 156            raise NotConvertible)
 157         ([], metasenv, ugraph)
 158         terms
 159     in
 160     let terms, terms' = List.split pairs in
 161      let where' =
 162       ProofEngineReduction.replace ~equality:(==) ~what:terms ~with_what:terms'
 163        ~where:where
 164      in
 165       CicMetaSubst.apply_subst subst where', metasenv, ugraph
 166   in
 167   let (subst,metasenv,ugraph,selected_context,selected_ty) =
 168    ProofEngineHelpers.select ~metasenv ~ugraph:CicUniv.empty_ugraph ~conjecture
 169     ~pattern in
 170   let ty', metasenv, ugraph = change subst ty selected_ty metasenv ugraph in
 171   let context', metasenv, ugraph =
 172    List.fold_right2
 173     (fun entry selected_entry (context', metasenv, ugraph) ->
 174      match entry,selected_entry with
 175          None,None -> (None::context'), metasenv, ugraph
 176        | Some (name,Cic.Decl ty),Some (`Decl selected_ty) ->
 177           let ty', metasenv, ugraph =
 178             change subst ty selected_ty metasenv ugraph
 179           in
 180            (Some (name,Cic.Decl ty')::context'), metasenv, ugraph
 181        | Some (name,Cic.Def (bo,ty)),Some (`Def (selected_bo,selected_ty)) ->
 182           let bo', metasenv, ugraph =
 183             change subst bo selected_bo metasenv ugraph
 184           in
 185           let ty', metasenv, ugraph =
 186            match ty,selected_ty with
 187               None,None -> None, metasenv, ugraph
 188             | Some ty,Some selected_ty ->
 189                 let ty', metasenv, ugraph =
 190                   change subst ty selected_ty metasenv ugraph
 191                 in
 192                 Some ty', metasenv, ugraph
 193             | _,_ -> assert false
 194           in
 195            (Some (name,Cic.Def (bo',ty'))::context'), metasenv, ugraph
 196        | _,_ -> assert false
 197     ) context selected_context ([], metasenv, ugraph) in
 198   let metasenv' =
 199     List.map
 200       (function
 201         | (n,_,_) when n = metano -> (metano,context',ty')
 202         | _ as t -> t)
 203       metasenv
 204   in
 205    let proof,goal = (curi,metasenv',_subst,pbo,pty, attrs), metano in
 206     if with_cast then
 207      let metano' = ProofEngineHelpers.new_meta_of_proof ~proof in
 208      let (newproof,_) =
 209        let irl= CicMkImplicit.identity_relocation_list_for_metavariable context'
 210        in
 211         ProofEngineHelpers.subst_meta_in_proof
 212          proof metano
 213           (Cic.Cast (Cic.Meta(metano',irl),ty')) [metano',context',ty']
 214      in
 215       newproof, [metano']
 216     else
 217      proof,[goal]
 218   in
 219     mk_tactic (change_tac ~pattern ~with_what)
 220
 221 let fold_tac ~reduction ~term ~pattern =
 222  let fold_tac ~reduction ~term ~pattern:(wanted,hyps_pat,concl_pat) status =
 223   assert (wanted = None); (* this should be checked syntactically *)
 224   let reduced_term =
 225     (fun context metasenv ugraph ->
 226       let term, metasenv, ugraph = term context metasenv ugraph in
 227       let reduction, metasenv, ugraph = reduction context metasenv ugraph in
 228       reduction context term, metasenv, ugraph)
 229   in
 230    apply_tactic
 231     (change_tac ~pattern:(Some reduced_term,hyps_pat,concl_pat) term) status
 232  in
 233   mk_tactic (fold_tac ~reduction ~term ~pattern)
 234