helm/software/lambda-delta/basic_rg/brgType.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U = NUri
  13 module C = Cps
  14 module S = Share
  15 module L = Log
  16 module H = Hierarchy
  17 module B = Brg
  18 module O = BrgOutput
  19 module E = BrgEnvironment
  20 module R = BrgReduction
  21
  22 exception TypeError of B.message
  23
  24 (* Internal functions *******************************************************)
  25
  26 let level = 4
  27
  28 let log1 s c t =
  29    let sc, st = s ^ " in the context", "the term" in
  30    L.log O.specs level (L.ct_items1 sc c st t)
  31
  32 let error1 st c t =
  33    let sc = "In the context" in
  34    raise (TypeError (L.ct_items1 sc c st t))
  35
  36 let error3 c t1 t2 t3 =
  37    let sc, st1, st2, st3 =
  38       "In the context", "the term", "is of type", "but must be of type"
  39    in
  40    raise (TypeError (L.ct_items3 sc c st1 t1 st2 t2 st3 t3))
  41
  42 (* Interface functions ******************************************************)
  43
  44 let si = ref false
  45
  46 let rec b_type_of f g c x =
  47 (*   L.warn "Entering T.b_type_of"; *)
  48    log1 "Now checking" c x;
  49    match x with
  50    | B.Sort (a, h)           ->
  51       let f h = f x (B.Sort (a, h)) in H.apply f g h
  52    | B.LRef (_, i)           ->
  53       let f _ = function
  54          | Some (_, B.Abst w)                  -> f x w
  55          | Some (_, B.Abbr (B.Cast (_, w, _))) -> f x w
  56          | Some (_, B.Abbr _)                  -> assert false
  57          | Some (_, B.Void)                    ->
  58             error1 "reference to excluded variable" c x
  59          | None                             ->
  60             error1 "variable not found" c x
  61       in
  62       B.get f c i
  63    | B.GRef (_, uri)         ->
  64       let f = function
  65          | _, _, B.Abst w                  -> f x w
  66          | _, _, B.Abbr (B.Cast (_, w, _)) -> f x w
  67          | _, _, B.Abbr _                  -> assert false
  68          | _, _, B.Void                    ->
  69             error1 "reference to excluded object" c x
  70       in
  71       E.get_obj f uri
  72    | B.Bind (a, B.Abbr v, t) ->
  73       let f xv xt tt =
  74          f (S.sh2 v xv t xt x (B.bind_abbr a)) (B.bind_abbr a xv tt)
  75       in
  76       let f xv cc = b_type_of (f xv) g cc t in
  77       let f xv = B.push (f xv) c a (B.Abbr xv) in
  78       let f xv vv = match xv with
  79          | B.Cast _ -> f xv
  80          | _        -> f (B.Cast ([], vv, xv))
  81       in
  82       type_of f g c v
  83    | B.Bind (a, B.Abst u, t) ->
  84       let f xu xt tt =
  85          f (S.sh2 u xu t xt x (B.bind_abst a)) (B.bind_abst a xu tt)
  86       in
  87       let f xu cc = b_type_of (f xu) g cc t in
  88       let f xu _ = B.push (f xu) c a (B.Abst xu) in
  89       type_of f g c u
  90    | B.Bind (a, B.Void, t)   ->
  91       let f xt tt =
  92          f (S.sh1 t xt x (B.bind a B.Void)) (B.bind a B.Void tt)
  93       in
  94       let f cc = b_type_of f g cc t in
  95       B.push f c a B.Void
  96    | B.Appl (a, v, t)        ->
  97       let f xv vv xt tt = function
  98          | Some w ->
  99             L.box (succ level);
 100             L.log O.specs (succ level) (L.t_items1 "Just scanned" c w);
 101             L.unbox (succ level);
 102             let f r =
 103 (*             L.warn (Printf.sprintf "Convertible: %b" a); *)
 104                if r then f (S.sh2 v xv t xt x (B.appl a)) (B.appl a xv tt)
 105                else error3 c xv vv w
 106             in
 107             R.are_convertible f ~si:!si c w vv
 108          | None   ->
 109             error1 "not a function" c xt
 110       in
 111       let f xv vv xt tt = R.domain (f xv vv xt tt) c tt in
 112       let f xv vv = b_type_of (f xv vv) g c t in
 113       type_of f g c v
 114    | B.Cast (a, u, t)        ->
 115       let f xu xt tt r =
 116          (* L.warn (Printf.sprintf "Convertible: %b" a); *)
 117          if r then f (S.sh2 u xu t xt x (B.cast a)) xu else error3 c xt tt xu
 118       in
 119       let f xu xt tt = R.are_convertible ~si:!si (f xu xt tt) c xu tt in
 120       let f xu _ = b_type_of (f xu) g c t in
 121       type_of f g c u
 122
 123 and type_of f g c x =
 124    let f t u = L.unbox level; f t u in
 125    L.box level; b_type_of f g c x