helm/software/lambda-delta/basic_ag/bagReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module I = AutItem
  16 module B = Bag
  17 module O = BagOutput
  18 module E = BagEnvironment
  19 module S = BagSubstitution
  20
  21 exception LRefNotFound of B.message
  22
  23 type machine = {
  24    i: int;
  25    c: B.context;
  26    s: B.term list
  27 }
  28
  29 type whd_result =
  30    | Sort_ of int
  31    | LRef_ of int * B.term option
  32    | GRef_ of B.obj
  33    | Bind_ of int * B.id * B.term * B.term
  34
  35 type ho_whd_result =
  36    | Sort of int
  37    | GRef of U.uri * B.term list
  38    | Abst of B.term
  39
  40 type ac_result = (int * NUri.uri * Bag.term list) list option
  41
  42 (* Internal functions *******************************************************)
  43
  44 let term_of_whdr = function
  45    | Sort_ h             -> B.Sort h
  46    | LRef_ (i, _)        -> B.LRef i
  47    | GRef_ (_, uri, _)   -> B.GRef uri
  48    | Bind_ (l, id, w, t) -> B.bind_abst l id w t
  49
  50 let level = 5
  51
  52 let error i = raise (LRefNotFound (L.items1 (string_of_int i)))
  53
  54 let empty_machine = {i = 0; c = B.empty_context; s = []}
  55
  56 let inc m = {m with i = succ m.i}
  57
  58 let unwind_to_term f m t =
  59    let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
  60    let f mc = C.list_fold_left f map t mc in
  61    B.contents f m.c
  62
  63 let unwind_stack f m =
  64    let map f v = unwind_to_term f m v in
  65    C.list_map f map m.s
  66
  67 let get f c m i =
  68    let f = function
  69       | Some (_, b) -> f b
  70       | None        -> error i
  71    in
  72    let f c = B.get f c i in
  73    B.append f c m.c
  74
  75 let push f c m l id w =
  76    assert (m.s = []);
  77    let f w = B.push f c l id (B.Abst w) in
  78    unwind_to_term f m w
  79
  80 (* to share *)
  81 let rec whd f c m x = match x with
  82    | B.Sort h                    -> f m (Sort_ h)
  83    | B.GRef uri                  ->
  84       let f obj = f m (GRef_ obj) in
  85       E.get_obj f uri
  86    | B.LRef i                    ->
  87       let f = function
  88          | B.Void   -> f m (LRef_ (i, None))
  89          | B.Abst t -> f m (LRef_ (i, Some t))
  90          | B.Abbr t -> whd f c m t
  91       in
  92       get f c m i
  93    | B.Cast (_, t)               -> whd f c m t
  94    | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t
  95    | B.Bind (l, id, B.Abst w, t) ->
  96       begin match m.s with
  97          | []      -> f m (Bind_ (l, id, w, t))
  98          | v :: tl ->
  99             let f mc = whd f c {m with c = mc; s = tl} t in
 100             B.push f m.c l id (B.Abbr (B.Cast (w, v)))
 101       end
 102    | B.Bind (l, id, b, t)         ->
 103       let f mc = whd f c {m with c = mc} t in
 104       B.push f m.c l id b
 105
 106 let insert f i uri vs = function
 107    | Some l -> f (Some ((i, uri, vs) :: l))
 108    | None   -> assert false
 109
 110 (* Interface functions ******************************************************)
 111
 112 let rec ho_whd f c m x =
 113    let aux m = function
 114       | Sort_ h                  -> f (Sort h)
 115       | Bind_ (_, _, w, _)       ->
 116          let f w = f (Abst w) in unwind_to_term f m w
 117       | LRef_ (_, Some w)        -> ho_whd f c m w
 118       | GRef_ (_, uri, B.Abst w) ->
 119          let f = function
 120             | Abst _ as r -> f r
 121             | GRef _ as r -> f r
 122             | Sort _      ->
 123                let f vs = f (GRef (uri, vs)) in unwind_stack f m
 124          in
 125          ho_whd f c m w
 126       | GRef_ (_, _, B.Abbr v)   -> ho_whd f c m v
 127       | LRef_ (_, None)          -> assert false
 128       | GRef_ (_, _, B.Void)     -> assert false
 129    in
 130    whd aux c m x
 131
 132 let ho_whd f c t =
 133    let f r = L.unbox level; f r in
 134    L.box level; L.log O.specs level (L.ct_items1 "Now scanning" c t);
 135    ho_whd f c empty_machine t
 136
 137 let rec are_convertible f xl c m1 t1 m2 t2 =
 138    let rec aux m1 r1 m2 r2 =
 139    let u, t = term_of_whdr r1, term_of_whdr r2 in
 140    L.log O.specs level (L.ct_items2 "Now really converting" c u "and" c t);
 141    match r1, r2 with
 142       | Sort_ h1, Sort_ h2                                 ->
 143          if h1 = h2 then f xl else f None
 144       | LRef_ (i1, _), LRef_ (i2, _)                       ->
 145          if i1 = i2 then are_convertible_stacks f xl c m1 m2 else f None
 146       | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
 147          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else f None
 148       | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
 149          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else
 150          if a1 < a2 then whd (aux m1 r1) c m2 v2 else
 151          whd (aux_rev m2 r2) c m1 v1
 152       | _, GRef_ (_, _, B.Abbr v2)                         ->
 153          whd (aux m1 r1) c m2 v2
 154       | GRef_ (_, _, B.Abbr v1), _                         ->
 155          whd (aux_rev m2 r2) c m1 v1
 156       | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
 157          let f xl =
 158             let h c =
 159                let m1, m2 = inc m1, inc m2 in
 160                S.subst (are_convertible f xl c m1 t1 m2) l1 l2 t2
 161             in
 162             if xl = None then f xl else push h c m1 l1 id1 w1
 163          in
 164          are_convertible f xl c m1 w1 m2 w2
 165 (* we detect the AUT-QE reduction rule for type/prop inclusion *)
 166       | GRef_ (_, uri, B.Abst _), Bind_ (l1, _, _, _)      ->
 167          let g vs = insert f l1 uri vs xl in
 168          if U.eq uri I.imp then unwind_stack g m1 else
 169          if U.eq uri I.all then unwind_stack g m1 else
 170          begin L.warn (U.string_of_uri uri); f None end
 171       | _                                                  -> f None
 172    and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
 173    let f m1 r1 = whd (aux m1 r1) c m2 t2 in
 174    whd f c m1 t1
 175
 176 and are_convertible_stacks f xl c m1 m2 =
 177    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 178    let map f xl v1 v2 = are_convertible f xl c mm1 v1 mm2 v2 in
 179    if List.length m1.s <> List.length m2.s then f None else
 180    C.list_fold_left2 f map xl m1.s m2.s
 181
 182 let are_convertible f c u t =
 183    let f b = L.unbox level; f b in
 184    L.box level;
 185    L.log O.specs level (L.ct_items2 "Now converting" c u "and" c t);
 186    are_convertible f (Some []) c empty_machine u empty_machine t