helm/software/lambda-delta/toplevel/metaOutput.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module P = Printf
  13 module F = Format
  14 module U = NUri
  15 module L = Log
  16 module M = Meta
  17
  18 type counters = {
  19    eabsts: int;
  20    eabbrs: int;
  21    pabsts: int;
  22    tsorts: int;
  23    tlrefs: int;
  24    tgrefs: int;
  25    pappls: int;
  26    tappls: int;
  27    tabsts: int;
  28    uris  : U.uri list;
  29    nodes : int;
  30    xnodes: int
  31 }
  32
  33 let initial_counters = {
  34    eabsts = 0; eabbrs = 0; pabsts = 0; pappls = 0;
  35    tsorts = 0; tlrefs = 0; tgrefs = 0; tappls = 0; tabsts = 0;
  36    uris = []; nodes = 0; xnodes = 0
  37 }
  38
  39 let rec count_term f c = function
  40    | M.Sort _          ->
  41       f {c with tsorts = succ c.tsorts; nodes = succ c.nodes}
  42    | M.LRef _          ->
  43       f {c with tlrefs = succ c.tlrefs; nodes = succ c.nodes}
  44    | M.GRef (_, u, ts) ->
  45       let c = {c with tgrefs = succ c.tgrefs} in
  46       let c = {c with pappls = c.pappls + List.length ts} in
  47       let c = {c with nodes = c.nodes + List.length ts} in
  48       let c =
  49          if Cps.list_mem ~eq:U.eq u c.uris
  50          then {c with nodes = succ c.nodes}
  51          else {c with xnodes = succ c.xnodes}
  52       in
  53       Cps.list_fold_left f count_term c ts
  54    | M.Appl (v, t)     ->
  55       let c = {c with tappls = succ c.tappls; nodes = succ c.nodes} in
  56       let f c = count_term f c t in
  57       count_term f c v
  58    | M.Abst (_, w, t)  ->
  59       let c = {c with tabsts = succ c.tabsts; nodes = succ c.nodes} in
  60       let f c = count_term f c t in
  61       count_term f c w
  62
  63 let count_par f c (_, w) = count_term f c w
  64
  65 let count_entry f c = function
  66    | _, pars, u, w, None        ->
  67       let c = {c with eabsts = succ c.eabsts} in
  68       let c = {c with pabsts = c.pabsts + List.length pars} in
  69       let c = {c with uris = u :: c.uris; nodes = succ c.nodes + List.length pars} in
  70       let f c = count_term f c w in
  71       Cps.list_fold_left f count_par c pars
  72    | _, pars, _, w, Some (_, v) ->
  73       let c = {c with eabbrs = succ c.eabbrs; xnodes = succ c.xnodes} in
  74       let c = {c with pabsts = c.pabsts + List.length pars} in
  75       let c = {c with nodes = c.nodes + List.length pars} in
  76       let f c = count_term f c v in
  77       let f c = count_term f c w in
  78       Cps.list_fold_left f count_par c pars
  79
  80 let count_item f c = function
  81    | Some e -> count_entry f c e
  82    | None   -> f c
  83
  84 let print_counters f c =
  85    let terms = c.tsorts + c.tlrefs + c.tgrefs + c.tappls + c.tabsts in
  86    let pars = c.pabsts + c.pappls in
  87    let items = c.eabsts + c.eabbrs in
  88    let nodes = c.nodes + c.xnodes in
  89    L.warn (P.sprintf "  Intermediate representation summary");
  90    L.warn (P.sprintf "    Total entry items:        %7u" items);
  91    L.warn (P.sprintf "      Declaration items:      %7u" c.eabsts);
  92    L.warn (P.sprintf "      Definition items:       %7u" c.eabbrs);
  93    L.warn (P.sprintf "    Total parameter items:    %7u" pars);
  94    L.warn (P.sprintf "      Application items:      %7u" c.pappls);
  95    L.warn (P.sprintf "      Abstraction items:      %7u" c.pabsts);
  96    L.warn (P.sprintf "    Total term items:         %7u" terms);
  97    L.warn (P.sprintf "      Sort items:             %7u" c.tsorts);
  98    L.warn (P.sprintf "      Local reference items:  %7u" c.tlrefs);
  99    L.warn (P.sprintf "      Global reference items: %7u" c.tgrefs);
 100    L.warn (P.sprintf "      Application items:      %7u" c.tappls);
 101    L.warn (P.sprintf "      Abstraction items:      %7u" c.tabsts);
 102    L.warn (P.sprintf "    Global Int. Complexity:   %7u" c.nodes);
 103    L.warn (P.sprintf "      + Abbreviation nodes:   %7u" nodes);
 104    f ()
 105
 106 let string_of_sort = function
 107    | true -> "Type"
 108    | false -> "Prop"
 109
 110 let string_of_transparent = function
 111    | true  -> "="
 112    | false -> "~"
 113
 114 let pp_list pp opend sep closed frm l =
 115    let rec aux frm = function
 116       | []       -> ()
 117       | [hd]     -> pp frm hd
 118       | hd :: tl -> F.fprintf frm "%a%s%a" pp hd sep aux tl
 119    in
 120    if l = [] then () else F.fprintf frm "%s%a%s" opend aux l closed
 121
 122 let pp_rev_list pp opend sep closed frm l =
 123    pp_list pp opend sep closed frm (List.rev l)
 124
 125 let rec pp_args frm args = pp_list pp_term "(" "," ")" frm args
 126
 127 and pp_term frm = function
 128    | M.Sort s            ->
 129       F.fprintf frm "@[*%s@]" (string_of_sort s)
 130    | M.LRef (l, i)       ->
 131       F.fprintf frm "@[%u@@#%u@]" l i
 132    | M.GRef (l, uri, ts) ->
 133       F.fprintf frm "@[%u@@$%s%a@]" l (U.string_of_uri uri) pp_args ts
 134    | M.Appl (v, t)       ->
 135       F.fprintf frm "@[(%a).%a@]" pp_term v pp_term t
 136    | M.Abst (id, w, t)   ->
 137       F.fprintf frm "@[[%s:%a].%a@]" id pp_term w pp_term t
 138
 139 let pp_par frm (id, w) =
 140     F.fprintf frm "%s:%a" id pp_term w
 141
 142 let pp_pars = pp_rev_list pp_par "[" "," "]"
 143
 144 let pp_body frm = function
 145    | None            -> ()
 146    | Some (trans, t) ->
 147       F.fprintf frm "%s%a" (string_of_transparent trans) pp_term t
 148
 149 let pp_entry frm (l, pars, uri, u, body) =
 150    F.fprintf frm "@[%u@@%s%a%a:%a@]@\n%!"
 151       l (U.string_of_uri uri) pp_pars pars pp_body body pp_term u
 152
 153 let pp_item f frm = function
 154    | Some entry -> pp_entry frm entry; f ()
 155    | None       -> f ()