helm/software/matita/contribs/dama/dama/ordered_set.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "datatypes/constructors.ma".
  16 include "logic/cprop_connectives.ma".
  17
  18
  19 (* TEMPLATES
  20 notation "''" non associative with precedence 90 for @{'}.
  21 notation "''" non associative with precedence 90 for @{'}.
  22
  23 interpretation "" ' = ( (os_l _)).
  24 interpretation "" ' = ( (os_r _)).
  25 *)
  26
  27 (* Definition 2.1 *)
  28 record half_ordered_set: Type ≝ {
  29   hos_carr:> Type;
  30   hos_excess: hos_carr → hos_carr → CProp;
  31   hos_coreflexive: coreflexive ? hos_excess;
  32   hos_cotransitive: cotransitive ? hos_excess
  33 }.
  34
  35 definition dual_hos : half_ordered_set → half_ordered_set.
  36 intro; constructor 1;
  37 [ apply (hos_carr h);
  38 | apply (λx,y.hos_excess h y x);
  39 | apply (hos_coreflexive h);
  40 | intros 4 (x y z H); simplify in H ⊢ %; cases (hos_cotransitive h ?? z H);
  41   [right|left] assumption;]
  42 qed.
  43
  44 record ordered_set : Type ≝ {
  45   os_l : half_ordered_set;
  46   os_r_ : half_ordered_set;
  47   os_with : os_r_ = dual_hos os_l
  48 }.
  49
  50 definition os_r : ordered_set → half_ordered_set.
  51 intro o; apply (dual_hos (os_l o)); qed.
  52
  53 definition Type_of_ordered_set : ordered_set → Type.
  54 intro o; apply (hos_carr (os_l o)); qed.
  55
  56 definition Type_of_ordered_set_dual : ordered_set → Type.
  57 intro o; apply (hos_carr (os_r o)); qed.
  58
  59 coercion Type_of_ordered_set_dual.
  60 coercion Type_of_ordered_set.
  61
  62 notation "a ≰≰ b" non associative with precedence 45 for @{'nleq_low $a $b}.
  63 interpretation "Ordered half set excess" 'nleq_low a b = (hos_excess _ a b).
  64
  65 interpretation "Ordered set excess (dual)" 'ngeq a b = (hos_excess (os_r _) a b).
  66 interpretation "Ordered set excess" 'nleq a b = (hos_excess (os_l _) a b).
  67
  68 notation "'exc_coreflexive'" non associative with precedence 90 for @{'exc_coreflexive}.
  69 notation "'cxe_coreflexive'" non associative with precedence 90 for @{'cxe_coreflexive}.
  70
  71 interpretation "exc_coreflexive" 'exc_coreflexive = (hos_coreflexive (os_l _)).
  72 interpretation "cxe_coreflexive" 'cxe_coreflexive = (hos_coreflexive (os_r _)).
  73
  74 notation "'exc_cotransitive'" non associative with precedence 90 for @{'exc_cotransitive}.
  75 notation "'cxe_cotransitive'" non associative with precedence 90 for @{'cxe_cotransitive}.
  76
  77 interpretation "exc_cotransitive" 'exc_cotransitive = (hos_cotransitive (os_l _)).
  78 interpretation "cxe_cotransitive" 'cxe_cotransitive = (hos_cotransitive (os_r _)).
  79
  80 (* Definition 2.2 (3) *)
  81 definition le ≝ λE:half_ordered_set.λa,b:E. ¬ (a ≰≰ b).
  82
  83 notation "hvbox(a break ≤≤ b)" non associative with precedence 45 for @{ 'leq_low $a $b }.
  84 interpretation "Ordered half set less or equal than" 'leq_low a b = (le _ a b).
  85
  86 interpretation "Ordered set greater or equal than" 'geq a b = (le (os_r _) a b).
  87 interpretation "Ordered set less or equal than" 'leq a b = (le (os_l _) a b).
  88
  89 lemma hle_reflexive: ∀E.reflexive ? (le E).
  90 unfold reflexive; intros 3 (E x H); apply (hos_coreflexive ?? H);
  91 qed.
  92
  93 notation "'le_reflexive'" non associative with precedence 90 for @{'le_reflexive}.
  94 notation "'ge_reflexive'" non associative with precedence 90 for @{'ge_reflexive}.
  95
  96 interpretation "le reflexive" 'le_reflexive = (hle_reflexive (os_l _)).
  97 interpretation "ge reflexive" 'ge_reflexive = (hle_reflexive (os_r _)).
  98
  99 (* DUALITY TESTS
 100 lemma test_le_ge_convertible :∀o:ordered_set.∀x,y:o. x ≤ y → y ≥ x.
 101 intros; assumption; qed.
 102
 103 lemma test_ge_reflexive :∀o:ordered_set.∀x:o. x ≥ x.
 104 intros; apply ge_reflexive. qed.
 105
 106 lemma test_le_reflexive :∀o:ordered_set.∀x:o. x ≤ x.
 107 intros; apply le_reflexive. qed.
 108 *)
 109
 110 lemma hle_transitive: ∀E.transitive ? (le E).
 111 unfold transitive; intros 7 (E x y z H1 H2 H3); cases (hos_cotransitive ??? y H3) (H4 H4);
 112 [cases (H1 H4)|cases (H2 H4)]
 113 qed.
 114
 115 notation "'le_transitive'" non associative with precedence 90 for @{'le_transitive}.
 116 notation "'ge_transitive'" non associative with precedence 90 for @{'ge_transitive}.
 117
 118 interpretation "le transitive" 'le_transitive = (hle_transitive (os_l _)).
 119 interpretation "ge transitive" 'ge_transitive = (hle_transitive (os_r _)).
 120
 121 (* Lemma 2.3 *)
 122 lemma exc_hle_variance:
 123   ∀O:half_ordered_set.∀a,b,a',b':O.a ≰≰ b → a ≤≤ a' → b' ≤≤ b → a' ≰≰ b'.
 124 intros (O a b a1 b1 Eab Laa1 Lb1b);
 125 cases (hos_cotransitive ??? a1 Eab) (H H); [cases (Laa1 H)]
 126 cases (hos_cotransitive ??? b1 H) (H1 H1); [assumption]
 127 cases (Lb1b H1);
 128 qed.
 129
 130 notation "'exc_le_variance'" non associative with precedence 90 for @{'exc_le_variance}.
 131 notation "'exc_ge_variance'" non associative with precedence 90 for @{'exc_ge_variance}.
 132
 133 interpretation "exc_le_variance" 'exc_le_variance = (exc_hle_variance (os_l _)).
 134 interpretation "exc_ge_variance" 'exc_ge_variance = (exc_hle_variance (os_r _)).
 135
 136 lemma square_half_ordered_set: half_ordered_set → half_ordered_set.
 137 intro O;
 138 apply (mk_half_ordered_set (O × O));
 139 [1: intros (x y); apply (\fst x ≰≰ \fst y ∨ \snd x ≰≰ \snd y);
 140 |2: intro x0; cases x0 (x y); clear x0; simplify; intro H;
 141     cases H (X X); apply (hos_coreflexive ?? X);
 142 |3: intros 3 (x0 y0 z0); cases x0 (x1 x2); cases y0 (y1 y2) ; cases z0 (z1 z2);
 143     clear x0 y0 z0; simplify; intro H; cases H (H1 H1); clear H;
 144     [1: cases (hos_cotransitive ??? z1 H1); [left; left|right;left]assumption;
 145     |2: cases (hos_cotransitive ??? z2 H1); [left;right|right;right]assumption]]
 146 qed.
 147
 148 lemma square_ordered_set: ordered_set → ordered_set.
 149 intro O; constructor 1;
 150 [ apply (square_half_ordered_set (os_l O));
 151 | apply (dual_hos (square_half_ordered_set (os_l O)));
 152 | reflexivity]
 153 qed.
 154
 155 notation "s 2 \atop \nleq" non associative with precedence 90
 156   for @{ 'square_os $s }.
 157 notation > "s 'squareO'" non associative with precedence 90
 158   for @{ 'squareO $s }.
 159 interpretation "ordered set square" 'squareO s = (square_ordered_set s).
 160 interpretation "ordered set square" 'square_os s = (square_ordered_set s).
 161
 162 definition os_subset ≝ λO:ordered_set.λP,Q:O→Prop.∀x:O.P x → Q x.
 163
 164 interpretation "ordered set subset" 'subseteq a b = (os_subset _ a b).
 165