helm/software/lambda-delta/basic_ag/bagReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module I = AutItem
  16 module B = Bag
  17 module O = BagOutput
  18 module E = BagEnvironment
  19 module S = BagSubstitution
  20
  21 exception LRefNotFound of B.message
  22
  23 type machine = {
  24    i: int;
  25    c: B.context;
  26    s: B.term list
  27 }
  28
  29 type whd_result =
  30    | Sort_ of int
  31    | LRef_ of int * B.term option
  32    | GRef_ of B.obj
  33    | Bind_ of int * B.id * B.term * B.term
  34
  35 type ho_whd_result =
  36    | Sort of int
  37    | GRef of U.uri * B.term list
  38    | Abst of B.term
  39
  40 type ac_result = (int * NUri.uri * Bag.term list) list option
  41
  42 type extension = No | NSI
  43
  44 (* Internal functions *******************************************************)
  45
  46 let term_of_whdr = function
  47    | Sort_ h             -> B.Sort h
  48    | LRef_ (i, _)        -> B.LRef i
  49    | GRef_ (_, uri, _)   -> B.GRef uri
  50    | Bind_ (l, id, w, t) -> B.bind_abst l id w t
  51
  52 let level = 5
  53
  54 let error i = raise (LRefNotFound (L.items1 (string_of_int i)))
  55
  56 let log1 s c t =
  57    let sc, st = s ^ " in the context", "the term" in
  58    L.log O.specs level (L.ct_items1 sc c st t)
  59
  60 let log2 s c u t =
  61    let sc, su, st = s ^ " in the context", "the term", "and the term" in
  62    L.log O.specs level (L.ct_items2 sc c su u st t)
  63
  64 let empty_machine = {i = 0; c = B.empty_context; s = []}
  65
  66 let inc m = {m with i = succ m.i}
  67
  68 let unwind_to_term f m t =
  69    let map f t (l, id, b) = f (B.Bind (l, id, b, t)) in
  70    let f mc = C.list_fold_left f map t mc in
  71    B.contents f m.c
  72
  73 let unwind_stack f m =
  74    let map f v = unwind_to_term f m v in
  75    C.list_map f map m.s
  76
  77 let get f c m i =
  78    let f = function
  79       | Some (_, b) -> f b
  80       | None        -> error i
  81    in
  82    let f c = B.get f c i in
  83    B.append f c m.c
  84
  85 let push f c m l id w =
  86    assert (m.s = []);
  87    let f w = B.push f c l id (B.Abst w) in
  88    unwind_to_term f m w
  89
  90 (* to share *)
  91 let rec whd f c m x = match x with
  92    | B.Sort h                    -> f m (Sort_ h)
  93    | B.GRef uri                  ->
  94       let f obj = f m (GRef_ obj) in
  95       E.get_obj f uri
  96    | B.LRef i                    ->
  97       let f = function
  98          | B.Void   -> f m (LRef_ (i, None))
  99          | B.Abst t -> f m (LRef_ (i, Some t))
 100          | B.Abbr t -> whd f c m t
 101       in
 102       get f c m i
 103    | B.Cast (_, t)               -> whd f c m t
 104    | B.Appl (v, t)               -> whd f c {m with s = v :: m.s} t
 105    | B.Bind (l, id, B.Abst w, t) ->
 106       begin match m.s with
 107          | []      -> f m (Bind_ (l, id, w, t))
 108          | v :: tl ->
 109             let f mc = whd f c {m with c = mc; s = tl} t in
 110             B.push f m.c l id (B.Abbr (B.Cast (w, v)))
 111       end
 112    | B.Bind (l, id, b, t)         ->
 113       let f mc = whd f c {m with c = mc} t in
 114       B.push f m.c l id b
 115
 116 let insert f i uri vs = function
 117    | Some l -> f (Some ((i, uri, vs) :: l))
 118    | None   -> assert false
 119
 120 (* Interface functions ******************************************************)
 121
 122 let ext = ref No
 123
 124 let rec ho_whd f c m x =
 125    let aux m = function
 126       | Sort_ h                  -> f (Sort h)
 127       | Bind_ (_, _, w, _)       ->
 128          let f w = f (Abst w) in unwind_to_term f m w
 129       | LRef_ (_, Some w)        -> ho_whd f c m w
 130       | GRef_ (_, uri, B.Abst w) ->
 131          let h = function
 132             | Abst _ as r -> f r
 133             | GRef _ as r -> f r
 134             | Sort _      ->
 135                let f vs = f (GRef (uri, vs)) in unwind_stack f m
 136          in
 137          if !ext = No then ho_whd h c m w else ho_whd f c m w
 138       | GRef_ (_, _, B.Abbr v)   -> ho_whd f c m v
 139       | LRef_ (_, None)          -> assert false
 140       | GRef_ (_, _, B.Void)     -> assert false
 141    in
 142    whd aux c m x
 143
 144 let ho_whd f c t =
 145    let f r = L.unbox level; f r in
 146    L.box level; log1 "Now scanning" c t;
 147    ho_whd f c empty_machine t
 148
 149 let rec are_convertible f xl c m1 t1 m2 t2 =
 150    let rec aux m1 r1 m2 r2 =
 151    let u, t = term_of_whdr r1, term_of_whdr r2 in
 152    log2 "Now really converting" c u t;
 153    match r1, r2 with
 154       | Sort_ h1, Sort_ h2                                 ->
 155          if h1 = h2 then f xl else f None
 156       | LRef_ (i1, _), LRef_ (i2, _)                       ->
 157          if i1 = i2 then are_convertible_stacks f xl c m1 m2 else f None
 158       | GRef_ (a1, _, B.Abst _), GRef_ (a2, _, B.Abst _)   ->
 159          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else f None
 160       | GRef_ (a1, _, B.Abbr v1), GRef_ (a2, _, B.Abbr v2) ->
 161          if a1 = a2 then are_convertible_stacks f xl c m1 m2 else
 162          if a1 < a2 then whd (aux m1 r1) c m2 v2 else
 163          whd (aux_rev m2 r2) c m1 v1
 164       | _, GRef_ (_, _, B.Abbr v2)                         ->
 165          whd (aux m1 r1) c m2 v2
 166       | GRef_ (_, _, B.Abbr v1), _                         ->
 167          whd (aux_rev m2 r2) c m1 v1
 168       | Bind_ (l1, id1, w1, t1), Bind_ (l2, id2, w2, t2)   ->
 169          let f xl =
 170             let h c =
 171                let m1, m2 = inc m1, inc m2 in
 172                S.subst (are_convertible f xl c m1 t1 m2) l1 l2 t2
 173             in
 174             if xl = None then f xl else push h c m1 l1 id1 w1
 175          in
 176          are_convertible f xl c m1 w1 m2 w2
 177 (* we detect the AUT-QE reduction rule for type/prop inclusion *)
 178       | GRef_ (_, uri, B.Abst _), Bind_ (l1, _, _, _) when !ext = No ->
 179          let g vs = insert f l1 uri vs xl in
 180          if U.eq uri I.imp then unwind_stack g m1 else
 181          if U.eq uri I.all then unwind_stack g m1 else
 182          begin L.warn (U.string_of_uri uri); f None end
 183       | Sort_ _, Bind_ (l2, id2, w2, t2)  when !ext = NSI  ->
 184          let m1, m2 = inc m1, inc m2 in
 185          let f c = are_convertible f xl c m1 (term_of_whdr r1) m2 t2 in
 186          push f c m2 l2 id2 w2
 187       | _                                                  -> f None
 188    and aux_rev m2 r2 m1 r1 = aux m1 r1 m2 r2 in
 189    let f m1 r1 = whd (aux m1 r1) c m2 t2 in
 190    whd f c m1 t1
 191
 192 and are_convertible_stacks f xl c m1 m2 =
 193    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 194    let map f xl v1 v2 = are_convertible f xl c mm1 v1 mm2 v2 in
 195    if List.length m1.s <> List.length m2.s then f None else
 196    C.list_fold_left2 f map xl m1.s m2.s
 197
 198 let are_convertible f c u t =
 199    let f b = L.unbox level; f b in
 200    L.box level; log2 "Now converting" c u t;
 201    are_convertible f (Some []) c empty_machine u empty_machine t