helm/software/lambda-delta/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module P = Output
  16 module B = Brg
  17 module O = BrgOutput
  18 module E = BrgEnvironment
  19
  20 exception TypeError of B.message
  21
  22 type machine = {
  23    c: B.context;
  24    s: (B.context * B.term) list;
  25    i: int
  26 }
  27
  28 (* Internal functions *******************************************************)
  29
  30 let level = 5
  31
  32 let log1 s c t =
  33    let sc, st = s ^ " in the context", "the term" in
  34    L.log O.specs level (L.ct_items1 sc c st t)
  35
  36 let log2 s cu u ct t =
  37    let s1, s2, s3 = s ^ " in the context", "the term", "and in the context" in
  38    L.log O.specs level (L.ct_items2 s1 cu s2 u s3 ct s2 t)
  39
  40 let error0 i =
  41    let s = Printf.sprintf "local reference not found %u" i in
  42    raise (TypeError (L.items1 s))
  43
  44 let error1 st c t =
  45    let sc = "In the context" in
  46    raise (TypeError (L.ct_items1 sc c st t))
  47
  48 let error3 c t1 t2 t3 =
  49    let sc, st1, st2, st3 =
  50       "In the context", "the term", "is of type", "but must be of type"
  51    in
  52    raise (TypeError (L.ct_items3 sc c st1 t1 st2 t2 st3 t3))
  53
  54 let err () = assert false
  55
  56 let get f m i =
  57    B.get error0 f m.c i
  58
  59 (* to share *)
  60 let rec step f ?(delta=false) ?(rt=false) m x =
  61 (*   L.warn "entering R.step"; *)
  62    match x with
  63    | B.Sort _                -> f m None x
  64    | B.GRef (a, uri)         ->
  65       let f = function
  66          | _, _, B.Abbr v when delta ->
  67             P.add ~gdelta:1 ();
  68             step f ~delta ~rt m v
  69          | _, _, B.Abst w when rt   ->
  70             P.add ~grt:1 ();
  71             step f ~delta ~rt m w
  72          | e, _, b                   ->
  73             f m (Some (e, b)) x
  74       in
  75       E.get_obj f uri
  76    | B.LRef (a, i)           ->
  77       let f c a = function
  78          | B.Abbr v          ->
  79             P.add ~ldelta:1 ();
  80             step f ~delta ~rt {m with c = c} v
  81          | B.Abst w when rt ->
  82             P.add ~lrt:1 ();
  83             step f ~delta ~rt {m with c = c} w
  84          | B.Void            ->
  85             f {m with c = c} None x
  86          | b                 ->
  87             let f e = f {m with c = c} (Some (e, b)) x in
  88             B.apix err f a
  89       in
  90       get f m i
  91    | B.Cast (_, _, t)        ->
  92       P.add ~tau:1 ();
  93       step f ~delta ~rt m t
  94    | B.Appl (_, v, t)        ->
  95       step f ~delta ~rt {m with s = (m.c, v) :: m.s} t
  96    | B.Bind (a, B.Abst w, t) ->
  97       begin match m.s with
  98          | []          -> f m None x
  99          | (c, v) :: s ->
 100             P.add ~beta:1 ~upsilon:(List.length s) ();
 101             let f c = step f ~delta ~rt {m with c = c; s = s} t in
 102             B.push f m.c ~c a (B.Abbr v) (* (B.Cast ([], w, v)) *)
 103       end
 104    | B.Bind (a, b, t)        ->
 105       P.add ~upsilon:(List.length m.s) ();
 106       let f c = step f ~delta ~rt {m with c = c} t in
 107       B.push f m.c ~c:m.c a b
 108
 109 let domain f m t =
 110    let f r = L.unbox level; f r in
 111    let f m _ = function
 112       | B.Bind (_, B.Abst w, _) -> f m w
 113       | _                       -> error1 "not a function" m.c t
 114    in
 115    L.box level; log1 "Now scanning" m.c t;
 116    step f ~delta:true ~rt:true m t
 117
 118 let push f m a b =
 119    assert (m.s = []);
 120    let a, i = match b with
 121       | B.Abst _ -> B.Apix m.i :: a, succ m.i
 122       | _        -> a, m.i
 123    in
 124    let f c = f {m with c = c; i = i} in
 125    B.push f m.c ~c:m.c a b
 126
 127 let rec ac_nfs f ~si r m1 a1 u m2 a2 t =
 128    log2 "Now converting nfs" m1.c u m2.c t;
 129    match a1, u, a2, t with
 130       | _, B.Sort (_, h1),
 131         _, B.Sort (_, h2)                                ->
 132          if h1 = h2 then f r else f false
 133       | Some (e1, B.Abst _), _, Some (e2, B.Abst _), _   ->
 134          if e1 = e2 then ac_stacks f ~si r m1 m2 else f false
 135       | Some (e1, B.Abbr v1), _, Some (e2, B.Abbr v2), _ ->
 136          if e1 = e2 then
 137             let f r =
 138                if r then f r
 139                else begin
 140                   P.add ~gdelta:2 ();
 141                   ac f ~si true m1 v1 m2 v2
 142                end
 143             in
 144             ac_stacks f ~si r m1 m2
 145          else if e1 < e2 then begin
 146             P.add ~gdelta:1 ();
 147             step (ac_nfs f ~si r m1 a1 u) m2 v2
 148          end else begin
 149             P.add ~gdelta:1 ();
 150             step (ac_nfs_rev f ~si r m2 a2 t) m1 v1
 151          end
 152       | _, _, Some (_, B.Abbr v2), _                     ->
 153          P.add ~gdelta:1 ();
 154          step (ac_nfs f ~si r m1 a1 u) m2 v2
 155       | Some (_, B.Abbr v1), _, _, _                     ->
 156          P.add ~gdelta:1 ();
 157          step (ac_nfs_rev f ~si r m2 a2 t) m1 v1
 158       | _, B.Bind (a1, (B.Abst w1 as b1), t1),
 159         _, B.Bind (a2, (B.Abst w2 as b2), t2)            ->
 160          let g m1 m2 = ac f ~si r m1 t1 m2 t2 in
 161          let g m1 = push (g m1) m2 a2 b2 in
 162          let f r = if r then push g m1 a1 b1 else f false in
 163          ac f ~si r m1 w1 m2 w2
 164       | _, B.Sort _, _, B.Bind (a, b, t) when si         ->
 165          P.add ~si:1 ();
 166          let f m1 m2 = ac f ~si r m1 u m2 t in
 167          let f m1 = push (f m1) m2 a b in
 168          push f m1 a b
 169       | _                                                -> f false
 170
 171 and ac_nfs_rev f ~si r m2 a2 t m1 a1 u = ac_nfs f ~si r m1 a1 u m2 a2 t
 172
 173 and ac f ~si r m1 t1 m2 t2 =
 174 (*   L.warn "entering R.are_convertible"; *)
 175    let g m1 a1 t1 = step (ac_nfs f ~si r m1 a1 t1) m2 t2 in
 176    if r = false then f false else step g m1 t1
 177
 178 and ac_stacks f ~si r m1 m2 =
 179 (*   L.warn "entering R.are_convertible_stacks"; *)
 180    if List.length m1.s <> List.length m2.s then f false else
 181    let map f r (c1, v1) (c2, v2) =
 182       let m1, m2 = {m1 with c = c1; s = []}, {m2 with c = c2; s = []} in
 183       ac f ~si r m1 v1 m2 v2
 184    in
 185    C.list_fold_left2 f map r m1.s m2.s
 186
 187 (* Interface functions ******************************************************)
 188
 189 let empty_machine = {
 190    c = B.empty_context; s = []; i = 0
 191 }
 192
 193 let get f m i =
 194    assert (m.s = []);
 195    let f c = f in
 196    get f m i
 197
 198 let assert_conversion f ?(si=false) ?(rt=false) mw u w v =
 199    let f b = L.unbox level; f b in
 200    let f mu u =
 201       let f = function
 202          | true  -> f ()
 203          | false -> error3 mw.c v w u
 204       in
 205       L.box level; log2 "Now converting" mu.c u mw.c w;
 206       ac f ~si true mu u mw w
 207    in
 208    if rt then domain f mw u else f mw u
 209
 210 let message1 st m t =
 211    L.ct_items1 "In the context" m.c st t