helm/software/matita/contribs/dama/dama/models/q_support.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Q/q/qtimes.ma".
  16 include "Q/q/qplus.ma".
  17 include "logic/cprop_connectives.ma".
  18
  19 interpretation "Q" 'Q = Q.
  20
  21 (* group over Q *)
  22 axiom qp : ℚ → ℚ → ℚ.
  23
  24 interpretation "Q plus" 'plus x y = (qp x y).
  25 interpretation "Q minus" 'minus x y = (qp x (Qopp y)).
  26
  27 axiom q_plus_OQ: ∀x:ℚ.x + OQ = x.
  28 axiom q_plus_sym: ∀x,y:ℚ.x + y = y + x.
  29 axiom q_plus_minus: ∀x.x - x = OQ.
  30 axiom q_plus_assoc: ∀x,y,z.x + (y + z) = x + y + z.
  31 axiom q_opp_plus: ∀x,y,z:Q. Qopp (y + z) = Qopp y + Qopp z.
  32
  33 (* order over Q *)
  34 axiom qlt : ℚ → ℚ → Prop.
  35 axiom qle : ℚ → ℚ → Prop.
  36 interpretation "Q less than" 'lt x y = (qlt x y).
  37 interpretation "Q less or equal than" 'leq x y = (qle x y).
  38
  39 inductive q_comparison (a,b:ℚ) : CProp ≝
  40  | q_leq : a ≤ b → q_comparison a b
  41  | q_gt : b < a → q_comparison a b.
  42
  43 axiom q_cmp:∀a,b:ℚ.q_comparison a b.
  44
  45 inductive q_le_elimination (a,b:ℚ) : CProp ≝
  46 | q_le_from_eq : a = b → q_le_elimination a b
  47 | q_le_from_lt : a < b → q_le_elimination a b.
  48
  49 axiom q_le_cases : ∀x,y:ℚ.x ≤ y → q_le_elimination x y.
  50
  51 axiom q_le_plus_l: ∀a,b,c:ℚ. a ≤ c - b → a + b ≤ c.
  52 axiom q_le_plus_r: ∀a,b,c:ℚ. a - b ≤ c → a ≤ c + b.
  53 axiom q_lt_plus_l: ∀a,b,c:ℚ. a < c - b → a + b < c.
  54 axiom q_lt_plus_r: ∀a,b,c:ℚ. a - b < c → a < c + b.
  55
  56 axiom q_lt_opp_opp: ∀a,b.b < a → Qopp a < Qopp b.
  57
  58 axiom q_le_n: ∀x. x ≤ x.
  59 axiom q_lt_to_le: ∀a,b:ℚ.a < b → a ≤ b.
  60
  61 axiom q_lt_corefl: ∀x:Q.x < x → False.
  62 axiom q_lt_le_incompat: ∀x,y:Q.x < y → y ≤ x → False.
  63
  64 axiom q_neg_gt: ∀r:ratio.Qneg r < OQ.
  65 axiom q_pos_OQ: ∀x.OQ < Qpos x.
  66
  67 axiom q_lt_trans: ∀x,y,z:Q. x < y → y < z → x < z.
  68 axiom q_lt_le_trans: ∀x,y,z:Q. x < y → y ≤ z → x < z.
  69 axiom q_le_lt_trans: ∀x,y,z:Q. x ≤ y → y < z → x < z.
  70 axiom q_le_trans: ∀x,y,z:Q. x ≤ y → y ≤ z → x ≤ z.
  71
  72 axiom q_le_lt_OQ_plus_trans: ∀x,y:Q.OQ ≤ x → OQ < y → OQ < x + y.
  73 axiom q_lt_le_OQ_plus_trans: ∀x,y:Q.OQ < x → OQ ≤ y → OQ < x + y.
  74 axiom q_le_OQ_plus_trans: ∀x,y:Q.OQ ≤ x → OQ ≤ y → OQ ≤ x + y.
  75
  76 axiom q_leWl: ∀x,y,z.OQ ≤ x → x + y ≤ z → y ≤ z.
  77 axiom q_ltWl: ∀x,y,z.OQ ≤ x → x + y < z → y < z.
  78
  79 (* distance *)
  80 axiom q_dist : ℚ → ℚ → ℚ.
  81
  82 notation "hbox(\dd [term 19 x, break term 19 y])" with precedence 90
  83 for @{'distance $x $y}.
  84 interpretation "ℚ distance" 'distance x y = (q_dist x y).
  85
  86 axiom q_d_ge_OQ : ∀x,y:ℚ. OQ ≤ ⅆ[x,y].
  87 axiom q_d_OQ: ∀x:Q.ⅆ[x,x] = OQ.
  88 axiom q_d_noabs: ∀x,y. x ≤ y → ⅆ[y,x] = y - x.
  89 axiom q_d_sym: ∀x,y. ⅆ[x,y] = ⅆ[y,x].
  90
  91 lemma q_2opp: ∀x:ℚ.Qopp (Qopp x) = x.
  92 intros; cases x; reflexivity; qed.
  93
  94 (* derived *)
  95 lemma q_lt_canc_plus_r:
  96   ∀x,y,z:Q.x + z < y + z → x < y.
  97 intros; rewrite < (q_plus_OQ y); rewrite < (q_plus_minus z);
  98 rewrite > q_plus_assoc; apply q_lt_plus_r; rewrite > q_2opp; assumption;
  99 qed.
 100
 101 lemma q_lt_inj_plus_r:
 102   ∀x,y,z:Q.x < y → x + z < y + z.
 103 intros; apply (q_lt_canc_plus_r ?? (Qopp z));
 104 do 2 rewrite < q_plus_assoc; rewrite > q_plus_minus;
 105 do 2 rewrite > q_plus_OQ; assumption;
 106 qed.
 107
 108 lemma q_le_inj_plus_r:
 109   ∀x,y,z:Q.x ≤ y → x + z ≤ y + z.
 110 intros;cases (q_le_cases ?? H);
 111 [1: rewrite > H1; apply q_le_n;
 112 |2: apply q_lt_to_le; apply q_lt_inj_plus_r; assumption;]
 113 qed.
 114
 115 lemma q_le_canc_plus_r:
 116   ∀x,y,z:Q.x + z ≤ y + z → x ≤ y.
 117 intros; lapply (q_le_inj_plus_r ?? (Qopp z) H) as H1;
 118 do 2 rewrite < q_plus_assoc in H1;
 119 rewrite > q_plus_minus in H1; do 2 rewrite > q_plus_OQ in H1; assumption;
 120 qed.