helm/software/matita/dama/integration_algebras.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/integration_algebras/".
  16
  17 include "reals.ma".
  18
  19 record is_vector_space (K: field) (G:abelian_group) (emult:K→G→G) : Prop
  20 ≝
  21  { vs_nilpotent: ∀v. emult 0 v = 0;
  22    vs_neutral: ∀v. emult 1 v = v;
  23    vs_distributive: ∀a,b,v. emult (a + b) v = (emult a v) + (emult b v);
  24    vs_associative: ∀a,b,v. emult (a * b) v = emult a (emult b v)
  25  }.
  26
  27 record vector_space (K:field): Type \def
  28 { vs_abelian_group :> abelian_group;
  29   emult: K → vs_abelian_group → vs_abelian_group;
  30   vs_vector_space_properties :> is_vector_space K vs_abelian_group emult
  31 }.
  32
  33 interpretation "Vector space external product" 'times a b =
  34  (cic:/matita/integration_algebras/emult.con _ _ a b).
  35
  36 record is_semi_norm (R:real) (V: vector_space R) (semi_norm:V→R) : Prop \def
  37  { sn_positive: ∀x:V. 0 ≤ semi_norm x;
  38    sn_omogeneous: ∀a:R.∀x:V. semi_norm (a*x) = (abs ? a) * semi_norm x;
  39    sn_triangle_inequality: ∀x,y:V. semi_norm (x + y) ≤ semi_norm x + semi_norm y
  40  }.
  41
  42 record is_norm (R:real) (V:vector_space R) (norm:V → R)
  43  : Prop \def
  44  { n_semi_norm:> is_semi_norm ? ? norm;
  45    n_properness: ∀x:V. norm x = 0 → x = 0
  46  }.
  47
  48 record is_lattice (C:Type) (join,meet:C→C→C) : Prop \def
  49  { (* abelian semigroup properties *)
  50    l_comm_j: symmetric ? join;
  51    l_associative_j: associative ? join;
  52    l_comm_m: symmetric ? meet;
  53    l_associative_m: associative ? meet;
  54    (* other properties *)
  55    l_adsorb_j_m: ∀f,g. join f (meet f g) = f;
  56    l_adsorb_m_j: ∀f,g. meet f (join f g) = f
  57  }.
  58
  59 record lattice (C:Type) : Type \def
  60  { join: C → C → C;
  61    meet: C → C → C;
  62    l_lattice_properties: is_lattice ? join meet
  63  }.
  64
  65 definition le \def λC:Type.λL:lattice C.λf,g. meet ? L f g = f.
  66
  67 interpretation "Lattice le" 'leq a b =
  68  (cic:/matita/integration_algebras/le.con _ _ a b).
  69
  70 definition carrier_of_lattice ≝
  71  λC:Type.λL:lattice C.C.
  72
  73 record is_riesz_space (K:ordered_field_ch0) (V:vector_space K)
  74  (L:lattice (Type_OF_vector_space ? V))
  75 : Prop
  76 \def
  77  { rs_compat_le_plus: ∀f,g,h. le ? L f g → le ? L (f+h) (g+h);
  78    rs_compat_le_times: ∀a:K.∀f. of_le ? 0 a → le ? L 0 f → le ? L 0 (a*f)
  79  }.
  80
  81 record riesz_space (K:ordered_field_ch0) : Type \def
  82  { rs_vector_space:> vector_space K;
  83    rs_lattice:> lattice rs_vector_space;
  84    rs_riesz_space_properties: is_riesz_space ? rs_vector_space rs_lattice
  85  }.
  86
  87 definition absolute_value \def λK.λS:riesz_space K.λf.join ? S f (-f).
  88
  89 record is_archimedean_riesz_space (K) (S:riesz_space K) : Prop
  90 \def
  91   { ars_archimedean: ∃u.∀n.∀a.∀p:n > O.
  92      le ? S
  93       (absolute_value ? S a)
  94       (emult ? S
  95         (inv ? (sum_field K n) (not_eq_sum_field_zero ? n p))
  96         u) →
  97      a = 0
  98   }.
  99
 100 record archimedean_riesz_space (K:ordered_field_ch0) : Type \def
 101  { ars_riesz_space:> riesz_space K;
 102    ars_archimedean_property: is_archimedean_riesz_space ? ars_riesz_space
 103  }.
 104
 105 record is_integral (K) (R:archimedean_riesz_space K) (I:R→K) : Prop
 106 \def
 107  { i_positive: ∀f:R. le ? R 0 f → of_le K 0 (I f);
 108    i_linear1: ∀f,g:R. I (f + g) = I f + I g;
 109    i_linear2: ∀f:R.∀k:K. I (emult ? R k f) = k*(I f)
 110  }.
 111
 112 definition is_weak_unit ≝
 113 (* This definition is by Spitters. He cites Fremlin 353P, but:
 114    1. that theorem holds only in f-algebras (as in Spitters, but we are
 115       defining it on Riesz spaces)
 116    2. Fremlin proves |x|/\u=0 \to u=0. How do we remove the absolute value?
 117  λR:real.λV:archimedean_riesz_space R.λunit: V.
 118   ∀x:V. meet x unit = 0 → u = 0.
 119 *) λR:real.λV:archimedean_riesz_space R.λe:V.True.
 120
 121 record integration_riesz_space (R:real) : Type \def
 122  { irs_archimedean_riesz_space:> archimedean_riesz_space R;
 123    irs_unit: irs_archimedean_riesz_space;
 124    irs_weak_unit: is_weak_unit ? ? irs_unit;
 125    integral: irs_archimedean_riesz_space → R;
 126    irs_integral_properties: is_integral R irs_archimedean_riesz_space integral;
 127    irs_limit1:
 128     ∀f:irs_archimedean_riesz_space.
 129      tends_to ?
 130       (λn.integral (meet ? irs_archimedean_riesz_space f
 131        ((sum_field R n)*irs_unit)))
 132        (integral f);
 133    irs_limit2:
 134     ∀f:irs_archimedean_riesz_space.
 135      tends_to ?
 136       (λn.
 137         integral (meet ? irs_archimedean_riesz_space f
 138          ((inv ? (sum_field R (S n))
 139            (not_eq_sum_field_zero R (S n) (le_S_S O n (le_O_n n)))
 140          ) * irs_unit))) 0;
 141    irs_quotient_space1:
 142     ∀f,g:irs_archimedean_riesz_space.
 143      f=g → integral (absolute_value ? irs_archimedean_riesz_space (f - g)) = 0
 144  }.
 145
 146 record is_algebra (K: field) (V:vector_space K) (mult:V→V→V) (one:V) : Prop
 147 ≝
 148  { (* ring properties *)
 149    a_ring: is_ring V mult one;
 150    (* algebra properties *)
 151    a_associative_left: ∀a,f,g. a * (mult f g) = mult (a * f) g;
 152    a_associative_right: ∀a,f,g. a * (mult f g) = mult f (a * g)
 153  }.
 154
 155 record algebra (K: field) (V:vector_space K) (a_one:V) : Type \def
 156  { a_mult: V → V → V;
 157    a_algebra_properties: is_algebra K V a_mult a_one
 158  }.
 159
 160 interpretation "Algebra product" 'times a b =
 161  (cic:/matita/integration_algebras/a_mult.con _ _ _ a b).
 162
 163 definition ring_of_algebra ≝
 164  λK.λV:vector_space K.λone:V.λA:algebra ? V one.
 165   mk_ring V (a_mult ? ? ? A) one
 166    (a_ring ? ? ? ? (a_algebra_properties ? ? ? A)).
 167
 168 coercion cic:/matita/integration_algebras/ring_of_algebra.con.
 169
 170 record is_f_algebra (K) (S:archimedean_riesz_space K) (one: S)
 171  (A:algebra ? S one) : Prop
 172 \def
 173 { compat_mult_le:
 174    ∀f,g:S.
 175     le ? S 0 f → le ? S 0 g → le ? S 0 (a_mult ? ? ? A f g);
 176   compat_mult_meet:
 177    ∀f,g,h:S.
 178     meet ? S f g = 0 → meet ? S (a_mult ? ? ? A h f) g = 0
 179 }.
 180
 181 record f_algebra (K:ordered_field_ch0) (R:archimedean_riesz_space K) (one:R) :
 182 Type \def
 183 { fa_algebra:> algebra ? R one;
 184   fa_f_algebra_properties: is_f_algebra ? ? ? fa_algebra
 185 }.
 186
 187 (* to be proved; see footnote 2 in the paper by Spitters *)
 188 axiom symmetric_a_mult:
 189  ∀K,R,one.∀A:f_algebra K R one. symmetric ? (a_mult ? ? ? A).
 190
 191 (* Here we are avoiding a construction (the quotient space to define
 192    f=g iff I(|f-g|)=0 *)
 193 record integration_f_algebra (R:real) : Type \def
 194  { ifa_integration_riesz_space:> integration_riesz_space R;
 195    ifa_f_algebra:>
 196     f_algebra ? ifa_integration_riesz_space
 197      (irs_unit ? ifa_integration_riesz_space)
 198  }.