helm/software/matita/contribs/ng_assembly/freescale/translation.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* ********************************************************************** *)
  16 (*                          Progetto FreeScale                            *)
  17 (*                                                                        *)
  18 (*   Sviluppato da: Ing. Cosimo Oliboni, oliboni@cs.unibo.it              *)
  19 (*   Ultima modifica: 05/08/2009                                          *)
  20 (*                                                                        *)
  21 (* ********************************************************************** *)
  22
  23 include "freescale/table_HC05.ma".
  24 include "freescale/table_HC08.ma".
  25 include "freescale/table_HCS08.ma".
  26 include "freescale/table_RS08.ma".
  27 include "common/option.ma".
  28
  29 (* ***************************** *)
  30 (* TRADUZIONE ESADECIMALE → INFO *)
  31 (* ***************************** *)
  32
  33 (* accesso alla tabella della ALU prescelta *)
  34 ndefinition opcode_table ≝
  35 λm:mcu_type.
  36  match m
  37   return λm:mcu_type.list (Prod4T (any_opcode m) instr_mode byte8_or_word16 byte8)
  38  with
  39   [ HC05  ⇒ opcode_table_HC05
  40   | HC08  ⇒ opcode_table_HC08
  41   | HCS08 ⇒ opcode_table_HCS08
  42   | RS08  ⇒ opcode_table_RS08
  43  ].
  44
  45 (* traduzione mcu+esadecimale → info *)
  46 (* NB: la ricerca per byte non matcha con una word con lo stesso byte superiore uguale *)
  47 (* NB: per matchare una word (precode+code) bisogna passare una word *)
  48 (* NB: il risultato e' sempre un'opzione, NON esiste un dummy opcode tipo UNKNOWN/ILLEGAL *)
  49 nlet rec full_info_of_word16_aux (m:mcu_type) (borw:byte8_or_word16)
  50                                 (param:list (Prod4T (any_opcode m) instr_mode byte8_or_word16 byte8)) on param ≝
  51  match param with
  52   [ nil ⇒ None ?
  53   | cons hd tl ⇒
  54    match thd4T … hd with
  55     [ Byte b ⇒ match borw with
  56      [ Byte borw' ⇒ match eq_b8 borw' b with
  57       [ true ⇒ Some ? hd
  58       | false ⇒ full_info_of_word16_aux m borw tl ]
  59      | Word _ ⇒ full_info_of_word16_aux m borw tl ]
  60     | Word w ⇒ match borw with
  61      [ Byte _ ⇒ full_info_of_word16_aux m borw tl
  62      | Word borw' ⇒ match eq_w16 borw' w with
  63       [ true ⇒ Some ? hd
  64       | false ⇒ full_info_of_word16_aux m borw tl ]
  65     ]]].
  66
  67 ndefinition full_info_of_word16 ≝
  68 λm:mcu_type.λborw:byte8_or_word16.
  69 full_info_of_word16_aux m borw (opcode_table m).
  70
  71 (* ******************************************************* *)
  72 (* TRADUZIONE MCU+OPCODE+MODALITA'+ARGOMENTI → ESADECIMALE *)
  73 (* ******************************************************* *)
  74
  75 (* introduzione di un tipo byte8 dipendente dall'mcu_type (phantom type) *)
  76 ninductive t_byte8 (m:mcu_type) : Type ≝
  77  TByte : byte8 → t_byte8 m.
  78
  79 (* introduzione di un tipo dipendente (dalla modalita') per gli argomenti *)
  80 ninductive MA_check : instr_mode → Type ≝
  81   maINH              : MA_check MODE_INH
  82 | maINHA             : MA_check MODE_INHA
  83 | maINHX             : MA_check MODE_INHX
  84 | maINHH             : MA_check MODE_INHH
  85 | maINHX0ADD         : MA_check MODE_INHX0ADD
  86 | maINHX1ADD         : byte8 → MA_check MODE_INHX1ADD
  87 | maINHX2ADD         : word16 → MA_check MODE_INHX2ADD
  88 | maIMM1             : byte8  → MA_check MODE_IMM1
  89 | maIMM1EXT          : byte8  → MA_check MODE_IMM1EXT
  90 | maIMM2             : word16 → MA_check MODE_IMM2
  91 | maDIR1             : byte8  → MA_check MODE_DIR1
  92 | maDIR2             : word16 → MA_check MODE_DIR2
  93 | maIX0              : MA_check MODE_IX0
  94 | maIX1              : byte8  → MA_check MODE_IX1
  95 | maIX2              : word16 → MA_check MODE_IX2
  96 | maSP1              : byte8  → MA_check MODE_SP1
  97 | maSP2              : word16 → MA_check MODE_SP2
  98 | maDIR1_to_DIR1     : byte8 → byte8 → MA_check MODE_DIR1_to_DIR1
  99 | maIMM1_to_DIR1     : byte8 → byte8 → MA_check MODE_IMM1_to_DIR1
 100 | maIX0p_to_DIR1     : byte8 → MA_check MODE_IX0p_to_DIR1
 101 | maDIR1_to_IX0p     : byte8 → MA_check MODE_DIR1_to_IX0p
 102 | maINHA_and_IMM1    : byte8 → MA_check MODE_INHA_and_IMM1
 103 | maINHX_and_IMM1    : byte8 → MA_check MODE_INHX_and_IMM1
 104 | maIMM1_and_IMM1    : byte8 → byte8 → MA_check MODE_IMM1_and_IMM1
 105 | maDIR1_and_IMM1    : byte8 → byte8 → MA_check MODE_DIR1_and_IMM1
 106 | maIX0_and_IMM1     : byte8 → MA_check MODE_IX0_and_IMM1
 107 | maIX0p_and_IMM1    : byte8 → MA_check MODE_IX0p_and_IMM1
 108 | maIX1_and_IMM1     : byte8 → byte8 → MA_check MODE_IX1_and_IMM1
 109 | maIX1p_and_IMM1    : byte8 → byte8 → MA_check MODE_IX1p_and_IMM1
 110 | maSP1_and_IMM1     : byte8 → byte8 → MA_check MODE_SP1_and_IMM1
 111 | maDIRn             : ∀n.byte8 → MA_check (MODE_DIRn n)
 112 | maDIRn_and_IMM1    : ∀n.byte8 → byte8 → MA_check (MODE_DIRn_and_IMM1 n)
 113 | maTNY              : ∀e.MA_check (MODE_TNY e)
 114 | maSRT              : ∀t.MA_check (MODE_SRT t)
 115 .
 116
 117 (* picker: trasforma l'argomento necessario in input a bytes_of_pseudo_instr_mode_param:
 118    MA_check i → list (t_byte8 m) *)
 119 ndefinition args_picker ≝
 120 λm:mcu_type.λi:instr_mode.λargs:MA_check i.
 121  match args with
 122   (* inherent: legale se nessun operando *)
 123   [ maINH    ⇒ nil ?
 124   | maINHA   ⇒ nil ?
 125   | maINHX   ⇒ nil ?
 126   | maINHH   ⇒ nil ?
 127   (* inherent address: legale se nessun operando/1 byte/1 word *)
 128   | maINHX0ADD ⇒ nil ?
 129   | maINHX1ADD b ⇒ [ TByte m b ]
 130   | maINHX2ADD w ⇒ [ TByte m (w16h w); TByte m (w16l w) ]
 131   (* _0/1/2: legale se nessun operando/1 byte/1 word *)
 132   | maIMM1 b ⇒ [ TByte m b ]
 133   | maIMM1EXT b ⇒ [ TByte m b ]
 134   | maIMM2 w ⇒ [ TByte m (w16h w); TByte m (w16l w) ]
 135   | maDIR1 b ⇒ [ TByte m b ]
 136   | maDIR2 w ⇒ [ TByte m (w16h w); TByte m (w16l w) ]
 137   | maIX0    ⇒ nil ?
 138   | maIX1 b  ⇒ [ TByte m b ]
 139   | maIX2 w  ⇒ [ TByte m (w16h w); TByte m (w16l w) ]
 140   | maSP1 b  ⇒ [ TByte m b ]
 141   | maSP2 w  ⇒ [ TByte m (w16h w); TByte m (w16l w) ]
 142   (* movimento: legale se 2 operandi byte *)
 143   | maDIR1_to_DIR1 b1 b2  ⇒ [ TByte m b1 ; TByte m b2 ]
 144   | maIMM1_to_DIR1 b1 b2  ⇒ [ TByte m b1 ; TByte m b2 ]
 145   | maIX0p_to_DIR1 b      ⇒ [ TByte m b]
 146   | maDIR1_to_IX0p b      ⇒ [ TByte m b]
 147   (* cbeq/dbnz: legale se 1/2 operandi byte *)
 148   | maINHA_and_IMM1 b     ⇒ [ TByte m b]
 149   | maINHX_and_IMM1 b     ⇒ [ TByte m b]
 150   | maIMM1_and_IMM1 b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 151   | maDIR1_and_IMM1 b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 152   | maIX0_and_IMM1  b     ⇒ [ TByte m b]
 153   | maIX0p_and_IMM1 b     ⇒ [ TByte m b]
 154   | maIX1_and_IMM1  b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 155   | maIX1p_and_IMM1 b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 156   | maSP1_and_IMM1  b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 157   (* DIRn: legale se 1 operando byte *)
 158   | maDIRn _ b ⇒ [ TByte m b]
 159   (* DIRn_and_IMM1: legale se 2 operandi byte *)
 160   | maDIRn_and_IMM1 _ b1 b2 ⇒ [ TByte m b1 ; TByte m b2 ]
 161   (* TNY: legale se nessun operando *)
 162   | maTNY _ ⇒ nil ?
 163   (* SRT: legale se nessun operando *)
 164   | maSRT _ ⇒ nil ?
 165   ].
 166
 167 (* trasformatore finale: mcu+opcode+instr_mode+args → list (t_byte8 m) *)
 168 nlet rec bytes_of_pseudo_instr_mode_param_aux (m:mcu_type) (o:any_opcode m) (i:instr_mode) (p:MA_check i)
 169                                              (param:list (Prod4T (any_opcode m) instr_mode byte8_or_word16 byte8)) on param ≝
 170  match param with
 171  [ nil ⇒ None ? | cons hd tl ⇒
 172   match (eq_anyop m o (fst4T … hd)) ⊗ (eq_im i (snd4T … hd)) with
 173    [ true ⇒ match thd4T … hd with
 174     [ Byte isab ⇒
 175      Some ? ([ (TByte m isab) ]@(args_picker m i p))
 176     | Word isaw ⇒
 177      Some ? ([ (TByte m (w16h isaw)) ; (TByte m (w16l isaw)) ]@(args_picker m i p))
 178     ]
 179    | false ⇒ bytes_of_pseudo_instr_mode_param_aux m o i p tl ]].
 180
 181 ndefinition bytes_of_pseudo_instr_mode_param ≝
 182 λm:mcu_type.λo:any_opcode m.λi:instr_mode.λp:MA_check i.
 183 bytes_of_pseudo_instr_mode_param_aux m o i p (opcode_table m).
 184
 185 (* ****************************** *)
 186 (* APPROCCIO COMPILAZIONE AL VOLO *)
 187 (* ****************************** *)
 188
 189 (* ausiliario di compile *)
 190 ndefinition defined_option ≝
 191  λT:Type.λo:option T.
 192   match o with
 193    [ None ⇒ False
 194    | Some _ ⇒ True
 195    ].
 196
 197 (* compila solo se l'intera istruzione+modalita'+argomenti ha riscontro nelle tabelle *)
 198 ndefinition compile ≝
 199 λmcu:mcu_type.λi:instr_mode.λop:opcode.λarg:MA_check i.
 200  match bytes_of_pseudo_instr_mode_param mcu (anyOP mcu op) i arg
 201   return λres:option ?.defined_option ? res → ?
 202  with
 203   [ None ⇒ λp:defined_option ? (None ?).False_rect_Type0 ? p
 204   | Some x ⇒ λp:defined_option ? (Some ? x).x
 205   ].
 206
 207 (* detipatore del compilato: (t_byte8 m) → byte8 *)
 208 nlet rec source_to_byte8_HC05_aux (p1:list (t_byte8 HC05)) (p2:list byte8) ≝
 209  match p1 with
 210   [ nil ⇒ p2
 211   | cons hd tl ⇒ match hd with [ TByte b ⇒ source_to_byte8_HC05_aux tl (p2@[b]) ]
 212   ].
 213
 214 nlet rec source_to_byte8_HC08_aux (p1:list (t_byte8 HC08)) (p2:list byte8) ≝
 215  match p1 with
 216   [ nil ⇒ p2
 217   | cons hd tl ⇒ match hd with [ TByte b ⇒ source_to_byte8_HC08_aux tl (p2@[b]) ]
 218   ].
 219
 220 nlet rec source_to_byte8_HCS08_aux (p1:list (t_byte8 HCS08)) (p2:list byte8) ≝
 221  match p1 with
 222   [ nil ⇒ p2
 223   | cons hd tl ⇒ match hd with [ TByte b ⇒ source_to_byte8_HCS08_aux tl (p2@[b]) ]
 224   ].
 225
 226 nlet rec source_to_byte8_RS08_aux (p1:list (t_byte8 RS08)) (p2:list byte8) ≝
 227  match p1 with
 228   [ nil ⇒ p2
 229   | cons hd tl ⇒ match hd with [ TByte b ⇒ source_to_byte8_RS08_aux tl (p2@[b]) ]
 230   ].
 231
 232 ndefinition source_to_byte8 ≝
 233 λm:mcu_type.
 234  match m
 235   return λm:mcu_type.list (t_byte8 m) → list byte8
 236  with
 237   [ HC05 ⇒ λl:list (t_byte8 HC05).source_to_byte8_HC05_aux l []
 238   | HC08 ⇒ λl:list (t_byte8 HC08).source_to_byte8_HC08_aux l []
 239   | HCS08 ⇒ λl:list (t_byte8 HCS08).source_to_byte8_HCS08_aux l []
 240   | RS08 ⇒ λl:list (t_byte8 RS08).source_to_byte8_RS08_aux l []
 241   ].