helm/software/lambda-delta/basic_rg/brg.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* kernel version: basic, relative, global *)
  13 (* note          : ufficial basic lambda-delta *)
  14
  15 type uri = Entity.uri
  16 type id = Entity.id
  17 type attrs = Entity.attrs
  18
  19 type bind = Void         (*      *)
  20           | Abst of term (* type *)
  21           | Abbr of term (* body *)
  22
  23 and term = Sort of attrs * int         (* attrs, hierarchy index *)
  24          | LRef of attrs * int         (* attrs, position index *)
  25          | GRef of attrs * uri         (* attrs, reference *)
  26          | Cast of attrs * term * term (* attrs, type, term *)
  27          | Appl of attrs * term * term (* attrs, argument, function *)
  28          | Bind of attrs * bind * term (* attrs, binder, scope *)
  29
  30 type entity = term Entity.entity (* attrs, uri, binder *)
  31
  32 type lenv = Null
  33 (* Cons: tail, relative local environment, attrs, binder *)
  34           | Cons of lenv * lenv * attrs * bind
  35
  36 (* helpers ******************************************************************)
  37
  38 let mk_uri root s =
  39    String.concat "/" ["ld:"; "brg"; root; s ^ ".ld"]
  40
  41 (* Currified constructors ***************************************************)
  42
  43 let abst w = Abst w
  44
  45 let abbr v = Abbr v
  46
  47 let lref a i = LRef (a, i)
  48
  49 let cast a u t = Cast (a, u, t)
  50
  51 let appl a u t = Appl (a, u, t)
  52
  53 let bind a b t = Bind (a, b, t)
  54
  55 let bind_abst a u t = Bind (a, Abst u, t)
  56
  57 let bind_abbr a v t = Bind (a, Abbr v, t)
  58
  59 let bind_void a t = Bind (a, Void, t)
  60
  61 (* local environment handling functions *************************************)
  62
  63 let empty = Null
  64
  65 let push e c a b = Cons (e, c, a, b)
  66
  67 let rec get i = function
  68    | Null                         -> Null, Null, [], Void
  69    | Cons (e, c, a, b) when i = 0 -> e, c, a, b
  70    | Cons (e, _, _, _)            -> get (pred i) e
  71
  72 let get e i = get i e
  73
  74 (* used in BrgOutput.pp_lenv *)
  75 let rec fold_right f map e x = match e with
  76    | Null              -> f x
  77    | Cons (e, c, a, b) -> fold_right (map f e c a b) map e x
  78
  79 (* used in MetaBrg.unwind_to_xlate_term *)
  80 let rec fold_left map x = function
  81    | Null              -> x
  82    | Cons (e, _, a, b) -> fold_left map (map x a b) e