helm/software/lambda-delta/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module S = Share
  15 module L = Log
  16 module P = Output
  17 module B = Brg
  18 module O = BrgOutput
  19 module E = BrgEnvironment
  20
  21 type machine = {
  22    c: B.context;
  23    s: (B.context * B.term) list;
  24    i: int
  25 }
  26
  27 type message = (machine, B.term) Log.item list
  28
  29 (* Internal functions *******************************************************)
  30
  31 let level = 5
  32
  33 let log1 s c t =
  34    let sc, st = s ^ " in the context", "the term" in
  35    L.log O.specs level (L.ct_items1 sc c st t)
  36
  37 let log2 s cu u ct t =
  38    let s1, s2, s3 = s ^ " in the context", "the term", "and in the context" in
  39    L.log O.specs level (L.ct_items2 s1 cu s2 u ~sc2:s3 ~c2:ct s2 t)
  40
  41 let are_alpha_convertible err f t1 t2 =
  42    let rec aux f = function
  43       | B.Sort (_, p1), B.Sort (_, p2)
  44       | B.LRef (_, p1), B.LRef (_, p2)         ->
  45          if p1 = p2 then f () else err ()
  46       | B.GRef (_, u1), B.GRef (_, u2)         ->
  47          if U.eq u1 u2 then f () else err ()
  48       | B.Cast (_, v1, t1), B.Cast (_, v2, t2)
  49       | B.Appl (_, v1, t1), B.Appl (_, v2, t2) ->
  50          let f _ = aux f (t1, t2) in
  51          aux f (v1, v2)
  52       | B.Bind (b1, t1), B.Bind (b2, t2)       ->
  53          let f _ = aux f (t1, t2) in
  54          aux_bind f (b1, b2)
  55       | _                                      -> err ()
  56    and aux_bind f = function
  57       | B.Abbr (_, v1), B.Abbr (_, v2)
  58       | B.Abst (_, v1), B.Abst (_, v2)         -> aux f (v1, v2)
  59       | B.Void _, B.Void _                     -> f ()
  60       | _                                      -> err ()
  61    in
  62    if S.eq t1 t2 then f () else aux f (t1, t2)
  63
  64 let get err f m i =
  65    B.get err f m.c i
  66
  67 (* to share *)
  68 let rec step f ?(delta=false) ?(rt=false) m x =
  69 (*   L.warn "entering R.step"; *)
  70    match x with
  71    | B.Sort _                  -> f m None x
  72    | B.GRef (_, uri)           ->
  73       let f = function
  74          | _, _, B.Abbr (_, v) when delta ->
  75             P.add ~gdelta:1 (); step f ~delta ~rt m v
  76          | _, _, B.Abst (_, w) when rt    ->
  77             P.add ~grt:1 (); step f ~delta ~rt m w
  78          | _, _, B.Void _                 ->
  79             assert false
  80          | e, _, b                        ->
  81             f m (Some (e, b)) x
  82       in
  83       E.get_obj C.err f uri
  84    | B.LRef (_, i)             ->
  85       let f c = function
  86          | B.Abbr (_, v)         ->
  87             P.add ~ldelta:1 ();
  88             step f ~delta ~rt {m with c = c} v
  89          | B.Abst (_, w) when rt ->
  90             P.add ~lrt:1 ();
  91             step f ~delta ~rt {m with c = c} w
  92          | B.Void _              ->
  93             assert false
  94          | B.Abst (a, _) as b    ->
  95             let f e = f {m with c = c} (Some (e, b)) x in
  96             B.apix C.err f a
  97       in
  98       get C.err f m i
  99    | B.Cast (_, _, t)          ->
 100       P.add ~tau:1 ();
 101       step f ~delta ~rt m t
 102    | B.Appl (_, v, t)          ->
 103       step f ~delta ~rt {m with s = (m.c, v) :: m.s} t
 104    | B.Bind (B.Abst (a, w), t) ->
 105       begin match m.s with
 106          | []          -> f m None x
 107          | (c, v) :: s ->
 108             P.add ~beta:1 ~upsilon:(List.length s) ();
 109             let f c = step f ~delta ~rt {m with c = c; s = s} t in
 110             B.push f m.c ~c (B.abbr a v) (* (B.Cast ([], w, v)) *)
 111       end
 112    | B.Bind (b, t)             ->
 113       P.add ~upsilon:(List.length m.s) ();
 114       let f c = step f ~delta ~rt {m with c = c} t in
 115       B.push f m.c ~c:m.c b
 116
 117 let push f m b =
 118    assert (m.s = []);
 119    let b, i = match b with
 120       | B.Abst (a, w) -> B.abst (B.Apix m.i :: a) w, succ m.i
 121       | b             -> b, m.i
 122    in
 123    let f c = f {m with c = c; i = i} in
 124    B.push f m.c ~c:m.c b
 125
 126 let rec ac_nfs err f ~si m1 a1 u m2 a2 t =
 127    log2 "Now converting nfs" m1.c u m2.c t;
 128    match a1, u, a2, t with
 129       | _, B.Sort (_, h1), _, B.Sort (_, h2)                       ->
 130          if h1 = h2 then f () else err ()
 131       | Some (e1, B.Abst _), _, Some (e2, B.Abst _), _             ->
 132          if e1 = e2 then ac_stacks err f m1 m2 else err ()
 133       | Some (e1, B.Abbr (_, v1)), _, Some (e2, B.Abbr (_, v2)), _ ->
 134          if e1 = e2 then
 135             let err _ = P.add ~gdelta:2 (); ac err f ~si m1 v1 m2 v2 in
 136             ac_stacks err f m1 m2
 137          else if e1 < e2 then begin
 138             P.add ~gdelta:1 ();
 139             step (ac_nfs err f ~si m1 a1 u) m2 v2
 140          end else begin
 141             P.add ~gdelta:1 ();
 142             step (ac_nfs_rev err f ~si m2 a2 t) m1 v1
 143          end
 144       | _, _, Some (_, B.Abbr (_, v2)), _                          ->
 145          P.add ~gdelta:1 ();
 146          step (ac_nfs err f ~si m1 a1 u) m2 v2
 147       | Some (_, B.Abbr (_, v1)), _, _, _                          ->
 148          P.add ~gdelta:1 ();
 149          step (ac_nfs_rev err f ~si m2 a2 t) m1 v1
 150       | _, B.Bind ((B.Abst (_, w1) as b1), t1),
 151         _, B.Bind ((B.Abst (_, w2) as b2), t2)                     ->
 152          let f m1 m2 = ac err f ~si m1 t1 m2 t2 in
 153          let f m1 = push (f m1) m2 b2 in
 154          let f _ = push f m1 b1 in
 155          ac err f ~si:false m1 w1 m2 w2
 156       | _, B.Sort _, _, B.Bind (b, t) when si                      ->
 157          P.add ~si:1 ();
 158          let f m1 m2 = ac err f ~si m1 u m2 t in
 159          let f m1 = push (f m1) m2 b in
 160          push f m1 b
 161       | _                                                          -> err ()
 162
 163 and ac_nfs_rev err f ~si m2 a2 t m1 a1 u = ac_nfs err f ~si m1 a1 u m2 a2 t
 164
 165 and ac err f ~si m1 t1 m2 t2 =
 166 (*   L.warn "entering R.are_convertible"; *)
 167    let f m1 a1 t1 = step (ac_nfs err f ~si m1 a1 t1) m2 t2 in
 168    step f m1 t1
 169
 170 and ac_stacks err f m1 m2 =
 171 (*   L.warn "entering R.are_convertible_stacks"; *)
 172    if List.length m1.s <> List.length m2.s then err () else
 173    let map f (c1, v1) (c2, v2) =
 174       let m1, m2 = {m1 with c = c1; s = []}, {m2 with c = c2; s = []} in
 175       ac err f ~si:false m1 v1 m2 v2
 176    in
 177    C.list_iter2 f map m1.s m2.s
 178
 179 (* Interface functions ******************************************************)
 180
 181 let empty_machine = {
 182    c = B.empty_context; s = []; i = 0
 183 }
 184
 185 let get err f m i =
 186    assert (m.s = []);
 187    let f c = f in
 188    get err f m i
 189
 190 let xwhd f m t =
 191    L.box level; log1 "Now scanning" m.c t;
 192    let f m _ t = L.unbox level; f m t in
 193    step f ~delta:true ~rt:true m t
 194
 195 let are_convertible err f ?(si=false) mu u mw w =
 196       L.box level; log2 "Now converting" mu.c u mw.c w;
 197       let f x = L.unbox level; f x in
 198       let err _ = ac err f ~si mu u mw w in
 199 (*      if S.eq mu mw then are_alpha_convertible err f u w else *) err ()
 200
 201 (* error reporting **********************************************************)
 202
 203 let pp_term m frm t = O.specs.L.pp_term m.c frm t
 204
 205 let pp_context frm m = O.specs.L.pp_context frm m.c
 206
 207 let specs = {
 208    L.pp_term = pp_term; L.pp_context = pp_context
 209 }