helm/software/matita/library/algebra/monoids.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "algebra/semigroups.ma".
  16
  17 record PreMonoid : Type ≝
  18  { magma:> Magma;
  19    e: magma
  20  }.
  21
  22 record isMonoid (M:PreMonoid) : Prop ≝
  23  { is_semi_group:> isSemiGroup M;
  24    e_is_left_unit:
  25     is_left_unit (mk_SemiGroup ? is_semi_group) (e M);
  26    e_is_right_unit:
  27     is_right_unit (mk_SemiGroup ? is_semi_group) (e M)
  28  }.
  29
  30 record Monoid : Type ≝
  31  { premonoid:> PreMonoid;
  32    monoid_properties:> isMonoid premonoid
  33  }.
  34
  35 interpretation "Monoid unit" 'neutral = (e ?).
  36
  37 definition is_left_inverse ≝
  38  λM:Monoid.
  39   λopp: M → M.
  40    ∀x:M. (opp x)·x = ⅇ.
  41
  42 definition is_right_inverse ≝
  43  λM:Monoid.
  44   λopp: M → M.
  45    ∀x:M. x·(opp x) = ⅇ.
  46
  47 theorem is_left_inverse_to_is_right_inverse_to_eq:
  48  ∀M:Monoid. ∀l,r.
  49   is_left_inverse M l → is_right_inverse M r →
  50    ∀x:M. l x = r x.
  51  intros;
  52  generalize in match (H x); intro;
  53  generalize in match (eq_f ? ? (λy.y·(r x)) ? ? H2);
  54  simplify; fold simplify (op M);
  55  intro; clear H2;
  56  generalize in match (op_associative ? (is_semi_group ? (monoid_properties M)));
  57  intro;
  58  rewrite > H2 in H3; clear H2;
  59  rewrite > H1 in H3;
  60  rewrite > (e_is_left_unit ? (monoid_properties M)) in H3;
  61  rewrite > (e_is_right_unit ? (monoid_properties M)) in H3;
  62  assumption.
  63 qed.