helm/software/components/tptp_grafite/tptp2grafite.ml

   1 module GA = GrafiteAst;;
   2 module LA = LexiconAst;;
   3 module PT = CicNotationPt;;
   4 module A = Ast;;
   5
   6 type sort = Prop | Univ;;
   7
   8 let floc = HExtlib.dummy_floc;;
   9
  10
  11 let paramod_timeout = ref 600;;
  12 let depth = ref 10;;
  13
  14 let universe = "Univ" ;;
  15 let prop = "Prop";;
  16
  17 let kw = [
  18  "and","myand"
  19 ];;
  20
  21 let mk_ident s =
  22   PT.Ident ((try List.assoc s kw with Not_found -> s),None)
  23 ;;
  24
  25 let rec collect_arities_from_term = function
  26   | A.Constant name -> [name,(0,Univ)]
  27   | A.Variable name -> [name,(0,Univ)]
  28   | A.Function (name,l) ->
  29       (name,(List.length l,Univ))::
  30         List.flatten (List.map collect_arities_from_term l)
  31 ;;
  32
  33 let rec collect_fv_from_term = function
  34   | A.Constant name -> []
  35   | A.Variable name -> [name]
  36   | A.Function (_,l) ->
  37       List.flatten (List.map collect_fv_from_term l)
  38 ;;
  39
  40 let collect_arities_from_atom a =
  41   let aux = function
  42     | A.Proposition name -> [name,(0,Prop)]
  43     | A.Predicate (name,args) ->
  44         (name,(List.length args,Prop)) ::
  45           (List.flatten (List.map collect_arities_from_term args))
  46     | A.True -> []
  47     | A.False -> []
  48     | A.Eq (t1,t2) ->
  49         collect_arities_from_term t1 @ collect_arities_from_term t2
  50     | A.NotEq (t1,t2) ->
  51         collect_arities_from_term t1 @ collect_arities_from_term t2
  52   in
  53   HExtlib.list_uniq (List.sort compare (List.flatten (List.map aux a)))
  54 ;;
  55
  56 let collect_fv_from_atom a =
  57   let aux = function
  58     | A.Proposition name -> [name]
  59     | A.Predicate (name,args) ->
  60         name :: List.flatten (List.map collect_fv_from_term args)
  61     | A.True -> []
  62     | A.False -> []
  63     | A.Eq (t1,t2) -> collect_fv_from_term t1 @ collect_fv_from_term t2
  64     | A.NotEq (t1,t2) -> collect_fv_from_term t1 @ collect_fv_from_term t2
  65   in
  66   let rec aux2 = function
  67     | [] -> []
  68     | hd::tl -> aux hd @ aux2 tl
  69   in
  70   HExtlib.list_uniq (List.sort compare (aux2 a))
  71 ;;
  72
  73 let rec collect_fv_from_formulae = function
  74   | A.Disjunction (a,b) ->
  75       collect_fv_from_formulae a @ collect_fv_from_formulae b
  76   | A.NegAtom a
  77   | A.Atom a -> collect_fv_from_atom [a]
  78 ;;
  79
  80 let rec convert_term = function
  81   | A.Variable x -> mk_ident x
  82   | A.Constant x -> mk_ident x
  83   | A.Function (name, args) ->
  84       PT.Appl (mk_ident name :: List.map convert_term args)
  85 ;;
  86
  87 let rec atom_of_formula neg pos = function
  88     | A.Disjunction (a,b) ->
  89         let neg, pos = atom_of_formula neg pos a in
  90         atom_of_formula neg pos b
  91     | A.NegAtom a -> a::neg, pos
  92     | A.Atom (A.NotEq (a,b)) -> (A.Eq (a,b) :: neg), pos
  93     | A.Atom a -> neg, a::pos
  94 ;;
  95
  96 let atom_of_formula f =
  97   let neg, pos = atom_of_formula [] [] f in
  98   neg @ pos
  99 ;;
 100
 101 let rec mk_arrow component tail = function
 102   | 0 -> begin
 103       match tail with
 104       | Prop -> mk_ident prop
 105       | Univ -> mk_ident universe
 106       end
 107   | n ->
 108       PT.Binder
 109         (`Forall,
 110           ((mk_ident "_"),Some (mk_ident component)),
 111           mk_arrow component tail (n-1))
 112 ;;
 113
 114 let build_ctx_for_arities univesally arities t =
 115   let binder = if univesally then `Forall else `Exists in
 116   let rec aux = function
 117     | [] -> t
 118     | (name,(nargs,sort))::tl ->
 119         PT.Binder
 120           (binder,
 121             (mk_ident name,Some (mk_arrow universe sort nargs)),
 122             aux tl)
 123   in
 124   aux arities
 125 ;;
 126
 127 let convert_atom universally a =
 128   let aux = function
 129   | A.Proposition p -> mk_ident p
 130   | A.Predicate (name,params) ->
 131       PT.Appl ((mk_ident name) :: (List.map convert_term params))
 132   | A.True -> mk_ident "True"
 133   | A.False -> mk_ident "False"
 134   | A.Eq (l,r)
 135   | A.NotEq (l,r) -> (* removes the negation *)
 136       PT.Appl [mk_ident "eq";mk_ident universe;convert_term l;convert_term r]
 137   in
 138   let rec aux2 = function
 139     | [] -> assert false
 140     | [x] -> aux x
 141     | he::tl ->
 142         if universally then
 143           PT.Binder (`Forall, (mk_ident "_", Some (aux he)), aux2 tl)
 144         else
 145           PT.Appl [mk_ident "And";aux he;aux2 tl]
 146   in
 147   let arities = collect_arities_from_atom a in
 148   let fv = collect_fv_from_atom a in
 149   build_ctx_for_arities universally
 150     (List.filter
 151       (function (x,(0,Univ)) -> List.mem x fv | _-> false)
 152       arities)
 153     (aux2 a)
 154 ;;
 155
 156 let collect_arities atom ctx =
 157   let atoms = atom@(List.flatten (List.map atom_of_formula ctx)) in
 158   collect_arities_from_atom atoms
 159 ;;
 160
 161 let collect_arities_from_formulae f =
 162   let rec collect_arities_from_formulae = function
 163   | A.Disjunction (a,b) ->
 164       collect_arities_from_formulae a @ collect_arities_from_formulae b
 165   | A.NegAtom a
 166   | A.Atom a -> collect_arities_from_atom [a]
 167   in
 168   HExtlib.list_uniq (List.sort compare (collect_arities_from_formulae f))
 169 ;;
 170
 171 let is_formulae_1eq_negated f =
 172   let atom = atom_of_formula f in
 173   match atom with
 174   | [A.NotEq (l,r)] -> true
 175   | _ -> false
 176 ;;
 177
 178 let collect_fv_1stord_from_formulae f =
 179   let arities = collect_arities_from_formulae f in
 180   let fv = collect_fv_from_formulae f in
 181   List.map fst
 182     (List.filter (function (x,(0,Univ)) -> List.mem x fv | _-> false) arities)
 183 ;;
 184
 185 let rec convert_formula fv no_arities context f =
 186   let atom = atom_of_formula f in
 187   let t = convert_atom (fv = []) atom in
 188   let rec build_ctx n = function
 189     | [] -> t
 190     | hp::tl ->
 191         PT.Binder
 192           (`Forall,
 193             (mk_ident ("H" ^ string_of_int n),
 194               Some (convert_formula [] true [] hp)),
 195             build_ctx (n+1) tl)
 196   in
 197   let arities = if no_arities then [] else collect_arities atom context in
 198   build_ctx_for_arities true arities (build_ctx 0 context)
 199 ;;
 200
 201 let check_if_atom_is_negative = function
 202   | A.True -> false
 203   | A.False -> true
 204   | A.Proposition _ -> false
 205   | A.Predicate _ -> false
 206   | A.Eq _ -> false
 207   | A.NotEq _ -> true
 208 ;;
 209
 210 let rec check_if_formula_is_negative = function
 211   | A.Disjunction (a,b) ->
 212       check_if_formula_is_negative a && check_if_formula_is_negative b
 213   | A.NegAtom a -> not (check_if_atom_is_negative a)
 214   | A.Atom a -> check_if_atom_is_negative a
 215 ;;
 216
 217 let convert_ast statements context = function
 218   | A.Comment s ->
 219       let s = String.sub s 1 (String.length s - 1) in
 220       let s =
 221         if s.[String.length s - 1] = '\n' then
 222           String.sub s 0 (String.length s - 1)
 223         else
 224           s
 225       in
 226       statements @ [GA.Comment (floc,GA.Note (floc,s))],
 227       context
 228   | A.Inclusion (s,_) ->
 229       statements @ [
 230         GA.Comment (
 231           floc, GA.Note (
 232             floc,"Inclusion of: " ^ s))], context
 233   | A.AnnotatedFormula (name,kind,f,_,_) ->
 234       match kind with
 235       | A.Axiom
 236       | A.Hypothesis ->
 237           statements, f::context
 238       | A.Negated_conjecture when not (check_if_formula_is_negative f) ->
 239           statements, f::context
 240       | A.Negated_conjecture ->
 241           let ueq_case = is_formulae_1eq_negated f in
 242           let fv = collect_fv_1stord_from_formulae f in
 243 (*
 244           if fv <> [] then
 245             prerr_endline ("FREE VARIABLES: " ^ String.concat "," fv);
 246 *)
 247           let f =
 248             PT.Binder
 249              (`Forall,
 250                (mk_ident universe,Some (PT.Sort `Set)),
 251                convert_formula fv false context f)
 252           in
 253           let o = PT.Theorem (`Theorem,name,f,None) in
 254           statements @ [
 255             GA.Executable(floc,GA.Command(floc,GA.Obj(floc,o)));
 256             GA.Executable(floc,GA.Tactic(floc, Some
 257              (GA.Intros (floc,(None,[]))),GA.Dot(floc)))] @
 258           (if fv <> [] then
 259             (List.flatten
 260               (List.map
 261                 (fun _ ->
 262                   [GA.Executable(floc,GA.Tactic(floc, Some
 263                     (GA.Exists floc),GA.Branch floc));
 264                    GA.Executable(floc,GA.Tactic(floc, None,
 265                     (GA.Pos (floc,[2]))))])
 266                 fv))
 267            else [])@
 268             [GA.Executable(floc,GA.Tactic(floc, Some (
 269               if ueq_case then
 270                   GA.AutoBatch (floc,([],["paramodulation","";
 271                   "timeout",string_of_int !paramod_timeout]))
 272               else
 273                   GA.AutoBatch (floc,([],[
 274                           "depth",string_of_int 5;
 275                           "width",string_of_int 5;
 276                           "size",string_of_int 20;
 277                           "timeout",string_of_int 10;
 278                   ]))
 279             ),
 280               GA.Semicolon(floc)));
 281             GA.Executable(floc,GA.Tactic(floc, Some (GA.Try(floc,
 282               GA.Assumption floc)), GA.Dot(floc)))
 283             ]@
 284           (if fv <> [] then
 285             (List.flatten
 286               (List.map
 287                 (fun _ ->
 288                   [GA.Executable(floc,GA.Tactic(floc, None, GA.Shift floc));
 289                    GA.Executable(floc,GA.NonPunctuationTactical(floc, GA.Skip floc,
 290                    (GA.Merge floc)))])
 291                 fv))
 292            else [])@
 293             [GA.Executable(floc,GA.Command(floc, GA.Print(floc,"proofterm")));
 294              GA.Executable(floc,GA.Command(floc, GA.Qed(floc)))],
 295           context
 296       | A.Definition
 297       | A.Lemma
 298       | A.Theorem
 299       | A.Conjecture
 300       | A.Lemma_conjecture
 301       | A.Plain
 302       | A.Unknown -> assert false
 303 ;;
 304
 305 (* HELPERS *)
 306 let resolve ~tptppath s =
 307   let resolved_name =
 308     if Filename.check_suffix s ".p" then
 309       (assert (String.length s > 5);
 310       let prefix = String.sub s 0 3 in
 311       tptppath ^ "/Problems/" ^ prefix ^ "/" ^ s)
 312     else
 313       tptppath ^ "/" ^ s
 314   in
 315   if HExtlib.is_regular resolved_name then
 316     resolved_name
 317   else
 318     begin
 319       prerr_endline ("Unable to find " ^ s ^ " (" ^ resolved_name ^ ")");
 320       exit 1
 321     end
 322 ;;
 323
 324 (* MAIN *)
 325 let tptp2grafite ?(timeout=600) ?(def_depth=10) ?raw_preamble ~tptppath ~filename () =
 326   paramod_timeout := timeout;
 327   depth := def_depth;
 328   let rec aux = function
 329     | [] -> []
 330     | ((A.Inclusion (file,_)) as hd) :: tl ->
 331         let file = resolve ~tptppath file in
 332         let lexbuf = Lexing.from_channel (open_in file) in
 333         let statements = Parser.main Lexer.yylex lexbuf in
 334         hd :: aux (statements @ tl)
 335     | hd::tl -> hd :: aux tl
 336   in
 337   let statements = aux [A.Inclusion (filename,[])] in
 338   let grafite_ast_statements,_ =
 339     List.fold_left
 340       (fun (st, ctx) f ->
 341         let newst, ctx = convert_ast st ctx f in
 342         newst, ctx)
 343       ([],[]) statements
 344   in
 345   let pp t =
 346     (* ZACK: setting width to 80 will trigger a bug of BoxPp.render_to_string
 347      * which will show up using the following command line:
 348      * ./tptp2grafite -tptppath ~tassi/TPTP-v3.1.1 GRP170-1 *)
 349     let width = max_int in
 350     let term_pp content_term =
 351       let pres_term = TermContentPres.pp_ast content_term in
 352       let dummy_tbl = Hashtbl.create 1 in
 353       let markup = CicNotationPres.render dummy_tbl pres_term in
 354       let s = BoxPp.render_to_string List.hd width markup ~map_unicode_to_tex:false in
 355       Pcre.substitute
 356         ~pat:"\\\\forall [Ha-z][a-z0-9_]*" ~subst:(fun x -> "\n" ^ x) s
 357     in
 358     CicNotationPp.set_pp_term term_pp;
 359     let lazy_term_pp = fun x -> assert false in
 360     let obj_pp = CicNotationPp.pp_obj CicNotationPp.pp_term in
 361     GrafiteAstPp.pp_statement
 362      ~map_unicode_to_tex:false ~term_pp ~lazy_term_pp ~obj_pp t
 363   in
 364   let buri = Pcre.replace ~pat:"\\.p$" ("cic:/matita/TPTP/" ^ filename) in
 365   let extra_statements_start = [
 366     GA.Executable(floc,GA.Command(floc,
 367     GA.Set(floc,"baseuri",buri)))]
 368   in
 369   let preamble =
 370     match raw_preamble with
 371     | None ->
 372        pp (GA.Executable(floc,
 373            GA.Command(floc,GA.Include(floc,false,"logic/equality.ma"))))
 374     | Some s -> s buri
 375   in
 376   let extra_statements_end = [] in
 377   let aliases = []
 378    (*[("eq","cic:/Coq/Init/Logic/eq.ind#xpointer(1/1)");
 379    ("trans_eq","cic:/Coq/Init/Logic/trans_eq.con");
 380    ("eq_ind_r","cic:/Coq/Init/Logic/eq_ind_r.con");
 381    ("eq_ind","cic:/Coq/Init/Logic/eq_ind.con");
 382    ("sym_eq","cic:/Coq/Init/Logic/sym_eq.con");
 383    ("refl_equal","cic:/Coq/Init/Logic/eq.ind#xpointer(1/1/1)")] *)
 384   in
 385   let s1 = List.map pp extra_statements_start in
 386   let s2 =
 387     List.map
 388      (fun (n,s) ->
 389        LexiconAstPp.pp_command (LA.Alias(floc, LA.Ident_alias(n,s))) ^ ".")
 390      aliases
 391   in
 392   let s3 = List.map pp grafite_ast_statements in
 393   let s4 = List.map pp extra_statements_end in
 394   String.concat "\n" (s1@[preamble]@s2@s3@s4)
 395 ;;