helm/software/matita/contribs/formal_topology/overlap/o-algebra.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "categories.ma".
  16
  17 inductive bool : Type0 := true : bool | false : bool.
  18
  19 lemma BOOL : objs1 SET.
  20 constructor 1; [apply bool] constructor 1;
  21 [ intros (x y); apply (match x with [ true ⇒ match y with [ true ⇒ True | _ ⇒ False] | false ⇒ match y with [ true ⇒ False | false ⇒ True ]]);
  22 | whd; simplify; intros; cases x; apply I;
  23 | whd; simplify; intros 2; cases x; cases y; simplify; intros; assumption;
  24 | whd; simplify; intros 3; cases x; cases y; cases z; simplify; intros;
  25   try assumption; apply I]
  26 qed.
  27
  28 lemma IF_THEN_ELSE_p :
  29   ∀S:setoid1.∀a,b:S.∀x,y:BOOL.x = y →
  30     (λm.match m with [ true ⇒ a | false ⇒ b ]) x =
  31     (λm.match m with [ true ⇒ a | false ⇒ b ]) y.
  32 whd in ⊢ (?→?→?→%→?);
  33 intros; cases x in e; cases y; simplify; intros; try apply refl1; whd in e; cases e;
  34 qed.
  35
  36 interpretation "unary morphism comprehension with no proof" 'comprehension T P =
  37   (mk_unary_morphism T ? P ?).
  38 interpretation "unary morphism1 comprehension with no proof" 'comprehension T P =
  39   (mk_unary_morphism1 T ? P ?).
  40
  41 notation > "hvbox({ ident i ∈ s | term 19 p | by })" with precedence 90
  42 for @{ 'comprehension_by $s (λ${ident i}. $p) $by}.
  43 notation < "hvbox({ ident i ∈ s | term 19 p })" with precedence 90
  44 for @{ 'comprehension_by $s (λ${ident i}:$_. $p) $by}.
  45
  46 interpretation "unary morphism comprehension with proof" 'comprehension_by s \eta.f p =
  47   (mk_unary_morphism s ? f p).
  48 interpretation "unary morphism1 comprehension with proof" 'comprehension_by s \eta.f p =
  49   (mk_unary_morphism1 s ? f p).
  50
  51 (* per il set-indexing vedere capitolo BPTools (foundational tools), Sect. 0.3.4 complete
  52    lattices, Definizione 0.9 *)
  53 (* USARE L'ESISTENZIALE DEBOLE *)
  54
  55
  56 notation > "hvbox(a break ≤ b)" non associative with precedence 45 for @{oa_leq $a $b}.
  57 notation > "a >< b" non associative with precedence 45 for @{oa_overlap $a $b}.
  58 notation > "⋁ p" non associative with precedence 45 for @{oa_join ? $p}.
  59 notation > "⋀ p" non associative with precedence 45 for @{oa_meet ? $p}.
  60 notation > "𝟙" non associative with precedence 90 for @{oa_one}.
  61 notation > "𝟘" non associative with precedence 90 for @{oa_zero}.
  62 record OAlgebra : Type2 := {
  63   oa_P :> SET1;
  64   oa_leq : oa_P × oa_P ⇒_1 CPROP;
  65   oa_overlap: oa_P × oa_P ⇒_1 CPROP;
  66   oa_meet: ∀I:SET.(I ⇒_2 oa_P) ⇒_2. oa_P;
  67   oa_join: ∀I:SET.(I ⇒_2 oa_P) ⇒_2. oa_P;
  68   oa_one: oa_P;
  69   oa_zero: oa_P;
  70   oa_leq_refl: ∀a:oa_P. a ≤ a;
  71   oa_leq_antisym: ∀a,b:oa_P.a ≤ b → b ≤ a → a = b;
  72   oa_leq_trans: ∀a,b,c:oa_P.a ≤ b → b ≤ c → a ≤ c;
  73   oa_overlap_sym: ∀a,b:oa_P.a >< b → b >< a;
  74   oa_meet_inf: ∀I:SET.∀p_i:I ⇒_2 oa_P.∀p:oa_P.p ≤ (⋀ p_i) = (∀i:I.p ≤ (p_i i));
  75   oa_join_sup: ∀I:SET.∀p_i:I ⇒_2 oa_P.∀p:oa_P.(⋁ p_i) ≤ p = (∀i:I.p_i i ≤ p);
  76   oa_zero_bot: ∀p:oa_P.𝟘 ≤ p;
  77   oa_one_top: ∀p:oa_P.p ≤ 𝟙;
  78   oa_overlap_preserves_meet_: ∀p,q:oa_P.p >< q →
  79         p >< (⋀ { x ∈ BOOL | match x with [ true ⇒ p | false ⇒ q ] | IF_THEN_ELSE_p oa_P p q });
  80   oa_join_split: ∀I:SET.∀p.∀q:I ⇒_2 oa_P.p >< (⋁ q) = (∃i:I.p >< (q i));
  81   (*oa_base : setoid;
  82   1) enum non e' il nome giusto perche' non e' suriettiva
  83   2) manca (vedere altro capitolo) la "suriettivita'" come immagine di insiemi di oa_base
  84   oa_enum : ums oa_base oa_P;
  85   oa_density: ∀p,q.(∀i.oa_overlap p (oa_enum i) → oa_overlap q (oa_enum i)) → oa_leq p q
  86   *)
  87   oa_density: ∀p,q.(∀r.p >< r → q >< r) → p ≤ q
  88 }.
  89
  90 notation "hvbox(a break ≤ b)" non associative with precedence 45 for @{ 'leq $a $b }.
  91
  92 interpretation "o-algebra leq" 'leq a b = (fun21 ??? (oa_leq ?) a b).
  93
  94 notation "hovbox(a mpadded width -150% (>)< b)" non associative with precedence 45
  95 for @{ 'overlap $a $b}.
  96 interpretation "o-algebra overlap" 'overlap a b = (fun21 ??? (oa_overlap ?) a b).
  97
  98 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∧) \below (\emsp) \nbsp term 90 p)"
  99 non associative with precedence 50 for @{ 'oa_meet $p }.
 100 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∧) \below (ident i ∈  I) break term 90 p)"
 101 non associative with precedence 50 for @{ 'oa_meet_mk (λ${ident i}:$I.$p) }.
 102
 103 notation > "hovbox(∧ f)" non associative with precedence 60
 104 for @{ 'oa_meet $f }.
 105 interpretation "o-algebra meet" 'oa_meet f =
 106   (fun12 ?? (oa_meet ??) f).
 107 interpretation "o-algebra meet with explicit function" 'oa_meet_mk f =
 108   (fun12 ?? (oa_meet ??) (mk_unary_morphism ?? f ?)).
 109
 110 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (\emsp) \nbsp term 90 p)"
 111 non associative with precedence 50 for @{ 'oa_join $p }.
 112 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (ident i ∈  I) break term 90 p)"
 113 non associative with precedence 50 for @{ 'oa_join_mk (λ${ident i}:$I.$p) }.
 114
 115 notation > "hovbox(∨ f)" non associative with precedence 60
 116 for @{ 'oa_join $f }.
 117 interpretation "o-algebra join" 'oa_join f =
 118   (fun12 ?? (oa_join ??) f).
 119 interpretation "o-algebra join with explicit function" 'oa_join_mk f =
 120   (fun12 ?? (oa_join ??) (mk_unary_morphism ?? f ?)).
 121
 122 definition binary_meet : ∀O:OAlgebra. O × O ⇒_1 O.
 123 intros; split;
 124 [ intros (p q);
 125   apply (∧ { x ∈ BOOL | match x with [ true ⇒ p | false ⇒ q ] | IF_THEN_ELSE_p ? p q });
 126 | intros; lapply (prop12 ? O (oa_meet O BOOL));
 127    [2: apply ({ x ∈ BOOL | match x with [ true ⇒ a | false ⇒ b ] | IF_THEN_ELSE_p ? a b });
 128    |3: apply ({ x ∈ BOOL | match x with [ true ⇒ a' | false ⇒ b' ] | IF_THEN_ELSE_p ? a' b' });
 129    | apply Hletin;]
 130   intro x; simplify; cases x; simplify; assumption;]
 131 qed.
 132
 133 interpretation "o-algebra binary meet" 'and a b =
 134   (fun21 ??? (binary_meet ?) a b).
 135
 136 prefer coercion Type1_OF_OAlgebra.
 137
 138 definition binary_join : ∀O:OAlgebra. O × O ⇒_1 O.
 139 intros; split;
 140 [ intros (p q);
 141   apply (∨ { x ∈ BOOL | match x with [ true ⇒ p | false ⇒ q ] | IF_THEN_ELSE_p ? p q });
 142 | intros; lapply (prop12 ? O (oa_join O BOOL));
 143    [2: apply ({ x ∈ BOOL | match x with [ true ⇒ a | false ⇒ b ] | IF_THEN_ELSE_p ? a b });
 144    |3: apply ({ x ∈ BOOL | match x with [ true ⇒ a' | false ⇒ b' ] | IF_THEN_ELSE_p ? a' b' });
 145    | apply Hletin;]
 146   intro x; simplify; cases x; simplify; assumption;]
 147 qed.
 148
 149 interpretation "o-algebra binary join" 'or a b =
 150   (fun21 ??? (binary_join ?) a b).
 151
 152 lemma oa_overlap_preservers_meet: ∀O:OAlgebra.∀p,q:O.p >< q → p >< (p ∧ q).
 153 (* next change to avoid universe inconsistency *)
 154 change in ⊢ (?→%→%→?) with (Type1_OF_OAlgebra O);
 155 intros;  lapply (oa_overlap_preserves_meet_ O p q f);
 156 lapply (prop21 O O CPROP (oa_overlap O) p p ? (p ∧ q) # ?);
 157 [3: apply (if ?? (Hletin1)); apply Hletin;|skip] apply refl1;
 158 qed.
 159
 160 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (\emsp) \nbsp term 90 p)"
 161 non associative with precedence 49 for @{ 'oa_join $p }.
 162 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (ident i ∈  I) break term 90 p)"
 163 non associative with precedence 49 for @{ 'oa_join_mk (λ${ident i}:$I.$p) }.
 164 notation < "hovbox(a ∨ b)" left associative with precedence 49
 165 for @{ 'oa_join_mk (λ${ident i}:$_.match $i with [ true ⇒ $a | false ⇒ $b ]) }.
 166
 167 notation > "hovbox(∨ f)" non associative with precedence 59
 168 for @{ 'oa_join $f }.
 169 notation > "hovbox(a ∨ b)" left associative with precedence 49
 170 for @{ 'oa_join (mk_unary_morphism BOOL ? (λx__:bool.match x__ with [ true ⇒ $a | false ⇒ $b ]) (IF_THEN_ELSE_p ? $a $b)) }.
 171
 172 interpretation "o-algebra join" 'oa_join f =
 173   (fun12 ?? (oa_join ??) f).
 174 interpretation "o-algebra join with explicit function" 'oa_join_mk f =
 175   (fun12 ?? (oa_join ??) (mk_unary_morphism ?? f ?)).
 176
 177 record ORelation (P,Q : OAlgebra) : Type2 ≝ {
 178   or_f_ : carr2 (P ⇒_2 Q);
 179   or_f_minus_star_ : carr2(P ⇒_2 Q);
 180   or_f_star_ : carr2(Q ⇒_2 P);
 181   or_f_minus_ : carr2(Q ⇒_2 P);
 182   or_prop1_ : ∀p,q. (or_f_ p ≤ q) = (p ≤ or_f_star_ q);
 183   or_prop2_ : ∀p,q. (or_f_minus_ p ≤ q) = (p ≤ or_f_minus_star_ q);
 184   or_prop3_ : ∀p,q. (or_f_ p >< q) = (p >< or_f_minus_ q)
 185 }.
 186
 187 definition ORelation_setoid : OAlgebra → OAlgebra → setoid2.
 188 intros (P Q);
 189 constructor 1;
 190 [ apply (ORelation P Q);
 191 | constructor 1;
 192    (* tenere solo una uguaglianza e usare la proposizione 9.9 per
 193       le altre (unicita' degli aggiunti e del simmetrico) *)
 194    [ apply (λp,q. And42
 195              (or_f_minus_star_ ?? p = or_f_minus_star_ ?? q)
 196              (or_f_minus_ ?? p = or_f_minus_ ?? q)
 197              (or_f_ ?? p = or_f_ ?? q)
 198              (or_f_star_ ?? p = or_f_star_ ?? q));
 199    | whd; simplify; intros; repeat split; intros; apply refl2;
 200    | whd; simplify; intros; cases a; clear a; split;
 201      intro a; apply sym1; generalize in match a;assumption;
 202    | whd; simplify; intros; cases a; cases a1; clear a a1; split; intro a;
 203      [ apply (.= (e a)); apply e4;
 204      | apply (.= (e1 a)); apply e5;
 205      | apply (.= (e2 a)); apply e6;
 206      | apply (.= (e3 a)); apply e7;]]]
 207 qed.
 208
 209 definition ORelation_of_ORelation_setoid :
 210   ∀P,Q.ORelation_setoid P Q → ORelation P Q ≝ λP,Q,x.x.
 211 coercion ORelation_of_ORelation_setoid.
 212
 213 definition or_f_minus_star:
 214  ∀P,Q:OAlgebra.(ORelation_setoid P Q) ⇒_2 (P ⇒_2 Q).
 215  intros; constructor 1;
 216   [ apply or_f_minus_star_;
 217   | intros; cases e; assumption]
 218 qed.
 219
 220 definition or_f: ∀P,Q:OAlgebra.(ORelation_setoid P Q) ⇒_2 (P ⇒_2 Q).
 221  intros; constructor 1;
 222   [ apply or_f_;
 223   | intros; cases e; assumption]
 224 qed.
 225
 226 definition or_f_minus: ∀P,Q:OAlgebra.(ORelation_setoid P Q) ⇒_2 (Q ⇒_2 P).
 227  intros; constructor 1;
 228   [ apply or_f_minus_;
 229   | intros; cases e; assumption]
 230 qed.
 231
 232 definition or_f_star: ∀P,Q:OAlgebra.(ORelation_setoid P Q) ⇒_2 (Q ⇒_2 P).
 233  intros; constructor 1;
 234   [ apply or_f_star_;
 235   | intros; cases e; assumption]
 236 qed.
 237
 238 lemma arrows1_of_ORelation_setoid : ∀P,Q. ORelation_setoid P Q → (P ⇒_2 Q).
 239 intros; apply (or_f ?? c);
 240 qed.
 241 coercion arrows1_of_ORelation_setoid.
 242
 243 notation "r \sup *" non associative with precedence 90 for @{'OR_f_star $r}.
 244 notation > "r *" non associative with precedence 90 for @{'OR_f_star $r}.
 245
 246 notation "r \sup (⎻* )" non associative with precedence 90 for @{'OR_f_minus_star $r}.
 247 notation > "r⎻*" non associative with precedence 90 for @{'OR_f_minus_star $r}.
 248
 249 notation "r \sup ⎻" non associative with precedence 90 for @{'OR_f_minus $r}.
 250 notation > "r⎻" non associative with precedence 90 for @{'OR_f_minus $r}.
 251
 252 interpretation "o-relation f⎻*" 'OR_f_minus_star r = (fun12 ?? (or_f_minus_star ? ?) r).
 253 interpretation "o-relation f⎻" 'OR_f_minus r = (fun12 ?? (or_f_minus ? ?) r).
 254 interpretation "o-relation f*" 'OR_f_star r = (fun12 ?? (or_f_star ? ?) r).
 255
 256 definition or_prop1 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
 257    (F p ≤ q) = (p ≤ F* q).
 258 intros; apply (or_prop1_ ?? F p q);
 259 qed.
 260
 261 definition or_prop2 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
 262    (F⎻ p ≤ q) = (p ≤ F⎻* q).
 263 intros; apply (or_prop2_ ?? F p q);
 264 qed.
 265
 266 definition or_prop3 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
 267    (F p >< q) = (p >< F⎻ q).
 268 intros; apply (or_prop3_ ?? F p q);
 269 qed.
 270
 271 definition ORelation_composition : ∀P,Q,R.
 272   binary_morphism2 (ORelation_setoid P Q) (ORelation_setoid Q R) (ORelation_setoid P R).
 273 intros;
 274 constructor 1;
 275 [ intros (F G);
 276   constructor 1;
 277   [ apply (G ∘ F);
 278   | apply rule (G⎻* ∘ F⎻* );
 279   | apply (F* ∘ G* );
 280   | apply (F⎻ ∘ G⎻);
 281   | intros;
 282     change with ((G (F p) ≤ q) = (p ≤ (F* (G* q))));
 283     apply (.= (or_prop1 :?));
 284     apply (or_prop1 :?);
 285   | intros;
 286     change with ((F⎻ (G⎻ p) ≤ q) = (p ≤ (G⎻* (F⎻* q))));
 287     apply (.= (or_prop2 :?));
 288     apply or_prop2 ;
 289   | intros; change with ((G (F (p)) >< q) = (p >< (F⎻ (G⎻ q))));
 290     apply (.= (or_prop3 :?));
 291     apply or_prop3;
 292   ]
 293 | intros; split; simplify;
 294    [3: unfold arrows1_of_ORelation_setoid; apply ((†e)‡(†e1));
 295    |1: apply ((†e)‡(†e1));
 296    |2,4: apply ((†e1)‡(†e));]]
 297 qed.
 298
 299 definition OA : category2.
 300 split;
 301 [ apply (OAlgebra);
 302 | intros; apply (ORelation_setoid o o1);
 303 | intro O; split;
 304   [1,2,3,4: apply id2;
 305   |5,6,7:intros; apply refl1;]
 306 | apply ORelation_composition;
 307 | intros (P Q R S F G H); split;
 308    [ change with (H⎻* ∘ G⎻* ∘ F⎻* = H⎻* ∘ (G⎻* ∘ F⎻* ));
 309      apply (comp_assoc2 ????? (F⎻* ) (G⎻* ) (H⎻* ));
 310    | apply ((comp_assoc2 ????? (H⎻) (G⎻) (F⎻))^-1);
 311    | apply ((comp_assoc2 ????? F G H)^-1);
 312    | apply ((comp_assoc2 ????? H* G* F* ));]
 313 | intros; split; unfold ORelation_composition; simplify; apply id_neutral_left2;
 314 | intros; split; unfold ORelation_composition; simplify; apply id_neutral_right2;]
 315 qed.
 316
 317 definition OAlgebra_of_objs2_OA: objs2 OA → OAlgebra ≝ λx.x.
 318 coercion OAlgebra_of_objs2_OA.
 319
 320 definition ORelation_setoid_of_arrows2_OA:
 321   ∀P,Q. arrows2 OA P Q → ORelation_setoid P Q ≝ λP,Q,c.c.
 322 coercion ORelation_setoid_of_arrows2_OA.
 323
 324 prefer coercion Type_OF_objs2.
 325
 326 (* alias symbol "eq" = "setoid1 eq". *)
 327
 328 (* qui la notazione non va *)
 329 lemma leq_to_eq_join: ∀S:OA.∀p,q:S. p ≤ q → q = (binary_join ? p q).
 330  intros;
 331  apply oa_leq_antisym;
 332   [ apply oa_density; intros;
 333     apply oa_overlap_sym;
 334     unfold binary_join; simplify;
 335     apply (. (oa_join_split : ?));
 336     exists; [ apply false ]
 337     apply oa_overlap_sym;
 338     assumption
 339   | unfold binary_join; simplify;
 340     apply (. (oa_join_sup : ?)); intro;
 341     cases i; whd in ⊢ (? ? ? ? ? % ?);
 342      [ assumption | apply oa_leq_refl ]]
 343 qed.
 344
 345 lemma overlap_monotone_left: ∀S:OA.∀p,q,r:S. p ≤ q → p >< r → q >< r.
 346  intros;
 347  apply (. (leq_to_eq_join : ?)‡#);
 348   [ apply f;
 349   | skip
 350   | apply oa_overlap_sym;
 351     unfold binary_join; simplify;
 352     apply (. (oa_join_split : ?));
 353     exists [ apply true ]
 354     apply oa_overlap_sym;
 355     assumption; ]
 356 qed.
 357
 358 (* Part of proposition 9.9 *)
 359 lemma f_minus_image_monotone: ∀S,T.∀R:arrows2 OA S T.∀p,q. p ≤ q → R⎻ p ≤ R⎻ q.
 360  intros;
 361  apply (. (or_prop2 : ?));
 362  apply oa_leq_trans; [2: apply f; | skip | apply (. (or_prop2 : ?)^ -1); apply oa_leq_refl;]
 363 qed.
 364
 365 (* Part of proposition 9.9 *)
 366 lemma f_minus_star_image_monotone: ∀S,T.∀R:arrows2 OA S T.∀p,q. p ≤ q → R⎻* p ≤ R⎻* q.
 367  intros;
 368  apply (. (or_prop2 : ?)^ -1);
 369  apply oa_leq_trans; [3: apply f; | skip | apply (. (or_prop2 : ?)); apply oa_leq_refl;]
 370 qed.
 371
 372 (* Part of proposition 9.9 *)
 373 lemma f_image_monotone: ∀S,T.∀R:arrows2 OA S T.∀p,q. p ≤ q → R p ≤ R q.
 374  intros;
 375  apply (. (or_prop1 : ?));
 376  apply oa_leq_trans; [2: apply f; | skip | apply (. (or_prop1 : ?)^ -1); apply oa_leq_refl;]
 377 qed.
 378
 379 (* Part of proposition 9.9 *)
 380 lemma f_star_image_monotone: ∀S,T.∀R:arrows2 OA S T.∀p,q. p ≤ q → R* p ≤ R* q.
 381  intros;
 382  apply (. (or_prop1 : ?)^ -1);
 383  apply oa_leq_trans; [3: apply f; | skip | apply (. (or_prop1 : ?)); apply oa_leq_refl;]
 384 qed.
 385
 386 lemma lemma_10_2_a: ∀S,T.∀R:arrows2 OA S T.∀p. p ≤ R⎻* (R⎻ p).
 387  intros;
 388  apply (. (or_prop2 : ?)^-1);
 389  apply oa_leq_refl.
 390 qed.
 391
 392 lemma lemma_10_2_b: ∀S,T.∀R:arrows2 OA S T.∀p. R⎻ (R⎻* p) ≤ p.
 393  intros;
 394  apply (. (or_prop2 : ?));
 395  apply oa_leq_refl.
 396 qed.
 397
 398 lemma lemma_10_2_c: ∀S,T.∀R:arrows2 OA S T.∀p. p ≤ R* (R p).
 399  intros;
 400  apply (. (or_prop1 : ?)^-1);
 401  apply oa_leq_refl.
 402 qed.
 403
 404 lemma lemma_10_2_d: ∀S,T.∀R:arrows2 OA S T.∀p. R (R* p) ≤ p.
 405  intros;
 406  apply (. (or_prop1 : ?));
 407  apply oa_leq_refl.
 408 qed.
 409
 410 lemma lemma_10_3_a: ∀S,T.∀R:arrows2 OA S T.∀p. R⎻ (R⎻* (R⎻ p)) = R⎻ p.
 411  intros; apply oa_leq_antisym;
 412   [ apply lemma_10_2_b;
 413   | apply f_minus_image_monotone;
 414     apply lemma_10_2_a; ]
 415 qed.
 416
 417 lemma lemma_10_3_b: ∀S,T.∀R:arrows2 OA S T.∀p. R* (R (R* p)) = R* p.
 418  intros; apply oa_leq_antisym;
 419   [ apply f_star_image_monotone;
 420     apply (lemma_10_2_d ?? R p);
 421   | apply lemma_10_2_c; ]
 422 qed.
 423
 424 lemma lemma_10_3_c: ∀S,T.∀R:arrows2 OA S T.∀p. R (R* (R p)) = R p.
 425  intros; apply oa_leq_antisym;
 426   [ apply lemma_10_2_d;
 427   | apply f_image_monotone;
 428     apply (lemma_10_2_c ?? R p); ]
 429 qed.
 430
 431 lemma lemma_10_3_d: ∀S,T.∀R:arrows2 OA S T.∀p. R⎻* (R⎻ (R⎻* p)) = R⎻* p.
 432  intros; apply oa_leq_antisym;
 433   [ apply f_minus_star_image_monotone;
 434     apply (lemma_10_2_b ?? R p);
 435   | apply lemma_10_2_a; ]
 436 qed.
 437
 438 lemma lemma_10_4_a: ∀S,T.∀R:arrows2 OA S T.∀p. R⎻* (R⎻ (R⎻* (R⎻ p))) = R⎻* (R⎻ p).
 439  intros; apply (†(lemma_10_3_a ?? R p));
 440 qed.
 441
 442 lemma lemma_10_4_b: ∀S,T.∀R:arrows2 OA S T.∀p. R (R* (R (R* p))) = R (R* p).
 443 intros; unfold in ⊢ (? ? ? % %); apply (†(lemma_10_3_b ?? R p));
 444 qed.
 445
 446 lemma oa_overlap_sym': ∀o:OA.∀U,V:o. (U >< V) = (V >< U).
 447  intros; split; intro; apply oa_overlap_sym; assumption.
 448 qed.