helm/software/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29 open GrafiteTypes
  30
  31 module TA = GrafiteAst
  32
  33 let debug = false
  34 let debug_print = if debug then prerr_endline else ignore
  35
  36   (** raised when one of the script margins (top or bottom) is reached *)
  37 exception Margin
  38 exception NoUnfinishedProof
  39 exception ActionCancelled of string
  40
  41 let safe_substring s i j =
  42   try String.sub s i j with Invalid_argument _ -> assert false
  43
  44 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  45 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  46 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  47 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  48 let newline_RE = Pcre.regexp "\n"
  49 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  50
  51 let comment str =
  52   if Pcre.pmatch ~rex:multiline_RE str then
  53     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  54   else
  55     "\n(**\n" ^ str ^ "\n*)"
  56
  57 let strip_comments str =
  58   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  59 ;;
  60
  61 let first_line s =
  62   let s = Pcre.replace ~rex:heading_nl_RE s in
  63   try
  64     let nl_pos = String.index s '\n' in
  65     String.sub s 0 nl_pos
  66   with Not_found -> s
  67
  68 type guistuff = {
  69   mathviewer:MatitaTypes.mathViewer;
  70   urichooser: UriManager.uri list -> UriManager.uri list;
  71   ask_confirmation: title:string -> message:string -> [`YES | `NO | `CANCEL];
  72 }
  73
  74 let eval_with_engine include_paths guistuff lexicon_status grafite_status user_goal
  75  skipped_txt nonskipped_txt st
  76 =
  77   let module TAPp = GrafiteAstPp in
  78   let module DTE = DisambiguateTypes.Environment in
  79   let parsed_text_length =
  80     String.length skipped_txt + String.length nonskipped_txt
  81   in
  82   let text = skipped_txt ^ nonskipped_txt in
  83   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  84   let enriched_history_fragment =
  85    MatitaEngine.eval_ast ~do_heavy_checks:(Helm_registry.get_bool
  86      "matita.do_heavy_checks")
  87     lexicon_status grafite_status (text,prefix_len,st)
  88   in
  89   let enriched_history_fragment = List.rev enriched_history_fragment in
  90   (* really fragile *)
  91   let res,_ =
  92     List.fold_left
  93       (fun (acc, to_prepend) (status,alias) ->
  94        match alias with
  95        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  96        | Some (k,value) ->
  97             let newtxt = LexiconAstPp.pp_alias value in
  98             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  99       ([],skipped_txt) enriched_history_fragment
 100   in
 101   res,"",parsed_text_length
 102 ;;
 103
 104 (* this function calls the parser in a way that it does not perform inclusions,
 105  * so that we can ensure the inclusion is performed after the included file
 106  * is compiled (if needed). matitac does not need that, since it compiles files
 107  * in the good order, here files may be compiled on demand. *)
 108 let wrap_with_make include_paths (f : GrafiteParser.statement) x =
 109   try
 110     f ~never_include:true ~include_paths x
 111   with
 112   | GrafiteParser.NoInclusionPerformed mafilename ->
 113       let root, buri, _, tgt =
 114         try Librarian.baseuri_of_script ~include_paths mafilename
 115         with Librarian.NoRootFor _ ->
 116           HLog.error ("The included file '"^mafilename^"' has no root file,");
 117           HLog.error "please create it.";
 118           raise (Failure ("No root file for "^mafilename))
 119       in
 120       let b = MatitacLib.Make.make root [tgt] in
 121       if b then
 122         try f ~include_paths x with LexiconEngine.IncludedFileNotCompiled _ ->
 123          raise
 124            (Failure ("Including: "^tgt^
 125              "\nNothing to do... did you run matitadep?"))
 126       else raise (Failure ("Compiling: " ^ tgt))
 127 ;;
 128
 129 let pp_eager_statement_ast =
 130   GrafiteAstPp.pp_statement ~term_pp:CicNotationPp.pp_term
 131     ~lazy_term_pp:(fun _ -> assert false) ~obj_pp:(fun _ -> assert false)
 132
 133 (* naive implementation of procedural proof script generation,
 134  * starting from an applicatiove *auto generated) proof.
 135  * this is out of place, but I like it :-P *)
 136 let cic2grafite context menv t =
 137   (* indents a proof script in a stupid way, better than nothing *)
 138   let stupid_indenter s =
 139     let next s =
 140       let idx_square_o = try String.index s '[' with Not_found -> -1 in
 141       let idx_square_c = try String.index s ']' with Not_found -> -1 in
 142       let idx_pipe = try String.index s '|' with Not_found -> -1 in
 143       let tok =
 144         List.sort (fun (i,_) (j,_) -> compare i j)
 145           [idx_square_o,'[';idx_square_c,']';idx_pipe,'|']
 146       in
 147       let tok = List.filter (fun (i,_) -> i <> -1) tok in
 148       match tok with
 149       | (i,c)::_ -> Some (i,c)
 150       | _ -> None
 151     in
 152     let break_apply n s =
 153       let tab = String.make (n+1) ' ' in
 154       Pcre.replace ~templ:(".\n" ^ tab ^ "apply") ~pat:"\\.apply" s
 155     in
 156     let rec ind n s =
 157       match next s with
 158       | None ->
 159           s
 160       | Some (position, char) ->
 161           try
 162             let s1, s2 =
 163               String.sub s 0 position,
 164               String.sub s (position+1) (String.length s - (position+1))
 165             in
 166             match char with
 167             | '[' -> break_apply n s1 ^ "\n" ^ String.make (n+2) ' ' ^
 168                        "[" ^ ind (n+2) s2
 169             | '|' -> break_apply n s1 ^ "\n" ^ String.make n ' ' ^
 170                        "|" ^ ind n s2
 171             | ']' -> break_apply n s1 ^ "\n" ^ String.make n ' ' ^
 172                        "]" ^ ind (n-2) s2
 173             | _ -> assert false
 174           with
 175           Invalid_argument err ->
 176             prerr_endline err;
 177             s
 178     in
 179      ind 0 s
 180   in
 181   let module PT = CicNotationPt in
 182   let module GA = GrafiteAst in
 183   let pp_t context t =
 184     let names =
 185       List.map (function Some (n,_) -> Some n | None -> None) context
 186     in
 187     CicPp.pp t names
 188   in
 189   let sort_of context t =
 190     try
 191       let ty,_ =
 192         CicTypeChecker.type_of_aux' menv context t
 193           CicUniv.oblivion_ugraph
 194       in
 195       let sort,_ = CicTypeChecker.type_of_aux' menv context ty
 196           CicUniv.oblivion_ugraph
 197       in
 198       match sort with
 199       | Cic.Sort Cic.Prop -> true
 200       | _ -> false
 201     with
 202       CicTypeChecker.TypeCheckerFailure _ ->
 203         HLog.error "auto proof to sript transformation error"; false
 204   in
 205   let floc = HExtlib.dummy_floc in
 206   (* minimalisti cic.term -> pt.term *)
 207   let print_term c t =
 208     let rec aux c = function
 209       | Cic.Rel _
 210       | Cic.MutConstruct _
 211       | Cic.MutInd _
 212       | Cic.Const _ as t ->
 213           PT.Ident (pp_t c t, None)
 214       | Cic.Appl l -> PT.Appl (List.map (aux c) l)
 215       | Cic.Implicit _ -> PT.Implicit
 216       | Cic.Lambda (Cic.Name n, s, t) ->
 217           PT.Binder (`Lambda, (PT.Ident (n,None), Some (aux c s)),
 218             aux (Some (Cic.Name n, Cic.Decl s)::c) t)
 219       | Cic.Prod (Cic.Name n, s, t) ->
 220           PT.Binder (`Forall, (PT.Ident (n,None), Some (aux c s)),
 221             aux (Some (Cic.Name n, Cic.Decl s)::c) t)
 222       | Cic.LetIn (Cic.Name n, s, ty, t) ->
 223           PT.Binder (`Lambda, (PT.Ident (n,None), Some (aux c s)),
 224             aux (Some (Cic.Name n, Cic.Def (s,ty))::c) t)
 225       | Cic.Meta _ -> PT.Implicit
 226       | Cic.Sort (Cic.Type u) -> PT.Sort (`Type u)
 227       | Cic.Sort Cic.Set -> PT.Sort `Set
 228       | Cic.Sort (Cic.CProp u) -> PT.Sort (`CProp u)
 229       | Cic.Sort Cic.Prop -> PT.Sort `Prop
 230       | _ as t -> PT.Ident ("ERROR: "^CicPp.ppterm t, None)
 231     in
 232     aux c t
 233   in
 234   (* prints an applicative proof, that is an auto proof.
 235    * don't use in the general case! *)
 236   let rec print_proof context = function
 237     | Cic.Rel _
 238     | Cic.Const _ as t ->
 239         [GA.Executable (floc,
 240           GA.Tactic (floc,
 241           Some (GA.Apply (floc, print_term context t)), GA.Dot floc))]
 242     | Cic.Appl (he::tl) ->
 243         let tl = List.map (fun t -> t, sort_of context t) tl in
 244         let subgoals =
 245           HExtlib.filter_map (function (t,true) -> Some t | _ -> None) tl
 246         in
 247         let args =
 248           List.map (function | (t,true) -> Cic.Implicit None | (t,_) -> t) tl
 249         in
 250         if List.length subgoals > 1 then
 251           (* branch *)
 252           [GA.Executable (floc,
 253             GA.Tactic (floc,
 254               Some (GA.Apply (floc, print_term context (Cic.Appl (he::args)))),
 255               GA.Semicolon floc))] @
 256           [GA.Executable (floc, GA.Tactic (floc, None, GA.Branch floc))] @
 257           (HExtlib.list_concat
 258           ~sep:[GA.Executable (floc, GA.Tactic (floc, None,GA.Shift floc))]
 259             (List.map (print_proof context) subgoals)) @
 260           [GA.Executable (floc, GA.Tactic (floc, None,GA.Merge floc))]
 261         else
 262           (* simple apply *)
 263           [GA.Executable (floc,
 264             GA.Tactic (floc,
 265             Some (GA.Apply
 266               (floc, print_term context (Cic.Appl (he::args)) )), GA.Dot floc))]
 267           @
 268           (match subgoals with
 269           | [] -> []
 270           | [x] -> print_proof context x
 271           | _ -> assert false)
 272     | Cic.Lambda (Cic.Name n, ty, bo) ->
 273         [GA.Executable (floc,
 274           GA.Tactic (floc,
 275             Some (GA.Cut (floc, Some n, (print_term context ty))),
 276             GA.Branch floc))] @
 277         (print_proof (Some (Cic.Name n, Cic.Decl ty)::context) bo) @
 278         [GA.Executable (floc, GA.Tactic (floc, None,GA.Shift floc))] @
 279         [GA.Executable (floc, GA.Tactic (floc,
 280           Some (GA.Assumption floc),GA.Merge floc))]
 281     | _ -> []
 282     (*
 283         debug_print (lazy (CicPp.ppterm t));
 284         assert false
 285         *)
 286   in
 287   (* performs a lambda closure of the proof term abstracting metas.
 288    * this is really an approximation of a closure, local subst of metas
 289    * is not kept into account *)
 290   let close_pt menv context t =
 291     let metas = CicUtil.metas_of_term t in
 292     let metas =
 293       HExtlib.list_uniq ~eq:(fun (i,_) (j,_) -> i = j)
 294         (List.sort (fun (i,_) (j,_) -> compare i j) metas)
 295     in
 296     let mk_rels_and_collapse_metas metas =
 297       let rec aux i map acc acc1 = function
 298         | [] -> acc, acc1, map
 299         | (j,_ as m)::tl ->
 300             let _,_,ty = CicUtil.lookup_meta j menv in
 301             try
 302               let n = List.assoc ty map in
 303               aux i map (Cic.Rel n :: acc) (m::acc1) tl
 304             with Not_found ->
 305               let map = (ty, i)::map in
 306               aux (i+1) map (Cic.Rel i :: acc) (m::acc1) tl
 307       in
 308       aux 1 [] [] [] metas
 309     in
 310     let rels, metas, map = mk_rels_and_collapse_metas metas in
 311     let n_lambdas = List.length map in
 312     let t =
 313       if metas = [] then
 314         t
 315       else
 316         let t =
 317           ProofEngineReduction.replace_lifting
 318            ~what:(List.map (fun (x,_) -> Cic.Meta (x,[])) metas)
 319            ~with_what:rels
 320            ~context:context
 321            ~equality:(fun _ x y ->
 322              match x,y with
 323              | Cic.Meta(i,_), Cic.Meta(j,_) when i=j -> true
 324              | _ -> false)
 325            ~where:(CicSubstitution.lift n_lambdas t)
 326         in
 327         let rec mk_lam = function
 328           | [] -> t
 329           | (ty,n)::tl ->
 330               let name = "fresh_"^ string_of_int n in
 331               Cic.Lambda (Cic.Name name, ty, mk_lam tl)
 332         in
 333          mk_lam
 334           (fst (List.fold_left
 335             (fun (l,liftno) (ty,_)  ->
 336               (l @ [CicSubstitution.lift liftno ty,liftno] , liftno+1))
 337             ([],0) map))
 338     in
 339       t
 340   in
 341   let ast = print_proof context (close_pt menv context t) in
 342   let pp t =
 343     (* ZACK: setting width to 80 will trigger a bug of BoxPp.render_to_string
 344      * which will show up using the following command line:
 345      * ./tptp2grafite -tptppath ~tassi/TPTP-v3.1.1 GRP170-1 *)
 346     let width = max_int in
 347     let term_pp content_term =
 348       let pres_term = TermContentPres.pp_ast content_term in
 349       let dummy_tbl = Hashtbl.create 1 in
 350       let markup = CicNotationPres.render dummy_tbl pres_term in
 351       let s = "(" ^ BoxPp.render_to_string
 352        ~map_unicode_to_tex:(Helm_registry.get_bool
 353          "matita.paste_unicode_as_tex")
 354        List.hd width markup ^ ")" in
 355       Pcre.substitute
 356         ~pat:"\\\\forall [Ha-z][a-z0-9_]*" ~subst:(fun x -> "\n" ^ x) s
 357     in
 358     CicNotationPp.set_pp_term term_pp;
 359     let lazy_term_pp = fun x -> assert false in
 360     let obj_pp = CicNotationPp.pp_obj CicNotationPp.pp_term in
 361     GrafiteAstPp.pp_statement
 362      ~map_unicode_to_tex:(Helm_registry.get_bool
 363        "matita.paste_unicode_as_tex")
 364      ~term_pp ~lazy_term_pp ~obj_pp t
 365   in
 366   let script = String.concat "" (List.map pp ast) in
 367   prerr_endline script;
 368   stupid_indenter script
 369 ;;
 370
 371 let rec eval_macro include_paths (buffer : GText.buffer) guistuff lexicon_status grafite_status user_goal unparsed_text parsed_text script mac =
 372   let module TAPp = GrafiteAstPp in
 373   let module MQ = MetadataQuery in
 374   let module MDB = LibraryDb in
 375   let module CTC = CicTypeChecker in
 376   let module CU = CicUniv in
 377   (* no idea why ocaml wants this *)
 378   let parsed_text_length = String.length parsed_text in
 379   let dbd = LibraryDb.instance () in
 380   let pp_macro = ApplyTransformation.txt_of_macro ~map_unicode_to_tex:true in
 381   match mac with
 382   (* WHELP's stuff *)
 383   | TA.WMatch (loc, term) ->
 384      let l =  Whelp.match_term ~dbd term in
 385      let entry = `Whelp (pp_macro [] [] mac, l) in
 386      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 387      [], "", parsed_text_length
 388   | TA.WInstance (loc, term) ->
 389      let l = Whelp.instance ~dbd term in
 390      let entry = `Whelp (pp_macro [] [] mac, l) in
 391      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 392      [], "", parsed_text_length
 393   | TA.WLocate (loc, s) ->
 394      let l = Whelp.locate ~dbd s in
 395      let entry = `Whelp (pp_macro [] [] mac, l) in
 396      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 397      [], "", parsed_text_length
 398   | TA.WElim (loc, term) ->
 399      let uri =
 400        match term with
 401        | Cic.MutInd (uri,n,_) -> UriManager.uri_of_uriref uri n None
 402        | _ -> failwith "Not a MutInd"
 403      in
 404      let l = Whelp.elim ~dbd uri in
 405      let entry = `Whelp (pp_macro [] [] mac, l) in
 406      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 407      [], "", parsed_text_length
 408   | TA.WHint (loc, term) ->
 409      let _subst = [] in
 410      let s = ((None,[0,[],term], _subst, lazy (Cic.Meta (0,[])) ,term, []),0) in
 411      let l = List.map fst (MQ.experimental_hint ~dbd s) in
 412      let entry = `Whelp (pp_macro [] [] mac, l) in
 413      guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 414      [], "", parsed_text_length
 415   (* REAL macro *)
 416   | TA.Hint (loc, rewrite) ->
 417       let user_goal' =
 418        match user_goal with
 419           Some n -> n
 420         | None -> raise NoUnfinishedProof
 421       in
 422       let proof = GrafiteTypes.get_current_proof grafite_status in
 423       let proof_status = proof,user_goal' in
 424       if rewrite then
 425         let l = MQ.equations_for_goal ~dbd proof_status in
 426         let l = List.filter (fun u -> not (LibraryObjects.in_eq_URIs u)) l in
 427         let entry =
 428           `Whelp (pp_macro [] [] (TA.WHint(loc, Cic.Implicit None)), l) in
 429         guistuff.mathviewer#show_uri_list ~reuse:true ~entry l;
 430         [], "", parsed_text_length
 431       else
 432         let l = List.map fst (MQ.experimental_hint ~dbd proof_status) in
 433         let selected = guistuff.urichooser l in
 434         (match selected with
 435         | [] -> [], "", parsed_text_length
 436         | [uri] ->
 437             let suri = UriManager.string_of_uri uri in
 438             let ast loc =
 439               TA.Executable (loc, (TA.Tactic (loc,
 440                Some (TA.Apply (loc, CicNotationPt.Uri (suri, None))),
 441                TA.Dot loc))) in
 442             let text =
 443              comment parsed_text ^ "\n" ^
 444               pp_eager_statement_ast (ast HExtlib.dummy_floc)
 445               ~map_unicode_to_tex:(Helm_registry.get_bool
 446                 "matita.paste_unicode_as_tex")
 447             in
 448             let text_len = MatitaGtkMisc.utf8_string_length text in
 449             let loc = HExtlib.floc_of_loc (0,text_len) in
 450             let statement = `Ast (GrafiteParser.LSome (ast loc),text) in
 451             let res,_,_parsed_text_len =
 452              eval_statement include_paths buffer guistuff lexicon_status
 453               grafite_status user_goal script statement
 454             in
 455              (* we need to replace all the parsed_text *)
 456              res,"",String.length parsed_text
 457         | _ ->
 458             HLog.error
 459               "The result of the urichooser should be only 1 uri, not:\n";
 460             List.iter (
 461               fun u -> HLog.error (UriManager.string_of_uri u ^ "\n")
 462             ) selected;
 463             assert false)
 464   | TA.Eval (_, kind, term) ->
 465       let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 466       let context =
 467        match user_goal with
 468           None -> []
 469         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 470       let ty,_ = CTC.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 471       let term =
 472         match kind with
 473         | `Normalize ->
 474              CicReduction.normalize ~delta:true ~subst:[] context term
 475         | `Simpl ->
 476             ProofEngineReduction.simpl context term
 477         | `Unfold None ->
 478             ProofEngineReduction.unfold ?what:None context term
 479         | `Unfold (Some lazy_term) ->
 480              let what, _, _ =
 481                lazy_term context metasenv CicUniv.empty_ugraph in
 482              ProofEngineReduction.unfold ~what context term
 483         | `Whd ->
 484             CicReduction.whd ~delta:true ~subst:[] context term
 485       in
 486       let t_and_ty = Cic.Cast (term,ty) in
 487       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 488       [({grafite_status with proof_status = No_proof},lexicon_status), parsed_text ],"",
 489         parsed_text_length
 490   | TA.Check (_,term) ->
 491       let metasenv = GrafiteTypes.get_proof_metasenv grafite_status in
 492       let context =
 493        match user_goal with
 494           None -> []
 495         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 496       let ty,_ = CTC.type_of_aux' metasenv context term CicUniv.empty_ugraph in
 497       let t_and_ty = Cic.Cast (term,ty) in
 498       guistuff.mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 499       [], "", parsed_text_length
 500   | TA.AutoInteractive (_, params) ->
 501       let user_goal' =
 502        match user_goal with
 503           Some n -> n
 504         | None -> raise NoUnfinishedProof
 505       in
 506       let proof = GrafiteTypes.get_current_proof grafite_status in
 507       let proof_status = proof,user_goal' in
 508       (try
 509         let _,menv,_,_,_,_ = proof in
 510         let i,cc,ty = CicUtil.lookup_meta user_goal' menv in
 511         let timestamp = Unix.gettimeofday () in
 512         let (_,menv,subst,_,_,_), _ =
 513           ProofEngineTypes.apply_tactic
 514             (Auto.auto_tac ~dbd ~params
 515               ~universe:grafite_status.GrafiteTypes.universe) proof_status
 516         in
 517         let proof_term =
 518           let irl =
 519             CicMkImplicit.identity_relocation_list_for_metavariable cc
 520           in
 521           CicMetaSubst.apply_subst subst (Cic.Meta (i,irl))
 522         in
 523         let time = Unix.gettimeofday () -. timestamp in
 524         let size, depth = Auto.size_and_depth cc menv proof_term in
 525         let trailer =
 526           Printf.sprintf
 527             "\n(* end auto(%s) proof: TIME=%4.2f SIZE=%d DEPTH=%d *)"
 528             Auto.revision time size depth
 529         in
 530         let proof_script =
 531           if List.exists (fun (s,_) -> s = "paramodulation") (snd params) then
 532               let proof_term, how_many_lambdas =
 533                 Auto.lambda_close ~prefix_name:"orrible_hack_"
 534                   proof_term menv cc
 535               in
 536               let ty,_ =
 537                 CicTypeChecker.type_of_aux'
 538                   menv [] proof_term CicUniv.empty_ugraph
 539               in
 540               prerr_endline (CicPp.ppterm proof_term);
 541               (* use declarative output *)
 542               let obj =
 543                 (* il proof_term vive in cc, devo metterci i lambda no? *)
 544                 (Cic.CurrentProof ("xxx",menv,proof_term,ty,[],[]))
 545               in
 546                ApplyTransformation.txt_of_cic_object
 547                 ~map_unicode_to_tex:(Helm_registry.get_bool
 548                   "matita.paste_unicode_as_tex")
 549                 ~skip_thm_and_qed:true
 550                 ~skip_initial_lambdas:how_many_lambdas
 551                 80 GrafiteAst.Declarative "" obj
 552           else
 553             if true then
 554               (* use cic2grafite *)
 555               cic2grafite cc menv proof_term
 556             else
 557               (* alternative using FG stuff *)
 558               let map_unicode_to_tex =
 559                  Helm_registry.get_bool "matita.paste_unicode_as_tex"
 560               in
 561               ApplyTransformation.procedural_txt_of_cic_term
 562                  ~map_unicode_to_tex 78 cc proof_term
 563         in
 564         let text = comment parsed_text ^ "\n" ^ proof_script ^ trailer in
 565         [],text,parsed_text_length
 566       with
 567         ProofEngineTypes.Fail _ as exn ->
 568           raise exn
 569           (* [], comment parsed_text ^ "\nfail.\n", parsed_text_length *))
 570   | TA.Inline (_,style,suri,prefix,flavour) ->
 571        let str =
 572          ApplyTransformation.txt_of_inline_macro
 573           ~map_unicode_to_tex:(Helm_registry.get_bool
 574             "matita.paste_unicode_as_tex")
 575           style ?flavour prefix suri
 576        in
 577        [], str, String.length parsed_text
 578
 579 and eval_executable include_paths (buffer : GText.buffer) guistuff
 580 lexicon_status grafite_status user_goal unparsed_text skipped_txt nonskipped_txt
 581 script ex loc
 582 =
 583  let module TAPp = GrafiteAstPp in
 584  let module MD = MultiPassDisambiguator in
 585  let module ML = MatitaMisc in
 586   try
 587    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 588     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 589        (Glib.Utf8.length skipped_txt))) ;
 590    eval_with_engine include_paths
 591     guistuff lexicon_status grafite_status user_goal skipped_txt nonskipped_txt
 592      (TA.Executable (loc, ex))
 593   with
 594      MatitaTypes.Cancel -> [], "", 0
 595    | GrafiteEngine.Macro (_loc,lazy_macro) ->
 596       let context =
 597        match user_goal with
 598           None -> []
 599         | Some n -> GrafiteTypes.get_proof_context grafite_status n in
 600       let grafite_status,macro = lazy_macro context in
 601        eval_macro include_paths buffer guistuff lexicon_status grafite_status
 602         user_goal unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 603
 604 and eval_statement include_paths (buffer : GText.buffer) guistuff lexicon_status
 605  grafite_status user_goal script statement
 606 =
 607   let (lexicon_status,st), unparsed_text =
 608     match statement with
 609     | `Raw text ->
 610         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 611         let ast =
 612          wrap_with_make include_paths
 613           (GrafiteParser.parse_statement (Ulexing.from_utf8_string text)) lexicon_status
 614         in
 615           ast, text
 616     | `Ast (st, text) -> (lexicon_status, st), text
 617   in
 618   let text_of_loc floc =
 619     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 620     let start, stop = HExtlib.loc_of_floc floc in
 621     let floc = HExtlib.floc_of_loc (0, start) in
 622     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 623     let floc = HExtlib.floc_of_loc (0, stop) in
 624     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 625     txt,nonskipped_txt,skipped_txt,len
 626   in
 627   match st with
 628   | GrafiteParser.LNone loc ->
 629       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 630        [(grafite_status,lexicon_status),parsed_text],"",
 631         parsed_text_length
 632   | GrafiteParser.LSome (GrafiteAst.Comment (loc, _)) ->
 633       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 634       let remain_len = String.length unparsed_text - parsed_text_length in
 635       let s = String.sub unparsed_text parsed_text_length remain_len in
 636       let s,text,len =
 637        try
 638         eval_statement include_paths buffer guistuff lexicon_status
 639          grafite_status user_goal script (`Raw s)
 640        with
 641           HExtlib.Localized (floc, exn) ->
 642            HExtlib.raise_localized_exception
 643              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 644         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 645            raise
 646             (MultiPassDisambiguator.DisambiguationError
 647               (offset+parsed_text_length, errorll))
 648       in
 649       assert (text=""); (* no macros inside comments, please! *)
 650       (match s with
 651       | (statuses,text)::tl ->
 652          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 653       | [] -> [], "", 0)
 654   | GrafiteParser.LSome (GrafiteAst.Executable (loc, ex)) ->
 655      let _, nonskipped, skipped, parsed_text_length =
 656        text_of_loc loc
 657      in
 658       eval_executable include_paths buffer guistuff lexicon_status
 659        grafite_status user_goal unparsed_text skipped nonskipped script ex loc
 660
 661 let fresh_script_id =
 662   let i = ref 0 in
 663   fun () -> incr i; !i
 664
 665 class script  ~(source_view: GSourceView.source_view)
 666               ~(mathviewer: MatitaTypes.mathViewer)
 667               ~set_star
 668               ~ask_confirmation
 669               ~urichooser
 670               () =
 671 let buffer = source_view#buffer in
 672 let source_buffer = source_view#source_buffer in
 673 let initial_statuses baseuri =
 674  let lexicon_status =
 675    CicNotation2.load_notation ~include_paths:[]
 676      BuildTimeConf.core_notation_script
 677  in
 678  let grafite_status = GrafiteSync.init baseuri in
 679   grafite_status,lexicon_status
 680 in
 681 let read_include_paths file =
 682  try
 683    let root, _buri, _fname, _tgt =
 684      Librarian.baseuri_of_script ~include_paths:[] file
 685    in
 686    let rc =
 687     Str.split (Str.regexp " ")
 688      (List.assoc "include_paths" (Librarian.load_root_file (root^"/root")))
 689    in
 690    List.iter (HLog.debug) rc; rc
 691  with Librarian.NoRootFor _ | Not_found -> []
 692 in
 693 let default_buri = "cic:/matita/tests" in
 694 let default_fname = ".unnamed.ma" in
 695 object (self)
 696   val mutable include_paths_ = []
 697
 698   val scriptId = fresh_script_id ()
 699
 700   val guistuff = {
 701     mathviewer = mathviewer;
 702     urichooser = urichooser;
 703     ask_confirmation = ask_confirmation;
 704   }
 705
 706   val mutable filename_ = (None : string option)
 707
 708   method has_name = filename_ <> None
 709
 710   method include_paths =
 711     include_paths_ @
 712     Helm_registry.get_list Helm_registry.string "matita.includes"
 713
 714   method private curdir =
 715     try
 716      let root, _buri, _fname, _tgt =
 717        Librarian.baseuri_of_script ~include_paths:self#include_paths
 718        self#filename
 719      in
 720      root
 721     with Librarian.NoRootFor _ -> Sys.getcwd ()
 722
 723   method buri_of_current_file =
 724     match filename_ with
 725     | None -> default_buri
 726     | Some f ->
 727         try
 728           let _root, buri, _fname, _tgt =
 729             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 730           in
 731           buri
 732         with Librarian.NoRootFor _ -> default_buri
 733
 734   method filename = match filename_ with None -> default_fname | Some f -> f
 735
 736   initializer
 737     ignore (GMain.Timeout.add ~ms:300000
 738        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 739     ignore (buffer#connect#modified_changed
 740       (fun _ -> set_star buffer#modified))
 741
 742   val mutable statements = []    (** executed statements *)
 743
 744   val mutable history = [ initial_statuses default_buri ]
 745     (** list of states before having executed statements. Head element of this
 746       * list is the current state, last element is the state at the beginning of
 747       * the script.
 748       * Invariant: this list length is 1 + length of statements *)
 749
 750   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 751   val mutable userGoal = None
 752
 753   (** text mark and tag representing locked part of a script *)
 754   val locked_mark =
 755     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 756   val beginning_of_statement_mark =
 757     buffer#create_mark ~name:"beginning_of_statement"
 758      ~left_gravity:true buffer#start_iter
 759   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 760   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 761
 762   method locked_mark = locked_mark
 763   method locked_tag = locked_tag
 764   method error_tag = error_tag
 765
 766     (* history can't be empty, the invariant above grant that it contains at
 767      * least the init grafite_status *)
 768   method grafite_status = match history with (s,_)::_ -> s | _ -> assert false
 769   method lexicon_status = match history with (_,ss)::_ -> ss | _ -> assert false
 770
 771   method private _advance ?statement () =
 772    let s = match statement with Some s -> s | None -> self#getFuture in
 773    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 774    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 775    let entries, newtext, parsed_len =
 776     try
 777      eval_statement self#include_paths buffer guistuff self#lexicon_status
 778       self#grafite_status userGoal self (`Raw s)
 779     with End_of_file -> raise Margin
 780    in
 781    let new_statuses, new_statements =
 782      let statuses, texts = List.split entries in
 783      statuses, texts
 784    in
 785    history <- new_statuses @ history;
 786    statements <- new_statements @ statements;
 787    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 788    let new_text = String.concat "" (List.rev new_statements) in
 789    if statement <> None then
 790      buffer#insert ~iter:start new_text
 791    else begin
 792      let parsed_text = String.sub s 0 parsed_len in
 793      if new_text <> parsed_text then begin
 794        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 795        buffer#delete ~start ~stop;
 796        buffer#insert ~iter:start new_text;
 797      end;
 798    end;
 799    self#moveMark (Glib.Utf8.length new_text);
 800    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext;
 801    (* here we need to set the Goal in case we are going to cursor (or to
 802       bottom) and we will face a macro *)
 803    match self#grafite_status.proof_status with
 804       Incomplete_proof p ->
 805        userGoal <-
 806          (try Some (Continuationals.Stack.find_goal p.stack)
 807          with Failure _ -> None)
 808     | _ -> userGoal <- None
 809
 810   method private _retract offset lexicon_status grafite_status new_statements
 811    new_history
 812   =
 813    let cur_grafite_status,cur_lexicon_status =
 814     match history with s::_ -> s | [] -> assert false
 815    in
 816     LexiconSync.time_travel ~present:cur_lexicon_status ~past:lexicon_status;
 817     GrafiteSync.time_travel ~present:cur_grafite_status ~past:grafite_status;
 818     statements <- new_statements;
 819     history <- new_history;
 820     self#moveMark (- offset)
 821
 822   method advance ?statement () =
 823     try
 824       self#_advance ?statement ();
 825       self#notify
 826     with
 827     | Margin -> self#notify
 828     | Not_found -> assert false
 829     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 830     | exc -> self#notify; raise exc
 831
 832   method retract () =
 833     try
 834       let cmp,new_statements,new_history,(grafite_status,lexicon_status) =
 835        match statements,history with
 836           stat::statements, _::(status::_ as history) ->
 837            assert (Glib.Utf8.validate stat);
 838            Glib.Utf8.length stat, statements, history, status
 839        | [],[_] -> raise Margin
 840        | _,_ -> assert false
 841       in
 842        self#_retract cmp lexicon_status grafite_status new_statements
 843         new_history;
 844        self#notify
 845     with
 846     | Margin -> self#notify
 847     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 848     | exc -> self#notify; raise exc
 849
 850   method private getFuture =
 851     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 852       ~stop:buffer#end_iter ()
 853
 854
 855   (** @param rel_offset relative offset from current position of locked_mark *)
 856   method private moveMark rel_offset =
 857     let mark = `MARK locked_mark in
 858     let old_insert = buffer#get_iter_at_mark `INSERT in
 859     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 860     let current_mark_pos = buffer#get_iter_at_mark mark in
 861     let new_mark_pos =
 862       match rel_offset with
 863       | 0 -> current_mark_pos
 864       | n when n > 0 -> current_mark_pos#forward_chars n
 865       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 866     in
 867     buffer#move_mark mark ~where:new_mark_pos;
 868     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 869     buffer#move_mark `INSERT old_insert;
 870     let mark_position = buffer#get_iter_at_mark mark in
 871     if source_view#move_mark_onscreen mark then
 872      begin
 873       buffer#move_mark mark mark_position;
 874       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 875      end;
 876     while Glib.Main.pending () do ignore(Glib.Main.iteration false); done
 877
 878   method clean_dirty_lock =
 879     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 880     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 881     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 882
 883   val mutable observers = []
 884
 885   method addObserver (o: LexiconEngine.status -> GrafiteTypes.status -> unit) =
 886     observers <- o :: observers
 887
 888   method private notify =
 889     let lexicon_status = self#lexicon_status in
 890     let grafite_status = self#grafite_status in
 891     List.iter (fun o -> o lexicon_status grafite_status) observers
 892
 893   method loadFromString s =
 894     buffer#set_text s;
 895     self#reset_buffer;
 896     buffer#set_modified true
 897
 898   method loadFromFile f =
 899     buffer#set_text (HExtlib.input_file f);
 900     self#reset_buffer;
 901     buffer#set_modified false
 902
 903   method assignFileName file =
 904     let file =
 905       match file with
 906       | Some f -> Some (Librarian.absolutize f)
 907       | None -> None
 908     in
 909     self#goto_top;
 910     filename_ <- file;
 911     include_paths_ <-
 912       (match file with Some file -> read_include_paths file | None -> []);
 913     self#reset_buffer;
 914     Sys.chdir self#curdir;
 915     HLog.debug ("Moving to " ^ Sys.getcwd ())
 916
 917   method saveToFile () =
 918     if self#has_name then
 919       let oc = open_out self#filename in
 920       output_string oc (buffer#get_text ~start:buffer#start_iter
 921                         ~stop:buffer#end_iter ());
 922       close_out oc;
 923       set_star false;
 924       buffer#set_modified false
 925     else
 926       HLog.error "Can't save, no filename selected"
 927
 928   method private _saveToBackupFile () =
 929     if buffer#modified then
 930       begin
 931         let f = self#filename in
 932         let oc = open_out f in
 933         output_string oc (buffer#get_text ~start:buffer#start_iter
 934                             ~stop:buffer#end_iter ());
 935         close_out oc;
 936         HLog.debug ("backup " ^ f ^ " saved")
 937       end
 938
 939   method private goto_top =
 940     let grafite_status,lexicon_status =
 941       let rec last x = function
 942       | [] -> x
 943       | hd::tl -> last hd tl
 944       in
 945       last (self#grafite_status,self#lexicon_status) history
 946     in
 947     (* FIXME: this is not correct since there is no undo for
 948      * library_objects.set_default... *)
 949     GrafiteSync.time_travel ~present:self#grafite_status ~past:grafite_status;
 950     LexiconSync.time_travel ~present:self#lexicon_status ~past:lexicon_status
 951
 952   method private reset_buffer =
 953     statements <- [];
 954     history <- [ initial_statuses self#buri_of_current_file ];
 955     userGoal <- None;
 956     self#notify;
 957     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 958     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 959
 960   method reset () =
 961     self#reset_buffer;
 962     source_buffer#begin_not_undoable_action ();
 963     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 964     source_buffer#end_not_undoable_action ();
 965     buffer#set_modified false;
 966
 967   method template () =
 968     let template = HExtlib.input_file BuildTimeConf.script_template in
 969     buffer#insert ~iter:(buffer#get_iter `START) template;
 970     buffer#set_modified false;
 971     set_star false
 972
 973   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 974   try
 975     let old_locked_mark =
 976      `MARK
 977        (buffer#create_mark ~name:"old_locked_mark"
 978          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 979     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 980     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 981     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 982     match pos with
 983     | `Top ->
 984         dispose_old_locked_mark ();
 985         self#goto_top;
 986         self#reset_buffer;
 987         self#notify
 988     | `Bottom ->
 989         (try
 990           let rec dowhile () =
 991             self#_advance ();
 992             let newpos = getpos () in
 993             if (getoldpos ())#compare newpos < 0 then
 994               begin
 995                 buffer#move_mark old_locked_mark newpos;
 996                 dowhile ()
 997               end
 998           in
 999           dowhile ();
1000           dispose_old_locked_mark ();
1001           self#notify
1002         with
1003         | Margin -> dispose_old_locked_mark (); self#notify
1004         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
1005     | `Cursor ->
1006         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
1007         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
1008         let remember =
1009          `MARK
1010            (buffer#create_mark ~name:"initial_insert"
1011              ~left_gravity:true (cursor_iter ())) in
1012         let dispose_remember () = buffer#delete_mark remember in
1013         let remember_iter () =
1014          buffer#get_iter_at_mark (`NAME "initial_insert") in
1015         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
1016         let icmp = cmp () in
1017         let forward_until_cursor () = (* go forward until locked > cursor *)
1018           let rec aux () =
1019             self#_advance ();
1020             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
1021             then
1022              begin
1023               buffer#move_mark old_locked_mark (getpos ());
1024               aux ()
1025              end
1026           in
1027           aux ()
1028         in
1029         let rec back_until_cursor len = (* go backward until locked < cursor *)
1030          function
1031             statements, ((grafite_status,lexicon_status)::_ as history)
1032             when len <= 0 ->
1033              self#_retract (icmp - len) lexicon_status grafite_status statements
1034               history
1035           | statement::tl1, _::tl2 ->
1036              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
1037           | _,_ -> assert false
1038         in
1039         (try
1040           begin
1041            if icmp < 0 then       (* locked < cursor *)
1042              (forward_until_cursor (); self#notify)
1043            else if icmp > 0 then  (* locked > cursor *)
1044              (back_until_cursor icmp (statements,history); self#notify)
1045            else                  (* cursor = locked *)
1046                ()
1047           end ;
1048           dispose_remember ();
1049           dispose_old_locked_mark ();
1050         with
1051         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
1052         | exc -> dispose_remember (); dispose_old_locked_mark ();
1053                  self#notify; raise exc)
1054   with Invalid_argument "Array.make" ->
1055      HLog.error "The script is too big!\n"
1056
1057   method onGoingProof () =
1058     match self#grafite_status.proof_status with
1059     | No_proof | Proof _ -> false
1060     | Incomplete_proof _ -> true
1061     | Intermediate _ -> assert false
1062
1063 (*   method proofStatus = MatitaTypes.get_proof_status self#status *)
1064   method proofMetasenv = GrafiteTypes.get_proof_metasenv self#grafite_status
1065
1066   method proofContext =
1067    match userGoal with
1068       None -> []
1069     | Some n -> GrafiteTypes.get_proof_context self#grafite_status n
1070
1071   method proofConclusion =
1072    match userGoal with
1073       None -> assert false
1074     | Some n ->
1075        GrafiteTypes.get_proof_conclusion self#grafite_status n
1076
1077   method stack = GrafiteTypes.get_stack self#grafite_status
1078   method setGoal n = userGoal <- n
1079   method goal = userGoal
1080
1081   method bos =
1082     match history with
1083     | _::[] -> true
1084     | _ -> false
1085
1086   method eos =
1087     let rec is_there_only_comments lexicon_status s =
1088       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
1089       let lexicon_status,st =
1090        GrafiteParser.parse_statement (Ulexing.from_utf8_string s)
1091         ~include_paths:self#include_paths lexicon_status
1092       in
1093       match st with
1094       | GrafiteParser.LSome (GrafiteAst.Comment (loc,_)) ->
1095           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
1096           (* CSC: why +1 in the following lines ???? *)
1097           let parsed_text_length = parsed_text_length + 1 in
1098           let remain_len = String.length s - parsed_text_length in
1099           let next = String.sub s parsed_text_length remain_len in
1100           is_there_only_comments lexicon_status next
1101       | GrafiteParser.LNone _
1102       | GrafiteParser.LSome (GrafiteAst.Executable _) -> false
1103     in
1104     try
1105       is_there_only_comments self#lexicon_status self#getFuture
1106     with
1107     | LexiconEngine.IncludedFileNotCompiled _
1108     | HExtlib.Localized _
1109     | CicNotationParser.Parse_error _ -> false
1110     | Margin | End_of_file -> true
1111     | Invalid_argument "Array.make" -> false
1112
1113   (* debug *)
1114   method dump () =
1115     HLog.debug "script status:";
1116     HLog.debug ("history size: " ^ string_of_int (List.length history));
1117     HLog.debug (sprintf "%d statements:" (List.length statements));
1118     List.iter HLog.debug statements;
1119     HLog.debug ("Current file name: " ^ self#filename);
1120 end
1121
1122 let _script = ref None
1123
1124 let script ~source_view ~mathviewer ~urichooser ~ask_confirmation ~set_star ()
1125 =
1126   let s = new script
1127     ~source_view ~mathviewer ~ask_confirmation ~urichooser ~set_star ()
1128   in
1129   _script := Some s;
1130   s
1131
1132 let current () = match !_script with None -> assert false | Some s -> s
1133