helm/software/lambda-delta/basic_ag/bagType.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module S = Share
  15 module L = Log
  16 module H = Hierarchy
  17 module B = Bag
  18 module O = BagOutput
  19 module E = BagEnvironment
  20 module R = BagReduction
  21
  22 exception TypeError of B.message
  23
  24 (* Internal functions *******************************************************)
  25
  26 let level = 4
  27
  28 let log1 s c t =
  29    let sc, st = s ^ " in the context", "the term" in
  30    L.log O.specs level (L.ct_items1 sc c st t)
  31
  32 let error1 st c t =
  33    let sc = "In the context" in
  34    raise (TypeError (L.ct_items1 sc c st t))
  35
  36 let error3 c t1 t2 t3 =
  37    let sc, st1, st2, st3 =
  38       "In the context", "the term", "is of type", "but must be of type"
  39    in
  40    raise (TypeError (L.ct_items3 sc c st1 t1 st2 t2 st3 t3))
  41
  42 let mk_gref u l =
  43    let map t v = B.Appl (v, t) in
  44    List.fold_left map (B.GRef u) l
  45
  46 (* Interface functions ******************************************************)
  47
  48 let rec b_type_of f g c x =
  49 (*   L.warn "Entering T.b_type_of"; *)
  50    log1 "Now checking" c x;
  51    match x with
  52    | B.Sort h                    ->
  53       let f h = f x (B.Sort h) in H.apply f g h
  54    | B.LRef i                    ->
  55       let f = function
  56          | Some (_, B.Abst w)               -> f x w
  57          | Some (_, B.Abbr (B.Cast (w, v))) -> f x w
  58          | Some (_, B.Abbr _)               -> assert false
  59          | Some (_, B.Void)                 ->
  60             error1 "reference to excluded variable" c x
  61          | None                             ->
  62             error1 "variable not found" c x
  63       in
  64       B.get f c i
  65    | B.GRef uri                  ->
  66       let f = function
  67          | _, _, B.Abst w               -> f x w
  68          | _, _, B.Abbr (B.Cast (w, v)) -> f x w
  69          | _, _, B.Abbr _               -> assert false
  70          | _, _, B.Void                 ->
  71             error1 "reference to excluded object" c x
  72       in
  73       E.get_obj f uri
  74    | B.Bind (l, id, B.Abbr v, t) ->
  75       let f xv xt tt =
  76          f (S.sh2 v xv t xt x (B.bind_abbr l id)) (B.bind_abbr l id xv tt)
  77       in
  78       let f xv cc = b_type_of (f xv) g cc t in
  79       let f xv = B.push "type abbr" (f xv) c l id (B.Abbr xv) in
  80       let f xv vv = match xv with
  81          | B.Cast _ -> f xv
  82          | _        -> f (B.Cast (vv, xv))
  83       in
  84       type_of f g c v
  85    | B.Bind (l, id, B.Abst u, t) ->
  86       let f xu xt tt =
  87          f (S.sh2 u xu t xt x (B.bind_abst l id)) (B.bind_abst l id xu tt)
  88       in
  89       let f xu cc = b_type_of (f xu) g cc t in
  90       let f xu _ = B.push "type abst" (f xu) c l id (B.Abst xu) in
  91       type_of f g c u
  92    | B.Bind (l, id, B.Void, t)   ->
  93       let f xt tt =
  94          f (S.sh1 t xt x (B.bind l id B.Void)) (B.bind l id B.Void tt)
  95       in
  96       let f cc = b_type_of f g cc t in
  97       B.push "type void" f c l id B.Void
  98    | B.Appl (v, t)            ->
  99       let f xv vv xt tt = function
 100          | R.Abst w                             ->
 101             L.box (succ level);
 102             L.log O.specs (succ level) (L.t_items1 "Just scanned" c w);
 103             L.unbox (succ level);
 104             let f a =
 105 (*             L.warn (Printf.sprintf "Convertible: %b" a); *)
 106                if a then f (S.sh2 v xv t xt x B.appl) (B.appl xv tt)
 107                else error3 c xv vv w
 108             in
 109             R.are_convertible f c w vv
 110          | _                                    ->
 111             error1 "not a function" c xt
 112       in
 113       let f xv vv xt tt = R.ho_whd (f xv vv xt tt) c tt in
 114       let f xv vv = b_type_of (f xv vv) g c t in
 115       type_of f g c v
 116    | B.Cast (u, t)            ->
 117       let f xu xt tt a =
 118          (* L.warn (Printf.sprintf "Convertible: %b" a); *)
 119          if a then f (S.sh2 u xu t xt x B.cast) xu else error3 c xt tt xu
 120       in
 121       let f xu xt tt = R.are_convertible (f xu xt tt) c xu tt in
 122       let f xu _ = b_type_of (f xu) g c t in
 123       type_of f g c u
 124
 125 and type_of f g c x =
 126    let f t u = L.unbox level; f t u in
 127    L.box level; b_type_of f g c x