helm/software/matita/contribs/formal_topology/overlap/categories.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "cprop_connectives.ma".
  16
  17 notation "hvbox(a break = \sub \ID b)" non associative with precedence 45
  18 for @{ 'eqID $a $b }.
  19
  20 notation > "hvbox(a break =_\ID b)" non associative with precedence 45
  21 for @{ cic:/matita/logic/equality/eq.ind#xpointer(1/1) ? $a $b }.
  22
  23 interpretation "ID eq" 'eqID x y = (cic:/matita/logic/equality/eq.ind#xpointer(1/1) ? x y).
  24
  25 record equivalence_relation (A:Type0) : Type1 ≝
  26  { eq_rel:2> A → A → CProp0;
  27    refl: reflexive ? eq_rel;
  28    sym: symmetric ? eq_rel;
  29    trans: transitive ? eq_rel
  30  }.
  31
  32 record setoid : Type1 ≝
  33  { carr:> Type0;
  34    eq: equivalence_relation carr
  35  }.
  36
  37 record equivalence_relation1 (A:Type1) : Type2 ≝
  38  { eq_rel1:2> A → A → CProp1;
  39    refl1: reflexive1 ? eq_rel1;
  40    sym1: symmetric1 ? eq_rel1;
  41    trans1: transitive1 ? eq_rel1
  42  }.
  43
  44 record setoid1: Type2 ≝
  45  { carr1:> Type1;
  46    eq1: equivalence_relation1 carr1
  47  }.
  48
  49 definition setoid1_of_setoid: setoid → setoid1.
  50  intro;
  51  constructor 1;
  52   [ apply (carr s)
  53   | constructor 1;
  54     [ apply (eq_rel s);
  55       apply (eq s)
  56     | apply (refl s)
  57     | apply (sym s)
  58     | apply (trans s)]]
  59 qed.
  60
  61 coercion setoid1_of_setoid.
  62 prefer coercion Type_OF_setoid.
  63
  64 record equivalence_relation2 (A:Type2) : Type3 ≝
  65  { eq_rel2:2> A → A → CProp2;
  66    refl2: reflexive2 ? eq_rel2;
  67    sym2: symmetric2 ? eq_rel2;
  68    trans2: transitive2 ? eq_rel2
  69  }.
  70
  71 record setoid2: Type3 ≝
  72  { carr2:> Type2;
  73    eq2: equivalence_relation2 carr2
  74  }.
  75
  76 definition setoid2_of_setoid1: setoid1 → setoid2.
  77  intro;
  78  constructor 1;
  79   [ apply (carr1 s)
  80   | constructor 1;
  81     [ apply (eq_rel1 s);
  82       apply (eq1 s)
  83     | apply (refl1 s)
  84     | apply (sym1 s)
  85     | apply (trans1 s)]]
  86 qed.
  87
  88 coercion setoid2_of_setoid1.
  89 prefer coercion Type_OF_setoid2.
  90 prefer coercion Type_OF_setoid.
  91 prefer coercion Type_OF_setoid1.
  92 (* we prefer 0 < 1 < 2 *)
  93
  94 record equivalence_relation3 (A:Type3) : Type4 ≝
  95  { eq_rel3:2> A → A → CProp3;
  96    refl3: reflexive3 ? eq_rel3;
  97    sym3: symmetric3 ? eq_rel3;
  98    trans3: transitive3 ? eq_rel3
  99  }.
 100
 101 record setoid3: Type4 ≝
 102  { carr3:> Type3;
 103    eq3: equivalence_relation3 carr3
 104  }.
 105
 106 interpretation "setoid3 eq" 'eq t x y = (eq_rel3 ? (eq3 t) x y).
 107 interpretation "setoid2 eq" 'eq t x y = (eq_rel2 ? (eq2 t) x y).
 108 interpretation "setoid1 eq" 'eq t x y = (eq_rel1 ? (eq1 t) x y).
 109 interpretation "setoid eq" 'eq t x y = (eq_rel ? (eq t) x y).
 110
 111 notation > "hvbox(a break =_12 b)" non associative with precedence 45
 112 for @{ eq_rel2 (carr2 (setoid2_of_setoid1 ?)) (eq2 (setoid2_of_setoid1 ?)) $a $b }.
 113 notation > "hvbox(a break =_0 b)" non associative with precedence 45
 114 for @{ eq_rel ? (eq ?) $a $b }.
 115 notation > "hvbox(a break =_1 b)" non associative with precedence 45
 116 for @{ eq_rel1 ? (eq1 ?) $a $b }.
 117 notation > "hvbox(a break =_2 b)" non associative with precedence 45
 118 for @{ eq_rel2 ? (eq2 ?) $a $b }.
 119 notation > "hvbox(a break =_3 b)" non associative with precedence 45
 120 for @{ eq_rel3 ? (eq3 ?) $a $b }.
 121
 122 interpretation "setoid3 symmetry" 'invert r = (sym3 ???? r).
 123 interpretation "setoid2 symmetry" 'invert r = (sym2 ???? r).
 124 interpretation "setoid1 symmetry" 'invert r = (sym1 ???? r).
 125 interpretation "setoid symmetry" 'invert r = (sym ???? r).
 126 notation ".= r" with precedence 50 for @{'trans $r}.
 127 interpretation "trans3" 'trans r = (trans3 ????? r).
 128 interpretation "trans2" 'trans r = (trans2 ????? r).
 129 interpretation "trans1" 'trans r = (trans1 ????? r).
 130 interpretation "trans" 'trans r = (trans ????? r).
 131
 132 record unary_morphism (A,B: setoid) : Type0 ≝
 133  { fun1:1> A → B;
 134    prop1: ∀a,a'. eq ? a a' → eq ? (fun1 a) (fun1 a')
 135  }.
 136
 137 record unary_morphism1 (A,B: setoid1) : Type1 ≝
 138  { fun11:1> A → B;
 139    prop11: ∀a,a'. eq1 ? a a' → eq1 ? (fun11 a) (fun11 a')
 140  }.
 141
 142 record unary_morphism2 (A,B: setoid2) : Type2 ≝
 143  { fun12:1> A → B;
 144    prop12: ∀a,a'. eq2 ? a a' → eq2 ? (fun12 a) (fun12 a')
 145  }.
 146
 147 record unary_morphism3 (A,B: setoid3) : Type3 ≝
 148  { fun13:1> A → B;
 149    prop13: ∀a,a'. eq3 ? a a' → eq3 ? (fun13 a) (fun13 a')
 150  }.
 151
 152 record binary_morphism (A,B,C:setoid) : Type0 ≝
 153  { fun2:2> A → B → C;
 154    prop2: ∀a,a',b,b'. eq ? a a' → eq ? b b' → eq ? (fun2 a b) (fun2 a' b')
 155  }.
 156
 157 record binary_morphism1 (A,B,C:setoid1) : Type1 ≝
 158  { fun21:2> A → B → C;
 159    prop21: ∀a,a',b,b'. eq1 ? a a' → eq1 ? b b' → eq1 ? (fun21 a b) (fun21 a' b')
 160  }.
 161
 162 record binary_morphism2 (A,B,C:setoid2) : Type2 ≝
 163  { fun22:2> A → B → C;
 164    prop22: ∀a,a',b,b'. eq2 ? a a' → eq2 ? b b' → eq2 ? (fun22 a b) (fun22 a' b')
 165  }.
 166
 167 record binary_morphism3 (A,B,C:setoid3) : Type3 ≝
 168  { fun23:2> A → B → C;
 169    prop23: ∀a,a',b,b'. eq3 ? a a' → eq3 ? b b' → eq3 ? (fun23 a b) (fun23 a' b')
 170  }.
 171
 172 notation "† c" with precedence 90 for @{'prop1 $c }.
 173 notation "l ‡ r" with precedence 90 for @{'prop2 $l $r }.
 174 notation "#" with precedence 90 for @{'refl}.
 175 interpretation "prop1" 'prop1 c  = (prop1 ????? c).
 176 interpretation "prop11" 'prop1 c = (prop11 ????? c).
 177 interpretation "prop12" 'prop1 c = (prop12 ????? c).
 178 interpretation "prop13" 'prop1 c = (prop13 ????? c).
 179 interpretation "prop2" 'prop2 l r = (prop2 ???????? l r).
 180 interpretation "prop21" 'prop2 l r = (prop21 ???????? l r).
 181 interpretation "prop22" 'prop2 l r = (prop22 ???????? l r).
 182 interpretation "prop23" 'prop2 l r = (prop23 ???????? l r).
 183 interpretation "refl" 'refl = (refl ???).
 184 interpretation "refl1" 'refl = (refl1 ???).
 185 interpretation "refl2" 'refl = (refl2 ???).
 186 interpretation "refl3" 'refl = (refl3 ???).
 187
 188 definition unary_morphism2_of_unary_morphism1:
 189   ∀S,T:setoid1.unary_morphism1 S T → unary_morphism2 (setoid2_of_setoid1 S) T.
 190  intros;
 191  constructor 1;
 192   [ apply (fun11 ?? u);
 193   | apply (prop11 ?? u); ]
 194 qed.
 195
 196 definition CPROP: setoid1.
 197  constructor 1;
 198   [ apply CProp0
 199   | constructor 1;
 200      [ apply Iff
 201      | intros 1; split; intro; assumption
 202      | intros 3; cases i; split; assumption
 203      | intros 5; cases i; cases i1; split; intro;
 204         [ apply (f2 (f x1)) | apply (f1 (f3 z1))]]]
 205 qed.
 206
 207 definition CProp0_of_CPROP: carr1 CPROP → CProp0 ≝ λx.x.
 208 coercion CProp0_of_CPROP.
 209
 210 alias symbol "eq" = "setoid1 eq".
 211 definition fi': ∀A,B:CPROP. A = B → B → A.
 212  intros; apply (fi ?? e); assumption.
 213 qed.
 214
 215 notation ". r" with precedence 50 for @{'fi $r}.
 216 interpretation "fi" 'fi r = (fi' ?? r).
 217
 218 definition and_morphism: binary_morphism1 CPROP CPROP CPROP.
 219  constructor 1;
 220   [ apply And
 221   | intros; split; intro; cases a1; split;
 222      [ apply (if ?? e a2)
 223      | apply (if ?? e1 b1)
 224      | apply (fi ?? e a2)
 225      | apply (fi ?? e1 b1)]]
 226 qed.
 227
 228 interpretation "and_morphism" 'and a b = (fun21 ??? and_morphism a b).
 229
 230 definition or_morphism: binary_morphism1 CPROP CPROP CPROP.
 231  constructor 1;
 232   [ apply Or
 233   | intros; split; intro; cases o; [1,3:left |2,4: right]
 234      [ apply (if ?? e a1)
 235      | apply (fi ?? e a1)
 236      | apply (if ?? e1 b1)
 237      | apply (fi ?? e1 b1)]]
 238 qed.
 239
 240 interpretation "or_morphism" 'or a b = (fun21 ??? or_morphism a b).
 241
 242 definition if_morphism: binary_morphism1 CPROP CPROP CPROP.
 243  constructor 1;
 244   [ apply (λA,B. A → B)
 245   | intros; split; intros;
 246      [ apply (if ?? e1); apply f; apply (fi ?? e); assumption
 247      | apply (fi ?? e1); apply f; apply (if ?? e); assumption]]
 248 qed.
 249
 250
 251 record category : Type1 ≝
 252  { objs:> Type0;
 253    arrows: objs → objs → setoid;
 254    id: ∀o:objs. arrows o o;
 255    comp: ∀o1,o2,o3. binary_morphism (arrows o1 o2) (arrows o2 o3) (arrows o1 o3);
 256    comp_assoc: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 257     comp o1 o3 o4 (comp o1 o2 o3 a12 a23) a34 = comp o1 o2 o4 a12 (comp o2 o3 o4 a23 a34);
 258    id_neutral_left: ∀o1,o2. ∀a: arrows o1 o2. comp ??? (id o1) a = a;
 259    id_neutral_right: ∀o1,o2. ∀a: arrows o1 o2. comp ??? a (id o2) = a
 260  }.
 261
 262 record category1 : Type2 ≝
 263  { objs1:> Type1;
 264    arrows1: objs1 → objs1 → setoid1;
 265    id1: ∀o:objs1. arrows1 o o;
 266    comp1: ∀o1,o2,o3. binary_morphism1 (arrows1 o1 o2) (arrows1 o2 o3) (arrows1 o1 o3);
 267    comp_assoc1: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 268     comp1 o1 o3 o4 (comp1 o1 o2 o3 a12 a23) a34 = comp1 o1 o2 o4 a12 (comp1 o2 o3 o4 a23 a34);
 269    id_neutral_right1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? (id1 o1) a = a;
 270    id_neutral_left1: ∀o1,o2. ∀a: arrows1 o1 o2. comp1 ??? a (id1 o2) = a
 271  }.
 272
 273 record category2 : Type3 ≝
 274  { objs2:> Type2;
 275    arrows2: objs2 → objs2 → setoid2;
 276    id2: ∀o:objs2. arrows2 o o;
 277    comp2: ∀o1,o2,o3. binary_morphism2 (arrows2 o1 o2) (arrows2 o2 o3) (arrows2 o1 o3);
 278    comp_assoc2: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 279     comp2 o1 o3 o4 (comp2 o1 o2 o3 a12 a23) a34 = comp2 o1 o2 o4 a12 (comp2 o2 o3 o4 a23 a34);
 280    id_neutral_right2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? (id2 o1) a = a;
 281    id_neutral_left2: ∀o1,o2. ∀a: arrows2 o1 o2. comp2 ??? a (id2 o2) = a
 282  }.
 283
 284 record category3 : Type4 ≝
 285  { objs3:> Type3;
 286    arrows3: objs3 → objs3 → setoid3;
 287    id3: ∀o:objs3. arrows3 o o;
 288    comp3: ∀o1,o2,o3. binary_morphism3 (arrows3 o1 o2) (arrows3 o2 o3) (arrows3 o1 o3);
 289    comp_assoc3: ∀o1,o2,o3,o4. ∀a12,a23,a34.
 290     comp3 o1 o3 o4 (comp3 o1 o2 o3 a12 a23) a34 = comp3 o1 o2 o4 a12 (comp3 o2 o3 o4 a23 a34);
 291    id_neutral_right3: ∀o1,o2. ∀a: arrows3 o1 o2. comp3 ??? (id3 o1) a = a;
 292    id_neutral_left3: ∀o1,o2. ∀a: arrows3 o1 o2. comp3 ??? a (id3 o2) = a
 293  }.
 294
 295 notation "'ASSOC'" with precedence 90 for @{'assoc}.
 296
 297 interpretation "category2 composition" 'compose x y = (fun22 ??? (comp2 ????) y x).
 298 interpretation "category2 assoc" 'assoc = (comp_assoc2 ????????).
 299 interpretation "category1 composition" 'compose x y = (fun21 ??? (comp1 ????) y x).
 300 interpretation "category1 assoc" 'assoc = (comp_assoc1 ????????).
 301 interpretation "category composition" 'compose x y = (fun2 ??? (comp ????) y x).
 302 interpretation "category assoc" 'assoc = (comp_assoc ????????).
 303
 304 definition category2_of_category1: category1 → category2.
 305  intro;
 306  constructor 1;
 307   [ apply (objs1 c);
 308   | intros; apply (setoid2_of_setoid1 (arrows1 c o o1));
 309   | apply (id1 c);
 310   | intros;
 311     constructor 1;
 312      [ intros; apply (comp1 c o1 o2 o3 c1 c2);
 313      | intros; whd in e e1 a a' b b'; change with (eq1 ? (b∘a) (b'∘a')); apply (e‡e1); ]
 314   | intros; simplify; whd in a12 a23 a34; whd; apply rule (ASSOC);
 315   | intros; simplify; whd in a; whd; apply id_neutral_right1;
 316   | intros; simplify; whd in a; whd; apply id_neutral_left1; ]
 317 qed.
 318 (*coercion category2_of_category1.*)
 319
 320 record functor2 (C1: category2) (C2: category2) : Type3 ≝
 321  { map_objs2:1> C1 → C2;
 322    map_arrows2: ∀S,T. unary_morphism2 (arrows2 ? S T) (arrows2 ? (map_objs2 S) (map_objs2 T));
 323    respects_id2: ∀o:C1. map_arrows2 ?? (id2 ? o) = id2 ? (map_objs2 o);
 324    respects_comp2:
 325      ∀o1,o2,o3.∀f1:arrows2 ? o1 o2.∀f2:arrows2 ? o2 o3.
 326      map_arrows2 ?? (f2 ∘ f1) = map_arrows2 ?? f2 ∘ map_arrows2 ?? f1}.
 327
 328 definition functor2_setoid: category2 → category2 → setoid3.
 329  intros (C1 C2);
 330  constructor 1;
 331   [ apply (functor2 C1 C2);
 332   | constructor 1;
 333      [ intros (f g);
 334        apply (∀c:C1. cic:/matita/logic/equality/eq.ind#xpointer(1/1) ? (f c) (g c));
 335      | simplify; intros; apply cic:/matita/logic/equality/eq.ind#xpointer(1/1/1);
 336      | simplify; intros; apply cic:/matita/logic/equality/sym_eq.con; apply H;
 337      | simplify; intros; apply cic:/matita/logic/equality/trans_eq.con;
 338         [2: apply H; | skip | apply H1;]]]
 339 qed.
 340
 341 definition functor2_of_functor2_setoid: ∀S,T. functor2_setoid S T → functor2 S T ≝ λS,T,x.x.
 342 coercion functor2_of_functor2_setoid.
 343
 344 definition CAT2: category3.
 345  constructor 1;
 346   [ apply category2;
 347   | apply functor2_setoid;
 348   | intros; constructor 1;
 349      [ apply (λx.x);
 350      | intros; constructor 1;
 351         [ apply (λx.x);
 352         | intros; assumption;]
 353      | intros; apply rule #;
 354      | intros; apply rule #; ]
 355   | intros; constructor 1;
 356      [ intros; constructor 1;
 357         [ intros; apply (c1 (c o));
 358         | intros; constructor 1;
 359            [ intro; apply (map_arrows2 ?? c1 ?? (map_arrows2 ?? c ?? c2));
 360            | intros; apply (††e); ]
 361         | intros; simplify;
 362           apply (.= †(respects_id2 : ?));
 363           apply (respects_id2 : ?);
 364         | intros; simplify;
 365           apply (.= †(respects_comp2 : ?));
 366           apply (respects_comp2 : ?); ]
 367         | intros; intro; simplify;
 368           apply (cic:/matita/logic/equality/eq_ind.con ????? (e ?));
 369           apply (cic:/matita/logic/equality/eq_ind.con ????? (e1 ?));
 370           constructor 1; ]
 371         | intros; intro; simplify; constructor 1;
 372         | intros; intro; simplify; constructor 1;
 373         | intros; intro; simplify; constructor 1; ]
 374 qed.
 375
 376 definition category2_of_objs3_CAT2: objs3 CAT2 → category2 ≝ λx.x.
 377 coercion category2_of_objs3_CAT2.
 378
 379 definition functor2_setoid_of_arrows3_CAT2: ∀S,T. arrows3 CAT2 S T → functor2_setoid S T ≝ λS,T,x.x.
 380 coercion functor2_setoid_of_arrows3_CAT2.
 381
 382 definition unary_morphism_setoid: setoid → setoid → setoid.
 383  intros;
 384  constructor 1;
 385   [ apply (unary_morphism s s1);
 386   | constructor 1;
 387      [ intros (f g); apply (∀a:s. eq ? (f a) (g a));
 388      | intros 1; simplify; intros; apply refl;
 389      | simplify; intros; apply sym; apply f;
 390      | simplify; intros; apply trans; [2: apply f; | skip | apply f1]]]
 391 qed.
 392
 393 definition SET: category1.
 394  constructor 1;
 395   [ apply setoid;
 396   | apply rule (λS,T:setoid.setoid1_of_setoid (unary_morphism_setoid S T));
 397   | intros; constructor 1; [ apply (λx:carr o.x); | intros; assumption ]
 398   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. c1 (c x)); | intros;
 399      apply († (†e));]
 400   | intros; whd; intros; simplify; whd in H1; whd in H;
 401     apply trans; [ apply (b (a' a1)); | lapply (prop1 ?? b (a a1) (a' a1));
 402      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 403   | intros; whd; intros; simplify; apply refl;
 404   | intros; simplify; whd; intros; simplify; apply refl;
 405   | intros; simplify; whd; intros; simplify; apply refl;
 406   ]
 407 qed.
 408
 409 definition setoid_of_SET: objs1 SET → setoid ≝ λx.x.
 410 coercion setoid_of_SET.
 411
 412 definition unary_morphism_setoid_of_arrows1_SET:
 413   ∀P,Q.arrows1 SET P Q → unary_morphism_setoid P Q  ≝ λP,Q,x.x.
 414 coercion unary_morphism_setoid_of_arrows1_SET.
 415
 416 notation > "A × term 74 B ⇒_1 term 19 C" non associative with precedence 72 for @{'binary_morphism1 $A $B $C}.
 417 notation > "A × term 74 B ⇒_2 term 19 C" non associative with precedence 72 for @{'binary_morphism2 $A $B $C}.
 418 notation > "A × term 74 B ⇒_3 term 19 C" non associative with precedence 72 for @{'binary_morphism3 $A $B $C}.
 419 notation > "B ⇒_1 C" right associative with precedence 72 for @{'arrows1_SET $B $C}.
 420 notation > "B ⇒_1. C" right associative with precedence 72 for @{'arrows1_SETlow $B $C}.
 421 notation > "B ⇒_2 C" right associative with precedence 72 for @{'arrows2_SET1 $B $C}.
 422 notation > "B ⇒_2. C" right associative with precedence 72 for @{'arrows2_SET1low $B $C}.
 423
 424 notation "A × term 74 B ⇒\sub 1 term 19 C" non associative with precedence 72 for @{'binary_morphism1 $A $B $C}.
 425 notation "A × term 74 B ⇒\sub 2 term 19 C" non associative with precedence 72 for @{'binary_morphism2 $A $B $C}.
 426 notation "A × term 74 B ⇒\sub 3 term 19 C" non associative with precedence 72 for @{'binary_morphism3 $A $B $C}.
 427 notation "B ⇒\sub 1 C" right associative with precedence 72 for @{'arrows1_SET $B $C}.
 428 notation "B ⇒\sub 2 C" right associative with precedence 72 for @{'arrows2_SET1 $B $C}.
 429
 430 interpretation "'binary_morphism1" 'binary_morphism1 A B C = (binary_morphism1 A B C).
 431 interpretation "'binary_morphism2" 'binary_morphism2 A B C = (binary_morphism2 A B C).
 432 interpretation "'binary_morphism3" 'binary_morphism3 A B C = (binary_morphism3 A B C).
 433 interpretation "'arrows1_SET low" 'arrows1_SET A B = (unary_morphism1 A B).
 434 interpretation "'arrows1_SETlow" 'arrows1_SETlow A B = (unary_morphism1 A B).
 435 interpretation "'arrows1_SET" 'arrows1_SET A B = (arrows1 SET A B).
 436
 437 definition unary_morphism1_setoid1: setoid1 → setoid1 → setoid1.
 438  intros;
 439  constructor 1;
 440   [ apply (unary_morphism1 s s1);
 441   | constructor 1;
 442      [ intros (f g);
 443        alias symbol "eq" = "setoid1 eq".
 444        apply (∀a: carr1 s. f a = g a);
 445      | intros 1; simplify; intros; apply refl1;
 446      | simplify; intros; apply sym1; apply f;
 447      | simplify; intros; apply trans1; [2: apply f; | skip | apply f1]]]
 448 qed.
 449
 450 definition unary_morphism1_of_unary_morphism1_setoid1 :
 451   ∀S,T. unary_morphism1_setoid1 S T → unary_morphism1 S T ≝ λP,Q,x.x.
 452 coercion unary_morphism1_of_unary_morphism1_setoid1.
 453
 454 definition SET1: objs3 CAT2.
 455  constructor 1;
 456   [ apply setoid1;
 457   | apply rule (λS,T.setoid2_of_setoid1 (unary_morphism1_setoid1 S T));
 458   | intros; constructor 1; [ apply (λx.x); | intros; assumption ]
 459   | intros; constructor 1; [ intros; constructor 1; [ apply (λx. c1 (c x)); | intros;
 460      apply († (†e));]
 461   | intros; whd; intros; simplify; whd in H1; whd in H;
 462     apply trans1; [ apply (b (a' a1)); | lapply (prop11 ?? b (a a1) (a' a1));
 463      [ apply Hletin | apply (e a1); ]  | apply e1; ]]
 464   | intros; whd; intros; simplify; apply refl1;
 465   | intros; simplify; whd; intros; simplify; apply refl1;
 466   | intros; simplify; whd; intros; simplify; apply refl1;
 467   ]
 468 qed.
 469
 470 interpretation "'arrows2_SET1 low" 'arrows2_SET1 A B = (unary_morphism2 A B).
 471 interpretation "'arrows2_SET1low" 'arrows2_SET1low A B = (unary_morphism2 A B).
 472 interpretation "'arrows2_SET1" 'arrows2_SET1 A B = (arrows2 SET1 A B).
 473
 474 definition setoid1_of_SET1: objs2 SET1 → setoid1 ≝ λx.x.
 475 coercion setoid1_of_SET1.
 476
 477 definition unary_morphism1_setoid1_of_arrows2_SET1:
 478   ∀P,Q.arrows2 SET1 P Q → unary_morphism1_setoid1 P Q ≝ λP,Q,x.x.
 479 coercion unary_morphism1_setoid1_of_arrows2_SET1.
 480
 481 variant objs2_of_category1: objs1 SET → objs2 SET1 ≝ setoid1_of_setoid.
 482 coercion objs2_of_category1.
 483
 484 prefer coercion Type_OF_setoid. (* we prefer the lower carrier projection *)
 485 prefer coercion Type_OF_objs1.