helm/software/lambda-delta/basic_ag/bagReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module B = Bag
  16 module O = BagOutput
  17 module E = BagEnvironment
  18 module S = BagSubstitution
  19
  20 type machine = {
  21    i: int;
  22    c: B.lenv;
  23    s: B.term list
  24 }
  25
  26 type whd_result =
  27    | Sort_ of int
  28    | LRef_ of int * B.term option
  29    | GRef_ of B.entry
  30    | Bind_ of int * B.id * B.term * B.term
  31
  32 type ho_whd_result =
  33    | Sort of int
  34    | Abst of B.term
  35
  36 (* Internal functions *******************************************************)
  37
  38 let term_of_whdr = function
  39    | Sort_ h             -> B.Sort h
  40    | LRef_ (i, _)        -> B.LRef i
  41    | GRef_ (_, uri, _)   -> B.GRef uri
  42    | Bind_ (l, id, w, t) -> B.bind_abst l id w t
  43
  44 let level = 5
  45
  46 let log1 s c t =
  47    let sc, st = s ^ " in the environment", "the term" in
  48    L.log O.specs level (L.et_items1 sc c st t)
  49
  50 let log2 s cu u ct t =
  51    let s1, s2, s3 = s ^ " in the environment", "the term", "and in the environment" in
  52    L.log O.specs level (L.et_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)
  53
  54 let empty_machine = {i = 0; c = B.empty_lenv; s = []}
  55
  56 let inc m = {m with i = succ m.i}
  57
  58 let unwind_to_term f m t =
  59    let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
  60    let f mc = C.list_fold_left f map t mc in
  61    B.contents f m.c
  62
  63 let unwind_stack f m =
  64    let map f v = unwind_to_term f m v in
  65    C.list_map f map m.s
  66
  67 let get f c m i =
  68    let f = function
  69       | Some (_, b) -> f b
  70       | None        -> assert false
  71    in
  72    let f c = B.get f c i in
  73    B.append f c m.c
  74
  75 let push msg f c m l id w =
  76    assert (m.s = []);
  77    let f w = B.push msg f c l id (B.Abst w) in
  78    unwind_to_term f m w
  79
  80 (* to share *)
  81 let rec whd f c m x =
  82 (*   L.warn "entering R.whd"; *)
  83    match x with
  84    | B.Sort h                    -> f m (Sort_ h)
  85    | B.GRef uri                  ->
  86       let f entry = f m (GRef_ entry) in
  87       E.get_entry f uri
  88    | B.LRef i                    ->
  89       let f = function
  90          | B.Void   -> f m (LRef_ (i, None))
  91          | B.Abst t -> f m (LRef_ (i, Some t))
  92          | B.Abbr t -> whd f c m t
  93       in
  94       get f c m i
  95    | B.Cast (_, t)               -> whd f c m t
  96    | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t
  97    | B.Bind (l, id, B.Abst w, t) ->
  98       begin match m.s with
  99          | []      -> f m (Bind_ (l, id, w, t))
 100          | v :: tl ->
 101             let nl = B.new_location () in
 102             let f mc = S.subst (whd f c {m with c = mc; s = tl}) nl l t in
 103             B.push "!" f m.c nl id (B.Abbr (B.Cast (w, v)))
 104       end
 105    | B.Bind (l, id, b, t)         ->
 106       let nl = B.new_location () in
 107       let f mc = S.subst (whd f c {m with c = mc}) nl l t in
 108       B.push "!" f m.c nl id b
 109
 110 (* Interface functions ******************************************************)
 111
 112 let rec ho_whd f c m x =
 113 (*   L.warn "entering R.ho_whd"; *)
 114    let aux m = function
 115       | Sort_ h                -> f (Sort h)
 116       | Bind_ (_, _, w, _)     ->
 117          let f w = f (Abst w) in unwind_to_term f m w
 118       | LRef_ (_, Some w)      -> ho_whd f c m w
 119       | GRef_ (_, _, B.Abst w) -> ho_whd f c m w
 120       | GRef_ (_, _, B.Abbr v) -> ho_whd f c m v
 121       | LRef_ (_, None)        -> assert false
 122       | GRef_ (_, _, B.Void)   -> assert false
 123    in
 124    whd aux c m x
 125
 126 let ho_whd f c t =
 127    let f r = L.unbox level; f r in
 128    L.box level; log1 "Now scanning" c t;
 129    ho_whd f c empty_machine t
 130
 131 let rec are_convertible f ~si a c m1 t1 m2 t2 =
 132 (*   L.warn "entering R.are_convertible"; *)
 133    let rec aux m1 r1 m2 r2 =
 134 (*   L.warn "entering R.are_convertible_aux"; *)
 135    let u, t = term_of_whdr r1, term_of_whdr r2 in
 136    log2 "Now really converting" c u c t;
 137    match r1, r2 with
 138       | Sort_ h1, Sort_ h2                                 ->
 139          if h1 = h2 then f a else f false
 140       | LRef_ (i1, _), LRef_ (i2, _)                       ->
 141          if i1 = i2 then are_convertible_stacks f ~si a c m1 m2 else f false
 142       | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
 143          if a1 = a2 then are_convertible_stacks f ~si a c m1 m2 else f false
 144       | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
 145          if a1 = a2 then
 146             let f a =
 147                if a then f a else are_convertible f ~si true c m1 v1 m2 v2
 148             in
 149             are_convertible_stacks f ~si a c m1 m2
 150          else
 151          if a1 < a2 then whd (aux m1 r1) c m2 v2 else
 152          whd (aux_rev m2 r2) c m1 v1
 153       | _, GRef_ (_, _, B.Abbr v2)                         ->
 154          whd (aux m1 r1) c m2 v2
 155       | GRef_ (_, _, B.Abbr v1), _                         ->
 156          whd (aux_rev m2 r2) c m1 v1
 157       | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
 158            let l = B.new_location () in
 159            let h c =
 160               let m1, m2 = inc m1, inc m2 in
 161               let f t1 = S.subst (are_convertible f ~si a c m1 t1 m2) l l2 t2 in
 162               S.subst f l l1 t1
 163          in
 164          let f r = if r then push "!" h c m1 l id1 w1 else f false in
 165          are_convertible f ~si a c m1 w1 m2 w2
 166 (* we detect the AUT-QE reduction rule for type/prop inclusion *)
 167       | Sort_ _, Bind_ (l2, id2, w2, t2) when si           ->
 168          let m1, m2 = inc m1, inc m2 in
 169          let f c = are_convertible f ~si a c m1 (term_of_whdr r1) m2 t2 in
 170          push "nsi" f c m2 l2 id2 w2
 171       | _                                                  -> f false
 172    and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
 173    let g m1 r1 = whd (aux m1 r1) c m2 t2 in
 174    if a = false then f false else whd g c m1 t1
 175
 176 and are_convertible_stacks f ~si a c m1 m2 =
 177 (*   L.warn "entering R.are_convertible_stacks"; *)
 178    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 179    let map f a v1 v2 = are_convertible f ~si a c mm1 v1 mm2 v2 in
 180    if List.length m1.s <> List.length m2.s then
 181       begin
 182 (*         L.warn (Printf.sprintf "Different lengths: %u %u"
 183             (List.length m1.s) (List.length m2.s)
 184          ); *)
 185          f false
 186       end
 187    else
 188       C.list_fold_left2 f map a m1.s m2.s
 189
 190 let are_convertible f ?(si=false) c u t =
 191    let f b = L.unbox level; f b in
 192    L.box level; log2 "Now converting" c u c t;
 193    are_convertible f ~si true c empty_machine u empty_machine t