helm/software/matita/contribs/POPLmark/Fsub/part1a.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Fsub/defn.ma".
  16
  17 (*** Lemma A.1 (Reflexivity) ***)
  18 theorem JS_Refl : ∀T,G.(G ⊢ T) → G ⊢ ♦ → G ⊢ T ⊴  T.
  19 intros 3; elim H;
  20  [1,2,3: autobatch
  21  | apply SA_All; [ autobatch | intros;autobatch depth=4 size=10]]
  22 qed.
  23
  24 (*
  25  * A slightly more general variant to lemma A.2.2, where weakening isn't
  26  * defined as concatenation of any two disjoint environments, but as
  27  * set inclusion.
  28  *)
  29
  30 lemma JS_weakening : ∀G,T,U.G ⊢ T ⊴ U → ∀H.H ⊢ ♦ → G ⊆ H → H ⊢ T ⊴ U.
  31 intros 4; elim H;
  32  [1,2,3,4: autobatch depth=4 size=7
  33  | apply (SA_All ? ? ? ? ? (H2 ? H6 H7));
  34    intros; apply H4;autobatch depth=4 size=7]
  35 qed.
  36
  37 inverter JS_indinv for JSubtype (%?%).
  38
  39 theorem narrowing:∀X,G,G1,U,P,M,N.
  40   G1 ⊢ P ⊴ U → (∀G2,T.G2@G1 ⊢ U ⊴ T → G2@G1 ⊢ P ⊴ T) → G ⊢ M ⊴ N →
  41   ∀l.G=l@ !X ⊴ U::G1 → l@ !X ⊴ P::G1 ⊢ M ⊴ N.
  42 intros 10.elim H2; destruct;
  43  [letin x \def fv_env. letin y ≝incl. autobatch depth=4 size=8.
  44  | autobatch depth=4 size=7;
  45  | elim (decidable_eq_nat X n)
  46     [apply (SA_Trans_TVar ? ? ? P); destruct;
  47       [ autobatch
  48       | lapply (WFE_bound_bound X t1 U ? ? H3); autobatch]
  49     | apply (SA_Trans_TVar ? ? ? t1); autobatch]
  50  | autobatch
  51  | apply SA_All;
  52     [ autobatch
  53     | intros; apply (H6 ? ? (mk_bound true X1 t2::l1)); autobatch]]
  54 qed.
  55
  56 lemma JS_trans_prova: ∀T,G1.(G1 ⊢ T) →
  57       ∀G,R,U.fv_env G1 ⊆ fv_env G → G ⊢ R ⊴ T → G ⊢ T ⊴ U → G ⊢ R ⊴ U.
  58 intros 3;elim H;clear H;
  59   [elim H3 using JS_indinv;destruct;autobatch
  60   |inversion H3; intros; destruct; assumption
  61   |*: elim H6 using JS_indinv;destruct;
  62     [1,3: autobatch
  63     |*: inversion H7; intros; destruct;
  64       [1,2: autobatch depth=4 width=4 size=9
  65       | apply SA_Top
  66          [ assumption
  67          | apply WFT_Forall;intros;autobatch depth=4]
  68       | apply SA_All
  69          [ autobatch
  70          | intros;apply (H4 X);simplify;
  71             [4: apply (narrowing X (mk_bound true X t::G) ? ? ? ? ? H11 ? ? [])
  72                [intros;apply H2;try unfold;intros;autobatch;
  73                |*:autobatch]
  74             |3:apply incl_cons;apply H5
  75             |*:autobatch]]]]]
  76 qed.
  77
  78 theorem JS_trans : ∀G,T,U,V.G ⊢ T ⊴ U → G ⊢ U ⊴ V → G ⊢ T ⊴ V.
  79 intros 5; apply (JS_trans_prova ? G); autobatch depth=2.
  80 qed.
  81
  82 theorem JS_narrow : ∀G1,G2,X,P,Q,T,U.
  83                        G2 @ !X ⊴ Q :: G1 ⊢ T ⊴ U → G1 ⊢ P ⊴ Q →
  84                        G2 @ !X ⊴ P :: G1 ⊢ T ⊴ U.
  85 intros;apply (narrowing ? ? ? ? ? ? ? H1 ? H) [|autobatch]
  86 intros;apply (JS_trans ? ? ? ? ? H2);apply (JS_weakening ? ? ? H1);autobatch.
  87 qed.