helm/software/lambda-delta/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module B = Brg
  16 module O = BrgOutput
  17 module E = BrgEnvironment
  18 module S = BrgSubstitution
  19
  20 exception LRefNotFound of B.message
  21
  22 type machine = {
  23    c: B.context;
  24    s: (B.term * int) list
  25 }
  26
  27 (* Internal functions *******************************************************)
  28
  29 let reductions = ref O.initial_reductions
  30
  31 let level = 5
  32
  33 let error i = raise (LRefNotFound (L.items1 (string_of_int i)))
  34
  35 let log1 s c t =
  36    let sc, st = s ^ " in the context", "the term" in
  37    L.log O.specs level (L.ct_items1 sc c st t)
  38
  39 let log2 s c u t =
  40    let sc, su, st = s ^ " in the context", "the term", "and the term" in
  41    L.log O.specs level (L.ct_items2 sc c su u st t)
  42
  43 let empty_machine = {
  44    c = B.empty_context; s = []
  45 }
  46
  47 let get f c m i =
  48    let f e = function
  49       | Some (_, b) -> f e b
  50       | None        -> error i
  51    in
  52    let f c = B.get f c i in
  53    B.append f c m.c
  54
  55 let lift_stack f s =
  56    let map f (v, i) = f (v, succ i) in
  57    Cps.list_map f map s
  58
  59 let unwind_to_term f m t =
  60    let map f t (a, b) = f (B.Bind (a, b, t)) in
  61    let f mc = C.list_fold_left f map t mc in
  62    assert (m.s = []);
  63    B.contents f m.c
  64
  65 let push f m a b =
  66    assert (m.s = []);
  67    f {m with c = (a, b) :: m.c}
  68
  69 (* to share *)
  70 let rec step f ?(delta=false) ?(sty=false) c m x =
  71 (*   L.warn "entering R.step"; *)
  72    match x with
  73    | B.Sort _                -> f m x
  74    | B.GRef (a, uri)         ->
  75       let f = function
  76          | _, _, B.Abbr v when delta ->
  77             reductions := O.add ~gdelta:1 !reductions;
  78             step f ~delta ~sty c m v
  79          | _, _, B.Abst w when sty   ->
  80             step f ~delta ~sty c m w
  81          | e, _, b                   ->
  82             f m (B.GRef (B.Entry (e, b) :: a, uri))
  83       in
  84       E.get_obj f uri
  85    | B.LRef (a, i)           ->
  86       let f e = function
  87          | B.Abbr v          ->
  88             reductions := O.add ~ldelta:1 !reductions;
  89             step f ~delta ~sty c m v
  90          | B.Abst w when sty ->
  91             step f ~delta ~sty c m w
  92          | b                 ->
  93             f m (B.LRef (B.Entry (e, b) :: a, i))
  94       in
  95       let f e = S.lift_bind (f e) (succ i) (0) in
  96       get f c m i
  97    | B.Cast (_, _, t)        ->
  98       reductions := O.add ~tau:1 !reductions;
  99       step f ~delta ~sty c m t
 100    | B.Appl (_, v, t)        ->
 101       step f ~delta ~sty c {m with s = (v, 0) :: m.s} t
 102    | B.Bind (a, B.Abst w, t) ->
 103       begin match m.s with
 104          | []           -> f m x
 105          | (v, h) :: tl ->
 106             reductions := O.add ~beta:1 !reductions;
 107             let f mc = step f ~delta ~sty c {c = mc; s = tl} t in
 108             let f v = B.push f m.c a (B.Abbr (B.Cast ([], w, v))) in
 109             S.lift f h (0) v
 110       end
 111    | B.Bind (a, b, t)        ->
 112       reductions := O.add ~upsilon:(List.length m.s) !reductions;
 113       let f sc mc = step f ~delta ~sty c {c = mc; s = sc} t in
 114       let f sc = B.push (f sc) m.c a b in
 115       lift_stack f m.s
 116
 117 (* Interface functions ******************************************************)
 118
 119 let domain f c t =
 120    let f r = L.unbox level; f r in
 121    let f m = function
 122       | B.Bind (_, B.Abst w, _) ->
 123          let f w = f (Some w) in unwind_to_term f m w
 124       | x                       -> f None
 125    in
 126    L.box level; log1 "Now scanning" c t;
 127    step f ~delta:true ~sty:true c empty_machine t
 128
 129 let rec ac_nfs f ~si r c m1 u m2 t =
 130 (*   L.warn "entering R.are_convertible_aux"; *)
 131    log2 "Now converting nfs" c u t;
 132    match u, t with
 133       | B.Sort (_, h1), B.Sort (_, h2)             ->
 134          if h1 = h2 then f r else f false
 135       | B.LRef (B.Entry (e1, B.Abst _) :: _, _),
 136         B.LRef (B.Entry (e2, B.Abst _) :: _, _)    ->
 137          if e1 = e2 then ac_stacks f ~si r c m1 m2 else f false
 138       | B.GRef (B.Entry (e1, B.Abst _) :: _, _),
 139         B.GRef (B.Entry (e2, B.Abst _) :: _, _)    ->
 140          if e1 = e2 then ac_stacks f ~si r c m1 m2 else f false
 141       | B.GRef (B.Entry (e1, B.Abbr v1) :: _, _),
 142         B.GRef (B.Entry (e2, B.Abbr v2) :: _, _)   ->
 143          if e1 = e2 then
 144             let f r =
 145                if r then f r
 146                else begin
 147                   reductions := O.add ~gdelta:2 !reductions;
 148                   ac f ~si true c m1 v1 m2 v2
 149                end
 150             in
 151             ac_stacks f ~si r c m1 m2
 152          else if e1 < e2 then begin
 153             reductions := O.add ~gdelta:1 !reductions;
 154             step (ac_nfs f ~si r c m1 u) c m2 v2
 155          end else begin
 156             reductions := O.add ~gdelta:1 !reductions;
 157             step (ac_nfs_rev f ~si r c m2 t) c m1 v1
 158          end
 159       | _, B.GRef (B.Entry (_, B.Abbr v2) :: _, _) ->
 160          reductions := O.add ~gdelta:1 !reductions;
 161          step (ac_nfs f ~si r c m1 u) c m2 v2
 162       | B.GRef (B.Entry (_, B.Abbr v1) :: _, _), _ ->
 163          reductions := O.add ~gdelta:1 !reductions;
 164          step (ac_nfs_rev f ~si r c m2 t) c m1 v1
 165       | B.Bind (a1, (B.Abst w1 as b1), t1),
 166         B.Bind (a2, (B.Abst w2 as b2), t2)         ->
 167          let g m1 m2 = ac f ~si r c m1 t1 m2 t2 in
 168          let g m1 = push (g m1) m2 a2 b2 in
 169          let f r = if r then push g m1 a1 b1 else f false in
 170          ac f ~si r c m1 w1 m2 w2
 171       | B.Sort _, B.Bind (a, b, t) when si         ->
 172          let f m1 m2 = ac f ~si r c m1 u m2 t in
 173          let f m1 = push (f m1) m2 a b in
 174          push f m1 a b
 175       | _                                          -> f false
 176
 177 and ac_nfs_rev f ~si r c m2 t m1 u = ac_nfs f ~si r c m1 u m2 t
 178
 179 and ac f ~si r c m1 t1 m2 t2 =
 180 (*   L.warn "entering R.are_convertible"; *)
 181    let g m1 t1 = step (ac_nfs f ~si r c m1 t1) c m2 t2 in
 182    if r = false then f false else step g c m1 t1
 183
 184 and ac_stacks f ~si r c m1 m2 =
 185 (*   L.warn "entering R.are_convertible_stacks"; *)
 186    let mm1, mm2 = {m1 with s = []}, {m2 with s = []} in
 187    let map f r (v1, h1) (v2, h2) =
 188       let f v1 = S.lift (ac f ~si r c mm1 v1 mm2) h2 (0) v2 in
 189       S.lift f h1 (0) v1
 190    in
 191    if List.length m1.s <> List.length m2.s then
 192       begin
 193 (*         L.warn (Printf.sprintf "Different lengths: %u %u"
 194             (List.length m1.s) (List.length m2.s)
 195          ); *)
 196          f false
 197       end
 198    else
 199       C.list_fold_left2 f map r m1.s m2.s
 200
 201 let are_convertible f ?(si=false) c u t =
 202    let f b = L.unbox level; f b in
 203    L.box level; log2 "Now converting" c u t;
 204    ac f ~si true c empty_machine u empty_machine t