helm/software/matita/library/didactic/exercises/natural_deduction_fst_order.ma

   1 (* Esercizio 0
   2    ===========
   3
   4    Compilare i seguenti campi:
   5
   6    Nome1: ...
   7    Cognome1: ...
   8    Matricola1: ...
   9    Account1: ...
  10
  11    Nome2: ...
  12    Cognome2: ...
  13    Matricola2: ...
  14    Account2: ...
  15
  16 *)
  17
  18 (*DOCBEGIN
  19
  20 I connettivi logici
  21 ===================
  22
  23 Per digitare i connettivi logici:
  24
  25 * `∧` : `\land`
  26 * `∨` : `\lor`
  27 * `¬` : `\lnot`
  28 * `⇒` : `=>`, `\Rightarrow`
  29 * `⊥` : `\bot`
  30 * `⊤` : `\top`
  31
  32 Per digitare i quantificatori:
  33
  34 * `∀` : `\forall`
  35 * `∃` : `\exists`
  36
  37 I termini, le formule e i nomi delle ipotesi
  38 ============================================
  39
  40 * I termini quantificati da `∀` e `∃`, quando argomenti di
  41   una regola, vengono scritti tra `{` e `}`.
  42
  43 * Le formule, quando argomenti di
  44   una regola, vengono scritte tra `(` e `)`.
  45
  46 * I nomi delle ipotesi, quando argomenti di
  47   una regola, vengono scritti tra `[` e `]`.
  48
  49 Le regole di deduzione naturale
  50 ===============================
  51
  52 Per digitare le regole di deduzione naturale
  53 è possibile utilizzare la palette che compare
  54 sulla sinistra dopo aver premuto `F2`.
  55
  56 L'albero si descrive partendo dalla radice. Le regole
  57 con premesse multiple sono seguite da `[`, `|` e `]`.
  58 Ad esempio:
  59
  60         apply rule (∧_i (A∨B) ⊥);
  61           [ …continua qui il sottoalbero per (A∨B)
  62           | …continua qui il sottoalbero per ⊥
  63           ]
  64
  65 Le regole vengono applicate alle loro premesse, ovvero
  66 gli argomenti delle regole sono le formule che normalmente
  67 scrivete sopra la linea che rappresenta l'applicazione della
  68 regola stessa. Ad esempio:
  69
  70         aply rule (∨_e (A∨B) [h1] C [h2] C);
  71           [ …prova di (A∨B)
  72           | …prova di C sotto l'ipotesi A (di nome h1)
  73           | …prova di C sotto l'ipotesi B (di nome h2)
  74           ]
  75
  76 Le regole che hanno una sola premessa non vengono seguite
  77 da parentesi quadre.
  78
  79 L'albero di deduzione
  80 =====================
  81
  82 Per visualizzare l'albero man mano che viene costruito
  83 dai comandi impartiti al sistema, premere `F3` e poi
  84 premere sul bottome home (in genere contraddistinto da
  85 una icona rappresentate una casa).
  86
  87 Si suggerisce di marcare tale finestra come `always on top`
  88 utilizzando il menu a tendina che nella maggior parte degli
  89 ambienti grafici si apre cliccando nel suo angolo in
  90 alto a sinistra.
  91
  92 Applicazioni di regole errate vengono contrassegnate con
  93 il colore rosso.
  94
  95 Usare i lemmi dimostrati in precedenza
  96 ======================================
  97
  98 Una volta dimostrati alcuni utili lemmi come `A ∨ ¬A` è possibile
  99 riutilizzarli in altre dimostrazioni utilizzando la "regola" `lem`.
 100
 101 La "regola" `lem` prende come argomenti:
 102
 103 - Il numero delle ipotesi del lemma che si vuole utilizzare, nel
 104   caso del terzo escluso `0`, nel caso di `¬¬A⇒A` le ipotesi sono `1`.
 105
 106 - Dopo il numero di ipotesi, è necessario digitare il nome del lemma.
 107
 108 - Infine, le formule che devono essere scritte come premesse per la
 109   "regola".
 110
 111 Ad esempio, per usare il lemma EM (terzo escluso) basta digitare
 112 `lem 0 EM`, mentre per usare il lemma NNAA (`¬¬A⇒A`) bisogna digitare
 113 `lem 1 NNAA (¬¬A)`. Ai lemmi con più di una premessa è necessario
 114 far seguire le parentesi quadre come spiegato in precedenza.
 115
 116 Si noti che "regola" `lem` non è una vera regola, ma una forma compatta
 117 per rappresentare l'albero di prova del lemma che si sta riutilizzando.
 118
 119 Per motivi che saranno più chiari una volta studiate logiche del
 120 primo ordine o di ordine superiore, i lemmi che si intende
 121 riutilizzare è bene che siano dimostrati astratti sugli atomi.
 122 Ovvero per ogni atomo `A`...`Z` che compare nella formula,
 123 è bene aggiungere una quantificazione all'inizio della formula stessa.
 124 Ad esempio scrivendo `∀A:CProp.` prima della formula `A ∨ ¬A`.
 125 La dimostrazione deve poi iniziare con il comando `assume`.
 126
 127 In tale modo il lemma EM può essere utilizzato sia per dimostrare
 128 `A ∨ ¬A`, sia `B ∨ ¬B`, sia `(A∨C) ∨ ¬(A∨C)`, etc ...
 129
 130 DOCEND*)
 131
 132
 133 include "didactic/support/natural_deduction.ma".
 134
 135 (* Il nostro linguaggio del primo ordine prevede le seguenti
 136    - costanti: c
 137    - funzioni: f, g (unarie), h (binaria)
 138    - predicati: P, Q (unari), R, S (binari)
 139 *)
 140 axiom c : sort.
 141 axiom f : sort → sort.
 142 axiom g : sort → sort.
 143 axiom h : sort → sort → sort.
 144 axiom P : sort → CProp.
 145 axiom Q : sort → CProp.
 146 axiom R : sort →sort → CProp.
 147 axiom S : sort →sort → CProp.
 148
 149 (* assumiamo il terzo escluso *)
 150 theorem EM: ∀A:CProp. A ∨ ¬ A.
 151 assume A: CProp.
 152 apply rule (prove (A ∨ ¬A));
 153 apply rule (RAA [H] (⊥)).
 154 apply rule (¬_e (¬(A ∨ ¬A)) (A ∨ ¬A));
 155         [ apply rule (discharge [H]).
 156         | apply rule (⊥_e (⊥));
 157           apply rule (¬_e (¬¬A) (¬A));
 158            [ apply rule (¬_i [K] (⊥)).
 159        apply rule (¬_e (¬(A ∨ ¬A)) (A ∨ ¬A));
 160               [ apply rule (discharge [H]).
 161               | apply rule (∨_i_r (¬A)).
 162           apply rule (discharge [K]).
 163               ]
 164            | apply rule (¬_i [K] (⊥)).
 165        apply rule (¬_e (¬(A ∨ ¬A)) (A ∨ ¬A));
 166               [ apply rule (discharge [H]).
 167               | apply rule (∨_i_l (A)).
 168           apply rule (discharge [K]).
 169               ]
 170            ]
 171         ]
 172 qed.
 173
 174 (* intuizionista *)
 175 lemma ex1: ¬(∃x.P x) ⇒ ∀x.¬ P x.
 176 apply rule (prove (¬(∃x.P x) ⇒ ∀x.¬ P x));
 177 (*BEGIN*)
 178 apply rule (⇒_i [h1] (∀x.¬ P x));
 179 apply rule (∀_i {l} (¬P l));
 180 apply rule (¬_i [h2] (⊥));
 181 apply rule (¬_e (¬(∃x.P x)) (∃x.P x));
 182         [ apply rule (discharge [h1]);
 183         | apply rule (∃_i {l} (P l));
 184           apply rule (discharge [h2]);
 185         ]
 186 (*END*)
 187 qed.
 188
 189 (* classico *)
 190 lemma ex2: ¬(∀x.P x) ⇒ ∃x.¬ P x.
 191 apply rule (prove (¬(∀x.P x) ⇒ ∃x.¬ P x));
 192 (*BEGIN*)
 193 apply rule (⇒_i [h1] (∃x.¬ P x));
 194 apply rule (RAA [h2] (⊥));
 195 apply rule (¬_e (¬(∀x.P x)) (∀x.P x));
 196         [ apply rule (discharge [h2]);
 197         | apply rule (∀_i {y} (P y));
 198     apply rule (RAA [h3] (⊥));
 199     apply rule (¬_e (¬∃x.¬ P x) (∃x.¬ P x));
 200            [ apply rule (discharge [h2]);
 201            | apply rule (∃_i {y} (¬P y));
 202        apply rule (discharge [h3]);
 203            ]
 204         ]
 205 (*END*)
 206 qed.
 207
 208 (* intuizionista *)
 209 lemma ex3: ((∃x.P x) ⇒ Q c) ⇒ ∀x.P x ⇒ Q c.
 210 apply rule (prove (((∃x.P x) ⇒ Q c) ⇒ ∀x.P x ⇒ Q c));
 211 (*BEGIN*)
 212 apply rule (⇒_i [h1] (∀x.P x ⇒ Q c));
 213 apply rule (∀_i {l} (P l ⇒ Q c));
 214 apply rule (⇒_i [h2] (Q c));
 215 apply rule (⇒_e ((∃x.P x) ⇒ Q c) (∃x.P x));
 216         [ apply rule (discharge [h1]);
 217         | apply rule (∃_i {l} (P l));
 218           apply rule (discharge [h2]);
 219         ]
 220 (*END*)
 221 qed.
 222
 223 (* classico *)
 224 lemma ex4: ((∀x.P x) ⇒ Q c) ⇒ ∃x.P x ⇒ Q c.
 225 apply rule (prove (((∀x.P x) ⇒ Q c) ⇒ ∃x.P x ⇒ Q c));
 226 (*BEGIN*)
 227 apply rule (⇒_i [h1] (∃x.P x ⇒ Q c));
 228 apply rule (∨_e ((∀x.P x) ∨ ¬(∀x.P x)) [h3] (?) [h3] (?));
 229         [ apply rule (lem 0 EM);
 230         | apply rule (∃_i {y} (P y ⇒ Q c));
 231        apply rule (⇒_i [h4] (Q c));
 232        apply rule (⇒_e ((∀x.P x) ⇒ Q c) ((∀x.P x)));
 233                [ apply rule (discharge [h1]);
 234          | apply rule (discharge [h3]);
 235                ]
 236   | apply rule (∃_e (∃x.¬P x) {y} [h4] (∃x.P x ⇒ Q c));
 237            [ apply rule (lem 1 ex2 (¬(∀x.P x)));
 238              apply rule (discharge [h3]);
 239      | apply rule (∃_i {y} (P y ⇒ Q c));
 240        apply rule (⇒_i [h5] (Q c));
 241        apply rule (⊥_e (⊥));
 242        apply rule (¬_e (¬P y) (P y));
 243                [ apply rule (discharge [h4]);
 244                | apply rule (discharge [h5]);
 245                ]
 246            ]
 247   ]
 248 (*END*)
 249 qed.