helm/software/matita/contribs/formal_topology/overlap/categories.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "cprop_connectives.ma".
  16
  17 record equivalence_relation (A:Type0) : Type1 ≝
  18  { eq_rel:2> A → A → CProp0;
  19    refl: reflexive ? eq_rel;
  20    sym: symmetric ? eq_rel;
  21    trans: transitive ? eq_rel
  22  }.
  23
  24 record setoid : Type1 ≝
  25  { carr:> Type0;
  26    eq: equivalence_relation carr
  27  }.
  28
  29 definition reflexive1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λA:Type1.λR:A→A→CProp1.∀x:A.R x x.
  30 definition symmetric1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λC:Type1.λlt:C→C→CProp1. ∀x,y:C.lt x y → lt y x.
  31 definition transitive1: ∀A:Type1.∀R:A→A→CProp1.CProp1 ≝ λA:Type1.λR:A→A→CProp1.∀x,y,z:A.R x y → R y z → R x z.
  32
  33 record equivalence_relation1 (A:Type1) : Type2 ≝
  34  { eq_rel1:2> A → A → CProp1;
  35    refl1: reflexive1 ? eq_rel1;
  36    sym1: symmetric1 ? eq_rel1;
  37    trans1: transitive1 ? eq_rel1
  38  }.
  39
  40 record setoid1: Type2 ≝
  41  { carr1:> Type1;
  42    eq1: equivalence_relation1 carr1
  43  }.
  44
  45 definition setoid1_of_setoid: setoid → setoid1.
  46  intro;
  47  constructor 1;
  48   [ apply (carr s)
  49   | constructor 1;
  50     [ apply (eq_rel s);
  51       apply (eq s)
  52     | apply (refl s)
  53     | apply (sym s)
  54     | apply (trans s)]]
  55 qed.
  56
  57 coercion setoid1_of_setoid.
  58 prefer coercion Type_OF_setoid.
  59
  60 definition reflexive2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λA:Type2.λR:A→A→CProp2.∀x:A.R x x.
  61 definition symmetric2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λC:Type2.λlt:C→C→CProp2. ∀x,y:C.lt x y → lt y x.
  62 definition transitive2: ∀A:Type2.∀R:A→A→CProp2.CProp2 ≝ λA:Type2.λR:A→A→CProp2.∀x,y,z:A.R x y → R y z → R x z.
  63
  64 record equivalence_relation2 (A:Type2) : Type3 ≝
  65  { eq_rel2:2> A → A → CProp2;
  66    refl2: reflexive2 ? eq_rel2;
  67    sym2: symmetric2 ? eq_rel2;
  68    trans2: transitive2 ? eq_rel2
  69  }.
  70
  71 record setoid2: Type3 ≝
  72  { carr2:> Type2;
  73    eq2: equivalence_relation2 carr2
  74  }.
  75
  76 definition setoid2_of_setoid1: setoid1 → setoid2.
  77  intro;
  78  constructor 1;
  79   [ apply (carr1 s)
  80   | constructor 1;
  81     [ apply (eq_rel1 s);
  82       apply (eq1 s)
  83     | apply (refl1 s)
  84     | apply (sym1 s)
  85     | apply (trans1 s)]]
  86 qed.
  87
  88 coercion setoid2_of_setoid1.
  89 prefer coercion Type_OF_setoid2.
  90 prefer coercion Type_OF_setoid.
  91 prefer coercion Type_OF_setoid1.
  92 (* we prefer 0 < 1 < 2 *)
  93
  94 interpretation "setoid2 eq" 'eq x y = (eq_rel2 _ (eq2 _) x y).
  95 interpretation "setoid1 eq" 'eq x y = (eq_rel1 _ (eq1 _) x y).
  96 interpretation "setoid eq" 'eq x y = (eq_rel _ (eq _) x y).
  97 interpretation "setoid2 symmetry" 'invert r = (sym2 ____ r).
  98 interpretation "setoid1 symmetry" 'invert r = (sym1 ____ r).
  99 interpretation "setoid symmetry" 'invert r = (sym ____ r).
 100 notation ".= r" with precedence 50 for @{'trans $r}.
 101 interpretation "trans2" 'trans r = (trans2 _____ r).
 102 interpretation "trans1" 'trans r = (trans1 _____ r).
 103 interpretation "trans" 'trans r = (trans _____ r).
 104
 105 record unary_morphism (A,B: setoid) : Type0 ≝
 106  { fun1:1> A → B;
 107    prop1: ∀a,a'. eq ? a a' → eq ? (fun1 a) (fun1 a')
 108  }.
 109
 110 record unary_morphism1 (A,B: setoid1) : Type1 ≝
 111  { fun11:1> A → B;
 112    prop11: ∀a,a'. eq1 ? a a' → eq1 ? (fun11 a) (fun11 a')
 113  }.
 114
 115 record unary_morphism2 (A,B: setoid2) : Type2 ≝
 116  { fun12:1> A → B;
 117    prop12: ∀a,a'. eq2 ? a a' → eq2 ? (fun12 a) (fun12 a')
 118  }.
 119
 120 record binary_morphism (A,B,C:setoid) : Type0 ≝
 121  { fun2:2> A → B → C;
 122    prop2: ∀a,a',b,b'. eq ? a a' → eq ? b b' → eq ? (fun2 a b) (fun2 a' b')
 123  }.
 124
 125 record binary_morphism1 (A,B,C:setoid1) : Type1 ≝
 126  { fun21:2> A → B → C;
 127    prop21: ∀a,a',b,b'. eq1 ? a a' → eq1 ? b b' → eq1 ? (fun21 a b) (fun21 a' b')
 128  }.
 129
 130 record binary_morphism2 (A,B,C:setoid2) : Type2 ≝
 131  { fun22:2> A → B → C;
 132    prop22: ∀a,a',b,b'. eq2 ? a a' → eq2 ? b b' → eq2 ? (fun22 a b) (fun22 a' b')
 133  }.
 134
 135 notation "† c" with precedence 90 for @{'prop1 $c }.
 136 notation "l ‡ r" with precedence 90 for @{'prop2 $l $r }.
 137 notation "#" with precedence 90 for @{'refl}.
 138 interpretation "prop1" 'prop1 c  = (prop1 _____ c).
 139 interpretation "prop11" 'prop1 c = (prop11 _____ c).
 140 interpretation "prop12" 'prop1 c = (prop12 _____ c).
 141 interpretation "prop2" 'prop2 l r = (prop2 ________ l r).
 142 interpretation "prop21" 'prop2 l r = (prop21 ________ l r).
 143 interpretation "prop22" 'prop2 l r = (prop22 ________ l r).
 144 interpretation "refl" 'refl = (refl ___).
 145 interpretation "refl1" 'refl = (refl1 ___).
 146 interpretation "refl2" 'refl = (refl2 ___).
 147
 148 definition CPROP: setoid1.
 149  constructor 1;
 150   [ apply CProp0
 151   | constructor 1;
 152      [ apply Iff
 153      | intros 1; split; intro; assumption
 154      | intros 3; cases i; split; assumption
 155      | intros 5; cases i; cases i1; split; intro;
 156         [ apply (f2 (f x1)) | apply (f1 (f3 z1))]]]
 157 qed.
 158
 159 alias symbol "eq" = "setoid1 eq".
 160 definition fi': ∀A,B:CPROP. A = B → B → A.
 161  intros; apply (fi ?? e); assumption.
 162 qed.
 163
 164 notation ". r" with precedence 50 for @{'fi $r}.
 165 interpretation "fi" 'fi r = (fi' __ r).
 166
 167 definition and_morphism: binary_morphism1 CPROP CPROP CPROP.
 168  constructor 1;
 169   [ apply And
 170   | intros; split; intro; cases a1; split;
 171      [ apply (if ?? e a2)
 172      | apply (if ?? e1 b1)
 173      | apply (fi ?? e a2)
 174      | apply (fi ?? e1 b1)]]
 175 qed.
 176
 177 interpretation "and_morphism" 'and a b = (fun21 ___ and_morphism a b).
 178
 179 definition or_morphism: binary_morphism1 CPROP CPROP CPROP.
 180  constructor 1;
 181   [ apply Or
 182   | intros; split; intro; cases o; [1,3:left |2,4: right]
 183      [ apply (if ?? e a1)
 184      | apply (fi ?? e a1)
 185      | apply (if ?? e1 b1)
 186      | apply (fi ?? e1 b1)]]
 187 qed.
 188
 189 interpretation "or_morphism" 'or a b = (fun21 ___ or_morphism a b).
 190
 191 definition if_morphism: binary_morphism1 CPROP CPROP CPROP.
 192  constructor 1;
 193   [ apply (λA,B. A → B)
 194   | intros; split; intros;
 195      [ apply (if ?? e1); apply f; apply (fi ?? e); assumption
 196      | apply (fi ?? e1); apply f; apply (if ?? e); assumption]]
 197 qed.
 198
 199 record category : Type1 ≝
 200  { objs:> Type0;
 201    arrows: objs → objs → setoid;
 202    id: ∀o:objs. arrows o o;
 203    comp: ∀o1,o2,o3. binary_morphism1 (arrows o1 o2) (arrows o2 o3) (arrows o1 o3);
 204    comp_assoc: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 205     comp o1 o3 o4 (comp o1 o2 o3 a12 a23) a34 = comp o1 o2 o4 a12 (comp o2 o3 o4 a23 a34);
 206    id_neutral_left: ∀o1,o2. ∀a: arrows o1 o2. comp ??? (id o1) a = a;
 207    id_neutral_right: ∀o1,o2. ∀a: arrows o1 o2. comp ??? a (id o2) = a
 208  }.
 209
 210 record category1 : Type2 ≝
 211  { objs1:> Type1;
 212    arrows1: objs1 → objs1 → setoid1;
 213    id1: ∀o:objs1. arrows1 o o;
 214    comp1: ∀o1,o2,o3. binary_morphism1 (arrows1 o1 o2) (arrows1 o2 o3) (arrows1 o1 o3);
 215    comp_assoc1: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 216     comp1 o1 o3 o4 (comp1 o1 o2 o3 a12 a23) a34 = comp1 o1 o2 o4 a12 (comp1 o2 o3 o4 a23 a34);
 217    id_neutral_right1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? (id1 o1) a = a;
 218    id_neutral_left1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? a (id1 o2) = a
 219  }.
 220
 221 record category2 : Type3 ≝
 222  { objs2:> Type2;
 223    arrows2: objs2 → objs2 → setoid2;
 224    id2: ∀o:objs2. arrows2 o o;
 225    comp2: ∀o1,o2,o3. binary_morphism2 (arrows2 o1 o2) (arrows2 o2 o3) (arrows2 o1 o3);
 226    comp_assoc2: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 227     comp2 o1 o3 o4 (comp2 o1 o2 o3 a12 a23) a34 = comp2 o1 o2 o4 a12 (comp2 o2 o3 o4 a23 a34);
 228    id_neutral_right2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? (id2 o1) a = a;
 229    id_neutral_left2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? a (id2 o2) = a
 230  }.
 231
 232 notation "'ASSOC'" with precedence 90 for @{'assoc}.
 233
 234 interpretation "category2 composition" 'compose x y = (fun22 ___ (comp2 ____) y x).
 235 interpretation "category2 assoc" 'assoc = (comp_assoc2 ________).
 236 interpretation "category1 composition" 'compose x y = (fun21 ___ (comp1 ____) y x).
 237 interpretation "category1 assoc" 'assoc = (comp_assoc1 ________).
 238 interpretation "category composition" 'compose x y = (fun2 ___ (comp ____) y x).
 239 interpretation "category assoc" 'assoc = (comp_assoc ________).
 240
 241 definition unary_morphism_setoid: setoid → setoid → setoid.
 242  intros;
 243  constructor 1;
 244   [ apply (unary_morphism s s1);
 245   | constructor 1;
 246      [ intros (f g); apply (∀a:s. eq ? (f a) (g a));
 247      | intros 1; simplify; intros; apply refl;
 248      | simplify; intros; apply sym; apply f;
 249      | simplify; intros; apply trans; [2: apply f; | skip | apply f1]]]
 250 qed.
 251
 252 definition SET: category1.
 253  constructor 1;
 254   [ apply setoid;
 255   | apply rule (λS,T:setoid.unary_morphism_setoid S T);
 256   | intros; constructor 1; [ apply (λx:carr o.x); | intros; assumption ]
 257   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. t1 (t x)); | intros;
 258      apply († (†e));]
 259   | intros; whd; intros; simplify; whd in H1; whd in H;
 260     apply trans; [ apply (b (a' a1)); | lapply (prop1 ?? b (a a1) (a' a1));
 261      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 262   | intros; whd; intros; simplify; apply refl;
 263   | intros; simplify; whd; intros; simplify; apply refl;
 264   | intros; simplify; whd; intros; simplify; apply refl;
 265   ]
 266 qed.
 267
 268 definition setoid_of_SET: objs1 SET → setoid.
 269  intros; apply o; qed.
 270 coercion setoid_of_SET.
 271
 272 notation "hbox(a break ⇒ b)" right associative with precedence 20 for @{ 'Imply $a $b }.
 273 interpretation "unary morphism" 'Imply a b = (arrows1 SET a b).
 274
 275 definition unary_morphism1_setoid1: setoid1 → setoid1 → setoid1.
 276  intros;
 277  constructor 1;
 278   [ apply (unary_morphism1 s s1);
 279   | constructor 1;
 280      [ intros (f g);
 281        alias symbol "eq" = "setoid1 eq".
 282        apply (∀a: carr1 s. f a = g a);
 283      | intros 1; simplify; intros; apply refl1;
 284      | simplify; intros; apply sym1; apply f;
 285      | simplify; intros; apply trans1; [2: apply f; | skip | apply f1]]]
 286 qed.
 287
 288 definition SET1: category2.
 289  constructor 1;
 290   [ apply setoid1;
 291   | apply rule (λS,T.unary_morphism1_setoid1 S T);
 292   | intros; constructor 1; [ apply (λx.x); | intros; assumption ]
 293   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. t1 (t x)); | intros;
 294      apply († (†e));]
 295   | intros; whd; intros; simplify; whd in H1; whd in H;
 296     apply trans1; [ apply (b (a' a1)); | lapply (prop11 ?? b (a a1) (a' a1));
 297      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 298   | intros; whd; intros; simplify; apply refl1;
 299   | intros; simplify; whd; intros; simplify; apply refl1;
 300   | intros; simplify; whd; intros; simplify; apply refl1;
 301   ]
 302 qed.
 303
 304 definition setoid1_OF_SET1: objs2 SET1 → setoid1.
 305  intros; apply o; qed.
 306
 307 coercion setoid1_OF_SET1.
 308
 309 definition setoid2_OF_category2: Type_OF_category2 SET1 → setoid2.
 310  intro; apply (setoid2_of_setoid1 t); qed.
 311 coercion setoid2_OF_category2.
 312
 313 definition objs2_OF_category1: Type_OF_category1 SET → objs2 SET1.
 314  intro; apply (setoid1_of_setoid t); qed.
 315 coercion objs2_OF_category1.
 316
 317 definition Type1_OF_SET1: Type_OF_category2 SET1 → Type1.
 318  intro; whd in t; apply (carr1 t);
 319 qed.
 320 coercion Type1_OF_SET1.
 321
 322 definition Type_OF_setoid1_of_carr: ∀U. carr U → Type_OF_setoid1 ?(*(setoid1_of_SET U)*).
 323  [ apply rule U;
 324  | intros; apply c;]
 325 qed.
 326 coercion Type_OF_setoid1_of_carr.
 327
 328 definition carr' ≝ λx:Type_OF_category1 SET.Type_OF_Type0 (carr x).
 329 coercion carr'. (* we prefer the lower carrier projection *)
 330
 331 interpretation "unary morphism1" 'Imply a b = (arrows2 SET1 a b).
 332
 333 lemma unary_morphism1_of_arrows1_SET1: ∀S,T. (S ⇒ T) → unary_morphism1 S T.
 334  intros; apply t;
 335 qed.
 336 coercion unary_morphism1_of_arrows1_SET1.