]> matita.cs.unibo.it Git - helm.git/blob - helm/software/matita/contribs/formal_topology/overlap/o-algebra.ma
o-algebra defined again
[helm.git] / helm / software / matita / contribs / formal_topology / overlap / o-algebra.ma
1 (**************************************************************************)
2 (*       ___                                                              *)
3 (*      ||M||                                                             *)
4 (*      ||A||       A project by Andrea Asperti                           *)
5 (*      ||T||                                                             *)
6 (*      ||I||       Developers:                                           *)
7 (*      ||T||         The HELM team.                                      *)
8 (*      ||A||         http://helm.cs.unibo.it                             *)
9 (*      \   /                                                             *)
10 (*       \ /        This file is distributed under the terms of the       *)
11 (*        v         GNU General Public License Version 2                  *)
12 (*                                                                        *)
13 (**************************************************************************)
14
15 include "categories.ma".
16 include "logic/cprop_connectives.ma". 
17
18 inductive bool : Type0 := true : bool | false : bool.
19
20 lemma BOOL : objs1 SET.
21 constructor 1; [apply bool] constructor 1;
22 [ intros (x y); apply (match x with [ true ⇒ match y with [ true ⇒ True | _ ⇒ False] | false ⇒ match y with [ true ⇒ False | false ⇒ True ]]);
23 | whd; simplify; intros; cases x; apply I;
24 | whd; simplify; intros 2; cases x; cases y; simplify; intros; assumption;
25 | whd; simplify; intros 3; cases x; cases y; cases z; simplify; intros; 
26   try assumption; apply I]
27 qed.
28
29 lemma IF_THEN_ELSE_p :
30   ∀S:setoid1.∀a,b:S.∀x,y:BOOL.x = y → 
31     (λm.match m with [ true ⇒ a | false ⇒ b ]) x =
32     (λm.match m with [ true ⇒ a | false ⇒ b ]) y.
33 whd in ⊢ (?→?→?→%→?);
34 intros; cases x in e; cases y; simplify; intros; try apply refl1; whd in e; cases e;
35 qed.
36
37 interpretation "unary morphism comprehension with no proof" 'comprehension T P = 
38   (mk_unary_morphism T _ P _).
39 interpretation "unary morphism1 comprehension with no proof" 'comprehension T P = 
40   (mk_unary_morphism1 T _ P _).
41
42 notation > "hvbox({ ident i ∈ s | term 19 p | by })" with precedence 90
43 for @{ 'comprehension_by $s (λ${ident i}. $p) $by}.
44 notation < "hvbox({ ident i ∈ s | term 19 p })" with precedence 90
45 for @{ 'comprehension_by $s (λ${ident i}:$_. $p) $by}.
46
47 interpretation "unary morphism comprehension with proof" 'comprehension_by s \eta.f p = 
48   (mk_unary_morphism s _ f p).
49 interpretation "unary morphism1 comprehension with proof" 'comprehension_by s \eta.f p = 
50   (mk_unary_morphism1 s _ f p).
51
52 definition hint: Type_OF_category2 SET1 → setoid2.
53  intro; apply (setoid2_of_setoid1 t); qed.
54 coercion hint.
55
56 definition hint2: Type_OF_category1 SET → objs2 SET1.
57  intro; apply (setoid1_of_setoid t); qed.
58 coercion hint2.
59
60 (* per il set-indexing vedere capitolo BPTools (foundational tools), Sect. 0.3.4 complete
61    lattices, Definizione 0.9 *)
62 (* USARE L'ESISTENZIALE DEBOLE *)
63 (* Far salire SET usando setoidi1 *)
64 (*alias symbol "comprehension_by" = "unary morphism comprehension with proof".*)
65 record OAlgebra : Type2 := {
66   oa_P :> SET1;
67   oa_leq : binary_morphism1 oa_P oa_P CPROP; (* CPROP is setoid1, CPROP importante che sia small *)
68   oa_overlap: binary_morphism1 oa_P oa_P CPROP;
69   oa_meet: ∀I:SET.unary_morphism2 (arrows2 SET1 I oa_P) oa_P;
70   oa_join: ∀I:SET.unary_morphism2 (arrows2 SET1 I oa_P) oa_P;
71   oa_one: oa_P;
72   oa_zero: oa_P;
73   oa_leq_refl: ∀a:oa_P. oa_leq a a; 
74   oa_leq_antisym: ∀a,b:oa_P.oa_leq a b → oa_leq b a → a = b;
75   oa_leq_trans: ∀a,b,c:oa_P.oa_leq a b → oa_leq b c → oa_leq a c;
76   oa_overlap_sym: ∀a,b:oa_P.oa_overlap a b → oa_overlap b a;
77   (* Errore: = in oa_meet_inf e oa_join_sup *)
78   oa_meet_inf: ∀I.∀p_i.∀p:oa_P.oa_leq p (oa_meet I p_i) → ∀i:I.oa_leq p (p_i i);
79   oa_join_sup: ∀I.∀p_i.∀p:oa_P.oa_leq (oa_join I p_i) p → ∀i:I.oa_leq (p_i i) p;
80   oa_zero_bot: ∀p:oa_P.oa_leq oa_zero p;
81   oa_one_top: ∀p:oa_P.oa_leq p oa_one;
82   oa_overlap_preserves_meet_: 
83       ∀p,q:oa_P.oa_overlap p q → oa_overlap p 
84        (oa_meet ? { x ∈ BOOL | match x with [ true ⇒ p | false ⇒ q ] | IF_THEN_ELSE_p oa_P p q });
85   (* ⇔ deve essere =, l'esiste debole *)
86   oa_join_split:
87       ∀I:SET.∀p.∀q:arrows2 SET1 I oa_P.
88        oa_overlap p (oa_join I q) ⇔ ∃i:I.oa_overlap p (q i);
89   (*oa_base : setoid;
90   1) enum non e' il nome giusto perche' non e' suriettiva
91   2) manca (vedere altro capitolo) la "suriettivita'" come immagine di insiemi di oa_base
92   oa_enum : ums oa_base oa_P;
93   oa_density: ∀p,q.(∀i.oa_overlap p (oa_enum i) → oa_overlap q (oa_enum i)) → oa_leq p q
94   *)
95   oa_density: 
96       ∀p,q.(∀r.oa_overlap p r → oa_overlap q r) → oa_leq p q
97 }.
98
99 interpretation "o-algebra leq" 'leq a b = (fun21 ___ (oa_leq _) a b).
100
101 notation "hovbox(a mpadded width -150% (>)< b)" non associative with precedence 45
102 for @{ 'overlap $a $b}.
103 interpretation "o-algebra overlap" 'overlap a b = (fun22 ___ (oa_overlap _) a b).
104
105 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∧) \below (\emsp) \nbsp term 90 p)" 
106 non associative with precedence 50 for @{ 'oa_meet $p }.
107 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∧) \below (ident i ∈  I) break term 90 p)" 
108 non associative with precedence 50 for @{ 'oa_meet_mk (λ${ident i}:$I.$p) }.
109
110 (*
111 notation < "hovbox(a ∧ b)" left associative with precedence 35
112 for @{ 'oa_meet_mk (λ${ident i}:$_.match $i with [ true ⇒ $a | false ⇒ $b ]) }.
113 *)
114 notation > "hovbox(∧ f)" non associative with precedence 60
115 for @{ 'oa_meet $f }.
116 (*
117 notation > "hovbox(a ∧ b)" left associative with precedence 50
118 for @{ 'oa_meet (mk_unary_morphism BOOL ? (λx__:bool.match x__ with [ true ⇒ $a | false ⇒ $b ]) (IF_THEN_ELSE_p ? $a $b)) }.
119 *)
120 interpretation "o-algebra meet" 'oa_meet f = 
121   (fun11 __ (oa_meet __) f).
122 interpretation "o-algebra meet with explicit function" 'oa_meet_mk f = 
123   (fun11 __ (oa_meet __) (mk_unary_morphism _ _ f _)).
124
125 definition binary_meet : ∀O:OAlgebra. binary_morphism1 O O O.
126 intros; split;
127 [ intros (p q); 
128   apply (∧ { x ∈ BOOL | match x with [ true ⇒ p | false ⇒ q ] | IF_THEN_ELSE_p ? p q });
129 | intros; apply (prop_1 ?? (oa_meet O BOOL)); intro x; simplify;
130   cases x; simplify; assumption;]
131 qed.
132
133 notation "hovbox(a ∧ b)" left associative with precedence 35
134 for @{ 'oa_meet_bin $a $b }.
135 interpretation "o-algebra binary meet" 'oa_meet_bin a b = 
136   (fun1 ___ (binary_meet _) a b).
137
138 lemma oa_overlap_preservers_meet: ∀O:OAlgebra.∀p,q:O.p >< q → p >< (p ∧ q).
139 intros;  lapply (oa_overlap_preservers_meet_ O p q f);
140 lapply (prop1 O O CPROP (oa_overlap O) p p ? (p ∧ q) # ?);
141 [3: apply (if ?? (Hletin1)); apply Hletin;|skip] apply refl1;
142 qed.
143
144 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (\emsp) \nbsp term 90 p)" 
145 non associative with precedence 49 for @{ 'oa_join $p }.
146 notation < "hovbox(mstyle scriptlevel 1 scriptsizemultiplier 1.7 (∨) \below (ident i ∈  I) break term 90 p)" 
147 non associative with precedence 49 for @{ 'oa_join_mk (λ${ident i}:$I.$p) }.
148 notation < "hovbox(a ∨ b)" left associative with precedence 49
149 for @{ 'oa_join_mk (λ${ident i}:$_.match $i with [ true ⇒ $a | false ⇒ $b ]) }.
150
151 notation > "hovbox(∨ f)" non associative with precedence 59
152 for @{ 'oa_join $f }.
153 notation > "hovbox(a ∨ b)" left associative with precedence 49
154 for @{ 'oa_join (mk_unary_morphism BOOL ? (λx__:bool.match x__ with [ true ⇒ $a | false ⇒ $b ]) (IF_THEN_ELSE_p ? $a $b)) }.
155
156 interpretation "o-algebra join" 'oa_join f = 
157   (fun_1 __ (oa_join __) f).
158 interpretation "o-algebra join with explicit function" 'oa_join_mk f = 
159   (fun_1 __ (oa_join __) (mk_unary_morphism _ _ f _)).
160
161 record ORelation (P,Q : OAlgebra) : Type ≝ {
162   or_f_ : arrows1 SET P Q;
163   or_f_minus_star_ : arrows1 SET P Q;
164   or_f_star_ : arrows1 SET Q P;
165   or_f_minus_ : arrows1 SET Q P;
166   or_prop1_ : ∀p,q. (or_f_ p ≤ q) = (p ≤ or_f_star_ q);
167   or_prop2_ : ∀p,q. (or_f_minus_ p ≤ q) = (p ≤ or_f_minus_star_ q);
168   or_prop3_ : ∀p,q. (or_f_ p >< q) = (p >< or_f_minus_ q)
169 }.
170
171
172 definition ORelation_setoid : OAlgebra → OAlgebra → setoid1.
173 intros (P Q);
174 constructor 1;
175 [ apply (ORelation P Q);
176 | constructor 1;
177    (* tenere solo una uguaglianza e usare la proposizione 9.9 per
178       le altre (unicita' degli aggiunti e del simmetrico) *)
179    [ apply (λp,q. And4 (eq1 ? (or_f_minus_star_ ?? p) (or_f_minus_star_ ?? q)) 
180              (eq1 ? (or_f_minus_ ?? p) (or_f_minus_ ?? q)) 
181              (eq1 ? (or_f_ ?? p) (or_f_ ?? q)) 
182              (eq1 ? (or_f_star_ ?? p) (or_f_star_ ?? q))); 
183    | whd; simplify; intros; repeat split; intros; apply refl1;
184    | whd; simplify; intros; cases H; clear H; split; 
185      intro a; apply sym; generalize in match a;assumption;
186    | whd; simplify; intros; cases H; cases H1; clear H H1; split; intro a;
187      [ apply (.= (H2 a)); apply H6;
188      | apply (.= (H3 a)); apply H7;
189      | apply (.= (H4 a)); apply H8;
190      | apply (.= (H5 a)); apply H9;]]]
191 qed.  
192
193 definition or_f_minus_star: ∀P,Q:OAlgebra.ORelation_setoid P Q ⇒ arrows1 SET P Q.
194  intros; constructor 1;
195   [ apply or_f_minus_star_;
196   | intros; cases H; assumption]
197 qed.
198
199 definition or_f: ∀P,Q:OAlgebra.ORelation_setoid P Q ⇒ arrows1 SET P Q.
200  intros; constructor 1;
201   [ apply or_f_;
202   | intros; cases H; assumption]
203 qed.
204
205 coercion or_f.
206
207 definition or_f_minus: ∀P,Q:OAlgebra.ORelation_setoid P Q ⇒ arrows1 SET Q P.
208  intros; constructor 1;
209   [ apply or_f_minus_;
210   | intros; cases H; assumption]
211 qed.
212
213 definition or_f_star: ∀P,Q:OAlgebra.ORelation_setoid P Q ⇒ arrows1 SET Q P.
214  intros; constructor 1;
215   [ apply or_f_star_;
216   | intros; cases H; assumption]
217 qed.
218
219 lemma arrows1_OF_ORelation_setoid : ∀P,Q. ORelation_setoid P Q → arrows1 SET P Q.
220 intros; apply (or_f ?? c);
221 qed.
222
223 coercion arrows1_OF_ORelation_setoid nocomposites.
224
225 lemma umorphism_OF_ORelation_setoid : ∀P,Q. ORelation_setoid P Q → P ⇒ Q.
226 intros; apply (or_f ?? c);
227 qed.
228
229 coercion umorphism_OF_ORelation_setoid.
230
231
232 lemma uncurry_arrows : ∀B,C. arrows1 SET B C → B → C. 
233 intros; apply ((fun_1 ?? c) t);
234 qed.
235
236 coercion uncurry_arrows 1.
237
238 lemma hint3 : ∀P,Q. arrows1 SET P Q → P ⇒ Q. intros; apply c;qed.
239 coercion hint3 nocomposites.
240
241 (*
242 lemma hint2: OAlgebra → setoid. intros; apply (oa_P o). qed.
243 coercion hint2 nocomposites.
244 *)
245
246
247 notation "r \sup *" non associative with precedence 90 for @{'OR_f_star $r}.
248 notation > "r *" non associative with precedence 90 for @{'OR_f_star $r}.
249
250 notation "r \sup (⎻* )" non associative with precedence 90 for @{'OR_f_minus_star $r}.
251 notation > "r⎻*" non associative with precedence 90 for @{'OR_f_minus_star $r}.
252
253 notation "r \sup ⎻" non associative with precedence 90 for @{'OR_f_minus $r}.
254 notation > "r⎻" non associative with precedence 90 for @{'OR_f_minus $r}.
255
256 interpretation "o-relation f⎻*" 'OR_f_minus_star r = (fun_1 __ (or_f_minus_star _ _) r).
257 interpretation "o-relation f⎻" 'OR_f_minus r = (fun_1 __ (or_f_minus _ _) r).
258 interpretation "o-relation f*" 'OR_f_star r = (fun_1 __ (or_f_star _ _) r).
259
260 definition or_prop1 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
261    (F p ≤ q) = (p ≤ F* q).
262 intros; apply (or_prop1_ ?? F p q);
263 qed.
264
265 definition or_prop2 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
266    (F⎻ p ≤ q) = (p ≤ F⎻* q).
267 intros; apply (or_prop2_ ?? F p q);
268 qed.
269
270 definition or_prop3 : ∀P,Q:OAlgebra.∀F:ORelation_setoid P Q.∀p,q.
271    (F p >< q) = (p >< F⎻ q).
272 intros; apply (or_prop3_ ?? F p q);
273 qed.
274
275 definition ORelation_composition : ∀P,Q,R. 
276   binary_morphism1 (ORelation_setoid P Q) (ORelation_setoid Q R) (ORelation_setoid P R).
277 intros;
278 constructor 1;
279 [ intros (F G);
280   constructor 1;
281   [ apply (G ∘ F);
282   | apply (G⎻* ∘ F⎻* );
283   | apply (F* ∘ G* );
284   | apply (F⎻ ∘ G⎻);
285   | intros; 
286     change with ((G (F p) ≤ q) = (p ≤ (F* (G* q))));
287     apply (.= (or_prop1 :?));
288     apply (or_prop1 :?);
289   | intros;
290     change with ((F⎻ (G⎻ p) ≤ q) = (p ≤ (G⎻* (F⎻* q))));
291     apply (.= (or_prop2 :?));
292     apply or_prop2 ; 
293   | intros; change with ((G (F (p)) >< q) = (p >< (F⎻ (G⎻ q))));
294     apply (.= (or_prop3 :?));
295     apply or_prop3;
296   ]
297 | intros; split; simplify; 
298    [1,3: unfold arrows1_OF_ORelation_setoid; apply ((†H)‡(†H1));
299    |2,4: apply ((†H1)‡(†H));]]
300 qed.
301
302 definition OA : category1.
303 split;
304 [ apply (OAlgebra);
305 | intros; apply (ORelation_setoid o o1);
306 | intro O; split;
307   [1,2,3,4: apply id1;
308   |5,6,7:intros; apply refl1;] 
309 | apply ORelation_composition;
310 | intros (P Q R S F G H); split;
311    [ change with (H⎻* ∘ G⎻* ∘ F⎻* = H⎻* ∘ (G⎻* ∘ F⎻* ));
312      apply (comp_assoc1 ????? (F⎻* ) (G⎻* ) (H⎻* ));
313    | apply ((comp_assoc1 ????? (H⎻) (G⎻) (F⎻))^-1);
314    | apply ((comp_assoc1 ????? F G H)^-1);
315    | apply ((comp_assoc1 ????? H* G* F* ));]
316 | intros; split; unfold ORelation_composition; simplify; apply id_neutral_left1;
317 | intros; split; unfold ORelation_composition; simplify; apply id_neutral_right1;]
318 qed.