helm/software/lambda-delta/toplevel/top.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 module P    = Printf
  13 module U    = NUri
  14 module C    = Cps
  15 module L    = Log
  16 module T    = Time
  17 module H    = Hierarchy
  18 module O    = Output
  19 module Y    = Entity
  20 module X    = Library
  21 module AP   = AutProcess
  22 module AO   = AutOutput
  23 module DA   = DrgAut
  24 module MA   = MetaAut
  25 module MO   = MetaOutput
  26 module ML   = MetaLibrary
  27 module DO   = DrgOutput
  28 module DBrg = DrgBrg
  29 module MBrg = MetaBrg
  30 module BrgO = BrgOutput
  31 module BrgR = BrgReduction
  32 module BrgU = BrgUntrusted
  33 module MBag = MetaBag
  34 module BagO = BagOutput
  35 module BagT = BagType
  36 module BagU = BagUntrusted
  37
  38 type status = {
  39    ast : AP.status;
  40    dst : DA.status;
  41    mst : MA.status;
  42    ac  : AO.counters;
  43    mc  : MO.counters;
  44    brgc: BrgO.counters;
  45    bagc: BagO.counters
  46 }
  47
  48 let initial_status mk_uri cover = {
  49    ac   = AO.initial_counters;
  50    mc   = MO.initial_counters;
  51    brgc = BrgO.initial_counters;
  52    bagc = BagO.initial_counters;
  53    mst  = MA.initial_status ~cover ();
  54    dst  = DA.initial_status (mk_uri cover);
  55    ast  = AP.initial_status
  56 }
  57
  58 let count count_fun c entity =
  59    if !L.level > 2 then count_fun C.start c entity else c
  60
  61 let flush_all () = L.flush 0; L.flush_err ()
  62
  63 let bag_error s msg =
  64    L.error BagO.specs (L.Warn s :: L.Loc :: msg); flush_all ()
  65
  66 let brg_error s msg =
  67    L.error BrgR.specs (L.Warn s :: L.Loc :: msg); flush_all ()
  68
  69 let process_entity f st =
  70    let f ast = f {st with ast = ast} in
  71    AP.process_entity f st.ast
  72
  73 (* kernel related ***********************************************************)
  74
  75 type kernel = Brg | Bag
  76
  77 type kernel_entity = BrgEntity  of Brg.entity
  78                    | BagEntity  of Bag.entity
  79                    | DrgEntity  of Drg.entity
  80                    | MetaEntity of Meta.entity
  81
  82 let kernel = ref Brg
  83
  84 let print_counters st = match !kernel with
  85    | Brg -> BrgO.print_counters C.start st.brgc
  86    | Bag -> BagO.print_counters C.start st.bagc
  87
  88 let xlate f st entity = match !kernel, entity with
  89    | Brg, DrgEntity e  ->
  90       let f e = f st (BrgEntity e) in Y.xlate f DBrg.brg_of_drg e
  91    | Brg, MetaEntity e ->
  92       let f e = f st (BrgEntity e) in Y.xlate f MBrg.brg_of_meta e
  93    | Bag, MetaEntity e ->
  94       let f e = f st (BagEntity e) in Y.xlate f MBag.bag_of_meta e
  95    | _, entity         -> f st entity
  96
  97 let count_entity st = function
  98    | MetaEntity e -> {st with mc = count MO.count_entity st.mc e}
  99    | BrgEntity e  -> {st with brgc = count BrgO.count_entity st.brgc e}
 100    | BagEntity e  -> {st with bagc = count BagO.count_entity st.bagc e}
 101    | _            -> st
 102
 103 let export_entity si g moch = function
 104    | DrgEntity e  -> X.export_entity DO.export_term si g e
 105    | BrgEntity e  -> X.old_export_entity BrgO.export_term si g e
 106    | MetaEntity e ->
 107       begin match moch with
 108          | None     -> ()
 109          | Some och -> ML.write_entity C.start och e
 110       end
 111    | BagEntity _  -> ()
 112
 113 let type_check f st si g k =
 114    let brg_err msg = brg_error "Type Error" msg; failwith "Interrupted" in
 115    let ok _ (a, u, _) = f st a u in
 116    match k with
 117       | BrgEntity entity     -> BrgU.type_check brg_err ok ~si g entity
 118       | BagEntity entity     -> BagU.type_check ok ~si g entity
 119       | DrgEntity (a, u, _)
 120       | MetaEntity (a, u, _) -> f st a u
 121
 122 (****************************************************************************)
 123
 124 let stage = ref 3
 125 let moch = ref None
 126 let meta = ref false
 127 let progress = ref false
 128 let preprocess = ref false
 129 let use_cover = ref true
 130 let si = ref false
 131 let cc = ref false
 132 let export = ref false
 133 let graph = ref (H.graph_of_string C.err C.start "Z2")
 134 let old = ref false
 135
 136 let process_3 f st a u =
 137    if !progress then
 138       let s = U.string_of_uri u in
 139       let err () = L.warn (P.sprintf "%s" s); f st in
 140       let f i = L.warn (P.sprintf "[%u] %s" i s); f st in
 141       Y.mark err f a
 142    else
 143       f st
 144
 145 let process_2 f st entity =
 146    let st = count_entity st entity in
 147    if !export then export_entity !si !graph !moch entity;
 148    if !stage > 2 then type_check (process_3 f) st !si !graph entity else f st
 149
 150 let process_1 f st entity =
 151    let st = count_entity st entity in
 152    if !export && !stage = 1 then export_entity !si !graph !moch entity;
 153    if !stage > 1 then xlate (process_2 f) st entity else f st
 154
 155 let process_0 f st entity =
 156    let f st entity =
 157       if !stage = 0 then f st else
 158       let frr mst = f {st with mst = mst} in
 159       let h mst e = process_1 f {st with mst = mst} (MetaEntity e) in
 160       let err dst = f {st with dst = dst} in
 161       let g dst e = process_1 f {st with dst = dst} (DrgEntity e) in
 162       if !old then MA.meta_of_aut frr h st.mst entity else
 163       DA.drg_of_aut err g st.dst entity
 164    in
 165    let st = {st with ac = count AO.count_entity st.ac entity} in
 166    if !preprocess then process_entity f st entity else f st entity
 167
 168 let rec process f book st = match book with
 169    | []           -> f st
 170    | entity :: tl ->
 171 (* we exploit tail recursion rather than CPS *)
 172       process f tl (process_0 C.start st entity)
 173
 174 (****************************************************************************)
 175
 176 let main =
 177 try
 178    let version_string = "Helena 0.8.1 M - October 2009" in
 179    let set_hierarchy s =
 180       let err () = L.warn (P.sprintf "Unknown type hierarchy: %s" s) in
 181       let f g = graph := g in
 182       H.graph_of_string err f s
 183    in
 184    let set_kernel = function
 185       | "brg" -> kernel := Brg
 186       | "bag" -> kernel := Bag
 187       | s     -> L.warn (P.sprintf "Unknown kernel version: %s" s)
 188    in
 189    let set_summary i = L.level := i in
 190    let print_version () = L.warn (version_string ^ "\n"); exit 0 in
 191    let set_stage i = stage := i in
 192    let set_meta_file name =
 193       let f och = moch := Some och in
 194       ML.open_out f name
 195    in
 196    let close = function
 197       | None     -> ()
 198       | Some och -> ML.close_out C.start och
 199    in
 200    let read_file name =
 201       if !L.level > 0 then T.gmtime version_string;
 202       if !L.level > 1 then
 203          L.warn (P.sprintf "Processing file: %s" name);
 204       if !L.level > 0 then T.utime_stamp "started";
 205       let base_name = Filename.chop_extension (Filename.basename name) in
 206       if !meta then set_meta_file base_name;
 207       let ich = open_in name in
 208       let lexbuf = Lexing.from_channel ich in
 209       let book = AutParser.book AutLexer.token lexbuf in
 210       close_in ich;
 211       if !L.level > 0 then T.utime_stamp "parsed";
 212       O.clear_reductions ();
 213       let mk_uri =
 214          if !stage < 2 then Drg.mk_uri else
 215          match !kernel with
 216             | Brg -> Brg.mk_uri
 217             | Bag -> Bag.mk_uri
 218       in
 219       let cover = if !use_cover then base_name else "" in
 220       let f st =
 221          if !L.level > 0 then T.utime_stamp "processed";
 222          if !L.level > 2 then AO.print_counters C.start st.ac;
 223          if !L.level > 2 && !preprocess then AO.print_process_counters C.start st.ast;
 224          if !L.level > 2 && !stage > 0 then MO.print_counters C.start st.mc;
 225          if !L.level > 2 && !stage > 1 then print_counters st;
 226          if !L.level > 2 && !stage > 1 then O.print_reductions ()
 227       in
 228       process f book (initial_status mk_uri cover)
 229    in
 230    let exit () =
 231       close !moch;
 232       if !L.level > 0 then T.utime_stamp "at exit";
 233       flush_all ()
 234    in
 235    let help =
 236       "Usage: helena [ -Vcijmopux | -Ss <number> | -hk <string> ] <file> ...\n\n" ^
 237       "Summary levels: 0 just errors (default), 1 time stamps, 2 processed file names, \
 238        3 data information, 4 typing information, 5 reduction information\n\n" ^
 239        "Stages: 0 parsing, 1 to intermediate, 2 to untrusted, 3 to trusted (default)\n"
 240    in
 241    let help_S = "<number>  set summary level (see above)" in
 242    let help_V = " show version information" in
 243
 244    let help_c = " output conversion constraints" in
 245    let help_h = "<string>  set type hierarchy (default: Z2)" in
 246    let help_i = " show local references by index" in
 247    let help_j = " show URI of processed kernel objects" in
 248    let help_k = "<string>  set kernel version (default: brg)" in
 249    let help_m = " output intermediate representation (HAL)" in
 250    let help_o = " use old abstract language instead of drg" in
 251    let help_p = " preprocess Automath source" in
 252    let help_r = " disable initial segment of URI hierarchy" in
 253    let help_s = "<number>  set translation stage (see above)" in
 254    let help_u = " activate sort inclusion" in
 255    let help_x = " export kernel entities (XML)" in
 256    L.box 0; L.box_err ();
 257    H.set_sorts ignore ["Set"; "Prop"] 0;
 258    at_exit exit;
 259    Arg.parse [
 260       ("-S", Arg.Int set_summary, help_S);
 261       ("-V", Arg.Unit print_version, help_V);
 262       ("-c", Arg.Set cc, help_c);
 263       ("-h", Arg.String set_hierarchy, help_h);
 264       ("-i", Arg.Set O.indexes, help_i);
 265       ("-j", Arg.Set progress, help_j);
 266       ("-k", Arg.String set_kernel, help_k);
 267       ("-m", Arg.Set meta, help_m);
 268       ("-o", Arg.Set old, help_o);
 269       ("-p", Arg.Set preprocess, help_p);
 270       ("-r", Arg.Clear use_cover, help_r);
 271       ("-s", Arg.Int set_stage, help_s);
 272       ("-u", Arg.Set si, help_u);
 273       ("-x", Arg.Set export, help_x)
 274    ] read_file help;
 275 with BagT.TypeError msg -> bag_error "Type Error" msg