helm/software/lambda-delta/basic_ag/bagReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module B = Bag
  16 module O = BagOutput
  17 module E = BagEnvironment
  18 module S = BagSubstitution
  19
  20 exception LRefNotFound of B.message
  21
  22 type machine = {
  23    i: int;
  24    c: B.context;
  25    s: B.term list
  26 }
  27
  28 type whd_result =
  29    | Sort_ of int
  30    | LRef_ of int * B.term option
  31    | GRef_ of B.obj
  32    | Bind_ of int * B.id * B.term * B.term
  33
  34 type ho_whd_result =
  35    | Sort of int
  36    | GRef of U.uri * B.term list
  37    | Abst of B.term
  38
  39 (* Internal functions *******************************************************)
  40
  41 let term_of_whdr = function
  42    | Sort_ h             -> B.Sort h
  43    | LRef_ (i, _)        -> B.LRef i
  44    | GRef_ (_, uri, _)   -> B.GRef uri
  45    | Bind_ (l, id, w, t) -> B.bind_abst l id w t
  46
  47 let level = 5
  48
  49 let error i = raise (LRefNotFound (L.items1 (string_of_int i)))
  50
  51 let log1 s c t =
  52    let sc, st = s ^ " in the context", "the term" in
  53    L.log O.specs level (L.ct_items1 sc c st t)
  54
  55 let log2 s c u t =
  56    let sc, su, st = s ^ " in the context", "the term", "and the term" in
  57    L.log O.specs level (L.ct_items2 sc c su u st t)
  58
  59 let empty_machine = {i = 0; c = B.empty_context; s = []}
  60
  61 let inc m = {m with i = succ m.i}
  62
  63 let unwind_to_term f m t =
  64    let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
  65    let f mc = C.list_fold_left f map t mc in
  66    B.contents f m.c
  67
  68 let unwind_stack f m =
  69    let map f v = unwind_to_term f m v in
  70    C.list_map f map m.s
  71
  72 let get f c m i =
  73    let f = function
  74       | Some (_, b) -> f b
  75       | None        -> error i
  76    in
  77    let f c = B.get f c i in
  78    B.append f c m.c
  79
  80 let push f c m l id w =
  81    assert (m.s = []);
  82    let f w = B.push f c l id (B.Abst w) in
  83    unwind_to_term f m w
  84
  85 (* to share *)
  86 let rec whd f c m x = match x with
  87    | B.Sort h                    -> f m (Sort_ h)
  88    | B.GRef uri                  ->
  89       let f obj = f m (GRef_ obj) in
  90       E.get_obj f uri
  91    | B.LRef i                    ->
  92       let f = function
  93          | B.Void   -> f m (LRef_ (i, None))
  94          | B.Abst t -> f m (LRef_ (i, Some t))
  95          | B.Abbr t -> whd f c m t
  96       in
  97       get f c m i
  98    | B.Cast (_, t)               -> whd f c m t
  99    | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t
 100    | B.Bind (l, id, B.Abst w, t) ->
 101       begin match m.s with
 102          | []      -> f m (Bind_ (l, id, w, t))
 103          | v :: tl ->
 104             let f mc = whd f c {m with c = mc; s = tl} t in
 105             B.push f m.c l id (B.Abbr (B.Cast (w, v)))
 106       end
 107    | B.Bind (l, id, b, t)         ->
 108       let f mc = whd f c {m with c = mc} t in
 109       B.push f m.c l id b
 110
 111 (* Interface functions ******************************************************)
 112
 113 let nsi = ref false
 114
 115 let rec ho_whd f c m x =
 116    let aux m = function
 117       | Sort_ h                -> f (Sort h)
 118       | Bind_ (_, _, w, _)     ->
 119          let f w = f (Abst w) in unwind_to_term f m w
 120       | LRef_ (_, Some w)      -> ho_whd f c m w
 121       | GRef_ (_, _, B.Abst w) -> ho_whd f c m w
 122       | GRef_ (_, _, B.Abbr v) -> ho_whd f c m v
 123       | LRef_ (_, None)        -> assert false
 124       | GRef_ (_, _, B.Void)   -> assert false
 125    in
 126    whd aux c m x
 127
 128 let ho_whd f c t =
 129    let f r = L.unbox level; f r in
 130    L.box level; log1 "Now scanning" c t;
 131    ho_whd f c empty_machine t
 132
 133 let rec are_convertible f a c m1 t1 m2 t2 =
 134    let rec aux m1 r1 m2 r2 =
 135    let u, t = term_of_whdr r1, term_of_whdr r2 in
 136    log2 "Now really converting" c u t;
 137    match r1, r2 with
 138       | Sort_ h1, Sort_ h2                                 ->
 139          if h1 = h2 then f a else f false
 140       | LRef_ (i1, _), LRef_ (i2, _)                       ->
 141          if i1 = i2 then are_convertible_stacks f a c m1 m2 else f false
 142       | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
 143          if a1 = a2 then are_convertible_stacks f a c m1 m2 else f false
 144       | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
 145          if a1 = a2 then
 146             let f a = if a then f a else are_convertible f true c m1 v1 m2 v2 in
 147             are_convertible_stacks f a c m1 m2
 148          else
 149          if a1 < a2 then whd (aux m1 r1) c m2 v2 else
 150          whd (aux_rev m2 r2) c m1 v1
 151       | _, GRef_ (_, _, B.Abbr v2)                         ->
 152          whd (aux m1 r1) c m2 v2
 153       | GRef_ (_, _, B.Abbr v1), _                         ->
 154          whd (aux_rev m2 r2) c m1 v1
 155       | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
 156            let h c =
 157               let m1, m2 = inc m1, inc m2 in
 158               S.subst (are_convertible f a c m1 t1 m2) l1 l2 t2
 159          in
 160          let f r = if r then push h c m1 l1 id1 w1 else f false in
 161          are_convertible f a c m1 w1 m2 w2
 162 (* we detect the AUT-QE reduction rule for type/prop inclusion *)
 163       | Sort_ _, Bind_ (l2, id2, w2, t2) when !nsi         ->
 164          let m1, m2 = inc m1, inc m2 in
 165          let f c = are_convertible f a c m1 (term_of_whdr r1) m2 t2 in
 166          push f c m2 l2 id2 w2
 167       | _                                                  -> f false
 168    and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
 169    let g m1 r1 = whd (aux m1 r1) c m2 t2 in
 170    if a = false then f false else whd g c m1 t1
 171
 172 and are_convertible_stacks f a c m1 m2 =
 173    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 174    let map f a v1 v2 = are_convertible f a c mm1 v1 mm2 v2 in
 175    if List.length m1.s <> List.length m2.s then
 176       begin
 177          L.warn (Printf.sprintf "Different lengths: %u %u"
 178             (List.length m1.s) (List.length m2.s)
 179          );
 180          f false
 181       end
 182    else
 183       C.list_fold_left2 f map a m1.s m2.s
 184
 185 let are_convertible f c u t =
 186    let f b = L.unbox level; f b in
 187    L.box level; log2 "Now converting" c u t;
 188    are_convertible f true c empty_machine u empty_machine t