helm/software/matita/contribs/ng_assembly/freescale/model.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* ********************************************************************** *)
  16 (*                          Progetto FreeScale                            *)
  17 (*                                                                        *)
  18 (*   Sviluppato da: Cosimo Oliboni, oliboni@cs.unibo.it                   *)
  19 (*     Cosimo Oliboni, oliboni@cs.unibo.it                                *)
  20 (*                                                                        *)
  21 (* ********************************************************************** *)
  22
  23 include "freescale/status.ma".
  24
  25 (* *********************************** *)
  26 (* IMPOSTAZIONI SPECIFICHE DEI MODELLI *)
  27 (* *********************************** *)
  28
  29 (* modelli di HC05 *)
  30 ninductive HC05_mcu_model : Type ≝
  31   MC68HC05J5A: HC05_mcu_model
  32   (*..*).
  33
  34 (* modelli di HC08 *)
  35 ninductive HC08_mcu_model : Type ≝
  36   MC68HC08AB16A: HC08_mcu_model
  37   (*..*).
  38
  39 ndefinition HC08_mcu_model_ind : ΠP:HC08_mcu_model → Prop.P MC68HC08AB16A → Πh:HC08_mcu_model.P h ≝
  40 λP:HC08_mcu_model → Prop.λp:P MC68HC08AB16A.λh:HC08_mcu_model.
  41  match h with [ MC68HC08AB16A ⇒ p ].
  42
  43 ndefinition HC08_mcu_model_rec : ΠP:HC08_mcu_model → Set.P MC68HC08AB16A → Πh:HC08_mcu_model.P h ≝
  44 λP:HC08_mcu_model → Set.λp:P MC68HC08AB16A.λh:HC08_mcu_model.
  45  match h with [ MC68HC08AB16A ⇒ p ].
  46
  47 ndefinition HC08_mcu_model_rect : ΠP:HC08_mcu_model → Type.P MC68HC08AB16A → Πh:HC08_mcu_model.P h ≝
  48 λP:HC08_mcu_model → Type.λp:P MC68HC08AB16A.λh:HC08_mcu_model.
  49  match h with [ MC68HC08AB16A ⇒ p ].
  50
  51 (* modelli di HCS08 *)
  52 ninductive HCS08_mcu_model : Type ≝
  53   MC9S08AW60 : HCS08_mcu_model
  54 | MC9S08GB60 : HCS08_mcu_model
  55   (*..*).
  56
  57 ndefinition HCS08_mcu_model_ind : ΠP:HCS08_mcu_model → Prop.P MC9S08GB60 → P MC9S08AW60 → Πh:HCS08_mcu_model.P h ≝
  58 λP:HCS08_mcu_model → Prop.λp:P MC9S08GB60.λp1:P MC9S08AW60.λh:HCS08_mcu_model.
  59  match h with [ MC9S08GB60 ⇒ p | MC9S08AW60 ⇒ p1 ].
  60
  61 ndefinition HCS08_mcu_model_rec : ΠP:HCS08_mcu_model → Set.P MC9S08GB60 → P MC9S08AW60 → Πh:HCS08_mcu_model.P h ≝
  62 λP:HCS08_mcu_model → Set.λp:P MC9S08GB60.λp1:P MC9S08AW60.λh:HCS08_mcu_model.
  63  match h with [ MC9S08GB60 ⇒ p | MC9S08AW60 ⇒ p1 ].
  64
  65 ndefinition HCS08_mcu_model_rect : ΠP:HCS08_mcu_model → Type.P MC9S08GB60 → P MC9S08AW60 → Πh:HCS08_mcu_model.P h ≝
  66 λP:HCS08_mcu_model → Type.λp:P MC9S08GB60.λp1:P MC9S08AW60.λh:HCS08_mcu_model.
  67  match h with [ MC9S08GB60 ⇒ p | MC9S08AW60 ⇒ p1 ].
  68
  69 (* modelli di RS08 *)
  70 ninductive RS08_mcu_model : Type ≝
  71   MC9RS08KA1 : RS08_mcu_model
  72 | MC9RS08KA2 : RS08_mcu_model.
  73
  74 ndefinition RS08_mcu_model_ind : ΠP:RS08_mcu_model → Prop.P MC9RS08KA1 → P MC9RS08KA2 → Πr:RS08_mcu_model.P r ≝
  75 λP:RS08_mcu_model → Prop.λp:P MC9RS08KA1.λp1:P MC9RS08KA2.λr:RS08_mcu_model.
  76   match r with [ MC9RS08KA1 ⇒ p | MC9RS08KA2 ⇒ p1 ].
  77
  78 ndefinition RS08_mcu_model_rec : ΠP:RS08_mcu_model → Set.P MC9RS08KA1 → P MC9RS08KA2 → Πr:RS08_mcu_model.P r ≝
  79 λP:RS08_mcu_model → Set.λp:P MC9RS08KA1.λp1:P MC9RS08KA2.λr:RS08_mcu_model.
  80   match r with [ MC9RS08KA1 ⇒ p | MC9RS08KA2 ⇒ p1 ].
  81
  82 ndefinition RS08_mcu_model_rect : ΠP:RS08_mcu_model → Type.P MC9RS08KA1 → P MC9RS08KA2 → Πr:RS08_mcu_model.P r ≝
  83 λP:RS08_mcu_model → Type.λp:P MC9RS08KA1.λp1:P MC9RS08KA2.λr:RS08_mcu_model.
  84   match r with [ MC9RS08KA1 ⇒ p | MC9RS08KA2 ⇒ p1 ].
  85
  86 (* raggruppamento dei modelli *)
  87 ninductive any_mcu_model : Type ≝
  88   FamilyHC05  : HC05_mcu_model → any_mcu_model
  89 | FamilyHC08  : HC08_mcu_model → any_mcu_model
  90 | FamilyHCS08 : HCS08_mcu_model → any_mcu_model
  91 | FamilyRS08  : RS08_mcu_model → any_mcu_model.
  92
  93 ndefinition any_mcu_model_ind
  94  : ΠP:any_mcu_model → Prop.(Πn:HC05_mcu_model.P (FamilyHC05 n)) → (Πn:HC08_mcu_model.P (FamilyHC08 n)) →
  95    (Πn:HCS08_mcu_model.P (FamilyHCS08 n)) → (Πn:RS08_mcu_model.P (FamilyRS08 n))→Πa:any_mcu_model.P a ≝
  96 λP:any_mcu_model → Prop.λf:Πn:HC05_mcu_model.P (FamilyHC05 n).λf1:Πn:HC08_mcu_model.P (FamilyHC08 n).
  97 λf2:Πn:HCS08_mcu_model.P (FamilyHCS08 n).λf3:Πn:RS08_mcu_model.P (FamilyRS08 n).λa:any_mcu_model.
  98  match a with [ FamilyHC05 n ⇒ f n | FamilyHC08 n ⇒ f1 n
  99               | FamilyHCS08 n ⇒ f2 n | FamilyRS08 n ⇒ f3 n ].
 100
 101 ndefinition any_mcu_model_rec
 102  : ΠP:any_mcu_model → Set.(Πn:HC05_mcu_model.P (FamilyHC05 n)) → (Πn:HC08_mcu_model.P (FamilyHC08 n)) →
 103    (Πn:HCS08_mcu_model.P (FamilyHCS08 n)) → (Πn:RS08_mcu_model.P (FamilyRS08 n))→Πa:any_mcu_model.P a ≝
 104 λP:any_mcu_model → Set.λf:Πn:HC05_mcu_model.P (FamilyHC05 n).λf1:Πn:HC08_mcu_model.P (FamilyHC08 n).
 105 λf2:Πn:HCS08_mcu_model.P (FamilyHCS08 n).λf3:Πn:RS08_mcu_model.P (FamilyRS08 n).λa:any_mcu_model.
 106  match a with [ FamilyHC05 n ⇒ f n | FamilyHC08 n ⇒ f1 n
 107               | FamilyHCS08 n ⇒ f2 n | FamilyRS08 n ⇒ f3 n ].
 108
 109 ndefinition any_mcu_model_rect
 110  : ΠP:any_mcu_model → Type.(Πn:HC05_mcu_model.P (FamilyHC05 n)) → (Πn:HC08_mcu_model.P (FamilyHC08 n)) →
 111    (Πn:HCS08_mcu_model.P (FamilyHCS08 n)) → (Πn:RS08_mcu_model.P (FamilyRS08 n))→Πa:any_mcu_model.P a ≝
 112 λP:any_mcu_model → Type.λf:Πn:HC05_mcu_model.P (FamilyHC05 n).λf1:Πn:HC08_mcu_model.P (FamilyHC08 n).
 113 λf2:Πn:HCS08_mcu_model.P (FamilyHCS08 n).λf3:Πn:RS08_mcu_model.P (FamilyRS08 n).λa:any_mcu_model.
 114  match a with [ FamilyHC05 n ⇒ f n | FamilyHC08 n ⇒ f1 n
 115               | FamilyHCS08 n ⇒ f2 n | FamilyRS08 n ⇒ f3 n ].
 116
 117 (*
 118 condizioni errore interne alla MCU
 119 (Il programma viene caricato dal produttore in ROM o impostato in EEPROM)
 120 HC05: +illegal address during opcode fetch
 121 HC08: +illegal address duting opcode fetch (ILAD mascherabile)
 122       +illegal opcode (ILOP mascherabile)
 123
 124 (Il programma viene programmato nella FLASH)
 125 HCS08: +illegal address during opcode fetch (ILAD mascherabile)
 126        +illegal opcode (ILOP mascherabile)
 127        +security = accesso a RAM e zone FLASH dichiarate sicure da zone sicure
 128                    da' 0 in lettura e ignore in scrittura, [FLASH]SEC00:SEC01 (1,0)
 129                    corrisponde a OFF, altre ON, disattivabile solo da modalita' sicura se
 130                    opzione [FLASH]KEYEN e' 1 passando chiave a 8byte da modalita' sicura.
 131                    Altrimenti disattivabile solo con FLASH mass erase. Obbiettivo
 132                    e' impedire duplicazione di software di controllo, dato che esiste
 133                    modalita' debugging. A restart viene ricaricata da FLASH impostazione
 134                    sicurezza!
 135 RS08: +illegal address durting opcode fetch (ILAD) mascherabile
 136       +illegal opcode (ILOP mascherabile)
 137       +security = solo la FLASH e' considerata sicura. Stesso meccanismo di HCS08
 138                   ma governato solo da [FLASH]SECD (0) OFF.Una volta attivato l'unica
 139                   disattivazione e' la cancellazione della FLASH.
 140 *)
 141
 142 (* memoria degli HC05 *)
 143 ndefinition memory_type_of_FamilyHC05 ≝
 144 λm:HC05_mcu_model.match m with
 145   [ MC68HC05J5A ⇒
 146    [
 147   (* astraggo molto *)
 148   (* 0x0000-0x001F,0x0FF0: sarebbe memory mapped IO *)
 149
 150      triple ??? 〈〈x0,x0〉:〈x8,x0〉〉 〈〈x0,x0〉:〈xF,xF〉〉 MEM_READ_WRITE (* 128B RAM+STACK *)
 151    ; triple ??? 〈〈x0,x3〉:〈x0,x0〉〉 〈〈x0,xC〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 2560B USER ROM *)
 152    ; triple ??? 〈〈x0,xE〉:〈x0,x0〉〉 〈〈x0,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 512B INTERNAL ROM *)
 153     ]
 154    (*..*)
 155   ].
 156
 157 (* memoria degli HC08 *)
 158 ndefinition memory_type_of_FamilyHC08 ≝
 159 λm:HC08_mcu_model.match m with
 160   [ MC68HC08AB16A ⇒
 161    [
 162   (* astraggo molto *)
 163   (* 0x0000-0x004F,0xFE00-0xFE01,0xFE03,
 164      0xFE0C-0xFE11,0xFE1A-0xFE1D,0xFE1F: sarebbe memory mapped IO *)
 165   (* 0x0500-0x057F,0xFE02,0xFE04-0xFE07,
 166      0xFE09-0xFE0B,0xFE12-0xFE19,0xFE1E,0xFFC0-0xFFCF : sarebbe reserved *)
 167
 168      triple ??? 〈〈x0,x0〉:〈x5,x0〉〉 〈〈x0,x2〉:〈x4,xF〉〉 MEM_READ_WRITE (* 512B RAM *)
 169    ; triple ??? 〈〈x0,x8〉:〈x0,x0〉〉 〈〈x0,x9〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 512B EEPROM *)
 170    ; triple ??? 〈〈xB,xE〉:〈x0,x0〉〉 〈〈xF,xD〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 16384B ROM *)
 171    ; triple ??? 〈〈xF,xE〉:〈x2,x0〉〉 〈〈xF,xF〉:〈x5,x2〉〉 MEM_READ_ONLY  (* 307B ROM *)
 172    ; triple ??? 〈〈xF,xF〉:〈xD,x0〉〉 〈〈xF,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 48B ROM *) ]
 173    (*..*)
 174   ].
 175
 176 (* memoria degli HCS08 *)
 177 ndefinition memory_type_of_FamilyHCS08 ≝
 178 λm:HCS08_mcu_model.match m with
 179   [ MC9S08AW60 ⇒
 180    [
 181   (* astraggo molto *)
 182   (* 0x0000-0x006F,0x1800-0x185F: sarebbe memory mapped IO *)
 183
 184      triple ??? 〈〈x0,x0〉:〈x7,x0〉〉 〈〈x0,x8〉:〈x6,xF〉〉 MEM_READ_WRITE (* 2048B RAM *)
 185    ; triple ??? 〈〈x0,x8〉:〈x7,x0〉〉 〈〈x1,x7〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 3984B FLASH *)
 186    ; triple ??? 〈〈x1,x8〉:〈x6,x0〉〉 〈〈xF,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 59296B FLASH *) ]
 187   | MC9S08GB60 ⇒
 188    [
 189   (* astraggo molto *)
 190   (* 0x0000-0x006F,0x1800-0x185F: sarebbe memory mapped IO *)
 191
 192      triple ??? 〈〈x0,x0〉:〈x8,x0〉〉 〈〈x1,x0〉:〈x7,xF〉〉 MEM_READ_WRITE (* 4096B RAM *)
 193    ; triple ??? 〈〈x1,x0〉:〈x8,x0〉〉 〈〈x1,x7〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 1920B FLASH *)
 194    ; triple ??? 〈〈x1,x8〉:〈x2,xC〉〉 〈〈xF,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 59348B FLASH *) ]
 195   ].
 196
 197 (* memoria dei RS08 *)
 198 ndefinition memory_type_of_FamilyRS08 ≝
 199 λm:RS08_mcu_model.match m with
 200   [ MC9RS08KA1 ⇒
 201    [
 202      triple ??? 〈〈x0,x0〉:〈x0,x0〉〉 〈〈x0,x0〉:〈x0,xE〉〉 MEM_READ_WRITE (* 15B RAM *)
 203   (* [000F] e' il registro X *)
 204   (* 0x0010-0x001E sarebbe memory mapped IO, proviamo per completezza con RAM *)
 205    ; triple ??? 〈〈x0,x0〉:〈x1,x0〉〉 〈〈x0,x0〉:〈x1,xE〉〉 MEM_READ_WRITE (* 15B MEMORY MAPPED IO *)
 206   (* [001F] e' il registro PAGESEL *)
 207    ; triple ??? 〈〈x0,x0〉:〈x2,x0〉〉 〈〈x0,x0〉:〈x4,xF〉〉 MEM_READ_WRITE (* 48B RAM *)
 208   (* [00C0-00FF] mappato da PAGESEL su [00pp pppp ppxx xxxx] *)
 209    ; triple ??? 〈〈x0,x0〉:〈xC,x0〉〉 〈〈x0,x0〉:〈xF,xF〉〉 MEM_READ_WRITE (* 64B RAM PAGING *)
 210   (* 0x0200-0x023F sarebbe memory mapped IO, proviamo per completezza con RAM *)
 211    ; triple ??? 〈〈x0,x2〉:〈x0,x0〉〉 〈〈x0,x2〉:〈x3,xF〉〉 MEM_READ_WRITE (* 64B MEMORY MAPPED IO *)
 212    ; triple ??? 〈〈x3,xC〉:〈x0,x0〉〉 〈〈x3,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 1024B FLASH *) ]
 213   | MC9RS08KA2 ⇒
 214    [
 215      triple ??? 〈〈x0,x0〉:〈x0,x0〉〉 〈〈x0,x0〉:〈x0,xE〉〉 MEM_READ_WRITE (* 15B RAM *)
 216   (* [000F] e' il registro X *)
 217   (* 0x0010-0x001E sarebbe memory mapped IO, proviamo per completezza con RAM *)
 218    ; triple ??? 〈〈x0,x0〉:〈x1,x0〉〉 〈〈x0,x0〉:〈x1,xE〉〉 MEM_READ_WRITE (* 15B MEMORY MAPPED IO *)
 219   (* [001F] e' il registro PAGESEL *)
 220    ; triple ??? 〈〈x0,x0〉:〈x2,x0〉〉 〈〈x0,x0〉:〈x4,xF〉〉 MEM_READ_WRITE (* 48B RAM *)
 221   (* [00C0-00FF] mappato da PAGESEL su [00pp pppp ppxx xxxx] *)
 222    ; triple ??? 〈〈x0,x0〉:〈xC,x0〉〉 〈〈x0,x0〉:〈xF,xF〉〉 MEM_READ_WRITE (* 64B RAM PAGING *)
 223   (* 0x0200-0x023F sarebbe memory mapped IO, proviamo per completezza con RAM *)
 224    ; triple ??? 〈〈x0,x2〉:〈x0,x0〉〉 〈〈x0,x2〉:〈x3,xF〉〉 MEM_READ_WRITE (* 64B MEMORY MAPPED IO *)
 225    ; triple ??? 〈〈x3,x8〉:〈x0,x0〉〉 〈〈x3,xF〉:〈xF,xF〉〉 MEM_READ_ONLY  (* 2048B FLASH *) ]
 226   ].
 227
 228 (* ∀modello.descrizione della memoria installata *)
 229 ndefinition memory_type_of_mcu_version ≝
 230 λmcu:any_mcu_model.match mcu with
 231  [ FamilyHC05  m ⇒ memory_type_of_FamilyHC05 m
 232  | FamilyHC08  m ⇒ memory_type_of_FamilyHC08 m
 233  | FamilyHCS08 m ⇒ memory_type_of_FamilyHCS08 m
 234  | FamilyRS08  m ⇒ memory_type_of_FamilyRS08 m
 235  ].
 236
 237 (* dato un modello costruisce un descrittore a partire dalla lista precedente *)
 238 nlet rec build_memory_type_of_mcu_version_aux t param (result:aux_chk_type t) on param ≝
 239  match param with
 240   [ nil ⇒ result
 241   | cons hd tl ⇒
 242    build_memory_type_of_mcu_version_aux t tl
 243     (check_update_ranged t result (fst3T ??? hd) (snd3T ??? hd) (thd3T ??? hd)) ].
 244
 245 ndefinition build_memory_type_of_mcu_version ≝
 246 λmcu:any_mcu_model.λt:memory_impl.
 247  build_memory_type_of_mcu_version_aux t (memory_type_of_mcu_version mcu) (out_of_bound_memory t).
 248
 249 (* sarebbe programma da caricare/zero_memory, ora test *)
 250 ndefinition memory_of_mcu_version ≝
 251 λmcu:any_mcu_model.λt:memory_impl.match mcu with
 252  [ FamilyHC05 m ⇒ match m with
 253   [ MC68HC05J5A ⇒ zero_memory t
 254     (*..*)
 255   ]
 256  | FamilyHC08 m ⇒ match m with
 257   [ MC68HC08AB16A ⇒ zero_memory t
 258     (*..*)
 259   ]
 260  (* tralascio l'enumerazione dei casi, per ora e' tutto 0 *)
 261  | FamilyHCS08 _ ⇒ zero_memory t
 262  | FamilyRS08 _ ⇒ zero_memory t
 263  ].
 264
 265 (*
 266    parametrizzati i non deterministici rispetto a tutti i valori casuali
 267    che verranno dati dall'esterno di tipo byte8 (ndby1-2) e bool (ndbo1-5).
 268    l'ACCENSIONE e' totalmente equivalente ad un reset causato da calo di tensione
 269    (reset V-low), la memoria ed il check puo' essere passata, per esempio da
 270    - (memory_of_mcu_version MC68HC05J5A)
 271    - (build_memory_type_of_mcu_version MC68HC05J5A)
 272 *)
 273 ndefinition start_of_mcu_version_HC05 ≝
 274 λmcu:HC05_mcu_model.λt:memory_impl.
 275 λmem:aux_mem_type t.λchk:aux_chk_type t.
 276 λndby1,ndby2:byte8.λirqfl,ndbo1,ndbo2,ndbo3,ndbo4,ndbo5:bool.
 277  let build ≝ λspm,spf,pcm:word16.
 278  let fetched_pc ≝ mk_word16 (mem_read_abs t mem (and_w16 〈〈xF,xF〉:〈xF,xE〉〉 pcm))
 279                             (mem_read_abs t mem (and_w16 〈〈xF,xF〉:〈xF,xF〉〉 pcm)) in
 280   mk_any_status HC05 t
 281    (mk_alu_HC05
 282     (* acc_low: ? *) ndby1 (* indx_low: ? *) ndby2
 283     (* sp: reset *) (or_w16 (and_w16 〈〈x0,x0〉:〈xF,xF〉〉 spm) spf) spm spf
 284     (* pc: reset+fetch *) (and_w16 fetched_pc pcm) pcm
 285     (* H: ? *) ndbo1 (* I: reset *) true (* N: ? *) ndbo2
 286     (* Z: ? *) ndbo3 (* C: ? *) ndbo4 (* IRQ: ? *) irqfl)
 287     (* mem *) mem
 288     (* chk *) chk
 289     (* clk: reset *) (None ?) in
 290  match mcu with
 291   [ MC68HC05J5A ⇒ build 〈〈x0,x0〉:〈x3,xF〉〉 〈〈x0,x0〉:〈xC,x0〉〉 〈〈x0,xF〉:〈xF,xF〉〉
 292     (*..*)
 293   ].
 294
 295 ndefinition start_of_mcu_version_HC08 ≝
 296 λmcu:HC08_mcu_model.λt:memory_impl.
 297 λmem:aux_mem_type t.λchk:aux_chk_type t.
 298 λndby1,ndby2:byte8.λirqfl,ndbo1,ndbo2,ndbo3,ndbo4,ndbo5:bool.
 299  let fetched_pc ≝ mk_word16 (mem_read_abs t mem 〈〈xF,xF〉:〈xF,xE〉〉)
 300                             (mem_read_abs t mem 〈〈xF,xF〉:〈xF,xF〉〉) in
 301   mk_any_status HC08 t
 302    (mk_alu_HC08
 303     (* acc_low: ? *) ndby1 (* indw_low: ? *) ndby2 (* indx_high: reset *)  〈x0,x0〉
 304     (* sp: reset *) 〈〈x0,x0〉:〈xF,xF〉〉 (* pc: reset+fetch *) fetched_pc
 305     (* V: ? *) ndbo1 (* H: ? *) ndbo2 (* I: reset *) true
 306     (* N: ? *) ndbo3 (* Z: ? *) ndbo4 (* C: ? *) ndbo5 (* IRQ: ? *) irqfl)
 307     (* mem *) mem
 308     (* chk *) chk
 309     (* clk: reset *) (None ?).
 310
 311 ndefinition start_of_mcu_version_HCS08 ≝
 312 λmcu:HCS08_mcu_model.λt:memory_impl.
 313 λmem:aux_mem_type t.λchk:aux_chk_type t.
 314 λndby1,ndby2:byte8.λirqfl,ndbo1,ndbo2,ndbo3,ndbo4,ndbo5:bool.
 315  let fetched_pc ≝ mk_word16 (mem_read_abs t mem 〈〈xF,xF〉:〈xF,xE〉〉)
 316                             (mem_read_abs t mem 〈〈xF,xF〉:〈xF,xF〉〉) in
 317   mk_any_status HCS08 t
 318    (mk_alu_HC08
 319     (* acc_low: ? *) ndby1 (* indw_low: ? *) ndby2 (* indx_high: reset *)  〈x0,x0〉
 320     (* sp: reset *) 〈〈x0,x0〉:〈xF,xF〉〉 (* pc: reset+fetch *) fetched_pc
 321     (* V: ? *) ndbo1 (* H: ? *) ndbo2 (* I: reset *) true
 322     (* N: ? *) ndbo3 (* Z: ? *) ndbo4 (* C: ? *) ndbo5 (* IRQ: ? *) irqfl)
 323     (* mem *) mem
 324     (* chk *) chk
 325     (* clk: reset *) (None ?).
 326
 327 ndefinition start_of_mcu_version_RS08 ≝
 328 λmcu:RS08_mcu_model.λt:memory_impl.
 329 λmem:aux_mem_type t.λchk:aux_chk_type t.
 330 λndby1,ndby2:byte8.λirqfl,ndbo1,ndbo2,ndbo3,ndbo4,ndbo5:bool.
 331  let build ≝ λpcm.
 332    mk_any_status RS08 t
 333     (mk_alu_RS08
 334      (* acc_low: reset *)  〈x0,x0〉
 335      (* pc: reset *) (and_w16 〈〈xF,xF〉:〈xF,xD〉〉 pcm) pcm
 336      (* spc: reset *) (and_w16 〈〈xF,xF〉:〈xF,xD〉〉 pcm)
 337      (* xm: reset *) 〈x0,x0〉 (* psm: *) 〈x8,x0〉
 338      (* Z: reset *) false (* C: reset *) false)
 339      (* mem *) mem
 340      (* chk *) chk
 341      (* clk: reset *) (None ?) in
 342   (* tralascio l'enumerazione dei casi, tanto i valori sono uguali *)
 343   build 〈〈x3,xF〉:〈xF,xF〉〉.
 344
 345 (*
 346    cio' che non viene resettato mantiene il valore precedente: nella documentazione
 347    viene riportato come "unaffected"/"indeterminate"/"unpredictable"
 348    il soft RESET e' diverso da un calo di tensione e la ram non variera'
 349 *)
 350 ndefinition reset_of_mcu ≝
 351 λm:mcu_type.λt:memory_impl.
 352 let pc_reset_h ≝ 〈〈xF,xF〉:〈xF,xE〉〉 in
 353 let pc_reset_l ≝ 〈〈xF,xF〉:〈xF,xF〉〉 in
 354 let pc_RS08_reset ≝ 〈〈xF,xF〉:〈xF,xD〉〉 in
 355 let sp_reset ≝ 〈〈x0,x0〉:〈xF,xF〉〉 in
 356  match m return λm:mcu_type.(any_status m t) → (any_status m t) with
 357 (* HC05: parzialmente non deterministico *)
 358   [ HC05 ⇒ λs:any_status HC05 t.match s with
 359    [ mk_any_status alu mem chk clk ⇒ match alu with
 360     [ mk_alu_HC05 acclow indxlow _ spm spf _ pcm hfl _ nfl zfl cfl irqfl ⇒
 361     let fetched_pc ≝ mk_word16 (mem_read_abs t mem (and_w16 pc_reset_h pcm))
 362                                (mem_read_abs t mem (and_w16 pc_reset_l pcm)) in
 363     mk_any_status HC05 t
 364      (mk_alu_HC05
 365       (* acc_low: inv. *) acclow (* indx_low: inv. *) indxlow
 366       (* sp: reset *) (or_w16 (and_w16 sp_reset spm) spf) spm spf
 367       (* pc: reset+fetch *) (and_w16 fetched_pc pcm) pcm
 368       (* H: inv. *) hfl (* I: reset *) true (* N: inv. *) nfl
 369       (* Z: inv. *) zfl (* C: inv. *) cfl (* IRQ: inv *) irqfl)
 370       (* mem: inv. *) mem
 371       (* chk: inv. *) chk
 372       (* clk: reset *) (None ?) ]]
 373 (* HC08: parzialmente non deterministico *)
 374   | HC08 ⇒ λs:any_status HC08 t.match s with
 375    [ mk_any_status alu mem chk clk ⇒ match alu with
 376     [ mk_alu_HC08 acclow indxlow _ _ _ vfl hfl _ nfl zfl cfl irqfl ⇒
 377     let fetched_pc ≝ mk_word16 (mem_read_abs t mem pc_reset_h)
 378                                (mem_read_abs t mem pc_reset_l) in
 379     mk_any_status HC08 t
 380      (mk_alu_HC08
 381       (* acc_low: inv. *) acclow (* indx_low: inv. *) indxlow (* indx_high: reset *) 〈x0,x0〉
 382       (* sp: reset *) sp_reset (* pc: reset+fetch *) fetched_pc
 383       (* V: inv. *) vfl (* H: inv. *) hfl (* I: reset *) true
 384       (* N: inv. *) nfl (* Z: inv. *) zfl (* C: inv. *) cfl (* IRQ: inv *) irqfl)
 385       (* mem: inv. *) mem
 386       (* chk: inv. *) chk
 387       (* clk: reset *) (None ?) ]]
 388 (* HCS08: parzialmente non deterministico *)
 389   | HCS08 ⇒ λs:any_status HCS08 t.match s with
 390    [ mk_any_status alu mem chk clk ⇒ match alu with
 391     [ mk_alu_HC08 acclow indxlow _ _ _ vfl hfl _ nfl zfl cfl irqfl ⇒
 392     let fetched_pc ≝ mk_word16 (mem_read_abs t mem pc_reset_h)
 393                                (mem_read_abs t mem pc_reset_l) in
 394     mk_any_status HCS08 t
 395      (mk_alu_HC08
 396       (* acc_low: inv. *) acclow (* indx_low: inv. *) indxlow (* indx_high: reset *) 〈x0,x0〉
 397       (* sp: reset *) sp_reset (* pc: reset+fetch *) fetched_pc
 398       (* V: inv. *) vfl (* H: inv. *) hfl (* I: reset *) true
 399       (* N: inv. *) nfl (* Z: inv. *) zfl (* C: inv. *) cfl (* IRQ: inv *) irqfl)
 400       (* mem: inv. *) mem
 401       (* chk: inv. *) chk
 402       (* clk: reset *) (None ?) ]]
 403 (* RS08: deterministico *)
 404   | RS08 ⇒ λs:any_status RS08 t.match s with
 405    [ mk_any_status alu mem chk clk ⇒ match alu with
 406     [ mk_alu_RS08 _ _ pcm _ _ _ _ _ ⇒
 407     mk_any_status RS08 t
 408      (mk_alu_RS08
 409       (* acc_low: reset *) 〈x0,x0〉
 410       (* pc: reset *) (and_w16 pc_RS08_reset pcm) pcm
 411       (* spc: reset *) (and_w16 pc_RS08_reset pcm)
 412       (* xm: reset *) 〈x0,x0〉 (* psm: reset *) 〈x8,x0〉
 413       (* Z: reset *) false (* C: reset *) false)
 414       (* mem: inv. *) mem
 415       (* chk: inv. *) chk
 416       (* clk: reset *) (None ?) ]]
 417   ].