helm/software/matita/contribs/formal_topology/overlap/categories.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "cprop_connectives.ma".
  16
  17 record equivalence_relation (A:Type0) : Type1 ≝
  18  { eq_rel:2> A → A → CProp0;
  19    refl: reflexive ? eq_rel;
  20    sym: symmetric ? eq_rel;
  21    trans: transitive ? eq_rel
  22  }.
  23
  24 record setoid : Type1 ≝
  25  { carr:> Type0;
  26    eq: equivalence_relation carr
  27  }.
  28
  29 definition reflexive1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λA:Type1.λR:A→A→CProp1.∀x:A.R x x.
  30 definition symmetric1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λC:Type1.λlt:C→C→CProp1. ∀x,y:C.lt x y → lt y x.
  31 definition transitive1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λA:Type1.λR:A→A→CProp1.∀x,y,z:A.R x y → R y z → R x z.
  32
  33 record equivalence_relation1 (A:Type1) : Type2 ≝
  34  { eq_rel1:2> A → A → CProp1;
  35    refl1: reflexive1 ? eq_rel1;
  36    sym1: symmetric1 ? eq_rel1;
  37    trans1: transitive1 ? eq_rel1
  38  }.
  39
  40 record setoid1: Type2 ≝
  41  { carr1:> Type1;
  42    eq1: equivalence_relation1 carr1
  43  }.
  44
  45 definition setoid1_of_setoid: setoid → setoid1.
  46  intro;
  47  constructor 1;
  48   [ apply (carr s)
  49   | constructor 1;
  50     [ apply (eq_rel s);
  51       apply (eq s)
  52     | apply (refl s)
  53     | apply (sym s)
  54     | apply (trans s)]]
  55 qed.
  56
  57 coercion setoid1_of_setoid.
  58
  59 definition reflexive2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λA:Type2.λR:A→A→CProp2.∀x:A.R x x.
  60 definition symmetric2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λC:Type2.λlt:C→C→CProp2. ∀x,y:C.lt x y → lt y x.
  61 definition transitive2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λA:Type2.λR:A→A→CProp2.∀x,y,z:A.R x y → R y z → R x z.
  62
  63 record equivalence_relation2 (A:Type2) : Type3 ≝
  64  { eq_rel2:2> A → A → CProp2;
  65    refl2: reflexive2 ? eq_rel2;
  66    sym2: symmetric2 ? eq_rel2;
  67    trans2: transitive2 ? eq_rel2
  68  }.
  69
  70 record setoid2: Type3 ≝
  71  { carr2:> Type2;
  72    eq2: equivalence_relation2 carr2
  73  }.
  74
  75 definition setoid2_of_setoid1: setoid1 → setoid2.
  76  intro;
  77  constructor 1;
  78   [ apply (carr1 s)
  79   | constructor 1;
  80     [ apply (eq_rel1 s);
  81       apply (eq1 s)
  82     | apply (refl1 s)
  83     | apply (sym1 s)
  84     | apply (trans1 s)]]
  85 qed.
  86
  87 coercion setoid2_of_setoid1.
  88
  89 interpretation "setoid2 eq" 'eq x y = (eq_rel2 _ (eq2 _) x y).
  90 interpretation "setoid1 eq" 'eq x y = (eq_rel1 _ (eq1 _) x y).
  91 interpretation "setoid eq" 'eq x y = (eq_rel _ (eq _) x y).
  92 interpretation "setoid2 symmetry" 'invert r = (sym2 ____ r).
  93 interpretation "setoid1 symmetry" 'invert r = (sym1 ____ r).
  94 interpretation "setoid symmetry" 'invert r = (sym ____ r).
  95 notation ".= r" with precedence 50 for @{'trans $r}.
  96 interpretation "trans2" 'trans r = (trans2 _____ r).
  97 interpretation "trans1" 'trans r = (trans1 _____ r).
  98 interpretation "trans" 'trans r = (trans _____ r).
  99
 100 record unary_morphism (A,B: setoid) : Type0 ≝
 101  { fun1:1> A → B;
 102    prop1: ∀a,a'. eq ? a a' → eq ? (fun1 a) (fun1 a')
 103  }.
 104
 105 record unary_morphism1 (A,B: setoid1) : Type1 ≝
 106  { fun11:1> A → B;
 107    prop11: ∀a,a'. eq1 ? a a' → eq1 ? (fun11 a) (fun11 a')
 108  }.
 109
 110 record unary_morphism2 (A,B: setoid2) : Type2 ≝
 111  { fun12:1> A → B;
 112    prop12: ∀a,a'. eq2 ? a a' → eq2 ? (fun12 a) (fun12 a')
 113  }.
 114
 115 record binary_morphism (A,B,C:setoid) : Type0 ≝
 116  { fun2:2> A → B → C;
 117    prop2: ∀a,a',b,b'. eq ? a a' → eq ? b b' → eq ? (fun2 a b) (fun2 a' b')
 118  }.
 119
 120 record binary_morphism1 (A,B,C:setoid1) : Type1 ≝
 121  { fun21:2> A → B → C;
 122    prop21: ∀a,a',b,b'. eq1 ? a a' → eq1 ? b b' → eq1 ? (fun21 a b) (fun21 a' b')
 123  }.
 124
 125 record binary_morphism2 (A,B,C:setoid2) : Type2 ≝
 126  { fun22:2> A → B → C;
 127    prop22: ∀a,a',b,b'. eq2 ? a a' → eq2 ? b b' → eq2 ? (fun22 a b) (fun22 a' b')
 128  }.
 129
 130 notation "† c" with precedence 90 for @{'prop1 $c }.
 131 notation "l ‡ r" with precedence 90 for @{'prop2 $l $r }.
 132 notation "#" with precedence 90 for @{'refl}.
 133 interpretation "prop1" 'prop1 c  = (prop1 _____ c).
 134 interpretation "prop11" 'prop1 c = (prop11 _____ c).
 135 interpretation "prop12" 'prop1 c = (prop12 _____ c).
 136 interpretation "prop2" 'prop2 l r = (prop2 ________ l r).
 137 interpretation "prop21" 'prop2 l r = (prop21 ________ l r).
 138 interpretation "prop22" 'prop2 l r = (prop22 ________ l r).
 139 interpretation "refl" 'refl = (refl ___).
 140 interpretation "refl1" 'refl = (refl1 ___).
 141 interpretation "refl2" 'refl = (refl2 ___).
 142
 143 definition CPROP: setoid1.
 144  constructor 1;
 145   [ apply CProp0
 146   | constructor 1;
 147      [ apply Iff
 148      | intros 1; split; intro; assumption
 149      | intros 3; cases i; split; assumption
 150      | intros 5; cases i; cases i1; split; intro;
 151         [ apply (f2 (f x1)) | apply (f1 (f3 z1))]]]
 152 qed.
 153
 154 alias symbol "eq" = "setoid1 eq".
 155 definition fi': ∀A,B:CPROP. A = B → B → A.
 156  intros; apply (fi ?? e); assumption.
 157 qed.
 158
 159 notation ". r" with precedence 50 for @{'fi $r}.
 160 interpretation "fi" 'fi r = (fi' __ r).
 161
 162 definition and_morphism: binary_morphism1 CPROP CPROP CPROP.
 163  constructor 1;
 164   [ apply And
 165   | intros; split; intro; cases a1; split;
 166      [ apply (if ?? e a2)
 167      | apply (if ?? e1 b1)
 168      | apply (fi ?? e a2)
 169      | apply (fi ?? e1 b1)]]
 170 qed.
 171
 172 interpretation "and_morphism" 'and a b = (fun21 ___ and_morphism a b).
 173
 174 definition or_morphism: binary_morphism1 CPROP CPROP CPROP.
 175  constructor 1;
 176   [ apply Or
 177   | intros; split; intro; cases o; [1,3:left |2,4: right]
 178      [ apply (if ?? e a1)
 179      | apply (fi ?? e a1)
 180      | apply (if ?? e1 b1)
 181      | apply (fi ?? e1 b1)]]
 182 qed.
 183
 184 interpretation "or_morphism" 'or a b = (fun21 ___ or_morphism a b).
 185
 186 definition if_morphism: binary_morphism1 CPROP CPROP CPROP.
 187  constructor 1;
 188   [ apply (λA,B. A → B)
 189   | intros; split; intros;
 190      [ apply (if ?? e1); apply f; apply (fi ?? e); assumption
 191      | apply (fi ?? e1); apply f; apply (if ?? e); assumption]]
 192 qed.
 193
 194 record category : Type1 ≝
 195  { objs:> Type0;
 196    arrows: objs → objs → setoid;
 197    id: ∀o:objs. arrows o o;
 198    comp: ∀o1,o2,o3. binary_morphism1 (arrows o1 o2) (arrows o2 o3) (arrows o1 o3);
 199    comp_assoc: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 200     comp o1 o3 o4 (comp o1 o2 o3 a12 a23) a34 = comp o1 o2 o4 a12 (comp o2 o3 o4 a23 a34);
 201    id_neutral_left: ∀o1,o2. ∀a: arrows o1 o2. comp ??? (id o1) a = a;
 202    id_neutral_right: ∀o1,o2. ∀a: arrows o1 o2. comp ??? a (id o2) = a
 203  }.
 204
 205 record category1 : Type2 ≝
 206  { objs1:> Type1;
 207    arrows1: objs1 → objs1 → setoid1;
 208    id1: ∀o:objs1. arrows1 o o;
 209    comp1: ∀o1,o2,o3. binary_morphism1 (arrows1 o1 o2) (arrows1 o2 o3) (arrows1 o1 o3);
 210    comp_assoc1: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 211     comp1 o1 o3 o4 (comp1 o1 o2 o3 a12 a23) a34 = comp1 o1 o2 o4 a12 (comp1 o2 o3 o4 a23 a34);
 212    id_neutral_right1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? (id1 o1) a = a;
 213    id_neutral_left1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? a (id1 o2) = a
 214  }.
 215
 216 record category2 : Type3 ≝
 217  { objs2:> Type2;
 218    arrows2: objs2 → objs2 → setoid2;
 219    id2: ∀o:objs2. arrows2 o o;
 220    comp2: ∀o1,o2,o3. binary_morphism2 (arrows2 o1 o2) (arrows2 o2 o3) (arrows2 o1 o3);
 221    comp_assoc2: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 222     comp2 o1 o3 o4 (comp2 o1 o2 o3 a12 a23) a34 = comp2 o1 o2 o4 a12 (comp2 o2 o3 o4 a23 a34);
 223    id_neutral_right2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? (id2 o1) a = a;
 224    id_neutral_left2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? a (id2 o2) = a
 225  }.
 226
 227 notation "'ASSOC'" with precedence 90 for @{'assoc}.
 228
 229 interpretation "category2 composition" 'compose x y = (fun22 ___ (comp2 ____) y x).
 230 interpretation "category2 assoc" 'assoc = (comp_assoc2 ________).
 231 interpretation "category1 composition" 'compose x y = (fun21 ___ (comp1 ____) y x).
 232 interpretation "category1 assoc" 'assoc = (comp_assoc1 ________).
 233 interpretation "category composition" 'compose x y = (fun2 ___ (comp ____) y x).
 234 interpretation "category assoc" 'assoc = (comp_assoc ________).
 235
 236 definition unary_morphism_setoid: setoid → setoid → setoid.
 237  intros;
 238  constructor 1;
 239   [ apply (unary_morphism s s1);
 240   | constructor 1;
 241      [ intros (f g); apply (∀a:s. eq ? (f a) (g a));
 242      | intros 1; simplify; intros; apply refl;
 243      | simplify; intros; apply sym; apply f;
 244      | simplify; intros; apply trans; [2: apply f; | skip | apply f1]]]
 245 qed.
 246
 247 definition SET: category1.
 248  constructor 1;
 249   [ apply setoid;
 250   | apply rule (λS,T:setoid.unary_morphism_setoid S T);
 251   | intros; constructor 1; [ apply (λx:carr o.x); | intros; assumption ]
 252   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. t1 (t x)); | intros;
 253      apply († (†e));]
 254   | intros; whd; intros; simplify; whd in H1; whd in H;
 255     apply trans; [ apply (b (a' a1)); | lapply (prop1 ?? b (a a1) (a' a1));
 256      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 257   | intros; whd; intros; simplify; apply refl;
 258   | intros; simplify; whd; intros; simplify; apply refl;
 259   | intros; simplify; whd; intros; simplify; apply refl;
 260   ]
 261 qed.
 262
 263 definition setoid_of_SET: objs1 SET → setoid.
 264  intros; apply o; qed.
 265 coercion setoid_of_SET.
 266
 267 notation "hbox(a break ⇒ b)" right associative with precedence 20 for @{ 'Imply $a $b }.
 268 interpretation "unary morphism" 'Imply a b = (arrows1 SET a b).
 269
 270 definition unary_morphism1_setoid1: setoid1 → setoid1 → setoid1.
 271  intros;
 272  constructor 1;
 273   [ apply (unary_morphism1 s s1);
 274   | constructor 1;
 275      [ intros (f g);
 276        alias symbol "eq" = "setoid1 eq".
 277        apply (∀a: carr1 s. f a = g a);
 278      | intros 1; simplify; intros; apply refl1;
 279      | simplify; intros; apply sym1; apply f;
 280      | simplify; intros; apply trans1; [2: apply f; | skip | apply f1]]]
 281 qed.
 282
 283 definition SET1: category2.
 284  constructor 1;
 285   [ apply setoid1;
 286   | apply rule (λS,T.unary_morphism1_setoid1 S T);
 287   | intros; constructor 1; [ apply (λx.x); | intros; assumption ]
 288   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. t1 (t x)); | intros;
 289      apply († (†e));]
 290   | intros; whd; intros; simplify; whd in H1; whd in H;
 291     apply trans1; [ apply (b (a' a1)); | lapply (prop11 ?? b (a a1) (a' a1));
 292      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 293   | intros; whd; intros; simplify; apply refl1;
 294   | intros; simplify; whd; intros; simplify; apply refl1;
 295   | intros; simplify; whd; intros; simplify; apply refl1;
 296   ]
 297 qed.
 298
 299 definition setoid1_OF_SET1: objs2 SET1 → setoid1.
 300  intros; apply o; qed.
 301
 302 coercion setoid1_OF_SET1.
 303
 304 definition setoid2_OF_category2: Type_OF_category2 SET1 → setoid2.
 305  intro; apply (setoid2_of_setoid1 t); qed.
 306 coercion setoid2_OF_category2.
 307
 308 definition objs2_OF_category1: Type_OF_category1 SET → objs2 SET1.
 309  intro; apply (setoid1_of_setoid t); qed.
 310 coercion objs2_OF_category1.
 311
 312 definition Type1_OF_SET1: Type_OF_category2 SET1 → Type1.
 313  intro; whd in t; apply (carr1 t);
 314 qed.
 315 coercion Type1_OF_SET1.
 316
 317 definition Type_OF_setoid1_of_carr: ∀U. carr U → Type_OF_setoid1 ?(*(setoid1_of_SET U)*).
 318  [ apply rule U;
 319  | intros; apply c;]
 320 qed.
 321 coercion Type_OF_setoid1_of_carr.
 322
 323 interpretation "unary morphism1" 'Imply a b = (arrows2 SET1 a b).
 324
 325 lemma unary_morphism1_of_arrows1_SET1: ∀S,T. (S ⇒ T) → unary_morphism1 S T.
 326  intros; apply t;
 327 qed.
 328 coercion unary_morphism1_of_arrows1_SET1.