helm/software/matita/contribs/POPLmark/Fsub/part1a_inversion3.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Fsub/defn2.ma".
  16
  17 (*** Lemma A.1 (Reflexivity) ***)
  18 theorem JS_Refl : ∀T,G.WFType G T → WFEnv G → G ⊢ T ⊴  T.
  19 intros 3; elim H;
  20  [1,2,3: autobatch
  21  | apply SA_All; [ autobatch | intros; autobatch depth=4 size=10]
  22  ]
  23 qed.
  24
  25 (*
  26  * A slightly more general variant to lemma A.2.2, where weakening isn't
  27  * defined as concatenation of any two disjoint environments, but as
  28  * set inclusion.
  29  *)
  30
  31 lemma JS_weakening : ∀G,T,U.G ⊢ T ⊴ U → ∀H.WFEnv H → incl ? G H → H ⊢ T ⊴ U.
  32 intros 4; elim H;
  33  [1,2,3,4: autobatch depth=4 size=7
  34  | apply (SA_All ? ? ? ? ? (H2 ? H6 H7));
  35    intros; apply H4; autobatch depth=4 size=7]
  36 qed.
  37
  38 lemma JSubtype_inv:
  39  ∀G:list bound.∀T1,T:Typ.
  40   ∀P:list bound → Typ → Typ → Prop.
  41    (∀t. WFEnv G → WFType G t → T=Top → P G t Top) →
  42    (∀n. WFEnv G → n ∈ fv_env G → T=TFree n → P G (TFree n) (TFree n)) →
  43    (∀n,t1,t.
  44     (mk_bound true n t1) ∈ G → G ⊢ t1 ⊴ t → P G t1 t → T=t → P G (TFree n) T) →
  45    (∀s1,s2,t1,t2. G ⊢ t1 ⊴ s1 → G ⊢ s2 ⊴ t2 → T=Arrow t1 t2 → P G (Arrow s1 s2) (Arrow t1 t2)) →
  46    (∀s1,s2,t1,t2. G ⊢ t1 ⊴ s1 →
  47     (∀X. ¬(X ∈ fv_env G) → (mk_bound true X t1)::G ⊢ subst_type_nat s2 (TFree X) O ⊴ subst_type_nat t2 (TFree X) O)
  48       → T=Forall t1 t2 → P G (Forall s1 s2) (Forall t1 t2)) →
  49     G ⊢ T1 ⊴ T → P G T1 T.
  50  intros;
  51  generalize in match (refl_eq ? T);
  52  generalize in match (refl_eq ? G);
  53  elim H5 in ⊢ (? ? ? % → ? ? ? % → %); destruct; autobatch width=4 size=7;
  54 qed.
  55
  56 theorem narrowing:∀X,G,G1,U,P,M,N.
  57   G1 ⊢ P ⊴ U → (∀G2,T.G2@G1 ⊢ U ⊴ T → G2@G1 ⊢ P ⊴ T) → G ⊢ M ⊴ N →
  58   ∀l.G=l@(mk_bound true X U::G1) → l@(mk_bound true X P::G1) ⊢ M ⊴ N.
  59 intros 10.elim H2; destruct;
  60  [letin x \def fv_env. letin y ≝incl. autobatch depth=4 size=8.
  61  | autobatch depth=4 size=7;
  62  | elim (decidable_eq_nat X n)
  63     [apply (SA_Trans_TVar ? ? ? P); destruct;
  64       [ autobatch
  65       | lapply (WFE_bound_bound true X t1 U ? ? H3); autobatch]
  66     | apply (SA_Trans_TVar ? ? ? t1); autobatch]
  67  | autobatch
  68  | apply SA_All;
  69     [ autobatch
  70     | intros; apply (H6 ? ? (mk_bound true X1 t2::l1));autobatch]]
  71 qed.
  72
  73 lemma JS_trans_prova: ∀T,G1.WFType G1 T →
  74 ∀G,R,U.incl ? (fv_env G1) (fv_env G) → G ⊢ R ⊴ T → G ⊢ T ⊴ U → G ⊢ R ⊴ U.
  75 intros 3;elim H;clear H; try autobatch;
  76   [ apply (JSubtype_inv ? ? ? ? ? ? ? ? ? H3); intros; destruct; autobatch
  77   | inversion H3; intros; destruct; assumption
  78   |*: apply (JSubtype_inv ? ? ? ? ? ? ? ? ? H6); intros; destruct;
  79     [1,3: autobatch
  80     |*: inversion H7; intros; destruct;
  81       [1,2: autobatch depth=4 width=4 size=9
  82       | apply SA_Top
  83          [ assumption
  84          | apply WFT_Forall;intros;autobatch depth=4]
  85       | apply SA_All
  86          [ autobatch
  87          | intros;apply (H4 X);simplify;
  88             [4: apply (narrowing X (mk_bound true X t::G) ? ? ? ? ? H9 ? ? [])
  89                [intros;apply H2;try unfold;intros;autobatch;
  90                |*:autobatch]
  91             |*: autobatch]]]]]
  92 qed.
  93
  94 theorem JS_trans : ∀G,T,U,V.G ⊢ T ⊴ U → G ⊢ U ⊴ V → G ⊢ T ⊴ V.
  95 intros 5; apply (JS_trans_prova ? G); autobatch depth=2.
  96 qed.
  97
  98 theorem JS_narrow : ∀G1,G2,X,P,Q,T,U.
  99                        (G2 @ (mk_bound true X Q :: G1)) ⊢ T ⊴ U → G1 ⊢ P ⊴ Q →
 100                        (G2 @ (mk_bound true X P :: G1)) ⊢ T ⊴ U.
 101 intros;apply (narrowing ? ? ? ? ? ? ? H1 ? H) [|autobatch]
 102 intros;apply (JS_trans ? ? ? ? ? H2);apply (JS_weakening ? ? ? H1);autobatch.
 103 qed.