helm/software/matita/contribs/ng_assembly/freescale_tests/micro_tests4.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* ********************************************************************** *)
  16 (*                          Progetto FreeScale                            *)
  17 (*                                                                        *)
  18 (*   Sviluppato da: Ing. Cosimo Oliboni, oliboni@cs.unibo.it              *)
  19 (*   Ultima modifica: 05/08/2009                                          *)
  20 (*                                                                        *)
  21 (* ********************************************************************** *)
  22
  23 include "freescale_tests/micro_tests_tools.ma".
  24 include "freescale/multivm.ma".
  25 include "freescale/status_lemmas.ma".
  26
  27 (* ****************************************** *)
  28 (* MICRO TEST DI CORRETTEZZA DELLE ISTRUZIONI *)
  29 (* ****************************************** *)
  30
  31 (* **************** *)
  32 (* HCS08 CBEQx/DBNZ *)
  33 (* **************** *)
  34
  35 ndefinition mTest_HCS08_CBEQ_DBNZ_source ≝ let m ≝ HCS08 in source_to_byte8 m (
  36 (* testa la logica di CBEQx/DBNZ e le modalita' xxx_and_IMM1 *)
  37 (* BEFORE: H:X=0x006F SP=0x006F PC=0x1860 *)
  38 (* [0x1860] 5clk *) (compile m ? CBEQA (maDIR1_and_IMM1 〈x7,x1〉 〈x0,x1〉) I) @
  39 (* [0x1863] 1clk *) (compile m ? NOP maINH I) @                               (* eseguito: A≠[0x0071]=0x01 *)
  40 (* [0x1864] 4clk *) (compile m ? CBEQA (maIMM1_and_IMM1 〈x0,x0〉 〈x0,x1〉) I) @
  41 (* [0x1867] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: A=0x00 *)
  42 (* [0x1868] 4clk *) (compile m ? CBEQX (maIMM1_and_IMM1 〈x6,xF〉 〈x0,x1〉) I) @
  43 (* [0x186B] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: X=0x6F *)
  44 (* [0x186C] 5clk *) (compile m ? CBEQA (maIX1p_and_IMM1 〈x0,x1〉 〈x0,x1〉) I) @ (* H:X++ *)
  45 (* [0x186F] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: A=[X+0x01]=[0x0070]=0x00 *)
  46 (* [0x1870] 5clk *) (compile m ? CBEQA (maIX0p_and_IMM1 〈x0,x1〉) I) @         (* H:X++ *)
  47 (* [0x1872] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: A=[X]=[0x0070]=0x00 *)
  48 (* [0x1873] 6clk *) (compile m ? CBEQA (maSP1_and_IMM1 〈x0,x2〉 〈x0,x1〉) I) @
  49 (* [0x1877] 1clk *) (compile m ? NOP maINH I) @                               (* eseguito: A≠[SP+0x02]=[0x0071]=0x01 *)
  50
  51 (* [0x1878] 7clk *) (compile m ? DBNZ (maDIR1_and_IMM1 〈x7,x2〉 〈x0,x1〉) I) @
  52 (* [0x187B] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: --[0x0072]=0x01≠0 *)
  53 (* [0x187C] 4clk *) (compile m ? DBNZ (maINHA_and_IMM1 〈x0,x1〉) I) @
  54 (* [0x187E] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: --A=0xFF≠0 *)
  55 (* [0x187F] 4clk *) (compile m ? DBNZ (maINHX_and_IMM1 〈x0,x1〉) I) @
  56 (* [0x1881] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: --X=0x70≠0 *)
  57 (* [0x1882] 7clk *) (compile m ? DBNZ (maIX1_and_IMM1 〈x0,x2〉 〈x0,x1〉) I) @
  58 (* [0x1885] 1clk *) (compile m ? NOP maINH I) @                               (* eseguito: --[X+0x02]=[0x0072]=0x00=0 *)
  59 (* [0x1886] 6clk *) (compile m ? DBNZ (maIX0_and_IMM1 〈x0,x1〉) I) @
  60 (* [0x1888] 1clk *) (compile m ? NOP maINH I) @                               (* non eseguito: --[X]=[0x0070]=0xFF≠0 *)
  61 (* [0x1889] 8clk *) (compile m ? DBNZ (maSP1_and_IMM1 〈x0,x1〉 〈x0,x1〉) I) @
  62 (* [0x188D] 1clk *) (compile m ? NOP maINH I)                                 (* non eseguito: --[SP+0x01]=[0x0070]=0xFE≠0 *)
  63 (* [0x188E] si puo' quindi enunciare che dopo 5+1+4+4+5+5+6+1 (31)
  64                                               7+4+4+7+1+6+8   (37) =68 clk *)
  65 (*          A<-0xFF PC<-0x188E H:X<-0070 *)
  66 ).
  67
  68 (* creazione del processore+caricamento+impostazione registri *)
  69 ndefinition mTest_HCS08_CBEQ_DBNZ_status ≝
  70 λt:memory_impl.
  71 λb1,b2,b3:byte8.
  72  setweak_sp_reg HCS08 t (* SP<-0x006F *)
  73   (setweak_indX_16_reg HCS08 t (* H:X<-0x006F *)
  74    (set_pc_reg HCS08 t (* PC<-mTest_HCS08_prog *)
  75     (start_of_mcu_version_HCS08
  76      MC9S08AW60 t
  77      (load_from_source_at t (* carica b1-3 in RAM:mTest_HCS08_RAM *)
  78       (load_from_source_at t (* carica mTest_bytes in RAM:mTest_HCS08_RAM *)
  79        (load_from_source_at t (zero_memory t) (* carica source in ROM:mTest_HCS08_prog *)
  80          mTest_HCS08_CBEQ_DBNZ_source mTest_HCS08_prog)
  81         mTest_bytes mTest_HCS08_RAM)
  82        [ b1 ; b2 ; b3 ] mTest_HCS08_RAM)
  83      (build_memory_type_of_mcu_version (FamilyHCS08 MC9S08AW60) t)
  84      (mk_byte8 x0 x0) (mk_byte8 x0 x0) (* non deterministici tutti a 0 *)
  85      false false false false false false) (* non deterministici tutti a 0 *)
  86     mTest_HCS08_prog)
  87    (mk_word16 (mk_byte8 x0 x0) (mk_byte8 x6 xF)))
  88   (mk_word16 (mk_byte8 x0 x0) (mk_byte8 x6 xF)).
  89
  90 (* dimostrazione senza svolgimento degli stati, immediata *)
  91 (* NB: la memoria e' cambiata e bisogna applicare eq_status *)
  92 nlemma ok_mTest_HCS08_CBEQ_DBNZ_full :
  93 ∀t:memory_impl.
  94  eq_anystatus HCS08 t
  95   (match execute HCS08 t (TickOK ? (mTest_HCS08_CBEQ_DBNZ_status t 〈x0,x0〉 〈x0,x1〉 〈x0,x2〉)) nat68
  96    with [ TickERR s _ ⇒ s | TickSUSP s _ ⇒ s | TickOK s ⇒ s ])
  97   (set_acc_8_low_reg HCS08 t (* nuovo A *)
  98    (set_pc_reg HCS08 t (* nuovo PC *)
  99     (setweak_indX_16_reg HCS08 t (mTest_HCS08_CBEQ_DBNZ_status t 〈xF,xE〉 〈x0,x1〉 〈x0,x0〉) (* nuovo H:X *)
 100      (mk_word16 〈x0,x0〉 〈x7,x0〉))
 101     (mk_word16 〈x1,x8〉 〈x8,xE〉))
 102    (mk_byte8 xF xF))
 103   [ 〈〈x0,x0〉:〈x7,x0〉〉 ; 〈〈x0,x0〉:〈x7,x1〉〉 ; 〈〈x0,x0〉:〈x7,x2〉〉 ] = true.
 104  #t;
 105  napply (eq_to_eqanystatus_weak [ 〈〈x0,x0〉:〈x7,x0〉〉 ; 〈〈x0,x0〉:〈x7,x1〉〉 ; 〈〈x0,x0〉:〈x7,x2〉〉 ] HCS08 t
 106         (match execute HCS08 t (TickOK ? (mTest_HCS08_CBEQ_DBNZ_status t 〈x0,x0〉 〈x0,x1〉 〈x0,x2〉)) nat68
 107          with [ TickERR s _ ⇒ s | TickSUSP s _ ⇒ s | TickOK s ⇒ s ])
 108         (set_acc_8_low_reg HCS08 t (* nuovo A *)
 109          (set_pc_reg HCS08 t (* nuovo PC *)
 110           (setweak_indX_16_reg HCS08 t (mTest_HCS08_CBEQ_DBNZ_status t 〈xF,xE〉 〈x0,x1〉 〈x0,x0〉) (* nuovo H:X *)
 111            (mk_word16 〈x0,x0〉 〈x7,x0〉))
 112           (mk_word16 〈x1,x8〉 〈x8,xE〉))
 113          (mk_byte8 xF xF)));
 114  nelim t;
 115  nnormalize in ⊢ (? ? ? %);
 116  napply refl_eq.
 117 nqed.