helm/software/matita/library/dama/property_exhaustivity.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "dama/ordered_uniform.ma".
  16 include "dama/property_sigma.ma".
  17
  18 lemma h_segment_upperbound:
  19   ∀C:half_ordered_set.
  20    ∀s:segment C.
  21     ∀a:sequence (half_segment_ordered_set C s).
  22       upper_bound ? ⌊n,\fst (a n)⌋ (seg_u C s).
  23 intros 4; simplify; cases (a n); simplify; unfold in H;
  24 cases (wloss_prop C); rewrite < H1 in H; simplify; cases H;
  25 assumption;
  26 qed.
  27
  28 notation "'segment_upperbound'" non associative with precedence 90 for @{'segment_upperbound}.
  29 notation "'segment_lowerbound'" non associative with precedence 90 for @{'segment_lowerbound}.
  30
  31 interpretation "segment_upperbound" 'segment_upperbound = (h_segment_upperbound (os_l ?)).
  32 interpretation "segment_lowerbound" 'segment_lowerbound = (h_segment_upperbound (os_r ?)).
  33
  34 lemma h_segment_preserves_uparrow:
  35   ∀C:half_ordered_set.∀s:segment C.∀a:sequence (half_segment_ordered_set C s).
  36    ∀x,h. uparrow C ⌊n,\fst (a n)⌋ x → uparrow (half_segment_ordered_set C s) a ≪x,h≫.
  37 intros; cases H (Ha Hx); split;
  38 [ intro n; intro H; apply (Ha n); apply rule H;
  39 | cases Hx; split;
  40   [ intro n; intro H; apply (H1 n);apply rule H;
  41   | intros; cases (H2 (\fst y)); [2: apply rule H3;]
  42     exists [apply w] apply (x2sx_ ?? (a w) y H4);]]
  43 qed.
  44
  45 notation "'segment_preserves_uparrow'" non associative with precedence 90 for @{'segment_preserves_uparrow}.
  46 notation "'segment_preserves_downarrow'" non associative with precedence 90 for @{'segment_preserves_downarrow}.
  47
  48 interpretation "segment_preserves_uparrow" 'segment_preserves_uparrow = (h_segment_preserves_uparrow (os_l ?)).
  49 interpretation "segment_preserves_downarrow" 'segment_preserves_downarrow = (h_segment_preserves_uparrow (os_r ?)).
  50
  51 (* Fact 2.18 *)
  52 lemma segment_cauchy:
  53   ∀C:ordered_uniform_space.∀s:‡C.∀a:sequence {[s]}.
  54     a is_cauchy → ⌊n,\fst (a n)⌋ is_cauchy.
  55 intros 6;
  56 alias symbol "pi1" (instance 3) = "pair pi1".
  57 alias symbol "pi2" = "pair pi2".
  58 apply (H (λx:{[s]} squareB.U 〈\fst (\fst x),\fst (\snd x)〉));
  59 (unfold segment_ordered_uniform_space; simplify);
  60 exists [apply U] split; [assumption;]
  61 intro; cases b; intros; simplify; split; intros; assumption;
  62 qed.
  63
  64 (* Definition 3.7 *)
  65 definition exhaustive ≝
  66   λC:ordered_uniform_space.
  67    ∀a,b:sequence C.
  68      (a is_increasing → a is_upper_located → a is_cauchy) ∧
  69      (b is_decreasing → b is_lower_located → b is_cauchy).
  70
  71 lemma h_uparrow_to_in_segment:
  72   ∀C:half_ordered_set.
  73    ∀s:segment C.
  74      ∀a:sequence C.
  75       (∀i.a i ∈ s) →
  76        ∀x:C. uparrow C a x →
  77          in_segment C s x.
  78 intros (C H a H1 x H2); unfold in H2; cases H2; clear H2;unfold in H3 H4; cases H4; clear H4; unfold in H2;
  79 cases (wloss_prop C) (W W); apply prove_in_segment; unfold;
  80 [ apply (hle_transitive ??? x ? (H2 O)); lapply (H1 O) as K; unfold in K; rewrite <W in K;
  81   cases K; unfold in H4 H6; apply H4;
  82 | intro; cases (H5 ? H4); clear H5 H4;lapply(H1 w) as K; unfold in K; rewrite<W in K;
  83   cases K; unfold in H5 H4; apply H5; apply H6;
  84 | apply (hle_transitive ??? x ?  (H2 O)); lapply (H1 0) as K; unfold in K; rewrite <W in K;
  85   cases K; unfold in H4 H6; apply H6;
  86 | intro; cases (H5 ? H4); clear H5 H4;lapply(H1 w) as K; unfold in K; rewrite<W in K;
  87   cases K; unfold in H5 H4; apply (H4 H6);]
  88 qed.
  89
  90 notation "'uparrow_to_in_segment'" non associative with precedence 90 for @{'uparrow_to_in_segment}.
  91 notation "'downarrow_to_in_segment'" non associative with precedence 90 for @{'downarrow_to_in_segment}.
  92
  93 interpretation "uparrow_to_in_segment" 'uparrow_to_in_segment = (h_uparrow_to_in_segment (os_l ?)).
  94 interpretation "downarrow_to_in_segment" 'downarrow_to_in_segment = (h_uparrow_to_in_segment (os_r ?)).
  95
  96 alias symbol "dependent_pair" = "dependent pair".
  97 (* Lemma 3.8 NON DUALIZZATO *)
  98 lemma restrict_uniform_convergence_uparrow:
  99   ∀C:ordered_uniform_space.property_sigma C →
 100     ∀s:segment (os_l C).exhaustive (segment_ordered_uniform_space C s) →
 101      ∀a:sequence (segment_ordered_uniform_space C s).
 102       ∀x:C. ⌊n,\fst (a n)⌋ ↑ x →
 103        in_segment (os_l C) s x ∧ ∀h:x ∈ s.a uniform_converges ≪x,h≫.
 104 intros; split;
 105 [1: apply (uparrow_to_in_segment s ⌊n,\fst (a \sub n)⌋ ? x H2);
 106     simplify; intros; cases (a i); assumption;
 107 |2: intros;
 108     lapply (uparrow_upperlocated a ≪x,h≫) as Ha1;
 109       [2: apply (segment_preserves_uparrow s); assumption;]
 110     lapply (segment_preserves_supremum s a ≪?,h≫ H2) as Ha2;
 111     cases Ha2; clear Ha2;
 112     cases (H1 a a); lapply (H5 H3 Ha1) as HaC;
 113     lapply (segment_cauchy C s ? HaC) as Ha;
 114     lapply (sigma_cauchy ? H  ? x ? Ha); [left; assumption]
 115     apply (restric_uniform_convergence C s ≪?,h≫ a Hletin)]
 116 qed.
 117
 118 lemma hint_mah1:
 119   ∀C. Type_OF_ordered_uniform_space__1 C → hos_carr (os_r C).
 120   intros; assumption; qed.
 121
 122 coercion hint_mah1 nocomposites.
 123
 124 lemma hint_mah2:
 125   ∀C. sequence (hos_carr (os_l C)) → sequence (hos_carr (os_r C)).
 126   intros; assumption; qed.
 127
 128 coercion hint_mah2 nocomposites.
 129
 130 lemma hint_mah3:
 131   ∀C. Type_OF_ordered_uniform_space C → hos_carr (os_r C).
 132   intros; assumption; qed.
 133
 134 coercion hint_mah3 nocomposites.
 135
 136 lemma hint_mah4:
 137   ∀C. sequence (hos_carr (os_r C)) → sequence (hos_carr (os_l C)).
 138   intros; assumption; qed.
 139
 140 coercion hint_mah4 nocomposites.
 141
 142 lemma hint_mah5:
 143   ∀C. segment (hos_carr (os_r C)) → segment (hos_carr (os_l C)).
 144   intros; assumption; qed.
 145
 146 coercion hint_mah5 nocomposites.
 147
 148 lemma hint_mah6:
 149   ∀C. segment (hos_carr (os_l C)) → segment (hos_carr (os_r C)).
 150   intros; assumption; qed.
 151
 152 coercion hint_mah6 nocomposites.
 153
 154 lemma restrict_uniform_convergence_downarrow:
 155   ∀C:ordered_uniform_space.property_sigma C →
 156     ∀s:segment (os_l C).exhaustive (segment_ordered_uniform_space C s) →
 157      ∀a:sequence (segment_ordered_uniform_space C s).
 158       ∀x:C. ⌊n,\fst (a n)⌋ ↓ x →
 159        in_segment (os_l C) s x ∧ ∀h:x ∈ s.a uniform_converges ≪x,h≫.
 160 intros; split;
 161 [1: apply (downarrow_to_in_segment s ⌊n,\fst (a n)⌋ ? x); [2: apply H2];
 162     simplify; intros; cases (a i); assumption;
 163 |2: intros;
 164     lapply (downarrow_lowerlocated a ≪x,h≫) as Ha1;
 165       [2: apply (segment_preserves_downarrow s a x h H2);]
 166     lapply (segment_preserves_infimum s a ≪?,h≫ H2) as Ha2;
 167     cases Ha2; clear Ha2;
 168     cases (H1 a a); lapply (H6 H3 Ha1) as HaC;
 169     lapply (segment_cauchy C s ? HaC) as Ha;
 170     lapply (sigma_cauchy ? H  ? x ? Ha); [right; assumption]
 171     apply (restric_uniform_convergence C s ≪x,h≫ a Hletin)]
 172 qed.