helm/software/lambda-delta/basic_ag/bag.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* kernel version: basic, absolute, global *)
  13 (* note          : experimental *)
  14
  15 type uri = Entity.uri
  16 type id = Entity.id
  17
  18 type bind = Void         (* exclusion *)
  19           | Abst of term (* abstraction *)
  20           | Abbr of term (* abbreviation *)
  21
  22 and term = Sort of int                    (* hierarchy index *)
  23          | LRef of int                    (* location *)
  24          | GRef of uri                    (* reference *)
  25          | Cast of term * term            (* domain, element *)
  26          | Appl of term * term            (* argument, function *)
  27          | Bind of int * id * bind * term (* location, name, binder, scope *)
  28
  29 type entity = term Entity.entity (* attrs, uri, binder *)
  30
  31 type lenv = (int * id * bind) list (* location, name, binder *)
  32
  33 type message = (lenv, term) Log.item list
  34
  35 (* helpers ******************************************************************)
  36
  37 let mk_uri si root s =
  38    let kernel = if si then "bag-si" else "bag" in
  39    String.concat "/" ["ld:"; kernel; root; s ^ ".ld"]
  40
  41 (* Currified constructors ***************************************************)
  42
  43 let abst w = Abst w
  44
  45 let abbr v = Abbr v
  46
  47 let lref i = LRef i
  48
  49 let cast u t = Cast (u, t)
  50
  51 let appl u t = Appl (u, t)
  52
  53 let bind l id b t = Bind (l, id, b, t)
  54
  55 let bind_abst l id u t = Bind (l, id, Abst u, t)
  56
  57 let bind_abbr l id v t = Bind (l, id, Abbr v, t)
  58
  59 (* location handling functions **********************************************)
  60
  61 let location = ref 0
  62
  63 let new_location () = let loc = !location in incr location; loc
  64
  65 let locations () = !location
  66
  67 (* local environment handling functions *************************************)
  68
  69 let empty_lenv = []
  70
  71 let push msg f es l id b =
  72    let rec does_not_occur loc = function
  73       | []                          -> true
  74       | (l, _, _) :: _ when l = loc -> false
  75       | _ :: es                     -> does_not_occur l es
  76    in
  77    if not (does_not_occur l es) then failwith msg else
  78    let c = (l, id, b) :: es in f c
  79
  80 let append f es1 es2 =
  81    f (List.append es2 es1)
  82
  83 let map f map es =
  84    Cps.list_map f map es
  85
  86 let contents f es = f es
  87
  88 let get f es i =
  89    let rec aux = function
  90       | []               -> f None
  91       | (l, id, b) :: tl -> if l = i then f (Some (id, b)) else aux tl
  92    in
  93    aux es