helm/software/lambda-delta/basic_rg/brg.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* kernel version: basic, relative, global *)
  13 (* note          : ufficial basic lambda-delta *)
  14
  15 type uri = Entity.uri
  16 type id = Entity.id
  17
  18 type attr = Name of bool * id  (* real?, name *)
  19           | Apix of int        (* additional position index *)
  20
  21 type attrs = attr list
  22
  23 type bind = Void of attrs        (* attrs       *)
  24           | Abst of attrs * term (* attrs, type *)
  25           | Abbr of attrs * term (* attrs, body *)
  26
  27 and term = Sort of attrs * int         (* attrs, hierarchy index *)
  28          | LRef of attrs * int         (* attrs, position index *)
  29          | GRef of attrs * uri         (* attrs, reference *)
  30          | Cast of attrs * term * term (* attrs, type, term *)
  31          | Appl of attrs * term * term (* attrs, argument, function *)
  32          | Bind of bind * term         (* binder, scope *)
  33
  34 type entry = bind Entity.entry (* age, uri, binder *)
  35
  36 type entity = bind Entity.entity
  37
  38 type lenv = Null
  39 (* Cons: tail, relative local environment, binder *)
  40              | Cons of lenv * lenv option * bind
  41
  42 (* Currified constructors ***************************************************)
  43
  44 let abst a w = Abst (a, w)
  45
  46 let abbr a v = Abbr (a, v)
  47
  48 let lref a i = LRef (a, i)
  49
  50 let cast a u t = Cast (a, u, t)
  51
  52 let appl a u t = Appl (a, u, t)
  53
  54 let bind b t = Bind (b, t)
  55
  56 let bind_abst a u t = Bind (Abst (a, u), t)
  57
  58 let bind_abbr a v t = Bind (Abbr (a, v), t)
  59
  60 (* local environment handling functions *************************************)
  61
  62 let empty_lenv = Null
  63
  64 let push f es ?c b =
  65    let es = Cons (es, c, b) in f es
  66
  67 let get err f es i =
  68    let rec aux j = function
  69       | Null                            -> err ()
  70       | Cons (tl, None, b)   when j = 0 -> f tl b
  71       | Cons (_, Some c, b) when j = 0  -> f c b
  72       | Cons (tl, _, _)                 -> aux (pred j) tl
  73    in
  74    aux i es
  75
  76 let rec rev_iter f map = function
  77    | Null                 -> f ()
  78    | Cons (tl, None, b)   ->
  79       let f _ = map f tl b in rev_iter f map tl
  80    | Cons (tl, Some c, b) ->
  81       let f _ = map f c b in rev_iter f map tl
  82
  83 let rec fold_left f map x = function
  84    | Null            -> f x
  85    | Cons (tl, _, b) ->
  86       let f x = fold_left f map x tl in
  87       map f x b
  88
  89 let rec name err f = function
  90    | []               -> err ()
  91    | Name (r, n) :: _ -> f n r
  92    | _ :: tl          -> name err f tl
  93
  94 let rec apix err f = function
  95    | []          -> err ()
  96    | Apix i :: _ -> f i
  97    | _ :: tl     -> apix err f tl