helm/software/lambda-delta/src/basic_ag/bagType.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module U  = NUri
  13 module C  = Cps
  14 module W  = Share
  15 module L  = Log
  16 module E  = Entity
  17 module H  = Hierarchy
  18 module S  = Status
  19 module Z  = Bag
  20 module ZO = BagOutput
  21 module ZE = BagEnvironment
  22 module ZR = BagReduction
  23
  24 exception TypeError of Z.message
  25
  26 (* Internal functions *******************************************************)
  27
  28 let level = 4
  29
  30 let log1 s c t =
  31    let sc, st = s ^ " in the envireonment", "the term" in
  32    L.log ZO.specs level (L.et_items1 sc c st t)
  33
  34 let error1 st c t =
  35    let sc = "In the envireonment" in
  36    raise (TypeError (L.et_items1 sc c st t))
  37
  38 let error3 c t1 t2 t3 =
  39    let sc, st1, st2, st3 =
  40       "In the envireonment", "the term", "is of type", "but must be of type"
  41    in
  42    raise (TypeError (L.et_items3 sc c st1 t1 st2 t2 st3 t3))
  43
  44 let mk_gref u l =
  45    let map t v = Z.Appl (v, t) in
  46    List.fold_left map (Z.GRef u) l
  47
  48 (* Interface functions ******************************************************)
  49
  50 let rec b_type_of f st c x =
  51 (*   L.warn "Entering T.b_type_of"; *)
  52    log1 "Now checking" c x;
  53    match x with
  54    | Z.Sort h                    ->
  55       let h = H.apply h in f x (Z.Sort h)
  56    | Z.LRef i                    ->
  57       let f = function
  58          | Some (_, Z.Abst w)               -> f x w
  59          | Some (_, Z.Abbr (Z.Cast (w, v))) -> f x w
  60          | Some (_, Z.Abbr _)               -> assert false
  61          | Some (_, Z.Void)                 ->
  62             error1 "reference to excluded variable" c x
  63          | None                             ->
  64             error1 "variable not found" c x
  65       in
  66       Z.get f c i
  67    | Z.GRef uri                  ->
  68       let f = function
  69          | _, _, E.Abst (_, w)          -> f x w
  70          | _, _, E.Abbr (Z.Cast (w, v)) -> f x w
  71          | _, _, E.Abbr _               -> assert false
  72          | _, _, E.Void                 -> assert false
  73       in
  74       ZE.get_entity f uri
  75    | Z.Bind (l, id, Z.Abbr v, t) ->
  76       let f xv xt tt =
  77          f (W.sh2 v xv t xt x (Z.bind_abbr l id)) (Z.bind_abbr l id xv tt)
  78       in
  79       let f xv cc = b_type_of (f xv) st cc t in
  80       let f xv = Z.push "type abbr" (f xv) c l id (Z.Abbr xv) in
  81       let f xv vv = match xv with
  82          | Z.Cast _ -> f xv
  83          | _        -> f (Z.Cast (vv, xv))
  84       in
  85       type_of f st c v
  86    | Z.Bind (l, id, Z.Abst u, t) ->
  87       let f xu xt tt =
  88          f (W.sh2 u xu t xt x (Z.bind_abst l id)) (Z.bind_abst l id xu tt)
  89       in
  90       let f xu cc = b_type_of (f xu) st cc t in
  91       let f xu _ = Z.push "type abst" (f xu) c l id (Z.Abst xu) in
  92       type_of f st c u
  93    | Z.Bind (l, id, Z.Void, t)   ->
  94       let f xt tt =
  95          f (W.sh1 t xt x (Z.bind l id Z.Void)) (Z.bind l id Z.Void tt)
  96       in
  97       let f cc = b_type_of f st cc t in
  98       Z.push "type void" f c l id Z.Void
  99    | Z.Appl (v, t)            ->
 100       let f xv vv xt tt = function
 101          | ZR.Abst w                             ->
 102             L.box (succ level);
 103             L.log ZO.specs (succ level) (L.t_items1 "Just scanned" c w);
 104             L.unbox (succ level);
 105             let f a =
 106 (*             L.warn (Printf.sprintf "Convertible: %b" a); *)
 107                if a then f (W.sh2 v xv t xt x Z.appl) (Z.appl xv tt)
 108                else error3 c xv vv w
 109             in
 110             ZR.are_convertible f ~si:st.S.si c w vv
 111          | _                                    ->
 112             error1 "not a function" c xt
 113       in
 114       let f xv vv xt tt = ZR.ho_whd (f xv vv xt tt) c tt in
 115       let f xv vv = b_type_of (f xv vv) st c t in
 116       type_of f st c v
 117    | Z.Cast (u, t)            ->
 118       let f xu xt tt a =
 119          (* L.warn (Printf.sprintf "Convertible: %b" a); *)
 120          if a then f (W.sh2 u xu t xt x Z.cast) xu else error3 c xt tt xu
 121       in
 122       let f xu xt tt = ZR.are_convertible (f xu xt tt) ~si:st.S.si c xu tt in
 123       let f xu _ = b_type_of (f xu) st c t in
 124       type_of f st c u
 125
 126 and type_of f st c x =
 127    let f t u = L.unbox level; f t u in
 128    L.box level; b_type_of f st c x