helm/software/matita/library/nat/lt_arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/nat/lt_arith".
  16
  17 include "nat/div_and_mod.ma".
  18
  19 (* plus *)
  20 theorem monotonic_lt_plus_r:
  21 \forall n:nat.monotonic nat lt (\lambda m.n+m).
  22 simplify.intros.
  23 elim n.simplify.assumption.
  24 simplify.unfold lt.
  25 apply le_S_S.assumption.
  26 qed.
  27
  28 variant lt_plus_r: \forall n,p,q:nat. p < q \to n + p < n + q \def
  29 monotonic_lt_plus_r.
  30
  31 theorem monotonic_lt_plus_l:
  32 \forall n:nat.monotonic nat lt (\lambda m.m+n).
  33 simplify.
  34 intros.
  35 rewrite < sym_plus. rewrite < (sym_plus n).
  36 apply lt_plus_r.assumption.
  37 qed.
  38
  39 variant lt_plus_l: \forall n,p,q:nat. p < q \to p + n < q + n \def
  40 monotonic_lt_plus_l.
  41
  42 theorem lt_plus: \forall n,m,p,q:nat. n < m \to p < q \to n + p < m + q.
  43 intros.
  44 apply (trans_lt ? (n + q)).
  45 apply lt_plus_r.assumption.
  46 apply lt_plus_l.assumption.
  47 qed.
  48
  49 theorem lt_plus_to_lt_l :\forall n,p,q:nat. p+n < q+n \to p<q.
  50 intro.elim n.
  51 rewrite > plus_n_O.
  52 rewrite > (plus_n_O q).assumption.
  53 apply H.
  54 unfold lt.apply le_S_S_to_le.
  55 rewrite > plus_n_Sm.
  56 rewrite > (plus_n_Sm q).
  57 exact H1.
  58 qed.
  59
  60 theorem lt_plus_to_lt_r :\forall n,p,q:nat. n+p < n+q \to p<q.
  61 intros.apply (lt_plus_to_lt_l n).
  62 rewrite > sym_plus.
  63 rewrite > (sym_plus q).assumption.
  64 qed.
  65
  66 theorem le_to_lt_to_plus_lt: \forall a,b,c,d:nat.
  67 a \le c \to b \lt d \to (a + b) \lt (c+d).
  68 intros.
  69 cut (a \lt c \lor a = c)
  70 [ elim Hcut
  71   [ apply (lt_plus );
  72       assumption
  73   | rewrite > H2.
  74     apply (lt_plus_r c b d).
  75     assumption
  76   ]
  77 | apply le_to_or_lt_eq.
  78   assumption
  79 ]
  80 qed.
  81
  82
  83 (* times and zero *)
  84 theorem lt_O_times_S_S: \forall n,m:nat.O < (S n)*(S m).
  85 intros.simplify.unfold lt.apply le_S_S.apply le_O_n.
  86 qed.
  87
  88 theorem lt_times_eq_O: \forall a,b:nat.
  89 O \lt a \to (a * b) = O \to b = O.
  90 intros.
  91 apply (nat_case1 b)
  92 [ intros.
  93   reflexivity
  94 | intros.
  95   rewrite > H2 in H1.
  96   rewrite > (S_pred a) in H1
  97   [ apply False_ind.
  98     apply (eq_to_not_lt O ((S (pred a))*(S m)))
  99     [ apply sym_eq.
 100       assumption
 101     | apply lt_O_times_S_S
 102     ]
 103   | assumption
 104   ]
 105 ]
 106 qed.
 107
 108 theorem O_lt_times_to_O_lt: \forall a,c:nat.
 109 O \lt (a * c) \to O \lt a.
 110 intros.
 111 apply (nat_case1 a)
 112 [ intros.
 113   rewrite > H1 in H.
 114   simplify in H.
 115   assumption
 116 | intros.
 117   apply lt_O_S
 118 ]
 119 qed.
 120
 121 (* times *)
 122 theorem monotonic_lt_times_r:
 123 \forall n:nat.monotonic nat lt (\lambda m.(S n)*m).
 124 simplify.
 125 intros.elim n.
 126 simplify.rewrite < plus_n_O.rewrite < plus_n_O.assumption.
 127 apply lt_plus.assumption.assumption.
 128 qed.
 129
 130 (* a simple variant of the previus monotionic_lt_times *)
 131 theorem monotonic_lt_times_variant: \forall c:nat.
 132 O \lt c \to monotonic nat lt (\lambda t.(t*c)).
 133 intros.
 134 apply (increasing_to_monotonic).
 135 unfold increasing.
 136 intros.
 137 simplify.
 138 rewrite > sym_plus.
 139 rewrite > plus_n_O in \vdash (? % ?).
 140 apply lt_plus_r.
 141 assumption.
 142 qed.
 143
 144 theorem lt_times_r: \forall n,p,q:nat. p < q \to (S n) * p < (S n) * q
 145 \def monotonic_lt_times_r.
 146
 147 theorem monotonic_lt_times_l:
 148 \forall m:nat.monotonic nat lt (\lambda n.n * (S m)).
 149 simplify.
 150 intros.
 151 rewrite < sym_times.rewrite < (sym_times (S m)).
 152 apply lt_times_r.assumption.
 153 qed.
 154
 155 variant lt_times_l: \forall n,p,q:nat. p<q \to p*(S n) < q*(S n)
 156 \def monotonic_lt_times_l.
 157
 158 theorem lt_times:\forall n,m,p,q:nat. n<m \to p<q \to n*p < m*q.
 159 intro.
 160 elim n.
 161 apply (lt_O_n_elim m H).
 162 intro.
 163 cut (lt O q).
 164 apply (lt_O_n_elim q Hcut).
 165 intro.change with (O < (S m1)*(S m2)).
 166 apply lt_O_times_S_S.
 167 apply (ltn_to_ltO p q H1).
 168 apply (trans_lt ? ((S n1)*q)).
 169 apply lt_times_r.assumption.
 170 cut (lt O q).
 171 apply (lt_O_n_elim q Hcut).
 172 intro.
 173 apply lt_times_l.
 174 assumption.
 175 apply (ltn_to_ltO p q H2).
 176 qed.
 177
 178 theorem lt_times_r1:
 179 \forall n,m,p. O < n \to m < p \to n*m < n*p.
 180 intros.
 181 elim H;apply lt_times_r;assumption.
 182 qed.
 183
 184 theorem lt_times_l1:
 185 \forall n,m,p. O < n \to m < p \to m*n < p*n.
 186 intros.
 187 elim H;apply lt_times_l;assumption.
 188 qed.
 189
 190 theorem lt_to_le_to_lt_times :
 191 \forall n,n1,m,m1. n < n1 \to m \le m1 \to O < m1 \to n*m < n1*m1.
 192 intros.
 193 apply (le_to_lt_to_lt ? (n*m1))
 194   [apply le_times_r.assumption
 195   |apply lt_times_l1
 196     [assumption|assumption]
 197   ]
 198 qed.
 199
 200 theorem lt_times_to_lt_l:
 201 \forall n,p,q:nat. p*(S n) < q*(S n) \to p < q.
 202 intros.
 203 cut (p < q \lor p \nlt q).
 204 elim Hcut.
 205 assumption.
 206 absurd (p * (S n) < q * (S n)).
 207 assumption.
 208 apply le_to_not_lt.
 209 apply le_times_l.
 210 apply not_lt_to_le.
 211 assumption.
 212 exact (decidable_lt p q).
 213 qed.
 214
 215 theorem lt_times_n_to_lt:
 216 \forall n,p,q:nat. O < n \to p*n < q*n \to p < q.
 217 intro.
 218 apply (nat_case n)
 219   [intros.apply False_ind.apply (not_le_Sn_n ? H)
 220   |intros 4.apply lt_times_to_lt_l
 221   ]
 222 qed.
 223
 224 theorem lt_times_to_lt_r:
 225 \forall n,p,q:nat. (S n)*p < (S n)*q \to lt p q.
 226 intros.
 227 apply (lt_times_to_lt_l n).
 228 rewrite < sym_times.
 229 rewrite < (sym_times (S n)).
 230 assumption.
 231 qed.
 232
 233 theorem lt_times_n_to_lt_r:
 234 \forall n,p,q:nat. O < n \to n*p < n*q \to lt p q.
 235 intro.
 236 apply (nat_case n)
 237   [intros.apply False_ind.apply (not_le_Sn_n ? H)
 238   |intros 4.apply lt_times_to_lt_r
 239   ]
 240 qed.
 241
 242
 243
 244 theorem nat_compare_times_l : \forall n,p,q:nat.
 245 nat_compare p q = nat_compare ((S n) * p) ((S n) * q).
 246 intros.apply nat_compare_elim.intro.
 247 apply nat_compare_elim.
 248 intro.reflexivity.
 249 intro.absurd (p=q).
 250 apply (inj_times_r n).assumption.
 251 apply lt_to_not_eq. assumption.
 252 intro.absurd (q<p).
 253 apply (lt_times_to_lt_r n).assumption.
 254 apply le_to_not_lt.apply lt_to_le.assumption.
 255 intro.rewrite < H.rewrite > nat_compare_n_n.reflexivity.
 256 intro.apply nat_compare_elim.intro.
 257 absurd (p<q).
 258 apply (lt_times_to_lt_r n).assumption.
 259 apply le_to_not_lt.apply lt_to_le.assumption.
 260 intro.absurd (q=p).
 261 symmetry.
 262 apply (inj_times_r n).assumption.
 263 apply lt_to_not_eq.assumption.
 264 intro.reflexivity.
 265 qed.
 266
 267 (* times and plus *)
 268 theorem lt_times_plus_times: \forall a,b,n,m:nat.
 269 a < n \to b < m \to a*m + b < n*m.
 270 intros 3.
 271 apply (nat_case n)
 272   [intros.apply False_ind.apply (not_le_Sn_O ? H)
 273   |intros.simplify.
 274    rewrite < sym_plus.
 275    unfold.
 276    change with (S b+a*m1 \leq m1+m*m1).
 277    apply le_plus
 278     [assumption
 279     |apply le_times
 280       [apply le_S_S_to_le.assumption
 281       |apply le_n
 282       ]
 283     ]
 284   ]
 285 qed.
 286
 287 (* div *)
 288
 289 theorem eq_mod_O_to_lt_O_div: \forall n,m:nat. O < m \to O < n\to n \mod m = O \to O < n / m.
 290 intros 4.apply (lt_O_n_elim m H).intros.
 291 apply (lt_times_to_lt_r m1).
 292 rewrite < times_n_O.
 293 rewrite > (plus_n_O ((S m1)*(n / (S m1)))).
 294 rewrite < H2.
 295 rewrite < sym_times.
 296 rewrite < div_mod.
 297 rewrite > H2.
 298 assumption.
 299 unfold lt.apply le_S_S.apply le_O_n.
 300 qed.
 301
 302 theorem lt_div_n_m_n: \forall n,m:nat. (S O) < m \to O < n \to n / m \lt n.
 303 intros.
 304 apply (nat_case1 (n / m)).intro.
 305 assumption.intros.rewrite < H2.
 306 rewrite > (div_mod n m) in \vdash (? ? %).
 307 apply (lt_to_le_to_lt ? ((n / m)*m)).
 308 apply (lt_to_le_to_lt ? ((n / m)*(S (S O)))).
 309 rewrite < sym_times.
 310 rewrite > H2.
 311 simplify.unfold lt.
 312 rewrite < plus_n_O.
 313 rewrite < plus_n_Sm.
 314 apply le_S_S.
 315 apply le_S_S.
 316 apply le_plus_n.
 317 apply le_times_r.
 318 assumption.
 319 rewrite < sym_plus.
 320 apply le_plus_n.
 321 apply (trans_lt ? (S O)).
 322 unfold lt. apply le_n.assumption.
 323 qed.
 324
 325 theorem eq_div_div_div_times: \forall n,m,q. O < n \to O < m \to
 326 q/n/m = q/(n*m).
 327 intros.
 328 apply (div_mod_spec_to_eq q (n*m) ? (q\mod n+n*(q/n\mod m)) ? (mod q (n*m)))
 329   [apply div_mod_spec_intro
 330     [apply (lt_to_le_to_lt ? (n*(S (q/n\mod m))))
 331       [rewrite < times_n_Sm.
 332        apply lt_plus_l.
 333        apply lt_mod_m_m.
 334        assumption
 335       |apply le_times_r.
 336        apply lt_mod_m_m.
 337        assumption
 338       ]
 339     |rewrite > sym_times in ⊢ (? ? ? (? (? ? %) ?)).
 340      rewrite < assoc_times.
 341      rewrite > (eq_times_div_minus_mod ? ? H1).
 342      rewrite > sym_times.
 343      rewrite > distributive_times_minus.
 344      rewrite > sym_times.
 345      rewrite > (eq_times_div_minus_mod ? ? H).
 346      rewrite < sym_plus in ⊢ (? ? ? (? ? %)).
 347      rewrite < assoc_plus.
 348      rewrite < plus_minus_m_m
 349       [rewrite < plus_minus_m_m
 350         [reflexivity
 351         |apply (eq_plus_to_le ? ? ((q/n)*n)).
 352          rewrite < sym_plus.
 353          apply div_mod.
 354          assumption
 355         ]
 356       |apply (trans_le ? (n*(q/n)))
 357         [apply le_times_r.
 358          apply (eq_plus_to_le ? ? ((q/n)/m*m)).
 359          rewrite < sym_plus.
 360          apply div_mod.
 361          assumption
 362         |rewrite > sym_times.
 363          rewrite > eq_times_div_minus_mod
 364           [apply le_n
 365           |assumption
 366           ]
 367         ]
 368       ]
 369     ]
 370   |apply div_mod_spec_div_mod.
 371    rewrite > (times_n_O O).
 372    apply lt_times;assumption
 373   ]
 374 qed.
 375
 376 theorem eq_div_div_div_div: \forall n,m,q. O < n \to O < m \to
 377 q/n/m = q/m/n.
 378 intros.
 379 apply (trans_eq ? ? (q/(n*m)))
 380   [apply eq_div_div_div_times;assumption
 381   |rewrite > sym_times.
 382    apply sym_eq.
 383    apply eq_div_div_div_times;assumption
 384   ]
 385 qed.
 386
 387 theorem SSO_mod: \forall n,m. O < m \to (S(S O))*n/m = (n/m)*(S(S O)) + mod ((S(S O))*n/m) (S(S O)).
 388 intros.
 389 rewrite < (lt_O_to_div_times n (S(S O))) in ⊢ (? ? ? (? (? (? % ?) ?) ?))
 390   [rewrite > eq_div_div_div_div
 391     [rewrite > sym_times in ⊢ (? ? ? (? (? (? (? % ?) ?) ?) ?)).
 392      apply div_mod.
 393      apply lt_O_S
 394     |apply lt_O_S
 395     |assumption
 396     ]
 397   |apply lt_O_S
 398   ]
 399 qed.
 400 (* Forall a,b : N. 0 < b \to b * (a/b) <= a < b * (a/b +1) *)
 401 (* The theorem is shown in two different parts: *)
 402
 403 theorem lt_to_div_to_and_le_times_lt_S: \forall a,b,c:nat.
 404 O \lt b \to a/b = c \to (b*c \le a \land a \lt b*(S c)).
 405 intros.
 406 split
 407 [ rewrite < H1.
 408   rewrite > sym_times.
 409   rewrite > eq_times_div_minus_mod
 410   [ apply (le_minus_m a (a \mod b))
 411   | assumption
 412   ]
 413 | rewrite < (times_n_Sm b c).
 414   rewrite < H1.
 415   rewrite > sym_times.
 416   rewrite > (div_mod a b) in \vdash (? % ?)
 417   [ rewrite > (sym_plus b ((a/b)*b)).
 418     apply lt_plus_r.
 419     apply lt_mod_m_m.
 420     assumption
 421   | assumption
 422   ]
 423 ]
 424 qed.
 425
 426 theorem lt_to_le_times_to_lt_S_to_div: \forall a,c,b:nat.
 427 O \lt b \to (b*c) \le a \to a \lt (b*(S c)) \to a/b = c.
 428 intros.
 429 apply (le_to_le_to_eq)
 430 [ apply (leb_elim (a/b) c);intros
 431   [ assumption
 432   | cut (c \lt (a/b))
 433     [ apply False_ind.
 434       apply (lt_to_not_le (a \mod b) O)
 435       [ apply (lt_plus_to_lt_l ((a/b)*b)).
 436         simplify.
 437         rewrite < sym_plus.
 438         rewrite < div_mod
 439         [ apply (lt_to_le_to_lt ? (b*(S c)) ?)
 440           [ assumption
 441           | rewrite > (sym_times (a/b) b).
 442             apply le_times_r.
 443             assumption
 444           ]
 445         | assumption
 446         ]
 447       | apply le_O_n
 448       ]
 449     | apply not_le_to_lt.
 450       assumption
 451     ]
 452   ]
 453 | apply (leb_elim c (a/b));intros
 454   [ assumption
 455   | cut((a/b) \lt c)
 456     [ apply False_ind.
 457       apply (lt_to_not_le (a \mod b) b)
 458       [ apply (lt_mod_m_m).
 459         assumption
 460       | apply (le_plus_to_le ((a/b)*b)).
 461         rewrite < (div_mod a b)
 462         [ apply (trans_le ? (b*c) ?)
 463           [ rewrite > (sym_times (a/b) b).
 464             rewrite > (times_n_SO b) in \vdash (? (? ? %) ?).
 465             rewrite < distr_times_plus.
 466             rewrite > sym_plus.
 467             simplify in \vdash (? (? ? %) ?).
 468             apply le_times_r.
 469             assumption
 470           | assumption
 471           ]
 472         | assumption
 473         ]
 474       ]
 475     | apply not_le_to_lt.
 476       assumption
 477     ]
 478   ]
 479 ]
 480 qed.
 481
 482
 483 theorem lt_to_lt_to_eq_div_div_times_times: \forall a,b,c:nat.
 484 O \lt c \to O \lt b \to (a/b) = (a*c)/(b*c).
 485 intros.
 486 apply sym_eq.
 487 cut (b*(a/b) \le a \land a \lt b*(S (a/b)))
 488 [ elim Hcut.
 489   apply lt_to_le_times_to_lt_S_to_div
 490   [ rewrite > (S_pred b)
 491     [ rewrite > (S_pred c)
 492       [ apply (lt_O_times_S_S)
 493       | assumption
 494       ]
 495     | assumption
 496     ]
 497   | rewrite > assoc_times.
 498     rewrite > (sym_times c (a/b)).
 499     rewrite < assoc_times.
 500     rewrite > (sym_times (b*(a/b)) c).
 501     rewrite > (sym_times a c).
 502     apply (le_times_r c (b*(a/b)) a).
 503     assumption
 504   | rewrite > (sym_times a c).
 505     rewrite > (assoc_times ).
 506     rewrite > (sym_times c (S (a/b))).
 507     rewrite < (assoc_times).
 508     rewrite > (sym_times (b*(S (a/b))) c).
 509     apply (lt_times_r1 c a (b*(S (a/b))));
 510       assumption
 511   ]
 512 | apply (lt_to_div_to_and_le_times_lt_S)
 513   [ assumption
 514   | reflexivity
 515   ]
 516 ]
 517 qed.
 518
 519 theorem times_mod: \forall a,b,c:nat.
 520 O \lt c \to O \lt b \to ((a*c) \mod (b*c)) = c*(a\mod b).
 521 intros.
 522 apply (div_mod_spec_to_eq2 (a*c) (b*c) (a/b) ((a*c) \mod (b*c)) (a/b) (c*(a \mod b)))
 523 [ rewrite > (lt_to_lt_to_eq_div_div_times_times a b c)
 524   [ apply div_mod_spec_div_mod.
 525     rewrite > (S_pred b)
 526     [ rewrite > (S_pred c)
 527       [ apply lt_O_times_S_S
 528       | assumption
 529       ]
 530     | assumption
 531     ]
 532   | assumption
 533   | assumption
 534   ]
 535 | apply div_mod_spec_intro
 536   [ rewrite > (sym_times b c).
 537     apply (lt_times_r1 c)
 538     [ assumption
 539     | apply (lt_mod_m_m).
 540       assumption
 541     ]
 542   | rewrite < (assoc_times (a/b) b c).
 543     rewrite > (sym_times a c).
 544     rewrite > (sym_times ((a/b)*b) c).
 545     rewrite < (distr_times_plus c ? ?).
 546     apply eq_f.
 547     apply (div_mod a b).
 548     assumption
 549   ]
 550 ]
 551 qed.
 552
 553
 554
 555
 556 (* general properties of functions *)
 557 theorem monotonic_to_injective: \forall f:nat\to nat.
 558 monotonic nat lt f \to injective nat nat f.
 559 unfold injective.intros.
 560 apply (nat_compare_elim x y).
 561 intro.apply False_ind.apply (not_le_Sn_n (f x)).
 562 rewrite > H1 in \vdash (? ? %).
 563 change with (f x < f y).
 564 apply H.apply H2.
 565 intros.assumption.
 566 intro.apply False_ind.apply (not_le_Sn_n (f y)).
 567 rewrite < H1 in \vdash (? ? %).
 568 change with (f y < f x).
 569 apply H.apply H2.
 570 qed.
 571
 572 theorem increasing_to_injective: \forall f:nat\to nat.
 573 increasing f \to injective nat nat f.
 574 intros.apply monotonic_to_injective.
 575 apply increasing_to_monotonic.assumption.
 576 qed.
 577