helm/software/matita/library/nat/div_and_mod.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        Matita is distributed under the terms of the          *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "datatypes/constructors.ma".
  16 include "nat/minus.ma".
  17
  18 let rec mod_aux p m n: nat \def
  19 match (leb m n) with
  20 [ true \Rightarrow m
  21 | false \Rightarrow
  22   match p with
  23   [O \Rightarrow m
  24   |(S q) \Rightarrow mod_aux q (m-(S n)) n]].
  25
  26 definition mod : nat \to nat \to nat \def
  27 \lambda n,m.
  28 match m with
  29 [O \Rightarrow n
  30 | (S p) \Rightarrow mod_aux n n p].
  31
  32 interpretation "natural remainder" 'module x y = (mod x y).
  33
  34 let rec div_aux p m n : nat \def
  35 match (leb m n) with
  36 [ true \Rightarrow O
  37 | false \Rightarrow
  38   match p with
  39   [O \Rightarrow O
  40   |(S q) \Rightarrow S (div_aux q (m-(S n)) n)]].
  41
  42 definition div : nat \to nat \to nat \def
  43 \lambda n,m.
  44 match m with
  45 [O \Rightarrow S n
  46 | (S p) \Rightarrow div_aux n n p].
  47
  48 interpretation "natural divide" 'divide x y = (div x y).
  49
  50 theorem le_mod_aux_m_m:
  51 \forall p,n,m. n \leq p \to (mod_aux p n m) \leq m.
  52 intro.elim p.
  53 apply (le_n_O_elim n H (\lambda n.(mod_aux O n m) \leq m)).
  54 simplify.apply le_O_n.
  55 simplify.
  56 apply (leb_elim n1 m).
  57 simplify.intro.assumption.
  58 simplify.intro.apply H.
  59 cut (n1 \leq (S n) \to n1-(S m) \leq n).
  60 apply Hcut.assumption.
  61 elim n1.
  62 simplify.apply le_O_n.
  63 simplify.apply (trans_le ? n2 n).
  64 apply le_minus_m.apply le_S_S_to_le.assumption.
  65 qed.
  66
  67 theorem lt_mod_m_m: \forall n,m. O < m \to (n \mod m) < m.
  68 intros 2.elim m.apply False_ind.
  69 apply (not_le_Sn_O O H).
  70 simplify.unfold lt.apply le_S_S.apply le_mod_aux_m_m.
  71 apply le_n.
  72 qed.
  73
  74 theorem div_aux_mod_aux: \forall p,n,m:nat.
  75 (n=(div_aux p n m)*(S m) + (mod_aux p n m)).
  76 intro.elim p.
  77 simplify.elim (leb n m).
  78 simplify.apply refl_eq.
  79 simplify.apply refl_eq.
  80 simplify.
  81 apply (leb_elim n1 m).
  82 simplify.intro.apply refl_eq.
  83 simplify.intro.
  84 rewrite > assoc_plus.
  85 elim (H (n1-(S m)) m).
  86 change with (n1=(S m)+(n1-(S m))).
  87 rewrite < sym_plus.
  88 apply plus_minus_m_m.
  89 change with (m < n1).
  90 apply not_le_to_lt.exact H1.
  91 qed.
  92
  93 theorem div_mod: \forall n,m:nat. O < m \to n=(n / m)*m+(n \mod m).
  94 intros 2.elim m.elim (not_le_Sn_O O H).
  95 simplify.
  96 apply div_aux_mod_aux.
  97 qed.
  98
  99 theorem eq_times_div_minus_mod:
 100 \forall a,b:nat. O \lt b \to
 101 (a /b)*b = a - (a \mod b).
 102 intros.
 103 rewrite > (div_mod a b) in \vdash (? ? ? (? % ?))
 104 [ apply (minus_plus_m_m (times (div a b) b) (mod a b))
 105 | assumption
 106 ]
 107 qed.
 108
 109 inductive div_mod_spec (n,m,q,r:nat) : Prop \def
 110 div_mod_spec_intro: r < m \to n=q*m+r \to (div_mod_spec n m q r).
 111
 112 (*
 113 definition div_mod_spec : nat \to nat \to nat \to nat \to Prop \def
 114 \lambda n,m,q,r:nat.r < m \land n=q*m+r).
 115 *)
 116
 117 theorem div_mod_spec_to_not_eq_O: \forall n,m,q,r.(div_mod_spec n m q r) \to m \neq O.
 118 intros 4.unfold Not.intros.elim H.absurd (le (S r) O).
 119 rewrite < H1.assumption.
 120 exact (not_le_Sn_O r).
 121 qed.
 122
 123 theorem div_mod_spec_div_mod:
 124 \forall n,m. O < m \to (div_mod_spec n m (n / m) (n \mod m)).
 125 intros.
 126 apply div_mod_spec_intro.
 127 apply lt_mod_m_m.assumption.
 128 apply div_mod.assumption.
 129 qed.
 130
 131 theorem div_mod_spec_to_eq :\forall a,b,q,r,q1,r1.
 132 (div_mod_spec a b q r) \to (div_mod_spec a b q1 r1) \to
 133 (eq nat q q1).
 134 intros.elim H.elim H1.
 135 apply (nat_compare_elim q q1).intro.
 136 apply False_ind.
 137 cut (eq nat ((q1-q)*b+r1) r).
 138 cut (b \leq (q1-q)*b+r1).
 139 cut (b \leq r).
 140 apply (lt_to_not_le r b H2 Hcut2).
 141 elim Hcut.assumption.
 142 apply (trans_le ? ((q1-q)*b)).
 143 apply le_times_n.
 144 apply le_SO_minus.exact H6.
 145 rewrite < sym_plus.
 146 apply le_plus_n.
 147 rewrite < sym_times.
 148 rewrite > distr_times_minus.
 149 rewrite > plus_minus.
 150 rewrite > sym_times.
 151 rewrite < H5.
 152 rewrite < sym_times.
 153 apply plus_to_minus.
 154 apply H3.
 155 apply le_times_r.
 156 apply lt_to_le.
 157 apply H6.
 158 (* eq case *)
 159 intros.assumption.
 160 (* the following case is symmetric *)
 161 intro.
 162 apply False_ind.
 163 cut (eq nat ((q-q1)*b+r) r1).
 164 cut (b \leq (q-q1)*b+r).
 165 cut (b \leq r1).
 166 apply (lt_to_not_le r1 b H4 Hcut2).
 167 elim Hcut.assumption.
 168 apply (trans_le ? ((q-q1)*b)).
 169 apply le_times_n.
 170 apply le_SO_minus.exact H6.
 171 rewrite < sym_plus.
 172 apply le_plus_n.
 173 rewrite < sym_times.
 174 rewrite > distr_times_minus.
 175 rewrite > plus_minus.
 176 rewrite > sym_times.
 177 rewrite < H3.
 178 rewrite < sym_times.
 179 apply plus_to_minus.
 180 apply H5.
 181 apply le_times_r.
 182 apply lt_to_le.
 183 apply H6.
 184 qed.
 185
 186 theorem div_mod_spec_to_eq2 :\forall a,b,q,r,q1,r1.
 187 (div_mod_spec a b q r) \to (div_mod_spec a b q1 r1) \to
 188 (eq nat r r1).
 189 intros.elim H.elim H1.
 190 apply (inj_plus_r (q*b)).
 191 rewrite < H3.
 192 rewrite > (div_mod_spec_to_eq a b q r q1 r1 H H1).
 193 assumption.
 194 qed.
 195
 196 theorem div_mod_spec_times : \forall n,m:nat.div_mod_spec ((S n)*m) (S n) m O.
 197 intros.constructor 1.
 198 unfold lt.apply le_S_S.apply le_O_n.
 199 rewrite < plus_n_O.rewrite < sym_times.reflexivity.
 200 qed.
 201
 202 lemma div_plus_times: \forall m,q,r:nat. r < m \to  (q*m+r)/ m = q.
 203 intros.
 204 apply (div_mod_spec_to_eq (q*m+r) m ? ((q*m+r) \mod m) ? r)
 205   [apply div_mod_spec_div_mod.
 206    apply (le_to_lt_to_lt ? r)
 207     [apply le_O_n|assumption]
 208   |apply div_mod_spec_intro[assumption|reflexivity]
 209   ]
 210 qed.
 211
 212 lemma mod_plus_times: \forall m,q,r:nat. r < m \to  (q*m+r) \mod m = r.
 213 intros.
 214 apply (div_mod_spec_to_eq2 (q*m+r) m ((q*m+r)/ m) ((q*m+r) \mod m) q r)
 215   [apply div_mod_spec_div_mod.
 216    apply (le_to_lt_to_lt ? r)
 217     [apply le_O_n|assumption]
 218   |apply div_mod_spec_intro[assumption|reflexivity]
 219   ]
 220 qed.
 221
 222 (* some properties of div and mod *)
 223 theorem div_times: \forall n,m:nat. ((S n)*m) / (S n) = m.
 224 intros.
 225 apply (div_mod_spec_to_eq ((S n)*m) (S n) ? ? ? O);
 226 [2: apply div_mod_spec_div_mod.
 227     unfold lt.apply le_S_S.apply le_O_n.
 228 |   skip
 229 |   apply div_mod_spec_times
 230 ]
 231 qed.
 232
 233 (*a simple variant of div_times theorem *)
 234 theorem lt_O_to_div_times: \forall a,b:nat. O \lt b \to
 235 a*b/b = a.
 236 intros.
 237 rewrite > sym_times.
 238 rewrite > (S_pred b H).
 239 apply div_times.
 240 qed.
 241
 242 theorem div_n_n: \forall n:nat. O < n \to n / n = S O.
 243 intros.
 244 apply (div_mod_spec_to_eq n n (n / n) (n \mod n) (S O) O).
 245 apply div_mod_spec_div_mod.assumption.
 246 constructor 1.assumption.
 247 rewrite < plus_n_O.simplify.rewrite < plus_n_O.reflexivity.
 248 qed.
 249
 250 theorem eq_div_O: \forall n,m. n < m \to n / m = O.
 251 intros.
 252 apply (div_mod_spec_to_eq n m (n/m) (n \mod m) O n).
 253 apply div_mod_spec_div_mod.
 254 apply (le_to_lt_to_lt O n m).
 255 apply le_O_n.assumption.
 256 constructor 1.assumption.reflexivity.
 257 qed.
 258
 259 theorem mod_n_n: \forall n:nat. O < n \to n \mod n = O.
 260 intros.
 261 apply (div_mod_spec_to_eq2 n n (n / n) (n \mod n) (S O) O).
 262 apply div_mod_spec_div_mod.assumption.
 263 constructor 1.assumption.
 264 rewrite < plus_n_O.simplify.rewrite < plus_n_O.reflexivity.
 265 qed.
 266
 267 theorem mod_S: \forall n,m:nat. O < m \to S (n \mod m) < m \to
 268 ((S n) \mod m) = S (n \mod m).
 269 intros.
 270 apply (div_mod_spec_to_eq2 (S n) m ((S n) / m) ((S n) \mod m) (n / m) (S (n \mod m))).
 271 apply div_mod_spec_div_mod.assumption.
 272 constructor 1.assumption.rewrite < plus_n_Sm.
 273 apply eq_f.
 274 apply div_mod.
 275 assumption.
 276 qed.
 277
 278 theorem mod_O_n: \forall n:nat.O \mod n = O.
 279 intro.elim n.simplify.reflexivity.
 280 simplify.reflexivity.
 281 qed.
 282
 283 theorem lt_to_eq_mod:\forall n,m:nat. n < m \to n \mod m = n.
 284 intros.
 285 apply (div_mod_spec_to_eq2 n m (n/m) (n \mod m) O n).
 286 apply div_mod_spec_div_mod.
 287 apply (le_to_lt_to_lt O n m).apply le_O_n.assumption.
 288 constructor 1.
 289 assumption.reflexivity.
 290 qed.
 291
 292 theorem mod_SO: \forall n:nat. mod n (S O) = O.
 293 intro.
 294 apply sym_eq.
 295 apply le_n_O_to_eq.
 296 apply le_S_S_to_le.
 297 apply lt_mod_m_m.
 298 apply le_n.
 299 qed.
 300
 301 theorem div_SO: \forall n:nat. div n (S O) = n.
 302 intro.
 303 rewrite > (div_mod ? (S O)) in \vdash (? ? ? %)
 304   [rewrite > mod_SO.
 305    rewrite < plus_n_O.
 306    apply times_n_SO
 307   |apply le_n
 308   ]
 309 qed.
 310
 311 theorem or_div_mod: \forall n,q. O < q \to
 312 ((S (n \mod q)=q) \land S n = (S (div n q)) * q \lor
 313 ((S (n \mod q)<q) \land S n= (div n q) * q + S (n\mod q))).
 314 intros.
 315 elim (le_to_or_lt_eq ? ? (lt_mod_m_m n q H))
 316   [right.split
 317     [assumption
 318     |rewrite < plus_n_Sm.
 319      apply eq_f.
 320      apply div_mod.
 321      assumption
 322     ]
 323   |left.split
 324     [assumption
 325     |simplify.
 326      rewrite > sym_plus.
 327      rewrite < H1 in ⊢ (? ? ? (? ? %)).
 328      rewrite < plus_n_Sm.
 329      apply eq_f.
 330      apply div_mod.
 331      assumption
 332     ]
 333   ]
 334 qed.
 335
 336 (* injectivity *)
 337 theorem injective_times_r: \forall n:nat.injective nat nat (\lambda m:nat.(S n)*m).
 338 change with (\forall n,p,q:nat.(S n)*p = (S n)*q \to p=q).
 339 intros.
 340 rewrite < (div_times n).
 341 rewrite < (div_times n q).
 342 apply eq_f2.assumption.
 343 reflexivity.
 344 qed.
 345
 346 variant inj_times_r : \forall n,p,q:nat.(S n)*p = (S n)*q \to p=q \def
 347 injective_times_r.
 348
 349 theorem lt_O_to_injective_times_r: \forall n:nat. O < n \to injective nat nat (\lambda m:nat.n*m).
 350 simplify.
 351 intros 4.
 352 apply (lt_O_n_elim n H).intros.
 353 apply (inj_times_r m).assumption.
 354 qed.
 355
 356 variant inj_times_r1:\forall n. O < n \to \forall p,q:nat.n*p = n*q \to p=q
 357 \def lt_O_to_injective_times_r.
 358
 359 theorem injective_times_l: \forall n:nat.injective nat nat (\lambda m:nat.m*(S n)).
 360 simplify.
 361 intros.
 362 apply (inj_times_r n x y).
 363 rewrite < sym_times.
 364 rewrite < (sym_times y).
 365 assumption.
 366 qed.
 367
 368 variant inj_times_l : \forall n,p,q:nat. p*(S n) = q*(S n) \to p=q \def
 369 injective_times_l.
 370
 371 theorem lt_O_to_injective_times_l: \forall n:nat. O < n \to injective nat nat (\lambda m:nat.m*n).
 372 simplify.
 373 intros 4.
 374 apply (lt_O_n_elim n H).intros.
 375 apply (inj_times_l m).assumption.
 376 qed.
 377
 378 variant inj_times_l1:\forall n. O < n \to \forall p,q:nat.p*n = q*n \to p=q
 379 \def lt_O_to_injective_times_l.
 380
 381
 382 (* n_divides computes the pair (div,mod) *)
 383
 384 (* p is just an upper bound, acc is an accumulator *)
 385 let rec n_divides_aux p n m acc \def
 386   match n \mod m with
 387   [ O \Rightarrow
 388     match p with
 389       [ O \Rightarrow pair nat nat acc n
 390       | (S p) \Rightarrow n_divides_aux p (n / m) m (S acc)]
 391   | (S a) \Rightarrow pair nat nat acc n].
 392
 393 (* n_divides n m = <q,r> if m divides n q times, with remainder r *)
 394 definition n_divides \def \lambda n,m:nat.n_divides_aux n n m O.
 395