helm/software/lambda-delta/basic_rg/brgReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module L = Log
  15 module P = Output
  16 module B = Brg
  17 module O = BrgOutput
  18 module E = BrgEnvironment
  19
  20 exception TypeError of B.message
  21
  22 type machine = {
  23    c: B.context;
  24    s: (B.context * B.term) list;
  25    i: int
  26 }
  27
  28 (* Internal functions *******************************************************)
  29
  30 let level = 5
  31
  32 let log1 s c t =
  33    let sc, st = s ^ " in the context", "the term" in
  34    L.log O.specs level (L.ct_items1 sc c st t)
  35
  36 let log2 s cu u ct t =
  37    let s1, s2, s3 = s ^ " in the context", "the term", "and in the context" in
  38    L.log O.specs level (L.ct_items2 s1 cu s2 u s3 ct s2 t)
  39
  40 let error0 i =
  41    let s = Printf.sprintf "local reference not found %u" i in
  42    raise (TypeError (L.items1 s))
  43
  44 let error1 st c t =
  45    let sc = "In the context" in
  46    raise (TypeError (L.ct_items1 sc c st t))
  47
  48 let error3 c t1 t2 t3 =
  49    let sc, st1, st2, st3 =
  50       "In the context", "the term", "is of type", "but must be of type"
  51    in
  52    raise (TypeError (L.ct_items3 sc c st1 t1 st2 t2 st3 t3))
  53
  54 let get f m i =
  55    B.get error0 f m.c i
  56
  57 (* to share *)
  58 let rec step f ?(delta=false) ?(rt=false) m x =
  59 (*   L.warn "entering R.step"; *)
  60    match x with
  61    | B.Sort _                -> f m None x
  62    | B.GRef (a, uri)         ->
  63       let f = function
  64          | _, _, B.Abbr v when delta ->
  65             P.add ~gdelta:1 ();
  66             step f ~delta ~rt m v
  67          | _, _, B.Abst w when rt   ->
  68             P.add ~grt:1 ();
  69             step f ~delta ~rt m w
  70          | e, _, b                   ->
  71             f m (Some (e, b)) x
  72       in
  73       E.get_obj f uri
  74    | B.LRef (a, i)           ->
  75       let f c a = function
  76          | B.Abbr v          ->
  77             P.add ~ldelta:1 ();
  78             step f ~delta ~rt {m with c = c} v
  79          | B.Abst w when rt ->
  80             P.add ~lrt:1 ();
  81             step f ~delta ~rt {m with c = c} w
  82          | B.Void            ->
  83             f {m with c = c} None x
  84          | b                 ->
  85             let f e = f {m with c = c} (Some (e, b)) x in
  86             B.apix C.err f a
  87       in
  88       get f m i
  89    | B.Cast (_, _, t)        ->
  90       P.add ~tau:1 ();
  91       step f ~delta ~rt m t
  92    | B.Appl (_, v, t)        ->
  93       step f ~delta ~rt {m with s = (m.c, v) :: m.s} t
  94    | B.Bind (a, B.Abst w, t) ->
  95       begin match m.s with
  96          | []          -> f m None x
  97          | (c, v) :: s ->
  98             P.add ~beta:1 ~upsilon:(List.length s) ();
  99             let f c = step f ~delta ~rt {m with c = c; s = s} t in
 100             B.push f m.c ~c a (B.Abbr v) (* (B.Cast ([], w, v)) *)
 101       end
 102    | B.Bind (a, b, t)        ->
 103       P.add ~upsilon:(List.length m.s) ();
 104       let f c = step f ~delta ~rt {m with c = c} t in
 105       B.push f m.c ~c:m.c a b
 106
 107 let domain f m t =
 108    let f r = L.unbox level; f r in
 109    let f m _ = function
 110       | B.Bind (_, B.Abst w, _) -> f m w
 111       | _                       -> error1 "not a function" m.c t
 112    in
 113    L.box level; log1 "Now scanning" m.c t;
 114    step f ~delta:true ~rt:true m t
 115
 116 let push f m a b =
 117    assert (m.s = []);
 118    let a, i = match b with
 119       | B.Abst _ -> B.Apix m.i :: a, succ m.i
 120       | _        -> a, m.i
 121    in
 122    let f c = f {m with c = c; i = i} in
 123    B.push f m.c ~c:m.c a b
 124
 125 let rec ac_nfs f ~si r m1 a1 u m2 a2 t =
 126    log2 "Now converting nfs" m1.c u m2.c t;
 127    match a1, u, a2, t with
 128       | _, B.Sort (_, h1),
 129         _, B.Sort (_, h2)                                ->
 130          if h1 = h2 then f r else f false
 131       | Some (e1, B.Abst _), _, Some (e2, B.Abst _), _   ->
 132          if e1 = e2 then ac_stacks f ~si r m1 m2 else f false
 133       | Some (e1, B.Abbr v1), _, Some (e2, B.Abbr v2), _ ->
 134          if e1 = e2 then
 135             let f r =
 136                if r then f r
 137                else begin
 138                   P.add ~gdelta:2 ();
 139                   ac f ~si true m1 v1 m2 v2
 140                end
 141             in
 142             ac_stacks f ~si r m1 m2
 143          else if e1 < e2 then begin
 144             P.add ~gdelta:1 ();
 145             step (ac_nfs f ~si r m1 a1 u) m2 v2
 146          end else begin
 147             P.add ~gdelta:1 ();
 148             step (ac_nfs_rev f ~si r m2 a2 t) m1 v1
 149          end
 150       | _, _, Some (_, B.Abbr v2), _                     ->
 151          P.add ~gdelta:1 ();
 152          step (ac_nfs f ~si r m1 a1 u) m2 v2
 153       | Some (_, B.Abbr v1), _, _, _                     ->
 154          P.add ~gdelta:1 ();
 155          step (ac_nfs_rev f ~si r m2 a2 t) m1 v1
 156       | _, B.Bind (a1, (B.Abst w1 as b1), t1),
 157         _, B.Bind (a2, (B.Abst w2 as b2), t2)            ->
 158          let g m1 m2 = ac f ~si r m1 t1 m2 t2 in
 159          let g m1 = push (g m1) m2 a2 b2 in
 160          let f r = if r then push g m1 a1 b1 else f false in
 161          ac f ~si r m1 w1 m2 w2
 162       | _, B.Sort _, _, B.Bind (a, b, t) when si         ->
 163          P.add ~si:1 ();
 164          let f m1 m2 = ac f ~si r m1 u m2 t in
 165          let f m1 = push (f m1) m2 a b in
 166          push f m1 a b
 167       | _                                                -> f false
 168
 169 and ac_nfs_rev f ~si r m2 a2 t m1 a1 u = ac_nfs f ~si r m1 a1 u m2 a2 t
 170
 171 and ac f ~si r m1 t1 m2 t2 =
 172 (*   L.warn "entering R.are_convertible"; *)
 173    let g m1 a1 t1 = step (ac_nfs f ~si r m1 a1 t1) m2 t2 in
 174    if r = false then f false else step g m1 t1
 175
 176 and ac_stacks f ~si r m1 m2 =
 177 (*   L.warn "entering R.are_convertible_stacks"; *)
 178    if List.length m1.s <> List.length m2.s then f false else
 179    let map f r (c1, v1) (c2, v2) =
 180       let m1, m2 = {m1 with c = c1; s = []}, {m2 with c = c2; s = []} in
 181       ac f ~si r m1 v1 m2 v2
 182    in
 183    C.list_fold_left2 f map r m1.s m2.s
 184
 185 (* Interface functions ******************************************************)
 186
 187 let empty_machine = {
 188    c = B.empty_context; s = []; i = 0
 189 }
 190
 191 let get f m i =
 192    assert (m.s = []);
 193    let f c = f in
 194    get f m i
 195
 196 let assert_conversion f ?(si=false) ?(rt=false) mw u w v =
 197    let f b = L.unbox level; f b in
 198    let f mu u =
 199       let f = function
 200          | true  -> f ()
 201          | false -> error3 mw.c v w u
 202       in
 203       L.box level; log2 "Now converting" mu.c u mw.c w;
 204       ac f ~si true mu u mw w
 205    in
 206    if rt then domain f mw u else f mw u
 207
 208 let message1 st m t =
 209    L.ct_items1 "In the context" m.c st t