helm/software/helena/src/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U  = NUri
  13 module C  = Cps
  14 module W  = Share
  15 module L  = Log
  16 module H  = Hierarchy
  17 module E  = Entity
  18 module N  = Level
  19 module O  = Output
  20 module Q  = Ccs
  21 module S  = Status
  22 module B  = Brg
  23 module BO = BrgOutput
  24 module BE = BrgEnvironment
  25
  26 type kam = {
  27    e: B.lenv;                 (* environment              *)
  28    s: (B.lenv * B.term) list; (* stack                    *)
  29    l: int;                    (* level                    *)
  30    d: int;                    (* inferred type iterations *)
  31    n: int option;             (* expected type iterations *)
  32 }
  33
  34 type message = (kam, B.term) L.message
  35
  36 (* Internal functions *******************************************************)
  37
  38 let level = 5
  39
  40 let log1 s c t =
  41    let sc, st = s ^ " in the environment", "the term" in
  42    L.log BO.specs level (L.et_items1 sc c st t)
  43
  44 let log2 s cu u ct t =
  45    let s1, s2, s3 = s ^ " in the environment (expected)", "the term", "and in the environment (inferred)" in
  46    L.log BO.specs level (L.et_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)
  47
  48 let rec list_and map = function
  49    | hd1 :: tl1, hd2 :: tl2 ->
  50       if map hd1 hd2 then list_and map (tl1, tl2) else false
  51    | l1, l2                 -> l1 = l2
  52
  53 let zero = Some 0
  54
  55 (* check closure *)
  56 let are_alpha_convertible err f t1 t2 =
  57    let rec aux f = function
  58       | B.Sort (_, p1), B.Sort (_, p2)
  59       | B.LRef (_, p1), B.LRef (_, p2)         ->
  60          if p1 = p2 then f () else err ()
  61       | B.GRef (_, u1), B.GRef (_, u2)         ->
  62          if U.eq u1 u2 then f () else err ()
  63       | B.Cast (_, v1, t1), B.Cast (_, v2, t2)
  64       | B.Appl (_, v1, t1), B.Appl (_, v2, t2) ->
  65          let f _ = aux f (t1, t2) in
  66          aux f (v1, v2)
  67       | B.Bind (_, b1, t1), B.Bind (_, b2, t2) ->
  68          let f _ = aux f (t1, t2) in
  69          aux_bind f (b1, b2)
  70       | _                                      -> err ()
  71    and aux_bind f = function
  72       | B.Abbr v1, B.Abbr v2                          -> aux f (v1, v2)
  73       | B.Abst (n1, v1), B.Abst (n2, v2) when n1 = n2 -> aux f (v1, v2)
  74       | B.Void, B.Void                                -> f ()
  75       | _                                             -> err ()
  76    in
  77    if W.eq t1 t2 then f () else aux f (t1, t2)
  78
  79 let assert_tstep m vo = match m.n with
  80    | Some n -> n > m.d
  81    | None   -> vo
  82
  83 let tstep m = {m with d = succ m.d}
  84
  85 let get m i =
  86    let _, c, a, b = B.get m.e i in c, a, b
  87
  88 (* to share *)
  89 let rec step st m x =
  90    log1 (Printf.sprintf "entering R.step: l:%u d:%i n:%s" m.l m.d (match m.n with Some n -> string_of_int n | None -> "infinite")) m.e x;
  91    match x with
  92    | B.Sort (a, h)                ->
  93       if assert_tstep m false then
  94          step st (tstep m) (B.Sort (a, H.apply h))
  95       else m, x, None
  96    | B.GRef (_, uri)              ->
  97       begin match BE.get_entity uri with
  98          | _, _, E.Abbr v when st.S.delta               ->
  99             O.add ~gdelta:1 (); step st m v
 100          | _, _, E.Abst (_, w) when assert_tstep m true ->
 101             O.add ~grt:1 (); step st (tstep m) w
 102          | _, _, E.Abbr v                               ->
 103             m, x, Some v
 104          | _, _, E.Abst _                               ->
 105             m, x, None
 106          | _, _, E.Void                                 ->
 107             assert false
 108       end
 109    | B.LRef (_, i)                ->
 110       begin match get m i with
 111          | c, _, B.Abbr v                          ->
 112             O.add ~ldelta:1 ();
 113             step st {m with e = c} v
 114          | c, _, B.Abst (_, w) when assert_tstep m true ->
 115             O.add ~lrt:1 ();
 116             step st {(tstep m) with e = c} w
 117          | _, a, B.Abst _                               ->
 118            m, B.LRef (a, i), None
 119          | _, _, B.Void                                 ->
 120             assert false
 121       end
 122    | B.Cast (_, u, t)             ->
 123       if assert_tstep m false then begin
 124          O.add ~e:1 ();
 125          step st (tstep m) u
 126       end else begin
 127          O.add ~epsilon:1 ();
 128          step st m t
 129       end
 130    | B.Appl (_, v, t)             ->
 131       step st {m with s = (m.e, v) :: m.s} t
 132    | B.Bind (a, B.Abst (n, w), t) ->
 133       let n = N.minus n m.d in
 134       let x = B.Bind (a, B.Abst (n, w), t) in
 135       begin match m.s with
 136          | []          -> m, x, None
 137          | (c, v) :: s ->
 138             if N.is_zero n then Q.add_nonzero st.S.cc a;
 139             O.add ~beta:1 ~theta:(List.length s) ();
 140             let e = B.push m.e c a (B.abbr v) (* (B.Cast ([], w, v)) *) in
 141             step st {m with e = e; s = s} t
 142       end
 143    | B.Bind (a, b, t)        ->
 144       O.add ~theta:(List.length m.s) ();
 145       let e = B.push m.e m.e a b in
 146       step st {m with e = e} t
 147
 148 let reset m ?(e=m.e) n =
 149    {m with e = e; n = n; s = []; d = 0}
 150
 151 let assert_iterations m1 m2 = match m1.n, m2.n with
 152       | Some n1, Some n2 -> n1 - m1.d = n2 - m2.d
 153       | _                -> false
 154
 155 let push m a b =
 156    assert (m.s = []);
 157    let a, l = match b with
 158       | B.Abst _ -> E.Apix m.l :: a, succ m.l
 159       | b        -> a, m.l
 160    in
 161    let e = B.push m.e m.e a b in
 162    {m with e = e; l = l}
 163
 164 let rec ac_nfs st (m1, t1, r1) (m2, t2, r2) =
 165    log2 "Now converting nfs" m1.e t1 m2.e t2;
 166    match t1, r1, t2, r2 with
 167       | B.Sort (_, h1), _, B.Sort (_, h2), _                ->
 168          h1 = h2
 169       | B.LRef (a1, _), _, B.LRef (a2, _), _                ->
 170          let e1 = E.apix C.err C.start a1 in
 171          let e2 = E.apix C.err C.start a2 in
 172          if e1 = e2 then ac_stacks st m1 m2 else false
 173       | B.GRef (_, u1), None, B.GRef (_, u2), None          ->
 174          if U.eq u1 u2 & assert_iterations m1 m2 then ac_stacks st m1 m2 else false
 175       | B.GRef (a1, u1), Some v1, B.GRef (a2, u2), Some v2  ->
 176          let e1 = E.apix C.err C.start a1 in
 177          let e2 = E.apix C.err C.start a2 in
 178          if e1 < e2 then begin
 179             O.add ~gdelta:1 ();
 180             ac_nfs st (m1, t1, r1) (step st m2 v2)
 181          end else if e2 < e1 then begin
 182             O.add ~gdelta:1 ();
 183             ac_nfs st (step st m1 v1) (m2, t2, r2)
 184          end else if U.eq u1 u2 & assert_iterations m1 m2 && ac_stacks st m1 m2 then true
 185          else begin
 186             O.add ~gdelta:2 ();
 187             ac st m1 v1 m2 v2
 188          end
 189       | _, _, B.GRef _, Some v2                             ->
 190          O.add ~gdelta:1 ();
 191          ac_nfs st (m1, t1, r1) (step st m2 v2)
 192       | B.GRef _, Some v1, _, _                             ->
 193          O.add ~gdelta:1 ();
 194          ac_nfs st (step st m1 v1) (m2, t2, r2)
 195       | B.Bind (a1, (B.Abst (n1, w1) as b1), t1), _,
 196         B.Bind (a2, (B.Abst (n2, w2) as b2), t2), _         ->
 197          if n1 = n2 then () else Q.add_equal st.S.cc a1 a2;
 198          if ac {st with S.si = false} (reset m1 zero) w1 (reset m2 zero) w2 then
 199             ac st (push m1 a1 b1) t1 (push m2 a2 b2) t2
 200          else false
 201       | B.Sort _, _, B.Bind (a, (B.Abst (n, _) as b), t), _ ->
 202          if N.is_zero n then () else Q.add_zero st.S.cc a;
 203          O.add ~si:1 ();
 204          ac st (push m1 a b) t1 (push m2 a b) t
 205       | _                                                   -> false
 206
 207 and ac st m1 t1 m2 t2 =
 208 (*   L.warn "entering R.are_convertible"; *)
 209    ac_nfs st (step st m1 t1) (step st m2 t2)
 210
 211 and ac_stacks st m1 m2 =
 212 (*   L.warn "entering R.are_convertible_stacks"; *)
 213    if List.length m1.s <> List.length m2.s then false else
 214    let map (c1, v1) (c2, v2) =
 215       let m1, m2 = reset m1 ~e:c1 zero, reset m2 ~e:c2 zero in
 216       ac {st with S.si = false} m1 v1 m2 v2
 217    in
 218    list_and map (m1.s, m2.s)
 219
 220 (* Interface functions ******************************************************)
 221
 222 let empty_kam = {
 223    e = B.empty; s = []; l = 0; d = 0; n = None
 224 }
 225
 226 let get m i =
 227    assert (m.s = []);
 228    let _, _, _, b = B.get m.e i in b
 229
 230 let xwhd st m n t =
 231    L.box level; log1 "Now scanning" m.e t;
 232    let m, t, _ = step {st with S.delta = true} (reset m n) t in
 233    L.unbox level; m, t
 234
 235 let are_convertible st m1 n1 t1 m2 n2 t2 =
 236    L.box level; log2 "Now converting" m1.e t1 m2.e t2;
 237    let r = ac {st with S.delta = st.S.expand} (reset m1 n1) t1 (reset m2 n2) t2 in
 238    L.unbox level; r
 239 (*    let err _ = in
 240       if W.eq mu mw then are_alpha_convertible err f u w else err () *)
 241
 242 (* error reporting **********************************************************)
 243
 244 let pp_term m frm t = BO.specs.L.pp_term m.e frm t
 245
 246 let pp_lenv frm m = BO.specs.L.pp_lenv frm m.e
 247
 248 let specs = {
 249    L.pp_term = pp_term; L.pp_lenv = pp_lenv
 250 }