helm/software/matita/contribs/formal_topology/overlap/basic_pairs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "relations.ma".
  16 include "notation.ma".
  17
  18 record basic_pair: Type1 ≝
  19  { concr: REL;
  20    form: REL;
  21    rel: arrows1 ? concr form
  22  }.
  23
  24 interpretation "basic pair relation" 'Vdash2 x y c = (fun21 ___ (rel c) x y).
  25 interpretation "basic pair relation (non applied)" 'Vdash c = (rel c).
  26
  27 alias symbol "eq" = "setoid1 eq".
  28 alias symbol "compose" = "category1 composition".
  29 record relation_pair (BP1,BP2: basic_pair): Type1 ≝
  30  { concr_rel: arrows1 ? (concr BP1) (concr BP2);
  31    form_rel: arrows1 ? (form BP1) (form BP2);
  32    commute: ⊩ ∘ concr_rel = form_rel ∘ ⊩
  33  }.
  34
  35
  36 interpretation "concrete relation" 'concr_rel r = (concr_rel __ r).
  37 interpretation "formal relation" 'form_rel r = (form_rel __ r).
  38
  39 definition relation_pair_equality:
  40  ∀o1,o2. equivalence_relation1 (relation_pair o1 o2).
  41  intros;
  42  constructor 1;
  43   [ apply (λr,r'. ⊩ ∘ r \sub\c = ⊩ ∘ r' \sub\c);
  44   | simplify;
  45     intros;
  46     apply refl1;
  47   | simplify;
  48     intros 2;
  49     apply sym1;
  50   | simplify;
  51     intros 3;
  52     apply trans1;
  53   ]
  54 qed.
  55
  56 definition relation_pair_setoid: basic_pair → basic_pair → setoid1.
  57  intros;
  58  constructor 1;
  59   [ apply (relation_pair b b1)
  60   | apply relation_pair_equality
  61   ]
  62 qed.
  63
  64 definition relation_pair_of_relation_pair_setoid :
  65   ∀P,Q. relation_pair_setoid P Q → relation_pair P Q ≝ λP,Q,x.x.
  66 coercion relation_pair_of_relation_pair_setoid.
  67
  68 lemma eq_to_eq':
  69   ∀o1,o2.∀r,r':relation_pair_setoid o1 o2. r=r' → r \sub\f ∘ ⊩ = r'\sub\f ∘ ⊩.
  70  intros 7 (o1 o2 r r' H c1 f2);
  71  split; intro H1;
  72   [ lapply (fi ?? (commute ?? r c1 f2) H1) as H2;
  73     lapply (if ?? (H c1 f2) H2) as H3;
  74     apply (if ?? (commute ?? r' c1 f2) H3);
  75   | lapply (fi ?? (commute ?? r' c1 f2) H1) as H2;
  76     lapply (fi ?? (H c1 f2) H2) as H3;
  77     apply (if ?? (commute ?? r c1 f2) H3);
  78   ]
  79 qed.
  80
  81 definition id_relation_pair: ∀o:basic_pair. relation_pair o o.
  82  intro;
  83  constructor 1;
  84   [1,2: apply id1;
  85   | lapply (id_neutral_right1 ? (concr o) ? (⊩)) as H;
  86     lapply (id_neutral_left1 ?? (form o) (⊩)) as H1;
  87     apply (.= H);
  88     apply (H1 \sup -1);]
  89 qed.
  90
  91 definition relation_pair_composition:
  92  ∀o1,o2,o3. binary_morphism1 (relation_pair_setoid o1 o2) (relation_pair_setoid o2 o3) (relation_pair_setoid o1 o3).
  93  intros;
  94  constructor 1;
  95   [ intros (r r1);
  96     constructor 1;
  97      [ apply (r1 \sub\c ∘ r \sub\c)
  98      | apply (r1 \sub\f ∘ r \sub\f)
  99      | lapply (commute ?? r) as H;
 100        lapply (commute ?? r1) as H1;
 101        alias symbol "trans" = "trans1".
 102        alias symbol "assoc" = "category1 assoc".
 103        apply (.= ASSOC);
 104        apply (.= #‡H1);
 105        alias symbol "invert" = "setoid1 symmetry".
 106        apply (.= ASSOC ^ -1);
 107        apply (.= H‡#);
 108        apply ASSOC]
 109   | intros;
 110     change with (⊩ ∘ (b\sub\c ∘ a\sub\c) = ⊩ ∘ (b'\sub\c ∘ a'\sub\c));
 111     change in e with (⊩ ∘ a \sub\c = ⊩ ∘ a' \sub\c);
 112     change in e1 with (⊩ ∘ b \sub\c = ⊩ ∘ b' \sub\c);
 113     apply (.= ASSOC);
 114     apply (.= #‡e1);
 115     apply (.= #‡(commute ?? b'));
 116     apply (.= ASSOC ^ -1);
 117     apply (.= e‡#);
 118     apply (.= ASSOC);
 119     apply (.= #‡(commute ?? b')\sup -1);
 120     apply (ASSOC ^ -1)]
 121 qed.
 122
 123 definition BP: category1.
 124  constructor 1;
 125   [ apply basic_pair
 126   | apply relation_pair_setoid
 127   | apply id_relation_pair
 128   | apply relation_pair_composition
 129   | intros;
 130     change with (⊩ ∘ (a34\sub\c ∘ (a23\sub\c ∘ a12\sub\c)) =
 131                  ⊩ ∘ ((a34\sub\c ∘ a23\sub\c) ∘ a12\sub\c));
 132     alias symbol "refl" = "refl1".
 133     alias symbol "prop2" = "prop21".
 134     apply (ASSOC‡#);
 135   | intros;
 136     change with (⊩ ∘ (a\sub\c ∘ (id_relation_pair o1)\sub\c) = ⊩ ∘ a\sub\c);
 137     apply ((id_neutral_right1 ????)‡#);
 138   | intros;
 139     change with (⊩ ∘ ((id_relation_pair o2)\sub\c ∘ a\sub\c) = ⊩ ∘ a\sub\c);
 140     apply ((id_neutral_left1 ????)‡#);]
 141 qed.
 142
 143 definition basic_pair_of_BP : objs1 BP → basic_pair ≝ λx.x.
 144 coercion basic_pair_of_BP.
 145
 146 definition relation_pair_setoid_of_arrows1_BP :
 147   ∀P,Q. arrows1 BP P Q → relation_pair_setoid P Q ≝ λP,Q,x.x.
 148 coercion relation_pair_setoid_of_arrows1_BP.
 149
 150 definition BPext: ∀o: BP. form o ⇒ Ω \sup (concr o).
 151  intros; constructor 1;
 152   [ apply (ext ? ? (rel o));
 153   | intros;
 154     apply (.= #‡e);
 155     apply refl1]
 156 qed.
 157
 158 definition BPextS: ∀o: BP. Ω \sup (form o) ⇒ Ω \sup (concr o).
 159  intros; constructor 1;
 160   [ apply (minus_image ?? (rel o));
 161   | intros; apply (#‡e); ]
 162 qed.
 163
 164 definition fintersects: ∀o: BP. binary_morphism1 (form o) (form o) (Ω \sup (form o)).
 165  intros (o); constructor 1;
 166   [ apply (λa,b: form o.{c | BPext o c ⊆ BPext o a ∩ BPext o b });
 167     intros; simplify; apply (.= (†e)‡#); apply refl1
 168   | intros; split; simplify; intros;
 169      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 170      | apply (. #‡((†e)‡(†e1))); assumption]]
 171 qed.
 172
 173 interpretation "fintersects" 'fintersects U V = (fun21 ___ (fintersects _) U V).
 174
 175 definition fintersectsS:
 176  ∀o:BP. binary_morphism1 (Ω \sup (form o)) (Ω \sup (form o)) (Ω \sup (form o)).
 177  intros (o); constructor 1;
 178   [ apply (λo: basic_pair.λa,b: Ω \sup (form o).{c | BPext o c ⊆ BPextS o a ∩ BPextS o b });
 179     intros; simplify; apply (.= (†e)‡#); apply refl1
 180   | intros; split; simplify; intros;
 181      [ apply (. #‡((†e^-1)‡(†e1^-1))); assumption
 182      | apply (. #‡((†e)‡(†e1))); assumption]]
 183 qed.
 184
 185 interpretation "fintersectsS" 'fintersects U V = (fun21 ___ (fintersectsS _) U V).
 186
 187 definition relS: ∀o: BP. binary_morphism1 (concr o) (Ω \sup (form o)) CPROP.
 188  intros (o); constructor 1;
 189   [ apply (λx:concr o.λS: Ω \sup (form o).∃y:form o.y ∈ S ∧ x ⊩_o y);
 190   | intros; split; intros; cases e2; exists [1,3: apply w]
 191      [ apply (. (#‡e1^-1)‡(e^-1‡#)); assumption
 192      | apply (. (#‡e1)‡(e‡#)); assumption]]
 193 qed.
 194
 195 interpretation "basic pair relation for subsets" 'Vdash2 x y c = (fun21 (concr _) __ (relS c) x y).
 196 interpretation "basic pair relation for subsets (non applied)" 'Vdash c = (fun21 ___ (relS c)).