helm/software/lambda-delta/basic_ag/bagReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module I = AutItem
  16 module B = Bag
  17 module O = BagOutput
  18 module E = BagEnvironment
  19 module S = BagSubstitution
  20
  21 exception LRefNotFound of B.message
  22
  23 type machine = {
  24    i: int;
  25    c: B.context;
  26    s: B.term list
  27 }
  28
  29 type whd_result =
  30    | Sort_ of int
  31    | LRef_ of int * B.term option
  32    | GRef_ of B.obj
  33    | Bind_ of int * B.id * B.term * B.term
  34
  35 type ho_whd_result =
  36    | Sort of int
  37    | GRef of U.uri * B.term list
  38    | Abst of B.term
  39
  40 type ac_result = (int * NUri.uri * Bag.term list) list option
  41
  42 (* Internal functions *******************************************************)
  43
  44 let term_of_whdr = function
  45    | Sort_ h             -> B.Sort h
  46    | LRef_ (i, _)        -> B.LRef i
  47    | GRef_ (_, uri, _)   -> B.GRef uri
  48    | Bind_ (l, id, w, t) -> B.bind_abst l id w t
  49
  50 let level = 5
  51
  52 let error i = raise (LRefNotFound (L.items1 (string_of_int i)))
  53
  54 let log1 s c t =
  55    let sc, st = s ^ " in the context", "the term" in
  56    L.log O.specs level (L.ct_items1 sc c st t)
  57
  58 let log2 s c u t =
  59    let sc, su, st = s ^ " in the context", "the term", "and the term" in
  60    L.log O.specs level (L.ct_items2 sc c su u st t)
  61
  62 let empty_machine = {i = 0; c = B.empty_context; s = []}
  63
  64 let inc m = {m with i = succ m.i}
  65
  66 let unwind_to_term f m t =
  67    let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
  68    let f mc = C.list_fold_left f map t mc in
  69    B.contents f m.c
  70
  71 let unwind_stack f m =
  72    let map f v = unwind_to_term f m v in
  73    C.list_map f map m.s
  74
  75 let get f c m i =
  76    let f = function
  77       | Some (_, b) -> f b
  78       | None        -> error i
  79    in
  80    let f c = B.get f c i in
  81    B.append f c m.c
  82
  83 let push f c m l id w =
  84    assert (m.s = []);
  85    let f w = B.push f c l id (B.Abst w) in
  86    unwind_to_term f m w
  87
  88 (* to share *)
  89 let rec whd f c m x = match x with
  90    | B.Sort h                    -> f m (Sort_ h)
  91    | B.GRef uri                  ->
  92       let f obj = f m (GRef_ obj) in
  93       E.get_obj f uri
  94    | B.LRef i                    ->
  95       let f = function
  96          | B.Void   -> f m (LRef_ (i, None))
  97          | B.Abst t -> f m (LRef_ (i, Some t))
  98          | B.Abbr t -> whd f c m t
  99       in
 100       get f c m i
 101    | B.Cast (_, t)               -> whd f c m t
 102    | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t
 103    | B.Bind (l, id, B.Abst w, t) ->
 104       begin match m.s with
 105          | []      -> f m (Bind_ (l, id, w, t))
 106          | v :: tl ->
 107             let f mc = whd f c {m with c = mc; s = tl} t in
 108             B.push f m.c l id (B.Abbr (B.Cast (w, v)))
 109       end
 110    | B.Bind (l, id, b, t)         ->
 111       let f mc = whd f c {m with c = mc} t in
 112       B.push f m.c l id b
 113
 114 let insert f i uri vs = function
 115    | Some l -> f (Some ((i, uri, vs) :: l))
 116    | None   -> assert false
 117
 118 (* Interface functions ******************************************************)
 119
 120 let rec ho_whd f c m x =
 121    let aux m = function
 122       | Sort_ h                  -> f (Sort h)
 123       | Bind_ (_, _, w, _)       ->
 124          let f w = f (Abst w) in unwind_to_term f m w
 125       | LRef_ (_, Some w)        -> ho_whd f c m w
 126       | GRef_ (_, uri, B.Abst w) ->
 127          let f = function
 128             | Abst _ as r -> f r
 129             | GRef _ as r -> f r
 130             | Sort _      ->
 131                let f vs = f (GRef (uri, vs)) in unwind_stack f m
 132          in
 133          ho_whd f c m w
 134       | GRef_ (_, _, B.Abbr v)   -> ho_whd f c m v
 135       | LRef_ (_, None)          -> assert false
 136       | GRef_ (_, _, B.Void)     -> assert false
 137    in
 138    whd aux c m x
 139
 140 let ho_whd f c t =
 141    let f r = L.unbox level; f r in
 142    L.box level; log1 "Now scanning" c t;
 143    ho_whd f c empty_machine t
 144
 145 let rec are_convertible f xl c m1 t1 m2 t2 =
 146    let rec aux m1 r1 m2 r2 =
 147    let u, t = term_of_whdr r1, term_of_whdr r2 in
 148    log2 "Now really converting" c u t;
 149    match r1, r2 with
 150       | Sort_ h1, Sort_ h2                                 ->
 151          if h1 = h2 then f xl else f None
 152       | LRef_ (i1, _), LRef_ (i2, _)                       ->
 153          if i1 = i2 then are_convertible_stacks f xl c m1 m2 else f None
 154       | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
 155          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else f None
 156       | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
 157          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else
 158          if a1 < a2 then whd (aux m1 r1) c m2 v2 else
 159          whd (aux_rev m2 r2) c m1 v1
 160       | _, GRef_ (_, _, B.Abbr v2)                         ->
 161          whd (aux m1 r1) c m2 v2
 162       | GRef_ (_, _, B.Abbr v1), _                         ->
 163          whd (aux_rev m2 r2) c m1 v1
 164       | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
 165          let f xl =
 166             let h c =
 167                let m1, m2 = inc m1, inc m2 in
 168                S.subst (are_convertible f xl c m1 t1 m2) l1 l2 t2
 169             in
 170             if xl = None then f xl else push h c m1 l1 id1 w1
 171          in
 172          are_convertible f xl c m1 w1 m2 w2
 173 (* we detect the AUT-QE reduction rule for type/prop inclusion *)
 174       | GRef_ (_, uri, B.Abst _), Bind_ (l1, _, _, _)      ->
 175          let g vs = insert f l1 uri vs xl in
 176          if U.eq uri I.imp then unwind_stack g m1 else
 177          if U.eq uri I.all then unwind_stack g m1 else
 178          begin L.warn (U.string_of_uri uri); f None end
 179       | _                                                  -> f None
 180    and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
 181    let f m1 r1 = whd (aux m1 r1) c m2 t2 in
 182    whd f c m1 t1
 183
 184 and are_convertible_stacks f xl c m1 m2 =
 185    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 186    let map f xl v1 v2 = are_convertible f xl c mm1 v1 mm2 v2 in
 187    if List.length m1.s <> List.length m2.s then f None else
 188    C.list_fold_left2 f map xl m1.s m2.s
 189
 190 let are_convertible f c u t =
 191    let f b = L.unbox level; f b in
 192    L.box level; log2 "Now converting" c u t;
 193    are_convertible f (Some []) c empty_machine u empty_machine t